-
-
Notifications
You must be signed in to change notification settings - Fork 1.6k
/
to_json.cr
378 lines (340 loc) · 7.23 KB
/
to_json.cr
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
class Object
def to_json
String.build do |str|
to_json str
end
end
def to_pretty_json(indent : String = " ")
String.build do |str|
to_pretty_json str, indent: indent
end
end
def to_pretty_json(io : IO, indent : String = " ")
to_json JSON::PrettyWriter.new(io, indent: indent)
end
end
# Handly struct to write JSON objects
struct JSON::ObjectBuilder(T)
def initialize(@io : T, @indent : String = " ", @indent_level : Int32 = 0)
@count = 0
end
# Adds a field to this JSON object
def field(name, value)
field(name) { value.to_json(@io) }
end
# Adds a field to this JSON object, with raw JSON object as string
def raw_field(name, value)
field(name) { value.to_s(@io) }
end
# Adds a field to this JSON object by specifying
# it's name, then executes the block, which must append the value.
def field(name)
if @count > 0
@io << ","
@io << '\n' if @indent_level > 0
end
@indent_level.times { @io << @indent }
name.to_s.to_json(@io)
@io << ":"
@io << " " if @indent_level > 0
yield
@count += 1
end
end
# Handly struct to write JSON arrays
struct JSON::ArrayBuilder(T)
def initialize(@io : T, @indent : String = " ", @indent_level : Int32 = 0)
@count = 0
end
# Appends a JSON value into this array
def <<(value)
push value
end
# Same as `#<<`
def push(value)
push { value.to_json(@io) }
end
# Executes the block, expecting it to append a value
# in this array
def push
if @count > 0
@io << ","
@io << '\n' if @indent_level > 0
end
@indent_level.times { @io << @indent }
yield
@count += 1
end
end
# The `JSON::Builder` module adds two methods, `json_object` and `json_array`
# to all `IO`s so generating JSON by streaming to an IO is easy and convenient.
#
# ### Example
#
# ```
# require "json"
#
# result = String.build do |io|
# io.json_object do |object|
# object.field "address", "Crystal Road 1234"
# object.field "location" do
# io.json_array do |array|
# array << 12.3
# array << 34.5
# end
# end
# end
# end
# result # => %({"address":"Crystal Road 1234","location":[12.3,34.5]})
# ```
module JSON::Builder
# Writes a JSON object to the given IO. Yields a `JSON::ObjectBuilder`.
def json_object
self << "{"
yield JSON::ObjectBuilder.new(self)
self << "}"
end
# Writes a JSON array to the given IO. Yields a `JSON::ArrayBuilder`.
def json_array
self << "["
yield JSON::ArrayBuilder.new(self)
self << "]"
end
end
module IO
include JSON::Builder
end
class JSON::PrettyWriter
include IO
def initialize(@io : IO, @indent : String)
@indent_level = 0
end
delegate read, to: @io
delegate write, to: @io
def json_object
self << "{\n"
@indent_level += 1
yield JSON::ObjectBuilder.new(self, @indent, @indent_level)
@indent_level -= 1
self << '\n'
@indent_level.times { @io << @indent }
self << "}"
end
def json_array
self << "[\n"
@indent_level += 1
yield JSON::ArrayBuilder.new(self, @indent, @indent_level)
@indent_level -= 1
self << '\n'
@indent_level.times { @io << @indent }
self << ']'
end
end
struct Nil
def to_json(io)
io << "null"
end
end
struct Bool
def to_json(io)
to_s io
end
end
struct Int
def to_json(io)
to_s io
end
end
struct Float
def to_json(io)
case self
when .nan?
raise JSON::Error.new("NaN not allowed in JSON")
when .infinite?
raise JSON::Error.new("Infinity not allowed in JSON")
else
to_s io
end
end
end
class String
def to_json(io)
io << '"'
each_char do |char|
case char
when '\\'
io << "\\\\"
when '"'
io << "\\\""
when '\b'
io << "\\b"
when '\f'
io << "\\f"
when '\n'
io << "\\n"
when '\r'
io << "\\r"
when '\t'
io << "\\t"
when .ascii_control?
io << "\\u"
ord = char.ord
io << '0' if ord < 0x1000
io << '0' if ord < 0x100
io << '0' if ord < 0x10
ord.to_s(16, io)
else
io << char
end
end
io << '"'
end
end
struct Symbol
def to_json(io)
to_s.to_json(io)
end
end
class Array
def to_json(io)
if empty?
io << "[]"
return
end
io.json_array do |array|
each do |element|
array << element
end
end
end
end
struct Set
def to_json(io)
if empty?
io << "[]"
return
end
io.json_array do |array|
each do |element|
array << element
end
end
end
end
class Hash
def to_json(io)
if empty?
io << "{}"
return
end
io.json_object do |object|
each do |key, value|
object.field key, value
end
end
end
end
struct Tuple
def to_json(io)
io.json_array do |array|
{% for i in 0...T.size %}
array << self[{{i}}]
{% end %}
end
end
end
struct NamedTuple
def to_json(io : IO)
io.json_object do |obj|
{% for key in T.keys %}
obj.field({{key.stringify}}, self[{{key.symbolize}}])
{% end %}
end
end
end
struct Time::Format
def to_json(value : Time, io : IO)
format(value).to_json(io)
end
end
struct Enum
def to_json(io)
io << value
end
end
struct Time
def to_json(io)
io << '"'
Time::Format::ISO_8601_DATE_TIME.format(self, io)
io << '"'
end
end
# Converter to be used with `JSON.mapping` and `YAML.mapping`
# to serialize a `Time` instance as the number of seconds
# since the unix epoch. See `Time.epoch`.
#
# ```
# require "json"
#
# class Person
# JSON.mapping({
# birth_date: {type: Time, converter: Time::EpochConverter},
# })
# end
#
# person = Person.from_json(%({"birth_date": 1459859781}))
# person.birth_date # => 2016-04-05 12:36:21 UTC
# person.to_json # => %({"birth_date":1459859781})
# ```
module Time::EpochConverter
def self.to_json(value : Time, io : IO)
io << value.epoch
end
end
# Converter to be used with `JSON.mapping` and `YAML.mapping`
# to serialize a `Time` instance as the number of milliseconds
# since the unix epoch. See `Time.epoch_ms`.
#
# ```
# require "json"
#
# class Person
# JSON.mapping({
# birth_date: {type: Time, converter: Time::EpochMillisConverter},
# })
# end
#
# person = Person.from_json(%({"birth_date": 1459860483856}))
# person.birth_date # => 2016-04-05 12:48:03 UTC
# person.to_json # => %({"birth_date":1459860483856})
# ```
module Time::EpochMillisConverter
def self.to_json(value : Time, io : IO)
io << value.epoch_ms
end
end
# Converter to be used with `JSON.mapping` to read the raw
# value of a JSON object property as a String.
#
# It can be useful to read ints and floats without losing precision,
# or to read an object and deserialize it later based on some
# condition.
#
# ```
# require "json"
#
# class Raw
# JSON.mapping({
# value: {type: String, converter: String::RawConverter},
# })
# end
#
# raw = Raw.from_json(%({"value": 123456789876543212345678987654321}))
# raw.value # => "123456789876543212345678987654321"
# raw.to_json # => %({"value":123456789876543212345678987654321})
# ```
module String::RawConverter
def self.to_json(value : String, io : IO)
io << value
end
end