-
Notifications
You must be signed in to change notification settings - Fork 56
/
porcelain.clj
1963 lines (1781 loc) · 91.7 KB
/
porcelain.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(ns clj-jgit.porcelain
(:require [clojure.java.io :as io]
[clojure.string :as str]
#_{:clj-kondo/ignore [:refer-all]}
[clj-jgit.internal :refer :all]
[clj-jgit.util :as util :refer [seq?! doseq-cmd-fn!]])
(:import (java.io File FileNotFoundException IOException ByteArrayOutputStream)
(java.nio.charset StandardCharsets)
(java.security GeneralSecurityException)
(java.util List)
(org.eclipse.jgit.api Git InitCommand StatusCommand AddCommand MergeCommand LogCommand
LsRemoteCommand Status ResetCommand$ResetType FetchCommand PushCommand CloneCommand
RmCommand ResetCommand SubmoduleUpdateCommand SubmoduleSyncCommand SubmoduleInitCommand ListBranchCommand$ListMode
CreateBranchCommand$SetupUpstreamMode CheckoutCommand$Stage
CommitCommand MergeCommand$FastForwardMode RevertCommand CreateBranchCommand
CheckoutCommand TransportConfigCallback TransportCommand ListBranchCommand TagCommand
CleanCommand DeleteTagCommand DiffCommand)
(org.eclipse.jgit.blame BlameResult)
(org.eclipse.jgit.diff DiffAlgorithm$SupportedAlgorithm)
(org.eclipse.jgit.errors UnsupportedCredentialItem)
(org.eclipse.jgit.lib RepositoryBuilder AnyObjectId PersonIdent BranchConfig$BranchRebaseMode ObjectId
SubmoduleConfig$FetchRecurseSubmodulesMode Ref Repository StoredConfig GpgConfig)
(org.eclipse.jgit.merge MergeStrategy)
(org.eclipse.jgit.notes Note)
(org.eclipse.jgit.revwalk RevCommit)
(org.eclipse.jgit.submodule SubmoduleWalk)
(org.eclipse.jgit.transport.sshd SshdSessionFactory DefaultProxyDataFactory JGitKeyCache KeyPasswordProvider)
(org.eclipse.jgit.transport CredentialItem CredentialItem$InformationalMessage CredentialItem$StringType CredentialItem$Username FetchResult UsernamePasswordCredentialsProvider URIish RefSpec RefLeaseSpec TagOpt
RemoteConfig CredentialsProvider CredentialItem$CharArrayType
CredentialItem$YesNoType CredentialItem$Password SshTransport)
(org.eclipse.jgit.treewalk TreeWalk)
(org.eclipse.jgit.treewalk.filter PathFilter)))
(defmulti discover-repo "Discover a Git repository in a path." type)
(defmethod discover-repo File
[^File file]
(discover-repo (.getPath file)))
(defmethod discover-repo String
[^String path]
(let [with-git (io/as-file (str path "/.git"))
bare (io/as-file (str path "/refs"))]
(cond
(.endsWith path ".git") (io/as-file path)
(.exists with-git) with-git
(.exists bare) (io/as-file path))))
(def ^:dynamic *cred-provider* nil)
(def ^:dynamic *ssh-key-dir* (str (System/getProperty "user.home") File/separator ".ssh"))
(def ^:dynamic *ssh-key-name* ["id_rsa", "id_dsa", "id_ecdsa", "id_ed25519"])
(def ^:dynamic *ssh-key-passphrase* "")
(def ^:dynamic *known-hosts-file* ["known_hosts" "known_hosts2"])
(def ^CredentialsProvider trust-any-provider
"Basic `CredentialsProvider` instance that accepts and adds any unknown server keys to `known_hosts` file."
(proxy [CredentialsProvider] []
(supports [items]
(->> items
(remove #(instance? CredentialItem$YesNoType %))
empty?))
(get [uri items]
(doall (map #(if (instance? CredentialItem$YesNoType %)
(.setValue ^CredentialItem$YesNoType % true)
(throw (UnsupportedCredentialItem. uri (-> ^CredentialItem % .getClass .getName))))
items))
true)
(isInteractive []
false)))
(defn user-pass-provider
"Create a new `UsernamePasswordCredentialsProvider` instance for given `login` and `password`.
Options:
:trust-all? Accept and add any server key not present in known_hosts file.
(default: false)
"
^UsernamePasswordCredentialsProvider [login password & {:keys [trust-all?] :or {trust-all? false}}]
(if trust-all?
(proxy [UsernamePasswordCredentialsProvider] [^String login ^String password]
(supports [items]
(->> items
(remove #(or (instance? CredentialItem$InformationalMessage %)
(instance? CredentialItem$Username %)
(instance? CredentialItem$Password %)
(instance? CredentialItem$StringType %)
(instance? CredentialItem$YesNoType %)))
empty?))
(get [uri items]
(doall (map #(cond
(instance? CredentialItem$Username %) (.setValue ^CredentialItem$Username % login)
(instance? CredentialItem$Password %) (.setValue ^CredentialItem$Password % (char-array password))
(instance? CredentialItem$StringType %) (.setValue ^CredentialItem$StringType % password)
(instance? CredentialItem$YesNoType %) (.setValue ^CredentialItem$YesNoType % true)
:else (throw (UnsupportedCredentialItem. uri (-> ^CredentialItem % .getClass .getName))))
items))
true)
(isInteractive []
false))
(UsernamePasswordCredentialsProvider. ^String login ^String password)))
#_{:clj-kondo/ignore [:unused-binding]}
(defn key-pass-provider
"Create a new `KeyPasswordProvider` instance for given `key-pw`."
^KeyPasswordProvider [^CredentialsProvider provider]
(reify KeyPasswordProvider
(getPassphrase [_ uri attempt]
(let [credential-item (CredentialItem$Password.)]
(if (.get provider ^URIish uri [credential-item])
(.getValue credential-item)
nil)))
(setAttempts [_ attempts]
true)
(getAttempts [_]
1)
(keyLoaded [_ uri attempt ex]
(when ex (throw (GeneralSecurityException. "Key passphrase mismatch")))
; never retry on error
false)))
(def ^SshdSessionFactory sshd-factory
"Handle SSH transport configuration."
(proxy [SshdSessionFactory] [(JGitKeyCache.) (DefaultProxyDataFactory.)]
(getSshDirectory []
(let [ssh-dir (io/as-file *ssh-key-dir*)]
(if (.isAbsolute ssh-dir)
ssh-dir
(.getAbsoluteFile ssh-dir))))
(createKeyPasswordProvider [^CredentialsProvider provider]
(key-pass-provider provider))
(getDefaultKnownHostsFiles [^File ssh-dir]
(let [ssh-dir (.toPath ssh-dir)
kh-files (->> (seq?! *known-hosts-file*)
(map #(.resolve ssh-dir ^String %)))]
(if (seq kh-files)
kh-files
(throw (IOException. (str "Couldn't find any known hosts file(s), tried: " *known-hosts-file*
" in " *ssh-key-dir*))))))
(getDefaultIdentities [^File ssh-dir]
(let [key-files (->> (seq?! *ssh-key-name*)
(map #(io/file ssh-dir %))
(filter #(.exists ^File %))
(map #(.toPath ^File %)))]
(if (seq key-files)
key-files
(throw (IOException. (str "Couldn't find any key file(s), tried: " *ssh-key-name*
" in " *ssh-key-dir*))))))))
(-> (Runtime/getRuntime) (.addShutdownHook (Thread. #(.close sshd-factory))))
(def ^TransportConfigCallback transport-callback
"Default `TransportConfigCallback`."
(reify ^TransportConfigCallback TransportConfigCallback
(configure [_ transport]
(when (instance? SshTransport transport)
(.setSshSessionFactory ^SshTransport transport sshd-factory)))))
(def ^:dynamic *transport-callback* transport-callback)
(defmacro with-credentials
"Use given `config` map for all commands in body that require credentials based authentication.
Options:
:login User name.
:pw User password.
:trust-all? If true any unknown server key is accepted and added to configured
`known_hosts` file. (default: false)
:cred-provider Use custom credentials provider. (default: nil = use default)
"
[config & body]
`(let [user-name# (get ~config :login "")
user-pw# (get ~config :pw "")
key-dir# (get ~config :key-dir *ssh-key-dir*)
trust-all?# (get ~config :trust-all? false)
cred-provider# (get ~config :credentials *cred-provider*)]
(binding [*ssh-key-dir* key-dir#
*transport-callback* nil
*cred-provider* (if (some? cred-provider#)
cred-provider#
(user-pass-provider user-name# user-pw# :trust-all? trust-all?#))]
~@body)))
(defmacro with-identity
"Use given `config` map for all commands in body that require key based authentication.
Options:
:name A string or seq of strings with private key name(s). The public
key must have the same name with an additional \".pub\" postfix.
(default: [\"id_rsa\", \"id_dsa\", \"id_ecdsa\", \"id_ed25519\"])
:pw Optional password for encrypted keys. (default: nil)
:key-dir Path to ssl keys and known_hosts file. (default: ~/.ssh)
:trust-any-host? If true any unknown server key is accepted and added to
known_hosts file. (default: false)
:cred-provider Use custom credentials provider. (default: nil = use default)
:transport-callback Use custom TransportConfigCallback
"
[config & body]
`(let [key-name# (get ~config :name *ssh-key-name*)
key-pw# (get ~config :pw *ssh-key-passphrase*)
key-dir# (get ~config :key-dir *ssh-key-dir*)
trust-all?# (get ~config :trust-all? false)
cred-provider# (get ~config :cred-provider *cred-provider*)
transport-cb# (get ~config :transport-callback *transport-callback*)]
(binding [*ssh-key-name* key-name#
*ssh-key-dir* key-dir#
*ssh-key-passphrase* key-pw#
*cred-provider* (cond
(and key-pw# (nil? cred-provider#)) (user-pass-provider nil key-pw# :trust-all? trust-all?#)
(and trust-all?# (nil? cred-provider#)) trust-any-provider
:else cred-provider#)
*transport-callback* transport-cb#]
~@body)))
(defn load-repo
"Given a `path` (either to the parent folder or to the `.git` folder itself), load the Git repository"
^Git [path]
(if-let [git-dir (discover-repo path)]
(-> (RepositoryBuilder.)
(.setGitDir git-dir)
(.readEnvironment)
(.findGitDir)
(.build)
(Git.))
(throw
(FileNotFoundException. (str "The Git repository at '" path "' could not be located.")))))
(defmacro with-repo
"Load Git repository at `path` and bind it to `repo`, then evaluate `body`.
Also provides a fresh `rev-walk` instance for `repo`."
[path & body]
`(with-open [~'repo (load-repo ~path)
~'rev-walk (new-rev-walk ~'repo)]
~@body))
(defn git-shutdown
"Release all resources held by JGit process. Not mandatory, but prevents leaks when, for example, running in
a webapp."
[] (Git/shutdown))
(defn git-add
"Add file contents to the index. `file-patterns` is either a String with a repository-relative path of the
file/directory to be added or coll of Strings with paths. If a directory name is given all files in the directory are
added recursively. Fileglobs (e.g. *.txt) are not yet supported.
Options:
:update? If set to true, the command only matches file-patterns
against already tracked files in the index rather than
the working tree. That means that it will never stage new
files, but that it will stage modified new contents of
tracked files and that it will remove files from the index
if the corresponding files in the working tree have been
removed. (default: false)
:working-tree-iterator Set the WorkingTreeIterator to be used. If nil a standard
FileTreeIterator is used. (default: nil)
"
[^Git repo file-patterns & {:keys [update? working-tree-iterator]
:or {update? false
working-tree-iterator nil}}]
(as-> (.add repo) cmd
^AddCommand (doseq-cmd-fn! cmd #(.addFilepattern ^AddCommand %1 %2) file-patterns)
(.setUpdate cmd update?)
(if (some? working-tree-iterator)
(.setWorkingTreeIterator cmd working-tree-iterator) cmd)
(.call cmd)))
(defonce branch-list-modes
{:all ListBranchCommand$ListMode/ALL
:remote ListBranchCommand$ListMode/REMOTE})
(defn strip-refs-head [s]
(str/replace s #"^refs/heads/" ""))
(defn git-branch-list
"Get a list of branch names for given `repo`. Returns a seq of strings.
Options:
:jgit? If true returns a seq with JGit objects instead. (default: false)
:list-mode :all, :local or :remote (default: :local)
"
[^Git repo & {:keys [jgit? list-mode]
:or {jgit? false
list-mode :local}}]
(as-> (.branchList repo) ^ListBranchCommand cmd
(if-not (= list-mode :local)
(.setListMode cmd (list-mode branch-list-modes)) cmd)
(.call cmd)
(if jgit?
cmd
(map #(-> (.getName ^Ref %) strip-refs-head) cmd))))
(defn git-branch-current
"The current branch name of given `repo`.
Options:
:jgit? If true returns the unmodified output by JGit. (default: false)
"
[^Git repo & {:keys [jgit?] :or {jgit? false}}]
(as-> (.getRepository repo) ^Repository r
(.getFullBranch r)
(if jgit?
r
(strip-refs-head r))))
(defn git-branch-attached?
"Is the given `repo` on a branch (true) or in a detached HEAD state?"
[^Git repo]
(some? (re-find #"^refs/heads/" (git-branch-current repo :jgit? true))))
(defonce branch-upstream-modes
{:no-track CreateBranchCommand$SetupUpstreamMode/NOTRACK
:set-upstream CreateBranchCommand$SetupUpstreamMode/SET_UPSTREAM
:track CreateBranchCommand$SetupUpstreamMode/TRACK})
(defn git-branch-create
"Create a new local branch for given `repo`.
Options:
:force? If true and the branch with the given name already exists, the
start-point of an existing branch will be set to a new :start-point;
if false, the existing branch will not be changed.
(default: false)
:start-point String that corresponds to the start-point option; if null, the
current HEAD will be used. (default: nil)
:upstream-mode Optional keyword that configures branch tracking:
:no-track
:set-upstream
:track
(default: nil)
"
[^Git repo branch-name & {:keys [force? ^String start-point upstream-mode]
:or {force? false
start-point nil
upstream-mode nil}}]
(as-> (.branchCreate repo) ^CreateBranchCommand cmd
(.setName cmd branch-name)
(.setForce cmd force?)
(if (some? start-point)
(.setStartPoint cmd start-point) cmd)
(if (some? upstream-mode)
(.setUpstreamMode cmd (upstream-mode branch-upstream-modes)) cmd)
(.call cmd)))
(defn git-branch-delete
"Delete one or several branches. `branch-names` may be either a string or a coll of strings. The result is a list with
the (full) names of the deleted branches. Note that we don't have a option corresponding to the -r option; remote
tracking branches are simply deleted just like local branches.
Options:
:force? true corresponds to the -D option, false to the -d option. If false a check
will be performed whether the branch to be deleted is already merged into
the current branch and deletion will be refused in this case.
(default: false)
"
[^Git repo branch-names & {:keys [force?]
:or {force? false}}]
(-> (.branchDelete repo)
(.setBranchNames ^"[Ljava.lang.String;" (into-array String (seq?! branch-names)))
(.setForce force?)
(.call)))
(defonce checkout-stage-modes
{:base CheckoutCommand$Stage/BASE
:ours CheckoutCommand$Stage/OURS
:theirs CheckoutCommand$Stage/THEIRS})
(defn git-checkout
"Checkout a branch to the working tree.
Options:
:all-paths? Do a path checkout on the entire repository. If this option is set,
neither the :create-branch? nor :name option is considered. In
other words, these options are exclusive. (default: false)
:create-branch? If true a branch will be created as part of the checkout and set to
the specified :start-point. (default: false)
:force? If true and the branch with the given name already exists, the
start point of an existing branch will be set to a new start-point;
if false, the existing branch will not be changed. (default: false)
:monitor Set a progress monitor. See JGit ProgressMonitor interface.
(default: nil)
:name The name of the branch or commit to check out, or the new branch name.
When only checking out paths and not switching branches, use
:start-point to specify from which branch or commit to check out
files. When :create-branch? is set to true, use this option to set
the name of the new branch and :start-point to specify the
start-point of the branch. (default: nil)
:orphan? Whether to create a new orphan branch. If true , the name of the new
orphan branch must be set using :name. The commit at which to start
the new orphan branch can be set using :start-point; if not
specified, \"HEAD\" is used. (default: false)
:paths String or coll of strings with path(s) to check out. If this option is
set, neither the :create-branch? nor :name option is considered.
In other words, these options are exclusive. (default: nil)
:stage When checking out the index, check out the specified stage for
unmerged paths. This can not be used when checking out a branch, only
when checking out the index. Keywords:
:base Base stage (#1)
:ours Ours stage (#2)
:theirs Theirs stage (#3)
(default: nil)
:start-point String that corresponds to the --start-point option. When checking
out :paths and this is not specified or null, the index is used.
When creating a new branch, this will be used as the start point. If
null, the current HEAD will be used. (default: nil)
:upstream-mode Optional keyword that configures branch tracking when creating a new
branch with :create-branch?.
Modes are:
:no-track
:set-upstream
:track
(default: nil)
Usage examples:
Check out an existing branch:
(git-checkout repo :name \"feature\");
Check out paths from the index:
(git-checkout repo :paths [\"file1.txt\" \"file2.txt\"]);
Check out a path from a commit:
(git-checkout repo :start-point \"HEAD\" :paths \"file1.txt\");
Create a new branch and make it the current branch:
(git-checkout repo :create-branch? true :name \"newbranch\");
Create a new tracking branch for a remote branch and make it the current branch:
(git-checkout repo :create-branch? true :name \"stable\"
:upstream-mode :set-upstream :start-point \"origin/stable\");
"
[^Git repo & {:keys [all-paths? create-branch? force? monitor name orphan? paths stage ^String start-point upstream-mode]
:or {all-paths? false
create-branch? false
force? false
monitor nil
name nil
orphan? false
paths nil
stage nil
start-point nil
upstream-mode nil}}]
(as-> (.checkout repo) ^CheckoutCommand cmd
(if (some? name)
(.setName cmd name) cmd)
(if (some? paths)
(.addPaths cmd (seq?! paths)) cmd)
(.setAllPaths cmd all-paths?)
(.setCreateBranch cmd create-branch?)
(.setForceRefUpdate cmd force?)
(if (some? monitor)
(.setProgressMonitor cmd monitor) cmd)
(.setOrphan cmd orphan?)
(if (some? stage)
(.setStage cmd (stage checkout-stage-modes)) cmd)
(if (some? start-point)
(.setStartPoint cmd start-point) cmd)
(if (some? upstream-mode)
(.setUpstreamMode cmd (upstream-mode branch-upstream-modes)) cmd)
(.call cmd)))
(declare git-cherry-pick)
(defonce tag-opt
{:auto-follow TagOpt/AUTO_FOLLOW
:fetch-tags TagOpt/FETCH_TAGS
:no-tags TagOpt/NO_TAGS})
(defn clone-cmd ^CloneCommand [uri]
(-> (Git/cloneRepository)
(.setURI uri)
^TransportCommand (.setCredentialsProvider *cred-provider*)
(.setTransportConfigCallback *transport-callback*)))
(defn git-clone
"Clone a repository into a new working directory from given `uri`.
Options:
:bare? Whether the cloned repository shall be bare. (default: false)
:branch The initial branch to check out when cloning the repository. Can be
specified as ref name (\"refs/heads/master\"), branch name
(\"master\") or tag name (\"v1.2.3\"). If set to nil \"HEAD\"
is used. (default: \"master\")
:callback Register a progress callback. See JGit CloneCommand.Callback
interface. (default: nil)
:clone-all? Whether all branches have to be fetched. (default: true)
:clone-branches String or coll of strings of branch(es) to clone. Ignored when
:clone-all? is true. Branches must be specified as full ref
names (e.g. \"refs/heads/master\"). (default: nil)
:clone-subs? If true; initialize and update submodules. Ignored when :bare?
is true. (default: false)
:dir The optional directory associated with the clone operation. If
the directory isn't set, a name associated with the source uri
will be used. (default: nil)
:depth Create a shallow clone with a history truncated to the specified number of commits. (default: nil)
:git-dir The repository meta directory (.git). (default: nil = automatic)
:no-checkout? If set to true no branch will be checked out after the clone.
This enhances performance of the clone command when there is no
need for a checked out branch. (default: false)
:mirror? Set up a mirror of the source repository. This implies that a
bare repository will be created. Compared to :bare?, :mirror?
not only maps local branches of the source to local branches of
the target, it maps all refs (including remote-tracking branches,
notes etc.) and sets up a refspec configuration such that all
these refs are overwritten by a git remote update in the target
repository. (default: false)
:monitor Set a progress monitor. See JGit ProgressMonitor interface.
(default: nil)
:remote The remote name used to keep track of the upstream repository for the
clone operation. If no remote name is set, \"origin\" is used.
(default: nil)
:tags Set the tag option used for the remote configuration explicitly.
Options:
:auto-follow - Automatically follow tags if we fetch the thing they point at.
:fetch-tags - Always fetch tags, even if we do not have the thing it points at.
:no-tags - Never fetch tags, even if we have the thing it points at.
(default: :auto-follow)
"
[uri & {:keys [bare? branch callback clone-all? clone-branches clone-subs? dir depth git-dir no-checkout? mirror? monitor
remote tags]
:or {bare? false
branch "master"
clone-all? true
clone-branches nil
clone-subs? false
callback nil
dir nil
depth nil
git-dir nil
no-checkout? false
mirror? false
monitor nil
remote nil
tags :auto-follow}}]
(as-> (clone-cmd uri) cmd
(.setBare cmd bare?)
(.setBranch cmd branch)
(.setCloneAllBranches cmd clone-all?)
(if (some? clone-branches)
(.setBranchesToClone cmd (seq?! clone-branches)) cmd)
(.setCloneSubmodules cmd clone-subs?)
(if (some? callback)
(.setCallback cmd callback) cmd)
(if (some? dir)
(.setDirectory cmd (io/as-file dir)) cmd)
(if (some? depth)
(.setDepth cmd depth) cmd)
(if (some? git-dir)
(.setGitDir cmd (io/as-file git-dir)) cmd)
(.setNoCheckout cmd no-checkout?)
(.setMirror cmd mirror?)
(if (some? monitor)
(.setProgressMonitor cmd monitor) cmd)
(if (some? remote)
(.setRemote cmd remote) cmd)
(.setTagOption cmd (tags tag-opt))
(.call cmd)))
(defn signing-pass-provider
"Return a new `CredentialsProvider` instance for given `key-pw`."
^CredentialsProvider
[^String key-pw]
(proxy [CredentialsProvider] []
(supports [items]
(if (some? (->> items
(filter #(when (instance? CredentialItem$CharArrayType %) true))
first))
true
false))
(get [uri items]
(let [^CredentialItem$CharArrayType pw-item (->> items
(filter #(when (instance? CredentialItem$CharArrayType %) true))
first)]
(if (some? pw-item)
(do (.setValue pw-item (char-array key-pw)) true)
false)))
(isInteractive []
false)))
(declare git-config-load)
(defn gpg-config
"Return commit signing config for given `repo`."
[^Git repo]
(let [config (GpgConfig. (git-config-load repo))]
{:sign? (.isSignCommits config)
:signing-key (.getSigningKey config)
:key-format (.getKeyFormat config)}))
(defn git-commit
"Record changes to given `repo`.
Options:
:all? If set to true the Commit command automatically stages files that
have been modified and deleted, but new files not known by the
repository are not affected. This corresponds to the parameter -a
on the command line. (default: false)
:allow-empty? Whether it should be allowed to create a commit which has the
same tree as it's sole predecessor (a commit which doesn't
change anything). By default when creating standard commits
(without specifying paths) JGit allows to create such commits.
When this flag is set to false an attempt to create an \"empty\"
standard commit will lead to an EmptyCommitException.
(default: true)
:amend? Used to amend the tip of the current branch. If set to true, the
previous commit will be amended. This is equivalent to --amend
on the command line. (default: false)
:author A map of format {:name \"me\" :email \"me@foo.net\"}. If no
author is explicitly specified the author will be set to the
committer or to the original author when amending. (default: nil)
:committer A map of format {:name \"me\" :email \"me@foo.net\"}. If no
committer is explicitly specified the committer will be deduced
from config info in current repository, with current time.
(default: nil)
:insert-change-id? If set to true a change id will be inserted into the commit
message. An existing change id is not replaced. An initial change
id (I000...) will be replaced by the change id.
(default: nil)
:no-verify? Whether this commit should *not* be verified by the pre-commit and
commit-msg hooks. (default: false)
:only String or coll of strings. If set commit dedicated path(s) only.
Full file paths are supported as well as directory paths; in the
latter case this commits all files/directories below the specified
path. (default: nil)
:reflog-comment Override the message written to the reflog or pass nil to specify
that no reflog should be written. If an empty string is passed
Git's default reflog msg is used. (default: \"\")
:sign? Sign the commit? If nil the git config is used (commit.gpgSign).
Note that unprotected GPG keys are currently not supported by JGit.
(default: nil)
:signing-key The GPG key id used for signing. If nil the git config is used (user.signingKey).
(default: nil)
:signing-pw The key password for the default credentials provider.
(default: nil)
:signing-provider Pass a custom CredentialsProvider instance, overrides :signing-pw.
(default: nil)
"
[^Git repo message & {:keys [all? allow-empty? amend? author committer insert-change-id? no-verify? only
reflog-comment sign? signing-key signing-pw signing-provider]
:or {all? false
allow-empty? true
amend? false
author nil
committer nil
insert-change-id? false
no-verify? false
only nil
reflog-comment ""
sign? nil
signing-key nil
signing-pw nil
signing-provider nil}}]
(let [sign? (if (some? sign?)
sign?
(:sign? (gpg-config repo)))]
(as-> (.commit repo) ^CommitCommand cmd
(.setAll cmd all?)
(.setAllowEmpty cmd allow-empty?)
(.setAmend cmd amend?)
(if (some? author)
(.setAuthor cmd (:name author) (:email author)) cmd)
(if (some? committer)
(.setCommitter cmd (:name committer) (:email committer)) cmd)
(.setInsertChangeId cmd insert-change-id?)
(.setMessage cmd message)
(.setNoVerify cmd no-verify?)
(if (some? only)
(doseq-cmd-fn! cmd #(.setOnly ^CommitCommand %1 %2) only) cmd)
(if (or (nil? reflog-comment)
(not (clojure.string/blank? reflog-comment)))
(.setReflogComment cmd reflog-comment) cmd)
(.setSign cmd sign?)
(if (and sign? (some? signing-key))
(.setSigningKey cmd signing-key) cmd)
(if (and sign? (some? signing-pw))
; see https://bugs.eclipse.org/bugs/show_bug.cgi?id=553116
(do (.setCredentialsProvider cmd (signing-pass-provider signing-pw)) cmd)
cmd)
(if (and sign? (some? signing-provider))
; see https://bugs.eclipse.org/bugs/show_bug.cgi?id=553116
(do (.setCredentialsProvider cmd signing-provider) cmd)
cmd)
(.call cmd))))
(defn git-config-load
"Return mutable JGit StoredConfig object for given `repo`."
^StoredConfig
[^Git repo]
(-> repo .getRepository .getConfig))
(defn git-config-save
"Save given `git-config` to repo's `.git/config` file."
[^StoredConfig git-config]
(.save git-config))
(defn parse-git-config-key
"Parse given Git `config-key` and return a vector of format [section subsection name]."
[^String config-key]
(let [keys (str/split config-key #"\.")]
(case (count keys)
2 [(first keys) nil (last keys)]
3 keys
(throw (Exception. (str "Invalid config-key format: " config-key))))))
(defn git-config-get
"Return Git config value as string for given Git `config-key`. Note that config keys that are not explicitly set in
global/current repo config will always return nil and not the default value."
[^StoredConfig git-config ^String config-key]
(->> (parse-git-config-key config-key)
(apply #(.getString git-config % %2 %3))))
(defn git-config-set
"Set given `config-value` for given Git `config-key`, always returns the passed JGit StoredConfig object."
^StoredConfig
[^StoredConfig git-config ^String config-key config-value]
(->> (parse-git-config-key config-key)
(apply #(.setString git-config % %2 %3 (str config-value))))
git-config)
(defn git-diff
"Diff given `repo`, returns a OutputStream instance. Passing no other arguments is equivalent to running git status.
Use `:new-commit` and `:old-commit` to specify a range for the diff, i.e.:
(git-diff repo :old-commit \"aaae79\" :new-commit \"HEAD\")
Options:
:context-lines `integer` that sets the number of lines of context shown before and after a modification.
(default: 3)
:monitor Set a progress monitor. See JGit ProgressMonitor interface.
(default: nil)
:destination-prefix A purely cosmetic `string` used for the new side in the output. Can be empty but not nil.
(default: \"b/\")
:name-and-status-only? If true only returns a vector with DiffEntries (filename and change status)
(default: false)
:new-commit Any `Resolvable` commit-ref used as end point for the diff.
default: nil (HEAD)
:new-tree Same as :new-tree but takes a CanonicalTreeParser instance. Takes precedence over :new-commit.
default: nil (HEAD)
:old-commit Any `Resolvable` commit-ref used as starting point for the diff.
default: nil (HEAD)
:old-tree Same as :old-tree but takes a CanonicalTreeParser instance. Takes precedence over :old-commit.
default: nil (HEAD)
:path-filter An `org.eclipse.jgit.treewalk.filter.TreeFilter` instance that limits the result, i.e.:
`(PathFilter/create \"project.clj\")`. See `org.eclipse.jgit.treewalk.filter` namespace for
all available filters or implement your own.
(default: PathFilter/ALL)
:output-stream The `OutputStream` instance the formatted diff is written to. Ignored if
`:name-and-status-only?` is true.
(default: ByteArrayOutputStream.)
:source-prefix A purely cosmetic `string` used for the old side in the output. Can be empty but not nil.
(default: \"a/\")
"
[^Git repo & {:keys [cached? context-lines destination-prefix new-tree old-tree new-commit old-commit
output-stream path-filter monitor name-and-status-only? source-prefix]
:or {cached? false
context-lines -1
destination-prefix "b/"
monitor nil
name-and-status-only? false
new-commit nil
new-tree nil
old-commit nil
old-tree nil
output-stream (ByteArrayOutputStream.)
path-filter PathFilter/ALL
source-prefix "a/"}}]
(let [old-tree (or old-tree (canonical-tree-parser repo old-commit))
new-tree (or new-tree (canonical-tree-parser repo new-commit))
diff-entries (as-> (.diff repo) ^DiffCommand cmd
(.setOutputStream cmd output-stream)
(.setCached cmd cached?)
(.setOldTree cmd old-tree)
(.setNewTree cmd new-tree)
(.setSourcePrefix cmd source-prefix)
(.setDestinationPrefix cmd destination-prefix)
(.setShowNameAndStatusOnly cmd name-and-status-only?)
(.setContextLines cmd context-lines)
(.setPathFilter cmd path-filter)
(.setProgressMonitor cmd monitor)
(.call cmd))]
(if name-and-status-only?
diff-entries
output-stream)))
(defn fetch-cmd ^FetchCommand [^Git repo]
(-> (.fetch repo)
^TransportCommand (.setCredentialsProvider *cred-provider*)
(.setTransportConfigCallback *transport-callback*)))
(defonce fetch-recurse-submodules-modes
{:no SubmoduleConfig$FetchRecurseSubmodulesMode/NO
:on-demand SubmoduleConfig$FetchRecurseSubmodulesMode/ON_DEMAND
:yes SubmoduleConfig$FetchRecurseSubmodulesMode/YES})
(defonce transport-tag-opts
{:auto-follow TagOpt/AUTO_FOLLOW
:fetch-tags TagOpt/FETCH_TAGS
:no-tags TagOpt/NO_TAGS})
(defn git-fetch
"Fetch changes from upstream `repo`.
Options:
:callback Register a progress callback. See JGit FetchCommand.Callback
interface. (default: nil)
:check-fetched? If set to true, objects received will be checked for validity.
(default: false)
:dry-run? Whether to do a dry run. (default: false)
:force? Update refs affected by the fetch forcefully? (default: false)
:monitor Set a progress monitor. See JGit ProgressMonitor interface.
(default: nil)
:recurse-subs Keyword that corresponds to the --(no-)recurse-submodules
options. If nil use the value of the
submodule.name.fetchRecurseSubmodules option configured per
submodule. If not specified there, use the value of the
fetch.recurseSubmodules option configured in git config. If not
configured in either, :on-demand is the built-in default.
:no
:on-demand
:yes
(default: nil)
:ref-specs String or coll of strings of RefSpecs to be used in the fetch
operation. (default: nil)
:remote The remote (uri or name) used for the fetch operation. If no
remote is set \"origin\" is used. (default: nil)
:rm-deleted-refs? If set to true, refs are removed which no longer exist in the
source. If nil the Git repo config is used, if no config could
be found false is used. (default: nil)
:tag-opt Keyword that sets the specification of annotated tag behavior
during fetch:
:auto-follow Automatically follow tags if we fetch the thing
they point at.
:fetch-tags Always fetch tags, even if we do not have the
thing it points at.
:no-tags Never fetch tags, even if we have the thing it
points at.
(default: nil)
:thin? Sets the thin-pack preference for fetch operation. (default: true)
"
^FetchResult [^Git repo & {:keys [callback check-fetched? dry-run? force? monitor recurse-subs ref-specs remote
rm-deleted-refs? tag-opt thin?]
:or {callback nil
check-fetched? false
dry-run? false
force? false
monitor nil
recurse-subs nil
ref-specs nil
remote nil
rm-deleted-refs? nil
tag-opt nil
thin? true}}]
(as-> (fetch-cmd repo) cmd
(if (some? callback)
(.setCallback cmd callback) cmd)
(.setCheckFetchedObjects cmd check-fetched?)
(.setDryRun cmd dry-run?)
(.setForceUpdate cmd force?)
(if (some? monitor)
(.setProgressMonitor cmd monitor) cmd)
(if (some? recurse-subs)
(.setRecurseSubmodules cmd (recurse-subs fetch-recurse-submodules-modes)) cmd)
(if (some? ref-specs)
(.setRefSpecs cmd ^"[Ljava.lang.String;" (into-array String (seq?! ref-specs))) cmd)
(if (some? remote)
(.setRemote cmd remote) cmd)
(if (some? rm-deleted-refs?)
(.setRemoveDeletedRefs cmd rm-deleted-refs?) cmd)
(if (some? tag-opt)
(.setTagOpt cmd (tag-opt transport-tag-opts)) cmd)
(.setThin cmd thin?)
(.call cmd)))
(defn git-fetch-all
"Fetch all refs from upstream `repo`"
([^Git repo]
(git-fetch-all repo "origin"))
([^Git repo remote]
(git-fetch repo :remote remote :ref-specs ["+refs/tags/*:refs/tags/*" "+refs/heads/*:refs/heads/*"])))
(defn git-init
"Initialize and return a new Git repository, if no options are passed a non-bare repo is created at user.dir
Options:
:bare? Whether the repository is bare or not. (default: false)
:dir The optional directory associated with the init operation. If no directory
is set, we'll use the current directory. (default: \".\")
:git-dir Set the repository meta directory (.git). (default: nil = use default)
:initial-branch Set the initial branch of the new repository. (default: \"master\")
"
^Git [& {:keys [bare? dir git-dir initial-branch]
:or {bare? false
dir "."
git-dir nil
initial-branch "master"}}]
(as-> (InitCommand.) cmd
(.setBare cmd bare?)
(.setDirectory cmd (io/as-file dir))
(if (some? git-dir)
(.setGitDir cmd (io/as-file git-dir)) cmd)
(.setInitialBranch cmd initial-branch)
(.call cmd)))
(defn git-remote-add
"Add a new remote to given `repo` and return the JGit RemoteAddCommand instance."
[^Git repo name ^String uri]
(doto (.remoteAdd repo)
(.setName name)
(.setUri (URIish. uri))
(.call)))
(defn git-remote-remove
"Remove a remote with given name from `repo` and return the JGit `RemoteRemoveCommand` instance."
[^Git repo name]
(doto (.remoteRemove repo)
(.setName name)
(.call)))
(defn git-remote-list
"Returns a seq of vectors with format [name [^URIish ..]] representing all configured remotes for given `repo`."
[^Git repo]
(->> (.remoteList repo)
.call
(map (fn [^RemoteConfig r]
[(.getName r) (.getURIs r)]))))
(defn git-log
"Returns a seq of maps representing the commit history for current branch of given `repo`. `:range` is equal to
setting both ´:since` and `:until`. To include the commit referenced by `:since ObjectId` in the returned seq append
the ObjectId with a `^`, i.e. `:since \"d13c67^\"`.
Options:
:all? Add all refs as commits to start the graph traversal from.
(default: false)
:jgit? If true returns a seq with the untouched JGit objects instead.
(default: false)
:max-count Limit the number of commits to output. (default: nil)
:paths String or coll of strings; show only commits that affect any of the
specified paths. The path must either name a file or a directory exactly
and use / (slash) as separator. Note that regex expressions or wildcards
are not supported. (default: nil)
:range Map with format {:since Resolvable :until Resolvable}. Adds the range
since..until. (default: nil)
:rev-filter Set a RevFilter for the LogCommand. (default: nil)
:since Same as --not until, or ^until; `until` being a Resolvable, i.e.
\"HEAD\", ObjectId, etc. (default: nil)
:skip Number of commits to skip before starting to show the log output.
(default: nil)
:until Resolvable (\"master\", ObjectId, etc) to start graph traversal from.
(default: nil)
"
[^Git repo & {:keys [all? jgit? max-count paths range rev-filter since skip until]
:or {all? false
jgit? false
max-count nil
paths nil
range nil
rev-filter nil
since nil
skip nil
until nil}}]
(as-> (.log repo) ^LogCommand cmd
(if (some? until)
(.add cmd (resolve-object until repo)) cmd)
(if (some? since)
(.not cmd (resolve-object since repo)) cmd)
(if (some? range)
(.addRange cmd (resolve-object (:since range) repo) (resolve-object (:until range) repo)) cmd)
(if all?
(.all cmd) cmd)
(if (some? max-count)
(.setMaxCount cmd max-count) cmd)
(if (some? paths)
(doseq-cmd-fn! cmd #(.addPath ^LogCommand %1 %2) paths) cmd)
(if (some? rev-filter)
(.setRevFilter cmd rev-filter) cmd)
(if (some? skip)
(.setSkip cmd skip) cmd)
(.call cmd)
(if jgit?
cmd
(map #(do {:id (.getId ^RevCommit %)