Config transition turns label-type attributes into lists

[adam-azarchs]

Description of the bug:

Setting cfg with a transition in attr.Label makes ctx.attr.<attribute> return a label list instead of a single label. See example below.

It's quite possible that this is intended behavior. Certainly for a one-to-many transition it would need to have this effect. In that case this is really a documentation problem, because it certainly isn't obvious that changing the configuration should change the type of the attribute value (and in fact the docs for the cfg parameter make no mention of transitions, though it does link to the docs on configurations, which do, but still don't mention anything about the type change).

What's the simplest, easiest way to reproduce this bug? Please provide a minimal example if possible.

WORKSPACE:

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "bazel_skylib",
    sha256 = "f7be3474d42aae265405a592bb7da8e171919d74c16f082a5457840f06054728",
    urls = [
        "https://mirror.bazel.build/github.com/bazelbuild/bazel-skylib/releases/download/1.2.1/bazel-skylib-1.2.1.tar.gz",
        "https://github.com/bazelbuild/bazel-skylib/releases/download/1.2.1/bazel-skylib-1.2.1.tar.gz",
    ],
)

BUILD.bazel:

load("@bazel_skylib//rules:common_settings.bzl", "string_setting")
load(":my_rule.bzl", "my_rule", "my_transition_rule")

string_setting(
    name = "kind",
    build_setting_default = "baz",
    values = [
        "bar",
        "baz",
    ],
)

filegroup(
    name = "empty",
)

my_rule(
    name = "without_transition",
    src = ":empty",
)

my_transition_rule(
    name = "with_transition",
    src = ":empty",
)

my_rule.bzl:

def _foo_transition_impl(settings, attr):
    _ignore = settings  # buildifier: disable=unused-variable
    return {
        "//:kind": "bar",
    }

_foo_transition = transition(
    implementation = _foo_transition_impl,
    inputs = [],
    outputs = ["//:kind"],
)

def _rule_impl(ctx):
    print(type(ctx.attr.src))

my_rule = rule(
    attrs = {
        "src": attr.label(
            cfg = "target",
        ),
    },
    implementation = _rule_impl,
)

my_transition_rule = rule(
    attrs = {
        "src": attr.label(
            cfg = _foo_transition,
        ),
        "_allowlist_function_transition": attr.label(
            default = "@bazel_tools//tools/allowlists/function_transition_allowlist",
        ),
    },
    implementation = _rule_impl,
)

$ bazel build :without_transition :with_transition
DEBUG: my_rule.bzl:14:10: Target
DEBUG: my_rule.bzl:14:10: list

Which operating system are you running Bazel on?

linux

What is the output of bazel info release?

release 5.2.0

If bazel info release returns development version or (@non-git), tell us how you built Bazel.

No response

What's the output of git remote get-url origin; git rev-parse master; git rev-parse HEAD ?

No response

Have you found anything relevant by searching the web?

Open issue tracking documentation (and lack thereof) for transitions:
#8377

Any other information, logs, or outputs that you want to share?

No response

[pcjanzen]

The behavior you're seeing is documented at https://bazel.build/rules/config#accessing-attributes-with-transitions

When attaching a transition to an outgoing edge (regardless of whether the transition is a 1:1 or 1:2+ transition), ctx.attr is forced to be a list if it isn't already. The order of elements in this list is unspecified.

[adam-azarchs]

So it does! In my defense, that document is a bit of a wall of text. It might be a good idea to link to that later section from https://bazel.build/rules/config#outgoing-edge-transitions, to aid others who might stop reading after the section which appears to tell them what they need to know.

[adam-azarchs]

This was closed by #15895