-
Notifications
You must be signed in to change notification settings - Fork 1
/
pll_freq.asm
833 lines (768 loc) · 26.6 KB
/
pll_freq.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
;****************************************************************************
;
; MC70 - Firmware for the Motorola MC micro trunking radio
; to use it as an Amateur-Radio transceiver
;
; Copyright (C) 2004 - 2012 Felix Erckenbrecht, DG1YFE
;
; This file is part of MC70.
;
; MC70 is free software: you can redistribute it and/or modify
; it under the terms of the GNU General Public License as published by
; the Free Software Foundation, either version 3 of the License, or
; (at your option) any later version.
;
; MC70 is distributed in the hope that it will be useful,
; but WITHOUT ANY WARRANTY; without even the implied warranty of
; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
; GNU General Public License for more details.
;
; You should have received a copy of the GNU General Public License
; along with MC70. If not, see <http://www.gnu.org/licenses/>.
;
;
;
;****************************************************************************
;************************************************
; P L L
;************************************************
;
; freq_init - Frequenzeinstellungen setzen
; freq_init_eep - Frequenzeinstellungen aus EEPROM holen
; freq_init_rom - Frequenzeinstellungen aus ROM holen
; pll_init - PLL initialisieren (D -> Kanalraster | A -> Status)
;
; pll_led - Überprüft PLL Lock alle 500ms (nix | nix)
; pll_chk - aktiviert rote LED, wenn PLL nicht eingerastet ist (nix)
; pll_lock_chk - PLL Lock auslesen ( nix | B=0 PLL not locked, $20=PLL locked)
; pll_set_channel - programmiert die PLL auf den in X:D gegebenen Kanal (X:D -> Kanal | nix )
; pll_set_freq - programmiert die PLL auf Frequenz ( X -> Zeiger auf Frequenz DWord | nix )
;
; set_rx_freq - Setzt die Frequenz zum Empfang, Frequenz - 21,4MHz ZF (X -> Zeiger auf Frequenz DWord | nix )
; set_tx_freq - Setzt die Frequenz zum Senden (X -> Zeiger auf Frequenz DWord | nix )
; set_freq - programmiert die PLL auf Frequenz (X - Zeiger auf Frequenz (32 Bit) | nix )
; frq_cv_freq_ch - Umrechnung Frequenz in Kanal ( X - Zeiger auf Frequenz DWord | X:D - Kanal)
; frq_cv_ch_freq - Umrechnung Kanal in Frequenz ( X:D - Kanal | X:D - Frequenz DWord)
; frq_get_freq - Liefert die aktuell eingestellte Frequenz ( nix | X:D - Frequenz DWord)
; frq_calc_freq - Umrechnung Eingabe in Frequenz
; ( D - Zeiger auf Eingabe (String), X - Zeiger auf Platz für Frequenz DWord)
; frq_sub_offset - Zieht FBASE von Frequenz ab, nötig für Kanalberechnung
; ( X - Pointer auf Frequenz DWord, D - Pointer auf DWord für Frequenz - FBASE )
; frq_add_offset - Zieht FBASe von Frequenz ab, nötig für Kanalberechnung
; ( X - Pointer auf Frequenz DWord, D - Pointer auf DWord für Frequenz - FBASE )
;
; frq_update - Teilt Control Task mit, dass eine neue Frequenz gesetzt wurde
; freq_print - Gibt Frequenz auf Display aus
; freq_offset_print - Gibt aktuelles Offset auf Display aus
;
;
;************************************************
; F R E Q U E N C Y
;************************************************
;********************
; F R E Q I N I T
;********************
;
; Frequenzeinstellungen setzen
;
; Versucht zunächst Frequenzeinstellungen aus EEPROM zu laden,
; schlägt dies fehl wird aus dem ROM initialisiert, die gelbe LED blinkt dabei
;
; Parameter : none
;
; Ergebnis : A - 0 = OK (Init aus EEPROM)
;
;
; changed Regs : A, B, X
;
freq_init
jsr freq_init_eep ; Versuchen Frequenzeinstellunegen aus EEPROM zu lesen
tsta
beq fri_end ; Bei Fehler
jsr freq_init_rom ; Aus ROM initialisieren
ldaa #1
fri_end
rts
;***************************
; F R E Q I N I T E E P
;***************************
;
; Frequenzeinstellungen aus EEPROM holen
;
; Parameter : None
;
; Ergebnis : A - 0 = OK
; Rest = Lesefehler
;
; Changed Regs : A,B,X
;
;
freq_init_eep
tsx
xgdx
subd #12
xgdx
txs ; 12 Bytes Platz auf dem Stack reservieren (3 DWords)
; zuletzt eingestellten Kanal aus EEPROM lesen
;
; Parameter : X - Zeiger auf Speicher für Frequenz, TxShift, Offset
;
; Ergebnis : A - 0 = OK
tsx
pshx ; Zieladresse auf Stack speichern
ldd #$01FA ; EEPROM Adresse $01FA
ldx #3 ; 3 Bytes lesen
jsr eep_seq_read
pulx ; Adresse von Stack löschen
tsta
bne ife_r_end ; Fehler zurückgeben
tsx
ldd 0,x ; Kanal holen
lsrd
lsrd
lsrd ; Nur obere 12 Bit berücksichtigen
ldx #1250 ; Frequenz berechnen
jsr multiply ; 16 Bit Multiply
pshb
psha
pshx ; 32 Bit Ergebnis sichern
ldd #FBASE%65536 ; Basisfrequenz (unterste einstellbare Frequenz) holen
ldx #FBASE>>16
ADD32
tsx
pula
pulb
std 8+4,x ; HiWord speichern
pula
pulb
std 10+4,x ; LoWord speichern
tsx
ldd 1+0,x
anda #%00000001 ; Nur 1 Bit vom Highword
ldx #25000
jsr multiply ; mit 25000 multiplizieren
pshb
pshx
tsx
ldab 1+3,x
andb #%00000010 ; Vorzeichen testen (+/- Shift)
pulx
pulb
beq ife_r_keep_sign
SIGINV32
bra ife_r_store_txshift
ife_r_keep_sign
ife_r_store_txshift
pshx ; HiWord sichern
tsx
std 6+2,x ; LoWord vom Offset speichern
pula
pulb
std 4+2,x ; HiWord vom Offset speichern
tsx
ldab 1+0,x
andb #%00000100 ; TX Shift aktiviert?
bne ife_r_store_offset ; Ja, dann Shiftwert auch nach "Offset" kopieren
ldd #0
std 0+0,x
std 2+0,x ; Offset deaktiviert
bra ife_r_end
ife_r_store_offset
ldd 6+0,x ; LoWord TxShift holen
std 2+0,x ; Im Platz für Offset speichern
ldd 4+0,x ; HiWord TXShift holen
std 0+0,x ; Im Platz für Offset speichern
clra
ife_r_end
tsta ; Lesen erfolgreich?
beq ife_ok ; Ja? Dann alles ok
tsx
xgdx
addd #12
xgdx
txs ; Stackspeicher freigeben
bra ife_end ; Mit Fehlermeldung enden
ife_ok
pulx
stx offset ; Offset holen
pulx
stx offset+2 ; und speichern
pulx
stx txshift
pulx ; TxShift holen
stx txshift+2 ; Und speichern
pulx
stx frequency
pulx ; Frequenz holen
stx frequency+2 ; und speichern
clra ; Alles ok -> A=0
ife_end
rts
;***************************
; F R E Q I N I T R O M
;***************************
;
; Frequenzeinstellungen aus ROM holen
;
; Parameter : none
;
; Ergebnis : none
;
; changed Regs : none
;
freq_init_rom
pshx
pshb
psha
ldx #FDEF%65536 ; Default Frequenz setzen (433,5)
stx frequency+2
ldx #FDEF>>16
stx frequency
ldx #FOFF0
stx offset
stx offset+2
ldx #FTXOFF>>16
stx txshift
ldx #FTXOFF%65536
stx txshift+2
pula
pulb
pulx
rts
;*****************
; P L L I N I T
;*****************
;
; Initialisiert PLL
;
; Parameter: D - Kanalraster
;
; Ergebnis : A - Status: 0=OK
; 1=Fehler (Kanalraster zu klein)
;
; changed Regs: A,B
;
pll_init
pshx
pshb
psha
aim #~BIT_PLLLATCH, PORT_PLLLATCH ; PTT Syn Latch = 0
ldx #FREF%65536 ; Referenzfrequenz LoWord
pshx ; Auf Stack
ldx #FREF>>16 ; Referenzfrequenz HiWord
pshx ; auf Stack
; Divisor (Kanalraster) befindet sich schon in D
jsr divide32
pula
pulb
pulx
subd #0
bne pli_error ; Kanalraster zu groß (obere 16 Bit <>0)
pshx
pula
pulb ; X -> D
anda #%11000000 ; Referenz Teiler ist 14 Bit groß,
bne pli_error ; alles >14 Bit -> Fehler
ldaa #1 ; select R
clrb
jsr send2pll ; set R
pula
pulb ; Kanalraster holen
; std f_step ; Kanalraster speicher
pshb
clra
pli_end
clr rxtx_state ; State auf RX zurücksetzen
clr ptt_debounce ; Debounce Counter zurücksetzen
pulb
pulx
rts
pli_error
pula
ldaa #1
bra pli_end
;***************
; P L L L E D
;***************
;
; Überprüft PLL Lock wenn PLL Timer abgelaufen ist
; aktiviert rote LED, wenn PLL nicht eingerastet ist
;
; Check PLL lock state
; if pll_timer is zero OR
; update is enforced (A != 0)
;
; Parameter : A : Force (A=1 forces update)
;
; Ergebnis : Nichts
;
; changed Regs : A,B
;
pll_led
ldab LOCKPORT
andb #LOCKBIT
tsta
bne plc_force_update
ldaa pll_update_flag
anda #BIT_PLL_UPDATE_NOW ; check if UI task requests immediate
bne plc_force_update ; update of PLL state
ldaa pll_timer
bne plc_end ; PLL check timer is zero? If not, exit
tba ; transfer state to A
beq plc_state_is_0 ; check if bit is zero
ldaa #BIT_PLL_STATE ; else set PLL state bit
; (this is different from the port bit!)
plc_state_is_0
eora pll_locked_flag ; Check for state change
anda #BIT_PLL_STATE ; if there was no change
beq plc_end ; exit here
ldaa #PLLCHKTIMEOUT ; in case something changed
staa pll_timer ; delay display of next change by
; a small time, to avoid congestion of the
; display comm if lock is unstable
plc_force_update
tstb
bne plc_locked
aim #~(BIT_PLL_STATE),pll_locked_flag ; save new status (PLL unlocked)
ldab #RED_LED+LED_ON ; activate red LED
bra plc_set_led
plc_locked
oim #(BIT_PLL_STATE),pll_locked_flag ; save new status (PLL locked)
ldab #RED_LED+LED_OFF ; deactivate red LED
plc_set_led
jsr led_set ; set LED state
aim #~(BIT_PLL_UPDATE_NOW),pll_update_flag ; signal update of PLL state
plc_end
rts
;
;************************
; P L L L O C K C H K
;************************
;
; Liest PLL Lock Status von PLL IC ein
;
; Parameter : None
;
; Returns : B - Status
; 0 = NOT locked
; "LOCKBIT" = PLL locked
;
; changed Regs: B
;
pll_lock_chk
ldab LOCKPORT
andb #LOCKBIT ; nur PTT Lock detect Bit lesen
rts
;*******************************
; P L L S E T C H A N N E L
;*******************************
;
; programmiert die PLL auf den in X:D gegebenen Kanal
;
; Parameter : X:D - Kanal
;
; Ergebnis : Nichts
;
; changed Regs : none
;
;
pll_set_channel
stx channel
std channel+2 ; Kanal speichern
pshb
psha
pshx ; Dividend auf Stack
ldd #PRESCALER ; Vorteiler 127 für 70cm, 40 für 2m Version
; PLL Teiler für %128 Vorteiler berechnen
jsr divide32 ; 32 Bit Division, Dividend auf Stack, Divisor in D,
; Ergebnis auf Stack, Rest in X
xgdx ; Teiler N = Quotient,
; Teiler A = Rest
pulx ; Quotient HiWord vom Stack löschen
pulx ; Quotient LoWord (Teiler für N holen)
clra ; A = Reg Select (0=AN, 1=R)
jsr send2pll ; X = Divider Value N
; B = Divider Value A
ldaa #1 ; select R
clrb
ldx #PLLREF
jsr send2pll ; set R
rts
;**************************
; P L L S E T F R E Q
;**************************
;
; programmiert die PLL auf Frequenz
;
; Parameter : X - Zeiger auf Frequenz (32 Bit)
;
; Ergebnis : Nichts
;
; changed Regs : none
;
;
; pll_set_freq
; jsr frq_cv_freq_ch ; Frequenz in Kanal mit Schrittweite f_step umrechnen
; ; Kanal kommt in X:D
; jsr pll_set_channel ; PLL programmieren
;
; rts
;**************************
; S E T R X F R E Q
;**************************
;
; Setzt die Frequenz zum Empfang (Frequenz - 21,4MHz ZF)
;
; Parameter : X - Zeiger auf Frequenz (32 Bit)
;
; Ergebnis : Nichts
;
; changed Regs : A, B, X
;
;
set_rx_freq
ldd 2,x ; Frequenzwort LoWord nach D
pshb
psha ; Lo Word auf Stack
ldx 0,x ; Frequenzwort HiWord nach X
pshx ; HiWord auf Stack
ldd #RXZF%65536 ; RXZF LoWord
ldx #RXZF>>16 ; RXZF HiWord
jsr sub32 ; RXZF von Frequenzwort abziehen -> RX VCO Frequenz berechnen
; SUB32
;****
; RX VCO Frequenz setzen
; Frequenz in Kanal mit Schrittweite f_step umrechnen
tsx
pshx ; Zeiger auf Dividend auf Stack legen
ldd #FSTEP ; Divisor holen
jsr divide32s ; Durch Kanalabstand teilen
ins
ins
ldd #FSTEP ; Kanalabstand holen
lsrd ; durch 2 teilen
xgdx ; nach X bringen und Rest nach D
pshx ; Kanalabstand/2 auf Stack
tsx
subd 0,x ; Ist der Rest >= halber Kanalabstand?
pulx ; Stack bereinigen
pulx ; HiWord vom Stack holen
pula
pulb ; LoWord vom Stack holen
bcs srf_cfc_end ; abrunden wenn Rest < f_step/2
addd #1 ; oder aufrunden
xgdx
adcb #0
adca #0 ; eventuellen Übertrag berücksichtigen
xgdx
srf_cfc_end
;****
jsr pll_set_channel ; PLL programmieren
jsr frq_get_freq ; eingestellte Frequenz (entsprechend Kanalraster) holen
pshb
psha
pshx
ldx #RXZF>>16
ldd #RXZF%65536
jsr add32 ; ZF addieren
; ADD32
pulx
stx frequency
pulx
stx frequency+2 ; und Empfangsfrequenz speichern
rts ; Rücksprung
;**************************
; S E T T X F R E Q
;**************************
;
; Setzt die Frequenz zum Senden
;
; Parameter : X - Zeiger auf Frequenz (32 Bit)
;
; Ergebnis : Nichts
;
; changed Regs : none
;
;
set_tx_freq
ldd 2,x ; Frequenzwort LoWord nach D
pshb
psha
ldx 0,x ; Frequenzwort HiWord nach X
pshx ; auf Stack
ldd offset+2
ldx offset
jsr sub32 ; Offset von Frequenzwort abziehen -> TX VCO Frequenz berechnen
stf_set
;********
; TX VCO Frequenz setzen
; Frequenz in Kanal mit Schrittweite f_step umrechnen
ldd #FSTEP ; Divisor holen
jsr divide32 ; Durch Kanalabstand teilen
ldd #FSTEP ; Kanalabstand holen
lsrd ; durch 2 teilen
xgdx ; nach X bringen und Rest nach D
pshx ; Kanalabstand/2 auf Stack
tsx
subd 0,x ; Ist der Rest >= halber Kanalabstand?
pulx ; Stack bereinigen
pulx ; HiWord vom Stack holen
pula
pulb ; LoWord vom Stack holen
bcs stf_cfc_end ; abrunden wenn Rest < f_step/2
addd #1 ; oder aufrunden
xgdx
adcb
adca ; eventuellen Übertrag berücksichtigen
xgdx
stf_cfc_end
;********
jsr pll_set_channel ; PLL programmieren
jsr frq_get_freq ; eingestellte Frequenz (entsprechend Kanalraster) holen
pshb
psha
pshx
ldx offset
ldd offset+2
jsr add32
pulx
stx frequency
pulx
stx frequency+2 ; und neue Frequenz speichern
rts
;**************************
; S E T F R E Q
;**************************
;
; Setzt die Frequenz auf die X zeigt, prüft vorher ob gesendet oder empfangen wird
;
; Parameter : X - Zeiger auf Frequenz (32 Bit)
;
; Ergebnis : Nichts
;
; changed Regs : none
;
;
set_freq
ldab rxtx_state ; senden oder empfangen wir gerade?
bne sfq_tx ; entsprechend status die Frequenz setzen
jmp set_rx_freq
sfq_tx
jmp set_tx_freq
;******************************
; F R Q C V F R E Q C H
;******************************
;
; Umrechnung Frequenz in Kanal
;
; Parameter : X - Zeiger auf Frequenz DWord
;
; Ergebnis : X:D - Kanal (Kanalabstand = f_step)
;
; changed Regs : D,X
;
;
frq_cv_freq_ch
ldd 2,x ; Frequenz LoWord und
ldx 0,x ; Frequenz HiWord holen
pshb
psha
pshx ; Frequenz=Dividend auf Stack
ldd #FSTEP ; Divisor holen
jsr divide32 ; Durch Kanalabstand teilen
ldd #FSTEP ; Kanalabstand holen
lsrd ; durch 2 teilen
xgdx ; nach X bringen und Rest nach D
pshx ; Kanalabstand/2 auf Stack
tsx
subd 0,x ; Ist der Rest >= halber Kanalabstand?
pulx ; Stack bereinigen
pulx ; HiWord vom Stack holen
pula
pulb ; LoWord vom Stack holen
bcs cfc_end ; abrunden wenn Rest < f_step/2
addd #1 ; oder aufrunden
xgdx
adcb
adca ; eventuellen Übertrag berücksichtigen
xgdx
cfc_end
rts
;******************************
; F R Q C V C H F R E Q
;******************************
;
; Umrechnung Kanal in Frequenz
;
; Parameter : X:D - Kanal
;
; Ergebnis : X:D - Frequenz des aktuell eingestellten Kanals
;
; changed Regs : D,X
;
;
frq_cv_ch_freq
pshb
psha
pshx ; Kanal auf Stack speichern
ldd #FSTEP ; Kanalabstand holen
ldx #0 ; HiWord = 0
jsr multiply32 ; Frequenz berechnen
rts
;**************************
; F R Q G E T F R E Q
;**************************
;
; Liefert die aktuell eingestellte Frequenz
;
;
; Parameter : none
;
; Ergebnis : X:D - Frequenz des aktuell eingestellten Kanals
;
; changed Regs : D,X
;
;
frq_get_freq
ldx channel+2
pshx
ldx channel
pshx
ldd #FSTEP
ldx #0
jsr multiply32
ins
ins
ins
ins ; Kanal vom Stack löschen
rts
;**********************
; F R Q U P D A T E
;**********************
;
; Funktion wird von UI Task aufgerufen. Teilt Control Task mit, dass eine neue Frequenz gesetzt wurde
;
; Parameter : X - Zeiger auf Frequenzwort
;
; Returns : Nothing
;
; changed Regs : None
;
frq_update
pshb
psha
ldd 2,x ; Frequenz holen
std ui_frequency+2
ldd 0,x
std ui_frequency ; Frequenz speichern
swi ; Taskswitch durchführen
pula
pulb
rts
;********************
; F R E Q P R I N T
;********************
;
; UI - Task
;
; Gibt Frequenz auf Display aus
;
; Parameter : X - Zeiger auf Frequenzwort
;
; Returns : Nothing
;
; changed Regs : A, B, X
;
freq_print
ldd 0,x ; Frequenz Hi Word holen
ldx 2,x ; Frequenz Lo Word holen
pshx ; Lo Word auf Stack
pshb
psha ; Hi Word auf Stack
ldaa #'l' ; unsigned Longint ausgeben
ldab #3 ; die letzten 3 Stellen abscheiden
jsr putchar
pulx
pulx ; Frequenz von Stack löschen
rts
;
;********************************
; F R E Q S E T O F F S E T
;********************************
;
; UI - Task
;
; Gibt aktuelles Offset auf Display aus
;
; Parameter : None
;
; Returns : Nothing
;
; changed Regs : None
;
;
;***********************************
; F R E Q O F F S E T P R I N T
;***********************************
;
; UI - Task
;
; Gibt aktuelles Offset auf Display aus
;
; Parameter : None
;
; Returns : Nothing
;
; changed Regs : A, B, X
;
freq_offset_print
clra ; Arrow = Off
ldx offset
beq fop_end ; Offset = 0 -> Pfeil aus
ldx offset+2
beq fop_end ; Offset = 0 -> Pfeil aus
ldx offset
bmi fop_negative ; TX Shift negativ? -> Pfeil an
; TX Shift positiv? -> Pfeil blinkt
ldaa #1
bra fop_end
fop_negative
ldaa #2
fop_end
ldab #6
jsr arrow_set
rts
;
;**********************
; F R E Q C H E C K
;**********************
;
; Control - Task
;
; Prüft auf Änderung der Frequenz und der TX Shift durch UI Task
; Setzt ggf. Frequenz und/oder Offset neu
;
; Parameter : None
;
; Returns : Nothing
;
; chanegd Regs : A, B, X
;
frq_check
ldx ui_frequency ; Neue Frequenz eingegeben?
beq frc_chk_shift ; = 0? Dann hat sich nix geändert
ldx #ui_frequency ; Zeiger auf Frequenz holen
jsr set_freq ; Frequenz setzen
ldx #0
stx ui_frequency ; Frequenz Flag setzen
frc_chk_shift
ldx ui_txshift
cpx #-1
beq frc_end ; neue Shift ?
stx offset
ldx ui_txshift+2
stx offset+2
ldx #-1
stx ui_txshift ; Frequenz Flag setzen
frc_end
rts