Add -v flag to print build version

Version string is generated using `git describe` and some CMake magic.

CMakeLists.txt

@@ -15,11 +15,23 @@ elseif(${UNIX})
   target_link_libraries(img2ktx PRIVATE m)
 endif()
 
+# Update build_version.h whenever current commit changes
+# c/o https://github.com/rpavlik/cmake-modules/blob/master/GetGitRevisionDescription.cmake
+# c/o https://stackoverflow.com/a/4318642
+list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_LIST_DIR}/cmake/)
+include(GetGitRevisionDescription)
+git_describe(GIT_DESCRIBE_RESULT --tags --always)
+configure_file(${CMAKE_CURRENT_LIST_DIR}/build_version.cpp.in ${CMAKE_CURRENT_BINARY_DIR}/build_version.cpp @ONLY)
+target_sources(img2ktx PRIVATE
+  ${CMAKE_CURRENT_BINARY_DIR}/build_version.cpp
+  ${CMAKE_CURRENT_LIST_DIR}/build_version.h
+)
+
 find_library(IMG2KTX_ISPC_TEXCOMP_LIB
   ispc_texcomp
   PATHS ${CMAKE_CURRENT_SOURCE_DIR} # Finds the pre-build Windows binary as a last resort
   DOC "the ispc_texcomp library to link against"
 )
 target_link_libraries(img2ktx PRIVATE ${IMG2KTX_ISPC_TEXCOMP_LIB})
 
-add_subdirectory(third_party)
+add_subdirectory(third_party)

build_version.cpp.in

@@ -0,0 +1 @@
+const char* img2ktx_build_version = "@GIT_DESCRIBE_RESULT@";

build_version.h

@@ -0,0 +1,2 @@
+#pragma once
+extern const char* img2ktx_build_version;

cmake/GetGitRevisionDescription.cmake

@@ -0,0 +1,172 @@
+# - Returns a version string from Git
+#
+# These functions force a re-configure on each git commit so that you can
+# trust the values of the variables in your build system.
+#
+#  get_git_head_revision(<refspecvar> <hashvar> [<additional arguments to git describe> ...])
+#
+# Returns the refspec and sha hash of the current head revision
+#
+#  git_describe(<var> [<additional arguments to git describe> ...])
+#
+# Returns the results of git describe on the source tree, and adjusting
+# the output so that it tests false if an error occurs.
+#
+#  git_get_exact_tag(<var> [<additional arguments to git describe> ...])
+#
+# Returns the results of git describe --exact-match on the source tree,
+# and adjusting the output so that it tests false if there was no exact
+# matching tag.
+#
+#  git_local_changes(<var>)
+#
+# Returns either "CLEAN" or "DIRTY" with respect to uncommitted changes.
+# Uses the return code of "git diff-index --quiet HEAD --".
+# Does not regard untracked files.
+#
+# Requires CMake 2.6 or newer (uses the 'function' command)
+#
+# Original Author:
+# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
+# http://academic.cleardefinition.com
+# Iowa State University HCI Graduate Program/VRAC
+#
+# Copyright Iowa State University 2009-2010.
+# Distributed under the Boost Software License, Version 1.0.
+# (See accompanying file LICENSE_1_0.txt or copy at
+# http://www.boost.org/LICENSE_1_0.txt)
+
+if(__get_git_revision_description)
+	return()
+endif()
+set(__get_git_revision_description YES)
+
+# We must run the following at "include" time, not at function call time,
+# to find the path to this module rather than the path to a calling list file
+get_filename_component(_gitdescmoddir ${CMAKE_CURRENT_LIST_FILE} PATH)
+
+function(get_git_head_revision _refspecvar _hashvar)
+	set(GIT_PARENT_DIR "${CMAKE_CURRENT_SOURCE_DIR}")
+	set(GIT_DIR "${GIT_PARENT_DIR}/.git")
+	while(NOT EXISTS "${GIT_DIR}")	# .git dir not found, search parent directories
+		set(GIT_PREVIOUS_PARENT "${GIT_PARENT_DIR}")
+		get_filename_component(GIT_PARENT_DIR ${GIT_PARENT_DIR} PATH)
+		if(GIT_PARENT_DIR STREQUAL GIT_PREVIOUS_PARENT)
+			# We have reached the root directory, we are not in git
+			set(${_refspecvar} "GITDIR-NOTFOUND" PARENT_SCOPE)
+			set(${_hashvar} "GITDIR-NOTFOUND" PARENT_SCOPE)
+			return()
+		endif()
+		set(GIT_DIR "${GIT_PARENT_DIR}/.git")
+	endwhile()
+	# check if this is a submodule
+	if(NOT IS_DIRECTORY ${GIT_DIR})
+		file(READ ${GIT_DIR} submodule)
+		string(REGEX REPLACE "gitdir: (.*)\n$" "\\1" GIT_DIR_RELATIVE ${submodule})
+		get_filename_component(SUBMODULE_DIR ${GIT_DIR} PATH)
+		get_filename_component(GIT_DIR ${SUBMODULE_DIR}/${GIT_DIR_RELATIVE} ABSOLUTE)
+	endif()
+	if(NOT IS_DIRECTORY "${GIT_DIR}")
+		file(READ ${GIT_DIR} worktree)
+ 		string(REGEX REPLACE "gitdir: (.*)worktrees(.*)\n$" "\\1" GIT_DIR ${worktree})
+ 	endif()
+	set(GIT_DATA "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/git-data")
+	if(NOT EXISTS "${GIT_DATA}")
+		file(MAKE_DIRECTORY "${GIT_DATA}")
+	endif()
+
+	if(NOT EXISTS "${GIT_DIR}/HEAD")
+		return()
+	endif()
+	set(HEAD_FILE "${GIT_DATA}/HEAD")
+	configure_file("${GIT_DIR}/HEAD" "${HEAD_FILE}" COPYONLY)
+
+	configure_file("${_gitdescmoddir}/GetGitRevisionDescription.cmake.in"
+		"${GIT_DATA}/grabRef.cmake"
+		@ONLY)
+	include("${GIT_DATA}/grabRef.cmake")
+
+	set(${_refspecvar} "${HEAD_REF}" PARENT_SCOPE)
+	set(${_hashvar} "${HEAD_HASH}" PARENT_SCOPE)
+endfunction()
+
+function(git_describe _var)
+	if(NOT GIT_FOUND)
+		find_package(Git QUIET)
+	endif()
+	get_git_head_revision(refspec hash)
+	if(NOT GIT_FOUND)
+		set(${_var} "GIT-NOTFOUND" PARENT_SCOPE)
+		return()
+	endif()
+	if(NOT hash)
+		set(${_var} "HEAD-HASH-NOTFOUND" PARENT_SCOPE)
+		return()
+	endif()
+
+	# TODO sanitize
+	#if((${ARGN}" MATCHES "&&") OR
+	#	(ARGN MATCHES "||") OR
+	#	(ARGN MATCHES "\\;"))
+	#	message("Please report the following error to the project!")
+	#	message(FATAL_ERROR "Looks like someone's doing something nefarious with git_describe! Passed arguments ${ARGN}")
+	#endif()
+
+	#message(STATUS "Arguments to execute_process: ${ARGN}")
+
+	execute_process(COMMAND
+		"${GIT_EXECUTABLE}"
+		describe
+		${hash}
+		${ARGN}
+		WORKING_DIRECTORY
+		"${CMAKE_CURRENT_SOURCE_DIR}"
+		RESULT_VARIABLE
+		res
+		OUTPUT_VARIABLE
+		out
+		ERROR_QUIET
+		OUTPUT_STRIP_TRAILING_WHITESPACE)
+	if(NOT res EQUAL 0)
+		set(out "${out}-${res}-NOTFOUND")
+	endif()
+
+	set(${_var} "${out}" PARENT_SCOPE)
+endfunction()
+
+function(git_get_exact_tag _var)
+	git_describe(out --exact-match ${ARGN})
+	set(${_var} "${out}" PARENT_SCOPE)
+endfunction()
+
+function(git_local_changes _var)
+	if(NOT GIT_FOUND)
+		find_package(Git QUIET)
+	endif()
+	get_git_head_revision(refspec hash)
+	if(NOT GIT_FOUND)
+		set(${_var} "GIT-NOTFOUND" PARENT_SCOPE)
+		return()
+	endif()
+	if(NOT hash)
+		set(${_var} "HEAD-HASH-NOTFOUND" PARENT_SCOPE)
+		return()
+	endif()
+
+	execute_process(COMMAND
+		"${GIT_EXECUTABLE}"
+		diff-index --quiet HEAD --
+		WORKING_DIRECTORY
+		"${CMAKE_CURRENT_SOURCE_DIR}"
+		RESULT_VARIABLE
+		res
+		OUTPUT_VARIABLE
+		out
+		ERROR_QUIET
+		OUTPUT_STRIP_TRAILING_WHITESPACE)
+	if(res EQUAL 0)
+		set(${_var} "CLEAN" PARENT_SCOPE)
+	else()
+		set(${_var} "DIRTY" PARENT_SCOPE)
+	endif()
+endfunction()

cmake/GetGitRevisionDescription.cmake.in

@@ -0,0 +1,41 @@
+#
+# Internal file for GetGitRevisionDescription.cmake
+#
+# Requires CMake 2.6 or newer (uses the 'function' command)
+#
+# Original Author:
+# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
+# http://academic.cleardefinition.com
+# Iowa State University HCI Graduate Program/VRAC
+#
+# Copyright Iowa State University 2009-2010.
+# Distributed under the Boost Software License, Version 1.0.
+# (See accompanying file LICENSE_1_0.txt or copy at
+# http://www.boost.org/LICENSE_1_0.txt)
+
+set(HEAD_HASH)
+
+file(READ "@HEAD_FILE@" HEAD_CONTENTS LIMIT 1024)
+
+string(STRIP "${HEAD_CONTENTS}" HEAD_CONTENTS)
+if(HEAD_CONTENTS MATCHES "ref")
+	# named branch
+	string(REPLACE "ref: " "" HEAD_REF "${HEAD_CONTENTS}")
+	if(EXISTS "@GIT_DIR@/${HEAD_REF}")
+		configure_file("@GIT_DIR@/${HEAD_REF}" "@GIT_DATA@/head-ref" COPYONLY)
+	else()
+		configure_file("@GIT_DIR@/packed-refs" "@GIT_DATA@/packed-refs" COPYONLY)
+		file(READ "@GIT_DATA@/packed-refs" PACKED_REFS)
+		if(${PACKED_REFS} MATCHES "([0-9a-z]*) ${HEAD_REF}")
+			set(HEAD_HASH "${CMAKE_MATCH_1}")
+		endif()
+	endif()
+else()
+	# detached HEAD
+	configure_file("@GIT_DIR@/HEAD" "@GIT_DATA@/head-ref" COPYONLY)
+endif()
+
+if(NOT HEAD_HASH)
+	file(READ "@GIT_DATA@/head-ref" HEAD_HASH LIMIT 1024)
+	string(STRIP "${HEAD_HASH}" HEAD_HASH)
+endif()

img2ktx.cpp

@@ -1,3 +1,5 @@
+#include "build_version.h"
+
 #include "ispc_texcomp.h"
 
 #pragma warning(push,3)
@@ -119,23 +121,29 @@ struct KtxHeader {
     uint32_t bytesOfKeyValueData;
 };
 
+void PrintVersion() {
+  fprintf(stdout, "img2ktx %s\n", img2ktx_build_version);
+}
+
 void PrintUsage(char *argv[]) {
-    fprintf(stderr, "Usage: %s [options] [input]\n", argv[0]);
-    fprintf(stderr, "options:\n");
-    fprintf(stderr, "  -o [out.ktx]      Output file [required]\n");
-    fprintf(stderr, "  -f [format]       Output format [required]\n");
-    fprintf(stderr, "  -r [width height] Resize input to width x height before conversion.\n");
-    fprintf(stderr, "                    Provided dimensions must both be >= 1.\n");
-    fprintf(stderr, "  -m                Enable mipmap generation\n");
-    fprintf(stderr, "  -c                Enable cubemap output. Each set of six input images will be\n");
-    fprintf(stderr, "                    treated as one cubemap. Face order is +X -X +Y -Y +Z -Z.\n");
-    fprintf(stderr, "  -q                Enable quiet mode (suppress non-error console output)\n");
-    fprintf(stderr, "  -h                Displays this help message\n");
-    fprintf(stderr, "formats:\n  ");
+    PrintVersion();
+    fprintf(stdout, "Usage: %s [options] [input]\n", argv[0]);
+    fprintf(stdout, R"options(options:
+  -o [out.ktx]      Output file [required]
+  -f [format]       Output format [required]
+  -r [width height] Resize input to width x height before conversion.
+                    Provided dimensions must both be >= 1.
+  -m                Enable mipmap generation
+  -c                Enable cubemap output. Each set of six input images will be
+                    treated as one cubemap. Face order is +X -X +Y -Y +Z -Z.
+  -q                Enable quiet mode (suppress non-error console output)
+  -h                Displays this help message
+  -v                Displays version information\)options");
+    fprintf(stdout, "formats:\n  ");
     for(int i=0; i<g_format_count; ++i) {
-        fprintf(stderr, "%s ", g_formats[i].name);
+        fprintf(stdout, "%s ", g_formats[i].name);
     }
-    fprintf(stderr, "\n");
+    fprintf(stdout, "\n");
 }
 
 #define qprintf(msg, ...) if (!quiet_mode) { printf( (msg), __VA_ARGS__); }
@@ -167,6 +175,10 @@ int main(int argc, char *argv[]) {
         } else if (strcmp("-h", argv[a]) == 0) {
             PrintUsage(argv);
             return 0;
+        }
+        else if (strcmp("-v", argv[a]) == 0) {
+          PrintVersion();
+          return 0;
         } else {
             // All remaining params are input filenames
             input_filenames.insert(input_filenames.end(), argv+a, argv+argc);