-
-
Notifications
You must be signed in to change notification settings - Fork 1.6k
/
log.cr
73 lines (63 loc) · 1.57 KB
/
log.cr
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
class Log
getter source : String
getter backend : Backend?
@level : Severity?
# :nodoc:
property initial_level : Severity
# :nodoc:
def initialize(@source : String, @backend : Backend?, level : Severity)
@initial_level = level
end
# :nodoc:
def changed_level : Severity?
@level
end
def level : Severity
@level || @initial_level
end
# Change this log severity level filter.
def level=(value : Severity)
@level = value
if (backend = @backend).responds_to?(:level=)
backend.level = value
end
value
end
# :nodoc:
def backend=(value : Backend?)
@backend = value
end
{% for method in %w(trace debug info notice warn error fatal) %}
{% severity = method.id.camelcase %}
# Logs a message if the logger's current severity is lower than or equal to
# `Severity::{{ severity }}`.
#
# The block is not called unless the current severity level would emit a
# message.
#
# Blocks which return `nil` do not emit anything:
#
# ```
# Log.{{method.id}} do
# if false
# "Nothing will be logged."
# end
# end
# ```
def {{method.id}}(*, exception : Exception? = nil)
severity = Severity::{{severity}}
return unless level <= severity
return unless backend = @backend
dsl = Emitter.new(@source, severity, exception)
result = yield dsl
case result
when Entry
backend.dispatch result
when Nil
# emit nothing
else
backend.dispatch dsl.emit(result.to_s)
end
end
{% end %}
end