/
AstyanaxPersistenceMethods.groovy
325 lines (281 loc) · 8.48 KB
/
AstyanaxPersistenceMethods.groovy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
/*
* Copyright 2012 ReachLocal Inc.
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
package com.reachlocal.grails.plugins.cassandra.astyanax
import com.netflix.astyanax.model.ColumnFamily
import com.netflix.astyanax.serializers.StringSerializer
import com.netflix.astyanax.model.ConsistencyLevel
import com.reachlocal.grails.plugins.cassandra.mapping.PersistenceProvider;
/**
* @author: Bob Florian
*/
class AstyanaxPersistenceMethods implements PersistenceProvider
{
// Read operations
def columnFamily(String name)
{
new ColumnFamily(name.toString(), StringSerializer.get(), StringSerializer.get())
}
def columnFamilyName(columnFamily)
{
columnFamily.name
}
def getRow(Object client, Object columnFamily, Object rowKey, consistencyLevel)
{
def cols = injectConsistencyLevel(client.prepareQuery(columnFamily), consistencyLevel).getKey(rowKey).execute().result
cols.isEmpty() ? null : cols
}
def getRows(Object client, Object columnFamily, Collection rowKeys, consistencyLevel)
{
injectConsistencyLevel(client.prepareQuery(columnFamily), consistencyLevel).getKeySlice(rowKeys).execute().result
}
def getRowsColumnSlice(Object client, Object columnFamily, Collection rowKeys, Collection columnNames, consistencyLevel)
{
injectConsistencyLevel(client.prepareQuery(columnFamily), consistencyLevel).getKeySlice(rowKeys).withColumnSlice(columnNames).execute().result
}
def getRowsColumnRange(Object client, Object columnFamily, Collection rowKeys, Object start, Object finish, Boolean reversed, Integer max, consistencyLevel)
{
injectConsistencyLevel(client.prepareQuery(columnFamily), consistencyLevel).getKeySlice(rowKeys)
.withColumnRange(start, finish, reversed, max)
.execute()
.result
}
def getRowsWithEqualityIndex(client, columnFamily, properties, max, consistencyLevel)
{
def exp = properties.collect {name, value ->
columnFamily.newIndexClause().whereColumn(name).equals().value(value)
}
injectConsistencyLevel(client.prepareQuery(columnFamily), consistencyLevel)
.searchWithIndex()
.setRowLimit(max)
.addPreparedExpressions(exp)
.execute()
.result
}
def countRowsWithEqualityIndex(client, columnFamily, properties, consistencyLevel)
{
def clause = properties.collect {name, value -> "${name} = '${value}'"}.join(" AND ")
def query = "SELECT COUNT(*) FROM ${columnFamily.name} WHERE ${clause}"
injectConsistencyLevel(client.prepareQuery(columnFamily), consistencyLevel)
.withCql(query)
.execute()
.result
.rows
.getRowByIndex(0)
.columns
.getColumnByIndex(0)
.longValue
}
def getRowsWithCqlWhereClause(client, columnFamily, clause, max, consistencyLevel)
{
def query = "SELECT * FROM ${columnFamily.name} WHERE ${clause} LIMIT ${max}"
injectConsistencyLevel(client.prepareQuery(columnFamily), consistencyLevel)
.withCql(query)
.execute()
.result
}
def getRowsColumnSliceWithCqlWhereClause(client, columnFamily, clause, max, columns, consistencyLevel)
{
def query = "SELECT ${columns.join(', ')} FROM ${columnFamily.name} WHERE ${clause} LIMIT ${max}"
injectConsistencyLevel(client.prepareQuery(columnFamily), consistencyLevel)
.withCql(query)
.execute()
.result
}
def countRowsWithCqlWhereClause(client, columnFamily, clause, consistencyLevel)
{
def query = "SELECT COUNT(*) FROM ${columnFamily.name} WHERE ${clause}"
injectConsistencyLevel(client.prepareQuery(columnFamily), consistencyLevel)
.withCql(query)
.execute()
.result
.rows
.getRowByIndex(0)
.columns
.getColumnByIndex(0)
.longValue
}
def getColumnRange(Object client, Object columnFamily, Object rowKey, Object start, Object finish, Boolean reversed, Integer max, consistencyLevel)
{
injectConsistencyLevel(client.prepareQuery(columnFamily).getKey(rowKey), consistencyLevel)
.withColumnRange(start, finish, reversed, max)
.execute()
.result
}
def countColumnRange(Object client, Object columnFamily, Object rowKey, Object start, Object finish, consistencyLevel)
{
def row = injectConsistencyLevel(client.prepareQuery(columnFamily), consistencyLevel).getKey(rowKey)
if (start || finish) {
row = row.withColumnRange(start, finish, false, Integer.MAX_VALUE)
}
row.getCount()
.execute()
.result
}
def getColumnSlice(Object client, Object columnFamily, Object rowKey, Collection columnNames, consistencyLevel)
{
injectConsistencyLevel(client.prepareQuery(columnFamily), consistencyLevel).getKey(rowKey)
.withColumnSlice(columnNames)
.execute()
.result
}
def getColumn(Object client, Object columnFamily, Object rowKey, Object columnName, consistencyLevel)
{
injectConsistencyLevel(client.prepareQuery(columnFamily), consistencyLevel).getKey(rowKey)
.getColumn(columnName)
.execute()
.result
}
def prepareMutationBatch(client, ConsistencyLevel consistencyLevel)
{
def m = client.prepareMutationBatch()
if (consistencyLevel) {
m.setConsistencyLevel(consistencyLevel)
}
return m
}
def prepareMutationBatch(client, consistencyLevel)
{
def m = client.prepareMutationBatch()
if (consistencyLevel) {
m.setConsistencyLevel(ConsistencyLevel.valueOf(consistencyLevel))
}
return m
}
void deleteColumn(mutationBatch, columnFamily, rowKey, columnName)
{
mutationBatch.withRow(columnFamily, rowKey).deleteColumn(columnName)
}
void putColumn(mutationBatch, columnFamily, rowKey, name, value)
{
mutationBatch.withRow(columnFamily, rowKey).putColumn(name, value)
}
void putColumn(mutationBatch, columnFamily, rowKey, name, value, ttl)
{
mutationBatch.withRow(columnFamily, rowKey).putColumn(name, value, ttl)
}
void putColumns(mutationBatch, columnFamily, rowKey, columnMap)
{
def r = mutationBatch.withRow(columnFamily, rowKey)
columnMap.each {k, v ->
if (v != null) {
r.putColumn(k, v, null)
}
else {
r.deleteColumn(k)
}
}
}
void putColumns(mutationBatch, columnFamily, rowKey, columnMap, ttlMap)
{
def r = mutationBatch.withRow(columnFamily, rowKey)
if (ttlMap instanceof Number) {
columnMap.each {k, v ->
if (v != null) {
r.putColumn(k, v, ttlMap)
}
else {
r.deleteColumn(k)
}
}
}
else {
columnMap.each {k, v ->
if (v != null) {
r.putColumn(k, v, ttlMap[k])
}
else {
r.deleteColumn(k)
}
}
}
}
void incrementCounterColumn(mutationBatch, columnFamily, rowKey, columnName)
{
mutationBatch.withRow(columnFamily, rowKey).incrementCounterColumn(columnName, 1)
}
void incrementCounterColumn(mutationBatch, columnFamily, rowKey, columnName, Long value)
{
mutationBatch.withRow(columnFamily, rowKey).incrementCounterColumn(columnName, value)
}
void incrementCounterColumns(mutationBatch, columnFamily, rowKey, columnMap)
{
mutationBatch.withRow(columnFamily, rowKey).incrementCounterColumns(columnMap)
}
void deleteRow(mutationBatch, columnFamily, rowKey)
{
mutationBatch.deleteRow([columnFamily], rowKey)
}
def execute(mutationBatch)
{
mutationBatch.execute()
}
def getRow(rows, key)
{
rows.getRow(key).columns
}
def getRowKey(row)
{
row.key
}
Iterable getColumns(row)
{
row.columns
}
def getColumn(row, name)
{
row.getColumnByName(name)
}
def getColumnByIndex(row, index)
{
row.getColumnByIndex(index)
}
def name(column)
{
column.name
}
String stringValue(column)
{
column.stringValue
}
byte[] byteArrayValue(column)
{
column.byteArrayValue
}
def longValue(column)
{
column.longValue
}
private injectConsistencyLevel(query, ConsistencyLevel consistencyLevel)
{
if (consistencyLevel) {
query.setConsistencyLevel(consistencyLevel)
}
return query
}
private injectConsistencyLevel(query, String consistencyLevel)
{
if (consistencyLevel) {
def cl = ConsistencyLevel.valueOf(consistencyLevel)
if (cl) {
query.setConsistencyLevel(cl)
}
else {
throw new IllegalArgumentException("'${consistencyLevel}' is not a valid ConsistencyLevel, must be one of [CL_ONE, CL_QUORUM, CL_ALL, CL_ANY, CL_EACH_QUORUM, CL_LOCAL_QUORUM, CL_TWO, CL_THREE]")
}
}
return query
}
}