-
Notifications
You must be signed in to change notification settings - Fork 106
/
utils.clj
146 lines (123 loc) · 3.66 KB
/
utils.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
(ns manifold.utils
{:no-doc true}
(:refer-clojure
:exclude [future])
(:require
[clojure.tools.logging :as log]
[manifold.executor :as ex])
(:import
[java.util.concurrent
Executors
Executor
ThreadFactory
BlockingQueue
ConcurrentHashMap]
[java.util.concurrent.locks
ReentrantLock
Lock]))
;;;
(defmacro wait-for [& body]
`(let [f# (fn []
(try
~@body
(catch Throwable e#
(log/error e# "error in manifold.utils/wait-for"))))]
(.execute ^Executor (ex/wait-pool) ^Runnable f#)
nil))
(defmacro future-with [executor & body]
`(let [frame# (clojure.lang.Var/cloneThreadBindingFrame)
^Executor executor# ~executor
f# (fn []
(let [curr-frame# (clojure.lang.Var/getThreadBindingFrame)]
(clojure.lang.Var/resetThreadBindingFrame frame#)
(try
~@body
(catch Throwable e#
(log/error e# "error in manifold.utils/future-with"))
(finally
(clojure.lang.Var/resetThreadBindingFrame curr-frame#)))))]
(.execute executor# ^Runnable f#)
nil))
;;;
(def ^ThreadLocal stack-depth (ThreadLocal.))
(def ^:const max-depth 50)
(defmacro without-overflow [executor & body]
`(let [depth# (.get stack-depth)
depth'# (if (nil? depth#) 0 depth#)
f# (fn [] ~@body)]
(if (> depth'# max-depth)
(future-with ~executor (f#))
(try
(.set stack-depth (unchecked-inc (unchecked-long depth'#)))
(f#)
(finally
(when (nil? depth#)
(.set stack-depth nil)))))))
;;;
(defn invoke-callbacks [^BlockingQueue callbacks]
(loop []
(when-let [c (.poll callbacks)]
(try
(c)
(catch Throwable e
(log/error e "error in invoke-callbacks")))
(recur))))
;;;
(defn fast-satisfies [protocol-var]
(let [^ConcurrentHashMap classes (ConcurrentHashMap.)]
(add-watch protocol-var ::memoization (fn [& _] (.clear classes)))
(fn [x]
(if (nil? x)
false
(let [cls (class x)
val (.get classes cls)]
(if (nil? val)
(let [val (satisfies? @protocol-var x)]
(.put classes cls val)
val)
val))))))
;;;
(defn mutex []
(ReentrantLock.))
(defmacro with-lock [lock & body]
`(let [^java.util.concurrent.locks.Lock lock# ~lock]
(.lock lock#)
(try
~@body
(finally
(.unlock lock#)))))
(defmacro with-lock* [lock & body]
`(let [^java.util.concurrent.locks.Lock lock# ~lock]
(.lock lock#)
(let [x# (do ~@body)]
(.unlock lock#)
x#)))
;;;
(defmacro when-core-async
"Suitable for altering behavior (like extending protocols), but not defs"
[& body]
(when (try
(require '[clojure.core.async])
true
(catch Exception _
false))
`(do ~@body)))
(defmacro when-class [class & body]
(when (try
(Class/forName (name class))
(catch Exception _
false))
`(do ~@body)))
;;;
(defmacro defprotocol+ [name & body]
(when-not (resolve name)
`(defprotocol ~name ~@body)))
(defmacro deftype+ [name & body]
(when-not (resolve name)
`(deftype ~name ~@body)))
(defmacro defrecord+ [name & body]
(when-not (resolve name)
`(defrecord ~name ~@body)))
(defmacro definterface+ [name & body]
(when-not (resolve name)
`(definterface ~name ~@body)))