-
-
Notifications
You must be signed in to change notification settings - Fork 1.6k
/
nodes.cr
173 lines (138 loc) · 3.73 KB
/
nodes.cr
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
module YAML::Nodes
# Abstract class of all YAML tree nodes.
abstract class Node
# The optional tag of a node.
property tag : String?
# The optional anchor of a node.
property anchor : String?
# The line where this node starts.
property start_line = 0
# The column where this node starts.
property start_column = 0
# The line where this node ends.
property end_line = 0
# The column where this node ends.
property end_column = 0
# Returns a tuple of `start_line` and `start_column`.
def location : {Int32, Int32}
{start_line, start_column}
end
# Raises a `YAML::ParseException` with the given message
# located at this node's `location`.
def raise(message) : NoReturn
::raise YAML::ParseException.new(message, *location)
end
# Returns the kind of this node, which is equivalent to the class name.
abstract def kind : String
end
# A YAML document.
class Document < Node
# The nodes inside this document.
#
# A document can hold at most one node.
getter nodes = [] of Node
# Appends a node to this document. Raises if more
# than one node is appended.
def <<(node)
if nodes.empty?
nodes << node
else
raise ArgumentError.new("Attempted to append more than one node")
end
end
def to_yaml(builder : YAML::Builder) : Nil
nodes.each &.to_yaml(builder)
end
def kind : String
"document"
end
end
# A scalar value.
class Scalar < Node
# The style of this scalar.
property style : ScalarStyle = ScalarStyle::ANY
# The value of this scalar.
property value : String
# Creates a scalar with the given *value*.
def initialize(@value : String)
end
def to_yaml(builder : YAML::Builder) : Nil
builder.scalar(value, anchor, tag, style)
end
def kind : String
"scalar"
end
end
# A sequence of nodes.
class Sequence < Node
include Enumerable(Node)
# The nodes in this sequence.
getter nodes = [] of Node
# The style of this sequence.
property style : SequenceStyle = SequenceStyle::ANY
# Appends a node into this sequence.
def <<(node)
@nodes << node
end
def each(&)
@nodes.each do |node|
yield node
end
end
def to_yaml(builder : YAML::Builder) : Nil
builder.sequence(anchor, tag, style) do
each &.to_yaml(builder)
end
end
def kind : String
"sequence"
end
end
# A mapping of nodes.
class Mapping < Node
property style : MappingStyle = MappingStyle::ANY
# The nodes inside this mapping, stored linearly
# as key1 - value1 - key2 - value2 - etc.
getter nodes = [] of Node
# Appends two nodes into this mapping.
def []=(key, value)
@nodes << key << value
end
# Appends a single node into this mapping.
def <<(node)
@nodes << node
end
# Yields each key-value pair in this mapping.
def each(&)
0.step(by: 2, to: @nodes.size - 1) do |i|
yield({@nodes[i], @nodes[i + 1]})
end
end
def to_yaml(builder : YAML::Builder) : Nil
builder.mapping(anchor, tag, style) do
each do |key, value|
key.to_yaml(builder)
value.to_yaml(builder)
end
end
end
def kind : String
"mapping"
end
end
# An alias.
class Alias < Node
# The node this alias points to.
# This is set by `YAML::Nodes.parse`, and is `nil` by default.
property value : Node?
# Creates an alias with the given *anchor*.
def initialize(@anchor : String)
end
def to_yaml(builder : YAML::Builder) : Nil
builder.alias(anchor.not_nil!)
end
def kind : String
"alias"
end
end
end