-
Notifications
You must be signed in to change notification settings - Fork 1
/
build.gradle
191 lines (152 loc) · 5.09 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
buildscript {
repositories {
maven {
url "https://plugins.gradle.org/m2/"
}
jcenter();
mavenCentral();
}
dependencies {
classpath 'org.ajoberstar:grgit:2.1.0'
classpath 'org.ajoberstar.reckon:reckon-gradle:0.3.0'
classpath 'com.bmuschko:gradle-nexus-plugin:2.3.1';
classpath "gradle.plugin.com.gorylenko.gradle-git-properties:gradle-git-properties:1.4.17"
}
}
allprojects {
apply plugin: 'java'
}
apply plugin: "org.ajoberstar.grgit"
apply plugin: "org.ajoberstar.reckon"
apply plugin: 'com.bmuschko.nexus'
apply plugin: "com.gorylenko.gradle-git-properties"
group = "cl.daplay"
description = "An idiomatic Java API for Surbtc REST services."
targetCompatibility = '1.8'
sourceCompatibility = '1.8'
reckon {
normal = scopeFromProp()
preRelease = snapshotFromProp()
}
ext {
versionPattern = /\d+\.\d+\.\d+/
}
def requireReleaseVersion(alert = "") {
// execute if not snapshot and matches \d.\d.\d
def execute = !version.toString().contains("SNAPSHOT") && (version.toString() ==~ versionPattern)
if (!execute && alert) {
println alert
}
return execute;
}
task generateVersionFile {
description = 'Generates file "version.properties".'
doLast {
def out = new File(project.buildDir, "resources/main/version.properties")
def props = new Properties()
props.setProperty('version', project.version.toString())
props.store(out.newWriter(), null)
}
}
processResources.finalizedBy generateVersionFile
task readmeUpdate {
description = 'Updates version in README.md'
onlyIf {
def alert = "README.md won't be updated, as $version is an SNAPSHOT version"
return requireReleaseVersion(alert)
}
// handle to README.md
def readme = new File(project.projectDir, "README.md")
// replace text in README.md
doLast {
def text = readme.text
readme.text = text.replaceAll versionPattern, version.toString()
}
// add, commit and push change
doLast {
grgit.add(patterns: ['README.md'])
grgit.commit(message: "chore(README.md) releases version: '${version.toString()}'.")
grgit.push()
}
}
// unused tasks added by plugin Reckon
project.tasks.remove(reckonTagCreate)
project.tasks.remove(reckonTagPush)
task release {
onlyIf {
def alert = "task Release, won't be executed, as $version is an SNAPSHOT version"
return requireReleaseVersion(alert)
}
final String releaseName = "v${version}"
println "releasing: $releaseName"
doLast {
grgit.tag.add(name: releaseName, message: releaseName, annotate: true)
grgit.push(refsOrSpecs: ["refs/tags/${releaseName}"])
}
}
release.dependsOn build
release.dependsOn readmeUpdate
release.finalizedBy uploadArchives
readmeUpdate.mustRunAfter(build)
javadoc {
doLast {
// contents of "gtag.js" file will be inserted after every head
String gtag = file("gtag.js").text
// for each html
def files = fileTree(destinationDir).include('**/*.html')
files.each { file ->
def content = file.text
def indexOfHead = content.indexOf("<head>");
if (indexOfHead) {
// determines post of insertion (just after head element)
def insertIndex = indexOfHead + "<head>".length()
// replace file
file.text = new StringBuilder(content).insert(insertIndex, gtag).toString()
}
}
}
}
allprojects {
repositories {
mavenCentral()
}
}
dependencies {
compile group: 'com.fasterxml.jackson.core', name: 'jackson-databind', version: '2.8.9'
compile group: 'com.fasterxml.jackson.datatype', name: 'jackson-datatype-jdk8', version: '2.8.9'
compile group: 'com.fasterxml.jackson.datatype', name: 'jackson-datatype-jsr310', version: '2.8.9'
testCompile group: 'junit', name: 'junit', version: '4.12'
}
test {
testLogging.showStandardStreams = true
final boolean skipIntegration = project.hasProperty('skipIntegration') && Boolean.parseBoolean(project.getProperty('skipIntegration'));
final boolean integrationConfiguration = project.hasProperty('jsurbtc.secret') && project.hasProperty('jsurbtc.key')
if (skipIntegration || !integrationConfiguration) {
exclude { it.name.endsWith('_IT.class') }
}
}
modifyPom {
project {
name project.name
description project.description
url 'https://github.com/daplay/jsurbtc'
scm {
url 'https://github.com/daplay/jsurbtc'
connection 'scm:https://github.com/daplay/jsurbtc.git'
developerConnection 'scm:git://github.com/daplay/jsurbtc.git'
}
licenses {
license {
name 'The Apache Software License, Version 2.0'
url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
}
}
developers {
developer {
id 'daplay'
name 'Daniel Meneses'
email 'daplay@gmail.com'
}
}
}
}