Add MaybeK type in the launcher lib

lib/launcher/cardano-wallet-launcher.cabal

@@ -46,10 +46,11 @@ library
   hs-source-dirs:
       src
   exposed-modules:
-      Cardano.Launcher
-    , Cardano.Launcher.Node
-      Cardano.Launcher.Wallet
-    , Cardano.Startup
+    Cardano.Launcher
+    Cardano.Launcher.Node
+    Cardano.Launcher.Wallet
+    Cardano.Startup
+    Data.MaybeK
   if os(windows)
     build-depends: Win32
     other-modules: Cardano.Startup.Windows

lib/launcher/src/Data/MaybeK.hs

@@ -0,0 +1,34 @@
+{-# LANGUAGE DataKinds #-}
+{-# LANGUAGE GADTs #-}
+{-# LANGUAGE StandaloneDeriving #-}
+
+module Data.MaybeK
+    ( MaybeK (..)
+    , Presence (..)
+    , fmapMaybeK
+    , maybeOfMaybeK
+    )
+where
+
+import Prelude
+
+-- | A type level tag to indicate whether a value is present or not.
+data Presence = Present | Absent
+
+-- | A Maybe carring the type level tag.
+data MaybeK x a where
+    NothingK :: MaybeK x Absent
+    JustK :: x -> MaybeK x Present
+
+deriving instance Show x => Show (MaybeK x a)
+deriving instance Eq x => Eq (MaybeK x a)
+
+-- | Map a function over a MaybeK.
+fmapMaybeK :: (x -> y) -> MaybeK x a -> MaybeK y a
+fmapMaybeK _ NothingK = NothingK
+fmapMaybeK f (JustK x) = JustK (f x)
+
+-- | Convert a MaybeK to a Maybe, dropping the type level tag.
+maybeOfMaybeK :: MaybeK x a -> Maybe x
+maybeOfMaybeK NothingK = Nothing
+maybeOfMaybeK (JustK x) = Just x