-
-
Notifications
You must be signed in to change notification settings - Fork 1.6k
/
unix_server.cr
87 lines (79 loc) · 2.16 KB
/
unix_server.cr
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
require "./unix_socket"
# A local interprocess communication server socket.
#
# Only available on UNIX and UNIX-like operating systems.
#
# Example usage:
# ```
# require "socket"
#
# def handle_client(client)
# message = client.gets
# client.puts message
# end
#
# server = UNIXServer.new("/tmp/myapp.sock")
# while client = server.accept?
# spawn handle_client(client)
# end
# ```
class UNIXServer < UNIXSocket
include Socket::Server
# Creates a named UNIX socket, listening on a filesystem pathname.
#
# Always deletes any existing filesystam pathname first, in order to cleanup
# any leftover socket file.
#
# The server is of stream type by default, but this can be changed for
# another type. For example datagram messages:
# ```
# UNIXServer.new("/tmp/dgram.sock", Socket::Type::DGRAM)
# ```
def initialize(@path : String, type : Type = Type::STREAM, backlog : Int = 128)
super(Family::UNIX, type)
bind(UNIXAddress.new(path)) do |error|
close(delete: false)
raise error
end
listen(backlog) do |error|
close
raise error
end
end
# Creates a UNIXServer from an already configured raw file descriptor
def initialize(*, fd : Int32, type : Type = Type::STREAM, @path : String? = nil)
super(fd: fd, type: type, path: @path)
end
# Creates a new UNIX server and yields it to the block. Eventually closes the
# server socket when the block returns.
#
# Returns the value of the block.
def self.open(path, type : Type = Type::STREAM, backlog = 128)
server = new(path, type, backlog)
begin
yield server
ensure
server.close
end
end
# Accepts an incoming connection.
#
# Returns the client socket or `nil` if the server is closed after invoking
# this method.
def accept? : UNIXSocket?
if client_fd = accept_impl
sock = UNIXSocket.new(fd: client_fd, type: type, path: @path)
sock.sync = sync?
sock
end
end
# Closes the socket, then deletes the filesystem pathname if it exists.
def close(delete = true)
super()
ensure
if delete && (path = @path)
File.delete(path) if File.exists?(path)
@path = nil
end
end
end