-
Notifications
You must be signed in to change notification settings - Fork 52
/
uTaskBarListProgress.pas
224 lines (183 loc) · 5.26 KB
/
uTaskBarListProgress.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
unit uTaskBarListProgress;
interface
uses
uTaskBarList,
jwaShlObj,
Controls,
Classes,
Windows,
jwaWinType,
ComCtrls,
Messages,
CommCtrl;
{$i JEDI.inc}
type
{$IFDEF DELPHI12_UP}
TTaskbarListProgressState = TProgressBarState;
{$ELSE}
TTaskbarListProgressState = (pbsNormal,
pbsError,
pbsPaused);
{$ENDIF}
TTaskbarListProgress = class(TTaskBarListComponent)
private
FMin,
FMax,
FPosition : ULONGLONG;
FProgressbar : TProgressbar;
FOrigProgressWndProc : ULong;
FState: TTaskbarListProgressState;
FMarquee: Boolean;
procedure SetMax(const Value: ULONGLONG);
procedure SetMin(const Value: ULONGLONG);
procedure SetPosition(const Value: ULONGLONG);
procedure SetState(const Value: TTaskbarListProgressState);
procedure SetProgressbar(const Value: TProgressBar);
procedure SetMarquee(const Value: Boolean);
protected
procedure DoUpdate; override;
procedure Notification(AComponent: TComponent; Operation: TOperation); override;
public
constructor Create(AOwner: TComponent); override;
destructor Destroy; override;
published
property Min : ULONGLONG read FMin write SetMin default 0;
property Max : ULONGLONG read FMax write SetMax default 100;
property Position : ULONGLONG read FPosition write SetPosition default 0;
property State : TTaskbarListProgressState read FState write SetState default pbsNormal;
property ProgressBar : TProgressBar read FProgressBar write SetProgressbar;
property Marquee : Boolean read FMarquee write SetMarquee default false;
end;
implementation
uses
SysUtils;
var
Progresses : TList;
function MyWndProc(hwnd : HWND; uMsg : UINT; wParam : WPARAM; lParam : LPARAM) : LRESULT; stdcall;
var
idx : Integer;
prog : TTaskbarListProgress;
begin
Result:=0;
for idx := 0 to Progresses.Count - 1 do
begin
prog := TTaskbarListProgress(Progresses[idx]);
if Assigned(Prog.ProgressBar) and
(hwnd = Prog.ProgressBar.Handle) then
begin
Result := CallWindowProc(Pointer(Prog.FOrigProgressWndProc), hwnd, uMsg, wParam, lParam);
case uMsg of
PBM_SETRANGE..PBM_SETRANGE32
{$IFDEF DELPHI12_UP}, PBM_SETMARQUEE, PBM_SETSTATE{$ENDIF}:
Prog.PostUpdateMessage;
end;
end;
end;
end;
{ TTaskbarListProgress }
constructor TTaskbarListProgress.Create(AOwner: TComponent);
begin
inherited;
FState := pbsNormal;
FMin := 0;
FMax := 100;
FPosition := 0;
FProgressbar := nil;
FMarquee := false;
Progresses.Add(Self);
FInitialized:=True;
end;
destructor TTaskbarListProgress.Destroy;
begin
Progresses.Remove(Self);
ProgressBar := nil;
inherited;
end;
procedure TTaskbarListProgress.DoUpdate;
var
NewState : DWORD;
begin
inherited;
if Assigned(FProgressbar) then
begin
FMin := FProgressbar.Min;
FMax := FProgressbar.Max;
FPosition := FProgressbar.Position;
{$IFDEF DELPHI12_UP}
FState := FProgressbar.State;
FMarquee := FProgressbar.Style = pbstMarquee;
{$ENDIF}
end;
if Assigned(FTaskbarList3) and CheckWin32Version(6,1) then
begin
if not FMarquee then
FTaskbarList3.SetProgressValue(TaskBarEntryHandle, FPosition - FMin, FMax - FMin);
if (FPosition = FMin) and (not FMarquee) then
begin
NewState := TBPF_NOPROGRESS;
end
else
begin
case FState of
pbsNormal: NewState := TBPF_NORMAL;
pbsPaused: NewState := TBPF_PAUSED;
pbsError: NewState := TBPF_ERROR;
end;
end;
FTaskbarList3.SetProgressState(TaskBarEntryHandle, NewState);
if FMarquee then
FTaskbarList3.SetProgressState(TaskBarEntryHandle, TBPF_INDETERMINATE);
end;
end;
procedure TTaskbarListProgress.Notification(AComponent: TComponent;
Operation: TOperation);
begin
inherited;
if (AComponent = FProgressbar) and (Operation = opRemove) then
FProgressbar := nil;
end;
procedure TTaskbarListProgress.SetMarquee(const Value: Boolean);
begin
FMarquee := Value;
PostUpdateMessage;
end;
procedure TTaskbarListProgress.SetMax(const Value: ULONGLONG);
begin
FMax := Value;
PostUpdateMessage;
end;
procedure TTaskbarListProgress.SetMin(const Value: ULONGLONG);
begin
FMin := Value;
PostUpdateMessage;
end;
procedure TTaskbarListProgress.SetPosition(const Value: ULONGLONG);
begin
FPosition := Value;
PostUpdateMessage;
end;
procedure TTaskbarListProgress.SetProgressbar(const Value: TProgressBar);
begin
if Assigned(FProgressbar) then
begin
SetWindowLong(FProgressbar.Handle, GWL_WNDPROC, FOrigProgressWndProc);
FProgressbar.RemoveFreeNotification(Self);
end;
FProgressBar := Value;
if Assigned(FProgressbar) then
begin
FProgressbar.FreeNotification(Self);
FOrigProgressWndProc := SetWindowLong(FProgressbar.Handle, GWL_WNDPROC, Integer(@MyWndProc));
PostUpdateMessage;
end;
end;
procedure TTaskbarListProgress.SetState(const Value: TTaskbarListProgressState);
begin
FState := Value;
PostUpdateMessage;
end;
initialization
Progresses := TList.Create;
finalization
Progresses.Free;
end.