Add Nix Flake (#27)

* Add Nix Flake

* Add CI job to test-drive Nix Flake

.github/workflows/quick-check.yml

@@ -80,3 +80,23 @@ jobs:
         with:
           command: check
           args: ${{ matrix.feature-flags }}
+
+  quick_check-flake:
+    runs-on: ubuntu-latest
+    steps:
+      - name: Install Nix
+        uses: DeterminateSystems/nix-installer-action@v4
+
+      - name: Cache Nix dependencies
+        uses: DeterminateSystems/magic-nix-cache-action@v2
+
+      - uses: actions/checkout@v2
+
+      - name: Check flake
+        run: nix flake check
+
+      - name: Build flake
+        run: nix build
+
+      - name: Test run flake
+        run: nix run . -- --version

default.nix

@@ -0,0 +1,30 @@
+{ lib
+, naersk
+, stdenv
+, hostPlatform
+, targetPlatform
+, cargo
+, rustc
+}:
+let
+  cargoToml = (builtins.fromTOML (builtins.readFile ./Cargo.toml));
+in
+naersk.lib."${targetPlatform.system}".buildPackage rec {
+  src = ./.;
+  buildInputs = [
+    cargo
+    rustc
+  ];
+  cargoBuildOptions = final: final ++ [ "--all-features" ];
+  CARGO_BUILD_INCREMENTAL = "false";
+  copyLibs = true;
+  name = cargoToml.package.name;
+  version = cargoToml.package.version;
+  meta = with lib; {
+    description = cargoToml.package.description;
+    homepage = cargoToml.package.homepage;
+    license = with licenses; [ mit ];
+    maintainers = with maintainers; [ ];
+    mainProgram = "tera";
+  };
+}

flake.nix

@@ -0,0 +1,47 @@
+{
+  description = "A command line utility written in Rust to render templates from json|toml|yaml && ENV, using the tera templating engine";
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+    naersk.url = "github:nmattia/naersk";
+    naersk.inputs.nixpkgs.follows = "nixpkgs";
+  };
+  outputs = { self, nixpkgs, naersk }:
+    let
+      cargoToml = (builtins.fromTOML (builtins.readFile ./Cargo.toml));
+      supportedSystems = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" ];
+      forAllSystems = f: nixpkgs.lib.genAttrs supportedSystems (system: f system);
+    in
+    {
+      overlay = final: prev: {
+        "${cargoToml.package.name}" = final.callPackage ./. { inherit naersk; };
+      };
+      packages = forAllSystems (system:
+        let
+          pkgs = import nixpkgs {
+            inherit system;
+            overlays = [
+              self.overlay
+            ];
+          };
+        in
+        {
+          "${cargoToml.package.name}" = pkgs."${cargoToml.package.name}";
+        });
+      defaultPackage = forAllSystems (system: (import nixpkgs {
+        inherit system;
+        overlays = [ self.overlay ];
+      })."${cargoToml.package.name}");
+      devShell = forAllSystems (system:
+        let
+          pkgs = import nixpkgs {
+            inherit system;
+            overlays = [ self.overlay ];
+          };
+        in
+        pkgs.mkShell {
+          inputsFrom = with pkgs; [
+            pkgs."${cargoToml.package.name}"
+          ];
+        });
+    };
+}