Wrong DOMAIN_SEPARATOR definition

[code423n4]

Lines of code

https://github.com/code-423n4/2022-05-rubicon/blob/8c312a63a91193c6a192a9aab44ff980fbfd7741/contracts/rubiconPools/BathToken.sol#L199-L210

Vulnerability details

Impact

Broke the EIP 2612

Proof of Concept

Some contract or dapp/backend could building the DOMAIN_SEPARATOR consulting the "rigth" name to the BathToken and build the signature with "rigth" digest message
When these try to use the permit function (L713), with the "rigth" signature(v, r, s), the permit function will revert with the message "bathToken: INVALID_SIGNATURE" because the expect DOMAIN_SEPARATOR in the BathToken.sol contract was built with "wrong" name

Recommended Mitigation Steps

In the initialize function(L181) move the name definition before the DOMAIN_SEPARATOR definition

function initialize(
    ERC20 token,
    address market,
    address _feeTo
) external {
    require(!initialized);
    string memory _symbol = string(
        abi.encodePacked(("bath"), token.symbol())
    );
    symbol = _symbol;
    underlyingToken = token;
    RubiconMarketAddress = market;
    bathHouse = msg.sender; //NOTE: assumed admin is creator on BathHouse

    uint256 chainId;
    assembly {
        chainId := chainid()
    }
    name = string(abi.encodePacked(_symbol, (" v1")));
    DOMAIN_SEPARATOR = keccak256(
        abi.encode(
            keccak256(
                "EIP712Domain(string name,string version,uint256 chainId,address verifyingContract)"
            ),
            keccak256(bytes(name)),
            keccak256(bytes("1")),
            chainId,
            address(this)
        )
    );
    decimals = token.decimals(); // v1 Change - 4626 Adherence

    // Add infinite approval of Rubicon Market for this asset
    IERC20(address(token)).approve(RubiconMarketAddress, 2**256 - 1);
    emit LogInit(block.timestamp);

    feeTo = address(this); //This contract is the fee recipient, rewarding HODLers
    feeBPS = 3; //Fee set to 3 BPS initially

    // Complete constract instantiation
    initialized = true;
}

[bghughes]

Duplicate of #38