forked from NVlabs/litmustestgen
-
Notifications
You must be signed in to change notification settings - Fork 0
/
c11_perturbed.als
executable file
·352 lines (299 loc) · 9.48 KB
/
c11_perturbed.als
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
// Automated Synthesis of Comprehensive Memory Model Litmus Test Suites
// Daniel Lustig, Andrew Wright, Alexandros Papakonstantinou, Olivier Giroux
// ASPLOS 2017
//
// Copyright (c) 2017, NVIDIA Corporation. All rights reserved.
//
// This file is licensed under the BSD-3 license. See LICENSE for details.
// C11/C++11, based on a model from Batty et al. [POPL 2016]
////////////////////////////////////////////////////////////////////////////////
// =Perturbations=
abstract sig PTag {}
one sig RE extends PTag {}
one sig LS extends PTag {}
one sig DR extends PTag {}
one sig DA extends PTag {}
fun no_p : PTag->univ { // no_p - constant for no perturbation
(PTag->univ) - (PTag->univ)
}
////////////////////////////////////////////////////////////////////////////////
// =C11 memory model=
pred C11_p[p: PTag->univ] {
DRF_p[no_p] // <-- !!!
Hb_p[p]
Coh_p[p]
Rf_p[p]
NaRf_p[p]
Rmw_p[p]
Ssimp_p[p]
}
pred Hb_p[p: PTag->univ] { irreflexive[hb_p[p]] }
pred Coh_p[p: PTag->univ] {
irreflexive[optional[~(rf_p[p])].(mo_p[p]).(optional[rf_p[p]]).(hb_p[p])]
}
pred Rf_p[p: PTag->univ] { irreflexive[(rf_p[p]).(hb_p[p])] }
pred NaRf_p[p: PTag->univ] {
no ((rf_p[p]).(ident[NA - p[RE]])) - vis_p[p]
}
pred Rmw_p[p: PTag->univ] {
irreflexive[rf_p[p] + ((mo_p[p]).(mo_p[p]).~(rf_p[p])) + ((mo_p[p]).(rf_p[p]))]
}
pred Com_p[p: PTag->univ] { irreflexive[*(rf_p[p] + mo_p[p] + fr_p[p]).(hb_p[p])] }
pred Ssimp_p[p: PTag->univ] {
acyclic[
(allpairs[MemoryOrderSeqCst.(ord_p[p])] - iden)
&
(optional[Fsb_p[p]].(hb_p[p] + fr_p[p] + mo_p[p]).(optional[sbF_p[p]]))
]
}
pred DRF_p[p: PTag->univ] {
no dr_p[p]
// Not in the model, but in Batty's thesis, section 3.1.3
Reads_p[p] in Writes_p[p].(rf_p[p]) // indeterminate reads
((address.~address) & ^(~(sb_p[p]) + sb_p[p])) - iden in sb_p[p] + ~(sb_p[p]) // unsequenced races
}
//////////////////////////////////////////////////////////////////////////////////////////////////////////////
// =Model of memory=
sig Address { }
sig Thread { start: one Event }
fact { start.~start in iden }
fact { Event = Thread.start.*sb }
fact { no start.~sb }
abstract sig MemoryOrder {}
one sig MemoryOrderNonAtomic extends MemoryOrder {}
one sig MemoryOrderRelaxed extends MemoryOrder {}
one sig MemoryOrderAcquire extends MemoryOrder {}
one sig MemoryOrderRelease extends MemoryOrder {}
one sig MemoryOrderAcqRel extends MemoryOrder {}
one sig MemoryOrderSeqCst extends MemoryOrder {}
fun A : Event { Event - MemoryOrderNonAtomic.ord }
fun NA : set Event { MemoryOrderNonAtomic.ord }
fun RLX : set Event { MemoryOrderRelaxed.ord }
fun ACQ : set Event { MemoryOrderAcquire.ord }
fun REL : set Event { MemoryOrderRelease.ord }
fun AR : set Event { MemoryOrderAcqRel.ord }
fun SC : set Event { MemoryOrderSeqCst.ord }
fun acq : set Event { ACQ + AR + SC - Write }
fun rel : set Event { REL + AR + SC - Read }
fact WriteMO {
all w: Write | w.memory_order in
MemoryOrderNonAtomic + MemoryOrderRelaxed +
MemoryOrderRelease + MemoryOrderSeqCst
}
fact ReadMO {
Read.memory_order in
MemoryOrderNonAtomic + MemoryOrderRelaxed +
MemoryOrderAcquire + MemoryOrderSeqCst
}
fact RMWMO {
RMW.memory_order in
MemoryOrderRelaxed + MemoryOrderRelease + MemoryOrderAcquire +
MemoryOrderAcqRel + MemoryOrderSeqCst
}
fact {
Fence.memory_order in
MemoryOrderRelease + MemoryOrderAcquire + MemoryOrderAcqRel + MemoryOrderSeqCst
}
abstract sig Event {
sb: set Event,
memory_order: one MemoryOrder,
sc: set Event,
}
fun ord : MemoryOrder->Event { ~memory_order }
abstract sig MemoryEvent extends Event {
address : one Address,
rf: set Event,
mo: set Event,
}
fact rf_wr { rf in Writes->Reads }
fact mo_writes { mo in Writes->Writes }
sig Write extends MemoryEvent {}
sig Read extends MemoryEvent {}
sig RMW extends MemoryEvent {}
sig Fence extends Event {}
fun Reads : set Event { Read + RMW }
fun Writes : set Event { Write + RMW }
////////////////////////////////////////////////////////////////////////////////
// =Constraints on basic model of memory=
// com
fun loc : Event->Event { MemoryEvent->MemoryEvent & address.~address }
fact { all r : Reads | lone r.~rf }
fun fr : Read->Write {
~rf.mo
+
((Reads - Writes.rf)->Writes & loc)
}
fact com_loc { rf + mo + fr in loc }
// sb
fact { irreflexive[sb] }
fact { transitive[sb] }
fact { all e: Event | one t: Thread | t->e in start.*sb }
fun thd : Event->Event { ^(sb + ~sb) }
// reads
fact { rf.~rf in iden }
// writes
fact { all a: Address | total[mo, a.~address :> (Writes & A)] }
//fact { no NA <: address.~address :> A }
// sc
fact { total[sc, SC] }
fact { sc in allpairs[SC] }
//////////////////////////////////////////////////////////////////////////////////////////////////////////////
// =Model of memory, under perturbation=
fun DR_step : MemoryOrder->MemoryOrder {
MemoryOrderAcqRel->MemoryOrderSeqCst +
MemoryOrderRelease->MemoryOrderAcqRel +
MemoryOrderRelaxed->MemoryOrderAcquire + // should still work here
MemoryOrderRelaxed->MemoryOrderRelease
}
fun DA_step : MemoryOrder->MemoryOrder {
MemoryOrderAcqRel->MemoryOrderSeqCst +
MemoryOrderAcquire->MemoryOrderAcqRel +
MemoryOrderRelaxed->MemoryOrderRelease + // should still work here
MemoryOrderRelaxed->MemoryOrderAcquire
}
fun ord_p[p: PTag->univ] : MemoryOrder->Event {
ord :> (Event - p[RE+DR+DA])
+
DR_step.ord :> ((Event & p[DR]) - p[RE])
+
DA_step.ord :> ((Event & p[DA]) - p[RE])
}
fun sb_p[p: PTag->univ] : Event->Event {
(Event - p[RE]) <: sb :> (Event - p[RE])
}
fun sc_p[p: PTag->univ] : Event->Event {
(Event - p[RE+DR+DA]) <: sc :> (Event - p[RE+DR+DA])
}
fun rf_p[p: PTag->univ] : Event->Event {
(Event - p[RE]) <: rf :> (Event - p[RE])
}
fun mo_p[p: PTag->univ] : Event->Event {
(Event - p[RE]) <: mo :> (Event - p[RE])
}
fun fr_p[p: PTag->univ] : Event->Event {
(Event - p[RE]) <: fr :> (Event - p[RE])
}
fun Writes_p[p: PTag->univ] : Event {
Writes - p[RE]
}
fun Reads_p[p: PTag->univ] : Event {
Reads - p[RE]
}
fun thd_p[p: PTag->univ] : Event->Event {
(Event - p[RE]) <: thd :> (Event - p[RE])
}
fun acq_p[p: PTag->univ] : set Event {
(MemoryOrderAcquire.(ord_p[p])) +
(MemoryOrderAcqRel.(ord_p[p])) +
(MemoryOrderSeqCst.(ord_p[p]) & (Reads + Fence))
// + (F & con) // ignoring consume
}
fun rel_p[p: PTag->univ] : set Event {
(MemoryOrderRelease.(ord_p[p])) +
(MemoryOrderAcqRel.(ord_p[p])) +
(MemoryOrderSeqCst.(ord_p[p]) & (Writes + Fence))
// + (F & con)? // ignoring consume
}
fun Fsb_p[p: PTag->univ] : Event->Event { ident[Fence].(sb_p[p]) }
fun sbF_p[p: PTag->univ] : Event->Event { (sb_p[p]).(ident[Fence]) }
fun rs_prime_p[p: PTag->univ] : Event->Event {
thd_p[p] + (((Event - p[RE])->(Event - p[RE])).(ident[RMW]))
}
fun rs_p[p: PTag->univ] : Event->Event {
(mo_p[p]) & (rs_prime_p[p]) - (((mo_p[p]) - (rs_prime_p[p])).(mo_p[p]))
}
fun sw_p[p: PTag->univ] : Event->Event {
(
(ident[rel_p[p]]).(optional[Fsb_p[p]]).(ident[Writes])
.(optional[rs_p[p]]).(rf_p[p]).(ident[Reads])
.(optional[sbF_p[p]]).(ident[acq_p[p]])
) - thd_p[p]
}
fun ithbr_p[p: PTag->univ] : Event->Event { sw_p[p] + (sw_p[p]).(sb_p[p]) }
fun ithb_p[p: PTag->univ] : Event->Event {
^(ithbr_p[p] + (sb_p[p]).(ithbr_p[p]))
}
fun hb_p[p: PTag->univ] : Event->Event {
^((sb_p[p]) + ithb_p[p])
}
fun hbl_p[p: PTag->univ] : Event->Event { hb_p[p] & loc }
fun vis_p[p: PTag->univ] : Event->Event {
(ident[Writes].(hbl_p[p]).(ident[Reads]))
-
((hbl_p[p]).(ident[Writes]).(hbl_p[p]))
}
fun cnf_p[p: PTag->univ] : Event->Event {
(((MemoryEvent - p[RE])->(MemoryEvent - p[RE])) & loc)
}
fun dr_p[p: PTag->univ] : Event->Event {
cnf_p[p] - hb_p[p] - ~(hb_p[p]) - allpairs[Event - NA - p[RE]] - thd_p[p]
}
//////////////////////////////////////////////////////////////////////////////////////////////////////////////
// =Alloy helpers=
fun allpairs[e: univ] : univ->univ { e->e }
fun ident[e: univ] : univ->univ { iden & e->e }
fun optional[f: univ->univ] : univ->univ { iden + f }
pred transitive[rel: Event->Event] { rel = ^rel }
pred irreflexive[rel: Event->Event] { no iden & rel }
pred acyclic[rel: Event->Event] { irreflexive[^rel] }
pred total[rel: Event->Event, bag: Event] {
all disj e, e': bag | e->e' in rel + ~rel
acyclic[rel]
}
//////////////////////////////////////////////////////////////////////////////////////////////////////////////
// =Constraints on the search space=
fact {
all a: Address | some (a.~address) :> Writes
}
// treat sb as if it were total per thread, even though it's not necessarily
fact {
all disj e1, e2: Event | e1->e2 in thd => e1->e2 in sb + ~sb
}
////////////////////////////////////////////////////////////////////////////////
let interesting_not_axiom[axiom] {
not axiom[no_p]
all e: Event | C11_p[RE->e]
all e: A - RLX | C11_p[DR->e]
all e: A - RLX | C11_p[DA->e]
all e: Fence & (AR + SC) | C11_p[DR->e]
all e: Fence & (AR + SC) | C11_p[DA->e]
}
////////////////////////////////////////////////////////////////////////////////
run Hb {
interesting_not_axiom[Hb_p]
} for 3
run Coh {
interesting_not_axiom[Coh_p]
} for 3
run Rf {
interesting_not_axiom[Rf_p]
} for 3
run NaRf {
interesting_not_axiom[NaRf_p]
} for 3
run Rmw {
interesting_not_axiom[Rmw_p]
} for 3
run Simp {
interesting_not_axiom[Ssimp_p]
} for 3
run Com {
interesting_not_axiom[Com_p]
} for 3
run union {
interesting_not_axiom[Hb_p]
or
interesting_not_axiom[Coh_p]
or
interesting_not_axiom[Rf_p]
or
interesting_not_axiom[NaRf_p]
or
interesting_not_axiom[Rmw_p]
or
interesting_not_axiom[Ssimp_p]
} for 3
run sanity {
some Event
C11_p[no_p]
} for 3