-
-
Notifications
You must be signed in to change notification settings - Fork 1.6k
/
signal.cr
278 lines (244 loc) · 7.14 KB
/
signal.cr
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
require "c/signal"
require "c/stdio"
require "c/sys/wait"
require "c/unistd"
# Safely handle inter-process signals on POSIX systems.
#
# Signals are dispatched to the event loop and later processed in a dedicated
# fiber. Some received signals may never be processed when the program
# terminates.
#
# ```
# puts "Ctrl+C still has the OS default action (stops the program)"
# sleep 3
#
# Signal::INT.trap do
# puts "Gotcha!"
# end
# puts "Ctrl+C will be caught from now on"
# sleep 3
#
# Signal::INT.reset
# puts "Ctrl+C is back to the OS default action"
# sleep 3
# ```
#
# Note:
# - An uncaught exception in a signal handler is a fatal error.
enum Signal : Int32
HUP = LibC::SIGHUP
INT = LibC::SIGINT
QUIT = LibC::SIGQUIT
ILL = LibC::SIGILL
TRAP = LibC::SIGTRAP
IOT = LibC::SIGIOT
ABRT = LibC::SIGABRT
FPE = LibC::SIGFPE
KILL = LibC::SIGKILL
BUS = LibC::SIGBUS
SEGV = LibC::SIGSEGV
SYS = LibC::SIGSYS
PIPE = LibC::SIGPIPE
ALRM = LibC::SIGALRM
TERM = LibC::SIGTERM
URG = LibC::SIGURG
STOP = LibC::SIGSTOP
TSTP = LibC::SIGTSTP
CONT = LibC::SIGCONT
CHLD = LibC::SIGCHLD
TTIN = LibC::SIGTTIN
TTOU = LibC::SIGTTOU
IO = LibC::SIGIO
XCPU = LibC::SIGXCPU
XFSZ = LibC::SIGXFSZ
VTALRM = LibC::SIGVTALRM
USR1 = LibC::SIGUSR1
USR2 = LibC::SIGUSR2
WINCH = LibC::SIGWINCH
{% if flag?(:linux) %}
PWR = LibC::SIGPWR
STKFLT = LibC::SIGSTKFLT
UNUSED = LibC::SIGUNUSED
{% end %}
# Sets the handler for this signal to the passed function.
#
# After executing this, whenever the current process receives the
# corresponding signal, the passed function will be called (instead of the OS
# default). The handler will run in a signal-safe fiber thought the event
# loop; there is no limit to what functions can be called, unlike raw signals
# that run on the sigaltstack.
#
# Note that `CHLD` is always trapped and child processes will always be reaped
# before the custom handler is called, hence a custom `CHLD` handler must
# check child processes using `Process.exists?`. Trying to use waitpid with a
# zero or negative value won't work.
def trap(&handler : Signal ->) : Nil
if self == CHLD
Crystal::Signal.child_handler = handler
else
Crystal::Signal.trap(self, handler)
end
end
# Resets the handler for this signal to the OS default.
#
# Note that trying to reset `CHLD` will actually set the default crystal
# handler that monitors and reaps child processes. This prevents zombie
# processes and is required by `Process#wait` for example.
def reset : Nil
Crystal::Signal.reset(self)
end
# Clears the handler for this signal and prevents the OS default action.
#
# Note that trying to ignore `CHLD` will actually set the default crystal
# handler that monitors and reaps child processes. This prevents zombie
# processes and is required by `Process#wait` for example.
def ignore : Nil
Crystal::Signal.ignore(self)
end
@@setup_default_handlers = Atomic(Int32).new(0)
# :nodoc:
def self.setup_default_handlers
_, success = @@setup_default_handlers.compare_and_set(0, 1)
return unless success
Crystal::Signal.start_loop
Signal::PIPE.ignore
Signal::CHLD.reset
end
end
# :nodoc:
module Crystal::Signal
# The number of libc functions that can be called safely from a signal(2)
# handler is very limited. An usual safe solution is to use a pipe(2) and
# just write the signal to the file descriptor and nothing more. A loop in
# the main program is responsible for reading the signals back from the
# pipe(2) and handle the signal there.
alias Handler = ::Signal ->
@@pipe = IO.pipe(read_blocking: false, write_blocking: true)
@@handlers = {} of ::Signal => Handler
@@child_handler : Handler?
@@mutex = Mutex.new
def self.trap(signal, handler) : Nil
@@mutex.synchronize do
unless @@handlers[signal]?
LibC.signal(signal.value, ->(value : Int32) {
writer.write_bytes(value)
})
end
@@handlers[signal] = handler
end
end
def self.child_handler=(handler : Handler) : Nil
@@child_handler = handler
end
def self.reset(signal) : Nil
set(signal, LibC::SIG_DFL)
end
def self.ignore(signal) : Nil
set(signal, LibC::SIG_IGN)
end
private def self.set(signal, handler)
if signal == ::Signal::CHLD
# don't reset/ignore SIGCHLD, Process#wait requires it
trap(signal, ->(signal : ::Signal) {
Crystal::SignalChildHandler.call
@@child_handler.try(&.call(signal))
})
else
@@mutex.synchronize do
@@handlers.delete(signal)
LibC.signal(signal.value, handler)
end
end
end
def self.start_loop
spawn do
loop do
value = reader.read_bytes(Int32)
process(::Signal.new(value))
end
end
end
private def self.process(signal) : Nil
if handler = @@handlers[signal]?
handler.call(signal)
else
fatal("missing handler for #{signal}")
end
rescue ex
ex.inspect_with_backtrace(STDERR)
fatal("uncaught exception while processing handler for #{signal}")
end
def self.after_fork
@@pipe = IO.pipe(read_blocking: false, write_blocking: true)
end
private def self.reader
@@pipe[0]
end
private def self.writer
@@pipe[1]
end
private def self.fatal(message : String)
Crystal.restore_blocking_state
STDERR.puts("FATAL: #{message}, exiting")
STDERR.flush
LibC._exit(1)
end
end
# :nodoc:
module Crystal::SignalChildHandler
# Process#wait will block until the sub-process has terminated. On POSIX
# systems, the SIGCHLD signal is triggered. We thus always trap SIGCHLD then
# reap/memorize terminated child processes and eventually notify
# Process#wait through a channel, that may be created before or after the
# child process exited.
@@pending = {} of LibC::PidT => Int32
@@waiting = {} of LibC::PidT => Channel::Buffered(Int32)
@@mutex = Mutex.new
def self.wait(pid : LibC::PidT) : Channel::Buffered(Int32)
channel = Channel::Buffered(Int32).new(1)
@@mutex.lock
if exit_code = @@pending.delete(pid)
@@mutex.unlock
channel.send(exit_code)
channel.close
else
@@waiting[pid] = channel
@@mutex.unlock
end
channel
end
def self.call : Nil
loop do
pid = LibC.waitpid(-1, out exit_code, LibC::WNOHANG)
case pid
when 0
return
when -1
return if Errno.value == Errno::ECHILD
raise Errno.new("waitpid")
end
@@mutex.lock
if channel = @@waiting.delete(pid)
@@mutex.unlock
channel.send(exit_code)
channel.close
else
@@pending[pid] = exit_code
@@mutex.unlock
end
end
end
def self.after_fork
@@pending.clear
@@waiting.each_value(&.close)
@@waiting.clear
end
end
# :nodoc:
fun __crystal_sigfault_handler(sig : LibC::Int, addr : Void*)
Crystal.restore_blocking_state
# Capture fault signals (SEGV, BUS) and finish the process printing a backtrace first
LibC.dprintf 2, "Invalid memory access (signal %d) at address 0x%lx\n", sig, addr
CallStack.print_backtrace
LibC._exit(sig)
end