forked from metabrainz/musicbrainz-server
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Artist.pm
564 lines (498 loc) · 20.3 KB
/
Artist.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
package MusicBrainz::Server::Data::Artist;
use Moose;
use namespace::autoclean;
use Carp;
use List::AllUtils qw( any );
use MusicBrainz::Server::Constants qw( $ARTIST_TYPE_GROUP );
use MusicBrainz::Server::Entity::Artist;
use MusicBrainz::Server::Entity::PartialDate;
use MusicBrainz::Server::Data::ArtistCredit;
use MusicBrainz::Server::Data::Edit;
use MusicBrainz::Server::Data::Utils qw(
is_special_artist
add_partial_date_to_row
conditional_merge_column_query
contains_string
find_best_primary_alias
hash_to_row
load_subobjects
merge_table_attributes
merge_date_period
order_by
);
use MusicBrainz::Server::Data::Utils::Cleanup qw( used_in_relationship );
use MusicBrainz::Server::Data::Utils::Uniqueness qw( assert_uniqueness_conserved );
use Scalar::Util qw( looks_like_number );
extends 'MusicBrainz::Server::Data::Entity';
with 'MusicBrainz::Server::Data::Role::Relatable',
'MusicBrainz::Server::Data::Role::Name',
'MusicBrainz::Server::Data::Role::Annotation' => { type => 'artist' },
'MusicBrainz::Server::Data::Role::Alias' => { type => 'artist' },
'MusicBrainz::Server::Data::Role::Area',
'MusicBrainz::Server::Data::Role::DeleteAndLog' => { type => 'artist' },
'MusicBrainz::Server::Data::Role::IPI' => { type => 'artist' },
'MusicBrainz::Server::Data::Role::ISNI' => { type => 'artist' },
'MusicBrainz::Server::Data::Role::GIDEntityCache',
'MusicBrainz::Server::Data::Role::PendingEdits' => { table => 'artist' },
'MusicBrainz::Server::Data::Role::Rating' => { type => 'artist' },
'MusicBrainz::Server::Data::Role::Tag' => { type => 'artist' },
'MusicBrainz::Server::Data::Role::Subscription' => {
table => 'editor_subscribe_artist',
column => 'artist',
active_class => 'MusicBrainz::Server::Entity::Subscription::Artist',
deleted_class => 'MusicBrainz::Server::Entity::Subscription::DeletedArtist',
},
'MusicBrainz::Server::Data::Role::LinksToEdit' => { table => 'artist' },
'MusicBrainz::Server::Data::Role::Collection';
sub _type { 'artist' }
sub _columns
{
return 'artist.id, artist.gid, artist.name COLLATE musicbrainz, artist.sort_name COLLATE musicbrainz, ' .
'artist.type, artist.area, artist.begin_area, artist.end_area, ' .
'gender, artist.edits_pending, artist.comment, artist.last_updated, ' .
'artist.begin_date_year, artist.begin_date_month, artist.begin_date_day, ' .
'artist.end_date_year, artist.end_date_month, artist.end_date_day,' .
'artist.ended';
}
sub _id_column
{
return 'artist.id';
}
sub _column_mapping
{
return {
id => 'id',
gid => 'gid',
name => 'name',
sort_name => 'sort_name',
type_id => 'type',
area_id => 'area',
begin_area_id => 'begin_area',
end_area_id => 'end_area',
gender_id => 'gender',
begin_date => sub { MusicBrainz::Server::Entity::PartialDate->new_from_row(shift, shift() . 'begin_date_') },
end_date => sub { MusicBrainz::Server::Entity::PartialDate->new_from_row(shift, shift() . 'end_date_') },
edits_pending => 'edits_pending',
comment => 'comment',
last_updated => 'last_updated',
ended => 'ended',
};
}
after '_delete_from_cache' => sub {
my ($self, @ids) = @_;
$self->c->model('ArtistCredit')->uncache_for_artist_ids(grep { looks_like_number($_) } @ids);
};
sub find_by_subscribed_editor
{
my ($self, $editor_id, $limit, $offset) = @_;
my $query = 'SELECT ' . $self->_columns . '
FROM ' . $self->_table . '
JOIN editor_subscribe_artist s ON artist.id = s.artist
WHERE s.editor = ?
ORDER BY artist.sort_name COLLATE musicbrainz, artist.id';
$self->query_to_list_limited($query, [$editor_id], $limit, $offset);
}
sub find_by_instrument {
my ($self, $instrument_id, $limit, $offset) = @_;
my $query =
'SELECT ' . $self->_columns . q(,
array_agg(
json_build_object('typeName', link_type.name, 'credit', lac.credited_as)
ORDER BY link_type.name, lac.credited_as, link_type.entity_type1, rels.id
) AS instrument_credits_and_rel_types
FROM ) . $self->_table . '
JOIN (
SELECT * FROM l_artist_artist
UNION ALL
SELECT * FROM l_artist_recording
UNION ALL
SELECT * FROM l_artist_release
) rels ON rels.entity0 = artist.id
JOIN link ON link.id = rels.link
JOIN link_type ON link_type.id = link.link_type
JOIN link_attribute ON link_attribute.link = link.id
JOIN link_attribute_type ON link_attribute_type.id = link_attribute.attribute_type
JOIN instrument ON instrument.gid = link_attribute_type.gid
LEFT JOIN link_attribute_credit lac ON (
lac.link = link_attribute.link AND
lac.attribute_type = link_attribute.attribute_type
)
WHERE instrument.id = ?
GROUP BY artist.id
ORDER BY artist.sort_name COLLATE musicbrainz';
$self->query_to_list_limited(
$query,
[$instrument_id],
$limit,
$offset,
sub {
my ($model, $row) = @_;
my $credits_and_rel_types = delete $row->{instrument_credits_and_rel_types};
{ artist => $model->_new_from_row($row), instrument_credits_and_rel_types => $credits_and_rel_types };
},
);
}
sub find_by_recording
{
my ($self, $recording_id, $limit, $offset) = @_;
my $query = 'SELECT ' . $self->_columns . '
FROM ' . $self->_table . '
JOIN artist_credit_name acn ON acn.artist = artist.id
JOIN recording ON recording.artist_credit = acn.artist_credit
WHERE recording.id = ?
ORDER BY artist.name COLLATE musicbrainz, artist.id';
$self->query_to_list_limited($query, [$recording_id], $limit, $offset);
}
sub find_by_release
{
my ($self, $release_id, $limit, $offset) = @_;
my $query = 'SELECT ' . $self->_columns . '
FROM ' . $self->_table . '
WHERE artist.id IN (SELECT artist.id
FROM artist
JOIN artist_credit_name acn ON acn.artist = artist.id
JOIN track ON track.artist_credit = acn.artist_credit
JOIN medium ON medium.id = track.medium
WHERE medium.release = ?)
OR artist.id IN (SELECT artist.id
FROM artist
JOIN artist_credit_name acn ON acn.artist = artist.id
JOIN release ON release.artist_credit = acn.artist_credit
WHERE release.id = ?)
ORDER BY artist.name COLLATE musicbrainz, artist.id';
$self->query_to_list_limited($query, [($release_id) x 2], $limit, $offset);
}
sub find_by_release_group
{
my ($self, $recording_id, $limit, $offset) = @_;
my $query = 'SELECT ' . $self->_columns . '
FROM ' . $self->_table . '
JOIN artist_credit_name acn ON acn.artist = artist.id
JOIN release_group ON release_group.artist_credit = acn.artist_credit
WHERE release_group.id = ?
ORDER BY artist.name COLLATE musicbrainz, artist.id';
$self->query_to_list_limited($query, [$recording_id], $limit, $offset);
}
sub find_by_work
{
my ($self, $work_id, $limit, $offset) = @_;
my $query = 'SELECT DISTINCT name COLLATE musicbrainz name_collate, s.*
FROM (
SELECT ' . $self->_columns . ' FROM '. $self->_table . '
JOIN artist_credit_name acn ON acn.artist = artist.id
JOIN recording ON recording.artist_credit = acn.artist_credit
JOIN l_recording_work lrw ON lrw.entity0 = recording.id
WHERE lrw.entity1 = ?
UNION ALL
SELECT ' . $self->_columns . ' FROM '. $self->_table . '
JOIN l_artist_work law ON law.entity0 = artist.id
WHERE law.entity1 = ?
) s
ORDER BY name COLLATE musicbrainz, id';
$self->query_to_list_limited($query, [($work_id) x 2], $limit, $offset);
}
sub _order_by {
my ($self, $order) = @_;
my $order_by = order_by($order, 'name', {
'name' => sub {
return 'sort_name COLLATE musicbrainz';
},
'area' => sub {
return 'area, name COLLATE musicbrainz';
},
'gender' => sub {
return 'gender, sort_name COLLATE musicbrainz';
},
'begin_date' => sub {
return 'begin_date_year, begin_date_month, begin_date_day, name COLLATE musicbrainz';
},
'begin_area' => sub {
return 'begin_area, name COLLATE musicbrainz';
},
'end_date' => sub {
return 'end_date_year, end_date_month, end_date_day, name COLLATE musicbrainz';
},
'end_area' => sub {
return 'end_area, name COLLATE musicbrainz';
},
'type' => sub {
return 'type, sort_name COLLATE musicbrainz';
},
});
return $order_by;
}
sub _area_columns
{
return ['area', 'begin_area', 'end_area'];
}
sub _find_by_area_order {
return 'sort_name, id';
}
sub load
{
my ($self, @objs) = @_;
load_subobjects($self, 'artist', @objs);
}
sub _insert_hook_after_each {
my ($self, $created, $artist) = @_;
$self->ipi->set($created->{id}, @{ $artist->{ipi_codes} });
$self->isni->set($created->{id}, @{ $artist->{isni_codes} });
}
sub update
{
my ($self, $artist_id, $update) = @_;
croak '$artist_id must be present and > 0' unless $artist_id > 0;
my $row = $self->_hash_to_row($update);
assert_uniqueness_conserved($self, artist => $artist_id, $update);
$self->sql->update_row('artist', $row, { id => $artist_id }) if %$row;
}
sub can_split
{
my ($self, $artist_id) = @_;
return 0 if is_special_artist($artist_id);
# Can only split if they have no relationships at all other than collaboration
# These AND NOT EXISTS clauses are ordered by my estimated likelihood of a
# relationship existing for a collaboration, as postgresql will not execute
# the later clauses if an earlier one has already excluded the lone artist row.
my $can_split = $self->sql->select_single_value(<<~'SQL', $artist_id);
SELECT TRUE FROM artist WHERE id = ?
AND NOT EXISTS (SELECT TRUE FROM l_artist_url lau WHERE lau.entity0 = artist.id)
AND NOT EXISTS (
SELECT TRUE FROM l_artist_artist laa
JOIN link ON laa.link = link.id
JOIN link_type lt ON link.link_type = lt.id
WHERE (
laa.entity1 = artist.id
AND lt.gid != '75c09861-6857-4ec0-9729-84eefde7fc86' --collaboration
)
OR laa.entity0 = artist.id
)
AND NOT EXISTS (SELECT TRUE FROM l_artist_recording lar WHERE lar.entity0 = artist.id)
AND NOT EXISTS (SELECT TRUE FROM l_artist_release lare WHERE lare.entity0 = artist.id)
AND NOT EXISTS (SELECT TRUE FROM l_artist_event lae WHERE lae.entity0 = artist.id)
AND NOT EXISTS (SELECT TRUE FROM l_artist_work law WHERE law.entity0 = artist.id)
AND NOT EXISTS (SELECT TRUE FROM l_artist_label lal WHERE lal.entity0 = artist.id)
AND NOT EXISTS (SELECT TRUE FROM l_artist_place lap WHERE lap.entity0 = artist.id)
AND NOT EXISTS (SELECT TRUE FROM l_artist_release_group larg WHERE larg.entity0 = artist.id)
AND NOT EXISTS (SELECT TRUE FROM l_artist_series las WHERE las.entity0 = artist.id)
AND NOT EXISTS (SELECT TRUE FROM l_artist_instrument lai WHERE lai.entity0 = artist.id)
AND NOT EXISTS (SELECT TRUE FROM l_area_artist lara WHERE lara.entity1 = artist.id)
SQL
return $can_split;
}
sub can_delete
{
my ($self, $artist_id) = @_;
return 0 if is_special_artist($artist_id);
my $active_credits = $self->sql->select_single_column_array(
'SELECT ref_count FROM artist_credit, artist_credit_name name
WHERE name.artist = ? AND name.artist_credit = id AND ref_count > 0',
$artist_id,
);
return @$active_credits == 0;
}
sub delete
{
my ($self, @artist_ids) = @_;
@artist_ids = grep { $self->can_delete($_) } @artist_ids;
$self->c->model('Collection')->delete_entities('artist', @artist_ids);
$self->c->model('Relationship')->delete_entities('artist', @artist_ids);
$self->annotation->delete(@artist_ids);
$self->alias->delete_entities(@artist_ids);
$self->ipi->delete_entities(@artist_ids);
$self->isni->delete_entities(@artist_ids);
$self->tags->delete(@artist_ids);
$self->rating->delete(@artist_ids);
$self->subscription->delete(@artist_ids);
$self->remove_gid_redirects(@artist_ids);
$self->delete_returning_gids(@artist_ids);
return 1;
}
sub merge
{
my ($self, $new_id, $old_ids, %opts) = @_;
if (any { is_special_artist($_) } @$old_ids) {
confess('Attempt to merge a special purpose artist into another artist');
}
$self->alias->merge($new_id, @$old_ids);
$self->ipi->merge($new_id, @$old_ids) unless is_special_artist($new_id);
$self->isni->merge($new_id, @$old_ids) unless is_special_artist($new_id);
$self->tags->merge($new_id, @$old_ids);
$self->rating->merge($new_id, @$old_ids);
$self->annotation->merge($new_id, @$old_ids);
$self->c->model('ArtistCredit')->merge_artists($new_id, $old_ids, %opts);
$self->c->model('Edit')->merge_entities('artist', $new_id, @$old_ids);
$self->c->model('Collection')->merge_entities('artist', $new_id, @$old_ids);
$self->c->model('Relationship')->merge_entities('artist', $new_id, $old_ids, rename_credits => $opts{rename});
# We detect cases where a merged artist type or gender is dropped due to
# it conflicting with a type or gender on the target or elsewhere (since
# only persons can have a gender). In Edit::Artist::Merge, we use the
# result of %dropped_columns to inform users of what information was
# dropped. This is done as opposed to failing the edit outright, since
# that's arguably more annoying for the editor. See MBS-10187.
my %dropped_columns;
unless (is_special_artist($new_id)) {
my $merge_columns = [ qw( area begin_area end_area ) ];
my $target_row = $self->sql->select_single_row_hash('SELECT gender, type FROM artist WHERE id = ?', $new_id);
my $target_type = $target_row->{type};
my $target_gender = $target_row->{gender};
my $merged_type = $target_type;
my $merged_gender = $target_gender;
if (!$merged_type) {
my ($query, $args) = conditional_merge_column_query(
'artist', 'type', $new_id, [$new_id, @$old_ids], 'IS NOT NULL');
$merged_type = $self->c->sql->select_single_value($query, @$args);
}
if (!$merged_gender) {
my ($query, $args) = conditional_merge_column_query(
'artist', 'gender', $new_id, [$new_id, @$old_ids], 'IS NOT NULL');
$merged_gender = $self->c->sql->select_single_value($query, @$args);
}
my $group_types = $self->sql->select_single_column_array(q{
WITH RECURSIVE atp(id) AS (
VALUES (?::int)
UNION
SELECT artist_type.id
FROM artist_type
JOIN atp ON atp.id = artist_type.parent
) SELECT * FROM atp
}, $ARTIST_TYPE_GROUP);
my $merged_type_is_group =
defined $merged_type &&
contains_string($group_types, $merged_type);
if ($merged_type_is_group && $merged_gender) {
my $target_type_is_group =
defined $target_type &&
contains_string($group_types, $target_type);
if ($target_type_is_group) {
$dropped_columns{gender} = $merged_gender;
push @$merge_columns, 'type';
} elsif ($target_gender) {
$dropped_columns{type} = $merged_type;
push @$merge_columns, 'gender';
} else {
$dropped_columns{gender} = $merged_gender;
$dropped_columns{type} = $merged_type;
}
} else {
push @$merge_columns, qw( gender type );
}
merge_table_attributes(
$self->sql => (
table => 'artist',
columns => $merge_columns,
old_ids => $old_ids,
new_id => $new_id,
),
);
merge_date_period(
$self->sql => (
table => 'artist',
old_ids => $old_ids,
new_id => $new_id,
),
);
}
$self->_delete_and_redirect_gids('artist', $new_id, @$old_ids);
return (1, \%dropped_columns);
}
sub _hash_to_row
{
my ($self, $artist) = @_;
my $row = hash_to_row($artist, {
area => 'area_id',
begin_area => 'begin_area_id',
end_area => 'end_area_id',
gender => 'gender_id',
type => 'type_id',
map { $_ => $_ } qw( comment ended name sort_name ),
});
if (exists $artist->{begin_date}) {
add_partial_date_to_row($row, $artist->{begin_date}, 'begin_date');
}
if (exists $artist->{end_date}) {
add_partial_date_to_row($row, $artist->{end_date}, 'end_date');
}
return $row;
}
sub load_related_info {
my ($self, $artists_ref, $user_lang) = @_;
my $c = $self->c;
my @artists = @{$artists_ref};
$c->model('ArtistType')->load(@artists);
$c->model('Gender')->load(@artists);
$c->model('Area')->load(@artists);
# Load and save aliases so Controller::Artist::show can use them later.
my $artist_aliases = $c->model('Artist')->alias->find_by_entity_ids(
map { $_->id } @artists,
);
my @all_aliases = map { @$_ } values %$artist_aliases;
$c->model('Artist')->alias_type->load(@all_aliases);
for my $artist (@artists) {
my @aliases = @{ $artist_aliases->{$artist->id} };
$artist->aliases(\@aliases);
if (defined $user_lang) {
my $best_alias = find_best_primary_alias(\@aliases, $user_lang);
$artist->primary_alias($best_alias->name) if defined $best_alias;
}
}
}
sub load_meta
{
my $self = shift;
MusicBrainz::Server::Data::Utils::load_meta($self->c, 'artist_meta', sub {
my ($obj, $row) = @_;
$obj->rating($row->{rating}) if defined $row->{rating};
$obj->rating_count($row->{rating_count}) if defined $row->{rating_count};
}, @_);
}
sub load_for_artist_credits {
my ($self, @artist_credits) = @_;
return unless @artist_credits;
my %artist_ids;
for my $ac (@artist_credits)
{
my @ac_artist_names = grep { $_->artist_id } $ac->all_names;
for my $artist_name (@ac_artist_names) {
$artist_ids{$artist_name->artist_id} = 1;
}
}
my $artists = $self->get_by_ids(keys %artist_ids);
for my $ac (@artist_credits)
{
my @ac_artist_names = grep { $_->artist_id } $ac->all_names;
for my $artist_name (@ac_artist_names) {
$artist_name->artist($artists->{$artist_name->artist_id});
}
}
}
sub is_empty {
my ($self, $artist_id) = @_;
my $used_in_relationship = used_in_relationship($self->c, artist => 'artist_row.id');
return $self->sql->select_single_value(<<~"SQL", $artist_id);
SELECT TRUE
FROM artist artist_row
WHERE id = ?
AND NOT (
EXISTS (
SELECT TRUE
FROM artist_credit_name acn
JOIN artist_credit ac ON ac.id = acn.artist_credit
WHERE acn.artist = artist_row.id
AND ac.ref_count > 0
LIMIT 1
) OR
$used_in_relationship
)
SQL
}
__PACKAGE__->meta->make_immutable;
no Moose;
1;
=head1 COPYRIGHT AND LICENSE
Copyright (C) 2009 Lukas Lalinsky
Copyright (C) 2011 MetaBrainz Foundation
This file is part of MusicBrainz, the open internet music database,
and is licensed under the GPL version 2, or (at your option) any
later version: http://www.gnu.org/licenses/gpl-2.0.txt
=cut