-
-
Notifications
You must be signed in to change notification settings - Fork 1.6k
/
multi_writer.cr
50 lines (41 loc) · 1.23 KB
/
multi_writer.cr
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
# An `IO` which writes to a number of underlying writer IOs.
#
# ```
# io1 = IO::Memory.new
# io2 = IO::Memory.new
# writer = IO::MultiWriter.new(io1, io2)
# writer.puts "foo bar"
# io1.to_s # => "foo bar\n"
# io2.to_s # => "foo bar\n"
# ```
class IO::MultiWriter < IO
# If `#sync_close?` is `true`, closing this `IO` will close all of the underlying
# IOs.
property? sync_close
getter? closed = false
@writers : Array(IO)
# Creates a new `IO::MultiWriter` which writes to *writers*. If
# *sync_close* is set, calling `#close` calls `#close` on all underlying
# writers.
def initialize(@writers : Array(IO), @sync_close = false)
end
# Creates a new `IO::MultiWriter` which writes to *writers*. If
# *sync_close* is set, calling `#close` calls `#close` on all underlying
# writers.
def initialize(*writers : IO, @sync_close = false)
@writers = writers.map(&.as(IO)).to_a
end
def write(slice : Bytes)
check_open
return if slice.empty?
@writers.each { |writer| writer.write(slice) }
end
def read(slice : Bytes)
raise IO::Error.new("Can't read from IO::MultiWriter")
end
def close
return if @closed
@closed = true
@writers.each { |writer| writer.close } if sync_close?
end
end