-
-
Notifications
You must be signed in to change notification settings - Fork 594
/
link.d
1562 lines (1475 loc) · 56 KB
/
link.d
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/**
* Compiler implementation of the
* $(LINK2 http://www.dlang.org, D programming language).
*
* Copyright: Copyright (C) 1999-2019 by The D Language Foundation, All Rights Reserved
* Authors: $(LINK2 http://www.digitalmars.com, Walter Bright)
* License: $(LINK2 http://www.boost.org/LICENSE_1_0.txt, Boost License 1.0)
* Source: $(LINK2 https://github.com/dlang/dmd/blob/master/src/dmd/link.d, _link.d)
* Documentation: https://dlang.org/phobos/dmd_link.html
* Coverage: https://codecov.io/gh/dlang/dmd/src/master/src/dmd/link.d
*/
module dmd.link;
import core.stdc.ctype;
import core.stdc.stdio;
import core.stdc.string;
import core.sys.posix.stdio;
import core.sys.posix.stdlib;
import core.sys.posix.unistd;
import core.sys.windows.winbase;
import core.sys.windows.windef;
import core.sys.windows.winreg;
import dmd.errors;
import dmd.globals;
import dmd.root.file;
import dmd.root.filename;
import dmd.root.outbuffer;
import dmd.root.rmem;
import dmd.utils;
version (Posix) extern (C) int pipe(int*);
version (Windows) extern (C) int putenv(const char*);
version (Windows) extern (C) int spawnlp(int, const char*, const char*, const char*, const char*);
version (Windows) extern (C) int spawnl(int, const char*, const char*, const char*, const char*);
version (Windows) extern (C) int spawnv(int, const char*, const char**);
version (CRuntime_Microsoft)
{
// until the new windows bindings are available when building dmd.
static if(!is(STARTUPINFOA))
{
alias STARTUPINFOA = STARTUPINFO;
// dwCreationFlags for CreateProcess() and CreateProcessAsUser()
enum : DWORD {
DEBUG_PROCESS = 0x00000001,
DEBUG_ONLY_THIS_PROCESS = 0x00000002,
CREATE_SUSPENDED = 0x00000004,
DETACHED_PROCESS = 0x00000008,
CREATE_NEW_CONSOLE = 0x00000010,
NORMAL_PRIORITY_CLASS = 0x00000020,
IDLE_PRIORITY_CLASS = 0x00000040,
HIGH_PRIORITY_CLASS = 0x00000080,
REALTIME_PRIORITY_CLASS = 0x00000100,
CREATE_NEW_PROCESS_GROUP = 0x00000200,
CREATE_UNICODE_ENVIRONMENT = 0x00000400,
CREATE_SEPARATE_WOW_VDM = 0x00000800,
CREATE_SHARED_WOW_VDM = 0x00001000,
CREATE_FORCEDOS = 0x00002000,
BELOW_NORMAL_PRIORITY_CLASS = 0x00004000,
ABOVE_NORMAL_PRIORITY_CLASS = 0x00008000,
CREATE_BREAKAWAY_FROM_JOB = 0x01000000,
CREATE_WITH_USERPROFILE = 0x02000000,
CREATE_DEFAULT_ERROR_MODE = 0x04000000,
CREATE_NO_WINDOW = 0x08000000,
PROFILE_USER = 0x10000000,
PROFILE_KERNEL = 0x20000000,
PROFILE_SERVER = 0x40000000
}
}
}
/****************************************
* Write filename to cmdbuf, quoting if necessary.
*/
private void writeFilename(OutBuffer* buf, const(char)[] filename)
{
/* Loop and see if we need to quote
*/
foreach (const char c; filename)
{
if (isalnum(c) || c == '_')
continue;
/* Need to quote
*/
buf.writeByte('"');
buf.writestring(filename);
buf.writeByte('"');
return;
}
/* No quoting necessary
*/
buf.writestring(filename);
}
private void writeFilename(OutBuffer* buf, const(char)* filename)
{
writeFilename(buf, filename.toDString());
}
version (Posix)
{
/*****************************
* As it forwards the linker error message to stderr, checks for the presence
* of an error indicating lack of a main function (NME_ERR_MSG).
*
* Returns:
* 1 if there is a no main error
* -1 if there is an IO error
* 0 otherwise
*/
private int findNoMainError(int fd)
{
version (OSX)
{
static immutable(char*) nmeErrorMessage = "`__Dmain`, referenced from:";
}
else
{
static immutable(char*) nmeErrorMessage = "undefined reference to `_Dmain`";
}
FILE* stream = fdopen(fd, "r");
if (stream is null)
return -1;
const(size_t) len = 64 * 1024 - 1;
char[len + 1] buffer; // + '\0'
size_t beg = 0, end = len;
bool nmeFound = false;
for (;;)
{
// read linker output
const(size_t) n = fread(&buffer[beg], 1, len - beg, stream);
if (beg + n < len && ferror(stream))
return -1;
buffer[(end = beg + n)] = '\0';
// search error message, stop at last complete line
const(char)* lastSep = strrchr(buffer.ptr, '\n');
if (lastSep)
buffer[(end = lastSep - &buffer[0])] = '\0';
if (strstr(&buffer[0], nmeErrorMessage))
nmeFound = true;
if (lastSep)
buffer[end++] = '\n';
if (fwrite(&buffer[0], 1, end, stderr) < end)
return -1;
if (beg + n < len && feof(stream))
break;
// copy over truncated last line
memcpy(&buffer[0], &buffer[end], (beg = len - end));
}
return nmeFound ? 1 : 0;
}
}
/*****************************
* Run the linker. Return status of execution.
*/
public int runLINK()
{
const phobosLibname = global.params.betterC ? null :
global.params.symdebug ? global.params.debuglibname : global.params.defaultlibname;
version (Windows)
{
if (phobosLibname)
global.params.libfiles.push(phobosLibname);
if (global.params.mscoff)
{
OutBuffer cmdbuf;
cmdbuf.writestring("/NOLOGO");
for (size_t i = 0; i < global.params.objfiles.dim; i++)
{
cmdbuf.writeByte(' ');
const(char)* p = global.params.objfiles[i];
writeFilename(&cmdbuf, p);
}
if (global.params.resfile)
{
cmdbuf.writeByte(' ');
writeFilename(&cmdbuf, global.params.resfile);
}
cmdbuf.writeByte(' ');
if (global.params.exefile)
{
cmdbuf.writestring("/OUT:");
writeFilename(&cmdbuf, global.params.exefile);
}
else
{
/* Generate exe file name from first obj name.
* No need to add it to cmdbuf because the linker will default to it.
*/
const(char)* n = global.params.objfiles[0];
n = FileName.name(n);
global.params.exefile = FileName.forceExt(n, "exe");
}
// Make sure path to exe file exists
ensurePathToNameExists(Loc.initial, global.params.exefile);
cmdbuf.writeByte(' ');
if (global.params.mapfile)
{
cmdbuf.writestring("/MAP:");
writeFilename(&cmdbuf, global.params.mapfile);
}
else if (global.params.map)
{
const(char)* fn = FileName.forceExt(global.params.exefile, "map");
const(char)* path = FileName.path(global.params.exefile);
const(char)* p;
if (path[0] == '\0')
p = FileName.combine(global.params.objdir, fn);
else
p = fn;
cmdbuf.writestring("/MAP:");
writeFilename(&cmdbuf, p);
}
for (size_t i = 0; i < global.params.libfiles.dim; i++)
{
cmdbuf.writeByte(' ');
cmdbuf.writestring("/DEFAULTLIB:");
writeFilename(&cmdbuf, global.params.libfiles[i]);
}
if (global.params.deffile)
{
cmdbuf.writeByte(' ');
cmdbuf.writestring("/DEF:");
writeFilename(&cmdbuf, global.params.deffile);
}
if (global.params.symdebug)
{
cmdbuf.writeByte(' ');
cmdbuf.writestring("/DEBUG");
// in release mode we need to reactivate /OPT:REF after /DEBUG
if (global.params.release)
cmdbuf.writestring(" /OPT:REF");
}
if (global.params.dll)
{
cmdbuf.writeByte(' ');
cmdbuf.writestring("/DLL");
}
for (size_t i = 0; i < global.params.linkswitches.dim; i++)
{
cmdbuf.writeByte(' ');
cmdbuf.writestring(global.params.linkswitches[i]);
}
VSOptions vsopt;
vsopt.initialize();
const(char)* lflags = vsopt.linkOptions(global.params.is64bit);
if (lflags)
{
cmdbuf.writeByte(' ');
cmdbuf.writestring(lflags);
}
char* p = cmdbuf.peekString();
const(char)* lnkfilename = null;
const size_t plen = strlen(p);
if (plen > 7000)
{
lnkfilename = FileName.forceExt(global.params.exefile, "lnk");
auto flnk = File(lnkfilename);
flnk.setbuffer(p, plen);
flnk._ref = 1;
if (flnk.write())
error(Loc.initial, "error writing file %s", lnkfilename);
if (strlen(lnkfilename) < plen)
sprintf(p, "@%s", lnkfilename);
}
const(char)* linkcmd = getenv(global.params.is64bit ? "LINKCMD64" : "LINKCMD");
if (!linkcmd)
linkcmd = getenv("LINKCMD"); // backward compatible
if (!linkcmd)
linkcmd = vsopt.linkerPath(global.params.is64bit);
const int status = executecmd(linkcmd, p);
if (lnkfilename)
{
remove(lnkfilename);
FileName.free(lnkfilename);
}
return status;
}
else
{
OutBuffer cmdbuf;
global.params.libfiles.push("user32");
global.params.libfiles.push("kernel32");
for (size_t i = 0; i < global.params.objfiles.dim; i++)
{
if (i)
cmdbuf.writeByte('+');
const(char)* p = global.params.objfiles[i];
const(char)* basename = FileName.removeExt(FileName.name(p));
const(char)* ext = FileName.ext(p);
if (ext && !strchr(basename, '.'))
{
// Write name sans extension (but not if a double extension)
writeFilename(&cmdbuf, p[0 .. ext - p - 1]);
}
else
writeFilename(&cmdbuf, p);
FileName.free(basename);
}
cmdbuf.writeByte(',');
if (global.params.exefile)
writeFilename(&cmdbuf, global.params.exefile);
else
{
/* Generate exe file name from first obj name.
* No need to add it to cmdbuf because the linker will default to it.
*/
const(char)* n = global.params.objfiles[0];
n = FileName.name(n);
global.params.exefile = FileName.forceExt(n, "exe");
}
// Make sure path to exe file exists
ensurePathToNameExists(Loc.initial, global.params.exefile);
cmdbuf.writeByte(',');
if (global.params.mapfile)
writeFilename(&cmdbuf, global.params.mapfile);
else if (global.params.map)
{
const(char)* fn = FileName.forceExt(global.params.exefile, "map");
const(char)* path = FileName.path(global.params.exefile);
const(char)* p;
if (path[0] == '\0')
p = FileName.combine(global.params.objdir, fn);
else
p = fn;
writeFilename(&cmdbuf, p);
}
else
cmdbuf.writestring("nul");
cmdbuf.writeByte(',');
for (size_t i = 0; i < global.params.libfiles.dim; i++)
{
if (i)
cmdbuf.writeByte('+');
writeFilename(&cmdbuf, global.params.libfiles[i]);
}
if (global.params.deffile)
{
cmdbuf.writeByte(',');
writeFilename(&cmdbuf, global.params.deffile);
}
/* Eliminate unnecessary trailing commas */
while (1)
{
const size_t i = cmdbuf.offset;
if (!i || cmdbuf.data[i - 1] != ',')
break;
cmdbuf.offset--;
}
if (global.params.resfile)
{
cmdbuf.writestring("/RC:");
writeFilename(&cmdbuf, global.params.resfile);
}
if (global.params.map || global.params.mapfile)
cmdbuf.writestring("/m");
version (none)
{
if (debuginfo)
cmdbuf.writestring("/li");
if (codeview)
{
cmdbuf.writestring("/co");
if (codeview3)
cmdbuf.writestring(":3");
}
}
else
{
if (global.params.symdebug)
cmdbuf.writestring("/co");
}
cmdbuf.writestring("/noi");
for (size_t i = 0; i < global.params.linkswitches.dim; i++)
{
cmdbuf.writestring(global.params.linkswitches[i]);
}
cmdbuf.writeByte(';');
char* p = cmdbuf.peekString();
const(char)* lnkfilename = null;
const size_t plen = strlen(p);
if (plen > 7000)
{
lnkfilename = FileName.forceExt(global.params.exefile, "lnk");
auto flnk = File(lnkfilename);
flnk.setbuffer(p, plen);
flnk._ref = 1;
if (flnk.write())
error(Loc.initial, "error writing file %s", lnkfilename);
if (strlen(lnkfilename) < plen)
sprintf(p, "@%s", lnkfilename);
}
const(char)* linkcmd = getenv("LINKCMD");
if (!linkcmd)
linkcmd = "link";
const int status = executecmd(linkcmd, p);
if (lnkfilename)
{
remove(lnkfilename);
FileName.free(lnkfilename);
}
return status;
}
}
else version (Posix)
{
pid_t childpid;
int status;
// Build argv[]
Strings argv;
const(char)* cc = getenv("CC");
if (!cc)
{
argv.push("cc");
}
else
{
// Split CC command to support link driver arguments such as -fpie or -flto.
char *arg = strdup(cc);
const(char)* tok = strtok(arg, " ");
while (tok)
{
argv.push(mem.xstrdup(tok));
tok = strtok(null, " ");
}
free(arg);
}
argv.append(&global.params.objfiles);
version (OSX)
{
// If we are on Mac OS X and linking a dynamic library,
// add the "-dynamiclib" flag
if (global.params.dll)
argv.push("-dynamiclib");
}
else version (Posix)
{
if (global.params.dll)
argv.push("-shared");
}
// None of that a.out stuff. Use explicit exe file name, or
// generate one from name of first source file.
argv.push("-o");
if (global.params.exefile)
{
argv.push(global.params.exefile);
}
else if (global.params.run)
{
version (all)
{
char[L_tmpnam + 14 + 1] name;
strcpy(name.ptr, P_tmpdir);
strcat(name.ptr, "/dmd_runXXXXXX");
int fd = mkstemp(name.ptr);
if (fd == -1)
{
error(Loc.initial, "error creating temporary file");
return 1;
}
else
close(fd);
global.params.exefile = mem.xstrdup(name.ptr);
argv.push(global.params.exefile);
}
else
{
/* The use of tmpnam raises the issue of "is this a security hole"?
* The hole is that after tmpnam and before the file is opened,
* the attacker modifies the file system to get control of the
* file with that name. I do not know if this is an issue in
* this context.
* We cannot just replace it with mkstemp, because this name is
* passed to the linker that actually opens the file and writes to it.
*/
char[L_tmpnam + 1] s;
char* n = tmpnam(s.ptr);
global.params.exefile = mem.xstrdup(n);
argv.push(global.params.exefile);
}
}
else
{
// Generate exe file name from first obj name
const(char)[] n = global.params.objfiles[0].toDString();
const(char)[] ex;
n = FileName.name(n);
if (const e = FileName.ext(n))
{
if (global.params.dll)
ex = FileName.forceExt(ex, global.dll_ext.toDString());
else
ex = FileName.removeExt(n);
}
else
ex = "a.out"; // no extension, so give up
argv.push(ex.ptr);
global.params.exefile = ex.ptr;
}
// Make sure path to exe file exists
ensurePathToNameExists(Loc.initial, global.params.exefile);
if (global.params.symdebug)
argv.push("-g");
if (global.params.is64bit)
argv.push("-m64");
else
argv.push("-m32");
version (OSX)
{
/* Without this switch, ld generates messages of the form:
* ld: warning: could not create compact unwind for __Dmain: offset of saved registers too far to encode
* meaning they are further than 255 bytes from the frame register.
* ld reverts to the old method instead.
* See: https://ghc.haskell.org/trac/ghc/ticket/5019
* which gives this tidbit:
* "When a C++ (or x86_64 Objective-C) exception is thrown, the runtime must unwind the
* stack looking for some function to catch the exception. Traditionally, the unwind
* information is stored in the __TEXT/__eh_frame section of each executable as Dwarf
* CFI (call frame information). Beginning in Mac OS X 10.6, the unwind information is
* also encoded in the __TEXT/__unwind_info section using a two-level lookup table of
* compact unwind encodings.
* The unwinddump tool displays the content of the __TEXT/__unwind_info section."
*
* A better fix would be to save the registers next to the frame pointer.
*/
argv.push("-Xlinker");
argv.push("-no_compact_unwind");
}
if (global.params.map || global.params.mapfile)
{
argv.push("-Xlinker");
version (OSX)
{
argv.push("-map");
}
else
{
argv.push("-Map");
}
if (!global.params.mapfile)
{
const(char)* fn = FileName.forceExt(global.params.exefile, "map");
const(char)* path = FileName.path(global.params.exefile);
const(char)* p;
if (path[0] == '\0')
p = FileName.combine(global.params.objdir, fn);
else
p = fn;
global.params.mapfile = cast(char*)p;
}
argv.push("-Xlinker");
argv.push(global.params.mapfile);
}
if (0 && global.params.exefile)
{
/* This switch enables what is known as 'smart linking'
* in the Windows world, where unreferenced sections
* are removed from the executable. It eliminates unreferenced
* functions, essentially making a 'library' out of a module.
* Although it is documented to work with ld version 2.13,
* in practice it does not, but just seems to be ignored.
* Thomas Kuehne has verified that it works with ld 2.16.1.
* BUG: disabled because it causes exception handling to fail
* because EH sections are "unreferenced" and elided
*/
argv.push("-Xlinker");
argv.push("--gc-sections");
}
/* Add libraries. The order of libraries passed is:
* 1. link switches others than with -L command line switch,
e.g. --whole-archive "lib.a" --no-whole-archive (global.params.linkswitches)
* 2. static libraries ending with *.a (global.params.libfiles)
* 3. link switches passed with -L command line switch (global.params.linkswitches)
* 4. libraries specified by pragma(lib), which were appended
* to global.params.libfiles. These are prefixed with "-l"
* 5. dynamic libraries passed to the command line (global.params.dllfiles)
* 6. standard libraries.
*/
foreach (p; global.params.linkswitches)
{
if (p && p[0] && !(p[0] == '-' && (p[1] == 'l' || p[1] == 'L')))
{
argv.push("-Xlinker");
argv.push(p);
}
}
foreach (p; global.params.libfiles)
{
if (FileName.equalsExt(p, "a"))
argv.push(p);
}
foreach (p; global.params.linkswitches)
{
if (!p || !p[0])
{
// Don't need -Xlinker if switch starts with -l or -L.
// Eliding -Xlinker is significant for -L since it allows our paths
// to take precedence over gcc defaults.
// All other link switches were already added in step 1.
argv.push("-Xlinker");
}
if (!p || !p[0] || p[0] == '-' && (p[1] == 'l' || p[1] == 'L'))
argv.push(p);
}
foreach (p; global.params.libfiles)
{
if (!FileName.equalsExt(p, "a"))
{
const plen = strlen(p);
char* s = cast(char*)mem.xmalloc(plen + 3);
s[0] = '-';
s[1] = 'l';
memcpy(s + 2, p, plen + 1);
argv.push(s);
}
}
foreach (p; global.params.dllfiles)
{
argv.push(p);
}
/* D runtime libraries must go after user specified libraries
* passed with -l.
*/
const libname = phobosLibname.toDString();
if (libname.length)
{
const bufsize = 2 + libname.length + 1;
auto buf = (cast(char*) malloc(bufsize))[0 .. bufsize];
buf[0 .. 2] = "-l";
char* getbuf(const(char)[] suffix)
{
buf[2 .. 2 + suffix.length] = suffix[];
buf[2 + suffix.length] = 0;
return buf.ptr;
}
if (libname.length > 3 + 2 && libname[0 .. 3] == "lib")
{
if (libname[$-2 .. $] == ".a")
{
argv.push("-Xlinker");
argv.push("-Bstatic");
argv.push(getbuf(libname[3 .. $-2]));
argv.push("-Xlinker");
argv.push("-Bdynamic");
}
else if (libname[$-3 .. $] == ".so")
argv.push(getbuf(libname[3 .. $-3]));
else
argv.push(getbuf(libname));
}
else
{
argv.push(getbuf(libname));
}
}
//argv.push("-ldruntime");
argv.push("-lpthread");
argv.push("-lm");
version (linux)
{
// Changes in ld for Ubuntu 11.10 require this to appear after phobos2
argv.push("-lrt");
// Link against libdl for phobos usage of dlopen
argv.push("-ldl");
}
if (global.params.verbose)
{
// Print it
OutBuffer buf;
for (size_t i = 0; i < argv.dim; i++)
{
buf.writestring(argv[i]);
buf.writeByte(' ');
}
message(buf.peekString());
}
argv.push(null);
// set up pipes
int[2] fds;
if (pipe(fds.ptr) == -1)
{
perror("unable to create pipe to linker");
return -1;
}
childpid = fork();
if (childpid == 0)
{
// pipe linker stderr to fds[0]
dup2(fds[1], STDERR_FILENO);
close(fds[0]);
execvp(argv[0], argv.tdata());
perror(argv[0]); // failed to execute
return -1;
}
else if (childpid == -1)
{
perror("unable to fork");
return -1;
}
close(fds[1]);
const(int) nme = findNoMainError(fds[0]);
waitpid(childpid, &status, 0);
if (WIFEXITED(status))
{
status = WEXITSTATUS(status);
if (status)
{
if (nme == -1)
{
perror("error with the linker pipe");
return -1;
}
else
{
error(Loc.initial, "linker exited with status %d", status);
if (nme == 1)
error(Loc.initial, "no main function specified");
}
}
}
else if (WIFSIGNALED(status))
{
error(Loc.initial, "linker killed by signal %d", WTERMSIG(status));
status = 1;
}
return status;
}
else
{
error(Loc.initial, "linking is not yet supported for this version of DMD.");
return -1;
}
}
/******************************
* Execute a rule. Return the status.
* cmd program to run
* args arguments to cmd, as a string
*/
version (Windows)
{
private int executecmd(const(char)* cmd, const(char)* args)
{
int status;
size_t len;
if (global.params.verbose)
message("%s %s", cmd, args);
if (!global.params.mscoff)
{
if ((len = strlen(args)) > 255)
{
char* q = cast(char*)alloca(8 + len + 1);
sprintf(q, "_CMDLINE=%s", args);
status = putenv(q);
if (status == 0)
{
args = "@_CMDLINE";
}
else
{
error(Loc.initial, "command line length of %d is too long", len);
}
}
}
// Normalize executable path separators
// https://issues.dlang.org/show_bug.cgi?id=9330
cmd = toWinPath(cmd);
version (CRuntime_Microsoft)
{
// Open scope so dmd doesn't complain about alloca + exception handling
{
// Use process spawning through the WinAPI to avoid issues with executearg0 and spawnlp
OutBuffer cmdbuf;
cmdbuf.writestring("\"");
cmdbuf.writestring(cmd);
cmdbuf.writestring("\" ");
cmdbuf.writestring(args);
STARTUPINFOA startInf;
startInf.dwFlags = STARTF_USESTDHANDLES;
startInf.hStdInput = GetStdHandle(STD_INPUT_HANDLE);
startInf.hStdOutput = GetStdHandle(STD_OUTPUT_HANDLE);
startInf.hStdError = GetStdHandle(STD_ERROR_HANDLE);
PROCESS_INFORMATION procInf;
BOOL b = CreateProcessA(null, cmdbuf.peekString(), null, null, 1, NORMAL_PRIORITY_CLASS, null, null, &startInf, &procInf);
if (b)
{
WaitForSingleObject(procInf.hProcess, INFINITE);
DWORD returnCode;
GetExitCodeProcess(procInf.hProcess, &returnCode);
status = returnCode;
CloseHandle(procInf.hProcess);
}
else
{
status = -1;
}
}
}
else
{
status = executearg0(cmd, args);
if (status == -1)
{
status = spawnlp(0, cmd, cmd, args, null);
}
}
if (status)
{
if (status == -1)
error(Loc.initial, "can't run '%s', check PATH", cmd);
else
error(Loc.initial, "linker exited with status %d", status);
}
return status;
}
}
/**************************************
* Attempt to find command to execute by first looking in the directory
* where DMD was run from.
* Returns:
* -1 did not find command there
* !=-1 exit status from command
*/
version (Windows)
{
private int executearg0(const(char)* cmd, const(char)* args)
{
const argv0 = global.params.argv0;
//printf("argv0='%s', cmd='%s', args='%s'\n",argv0,cmd,args);
// If cmd is fully qualified, we don't do this
if (FileName.absolute(cmd))
return -1;
const file = FileName.replaceName(argv0, cmd.toDString);
//printf("spawning '%s'\n",file);
// spawnlp returns intptr_t in some systems, not int
return spawnl(0, file.ptr, file.ptr, args, null);
}
}
/***************************************
* Run the compiled program.
* Return exit status.
*/
public int runProgram()
{
//printf("runProgram()\n");
if (global.params.verbose)
{
OutBuffer buf;
buf.writestring(global.params.exefile);
for (size_t i = 0; i < global.params.runargs.dim; ++i)
{
buf.writeByte(' ');
buf.writestring(global.params.runargs[i]);
}
message(buf.peekString());
}
// Build argv[]
Strings argv;
argv.push(global.params.exefile);
for (size_t i = 0; i < global.params.runargs.dim; ++i)
{
const(char)* a = global.params.runargs[i];
version (Windows)
{
// BUG: what about " appearing in the string?
if (strchr(a, ' '))
{
char* b = cast(char*)mem.xmalloc(3 + strlen(a));
sprintf(b, "\"%s\"", a);
a = b;
}
}
argv.push(a);
}
argv.push(null);
version (Windows)
{
const(char)* ex = FileName.name(global.params.exefile);
if (ex == global.params.exefile)
ex = FileName.combine(".", ex);
else
ex = global.params.exefile;
// spawnlp returns intptr_t in some systems, not int
return spawnv(0, ex, argv.tdata());
}
else version (Posix)
{
pid_t childpid;
int status;
childpid = fork();
if (childpid == 0)
{
const(char)* fn = argv[0];
if (!FileName.absolute(fn))
{
// Make it "./fn"
fn = FileName.combine(".", fn);
}
execv(fn, argv.tdata());
perror(fn); // failed to execute
return -1;
}
waitpid(childpid, &status, 0);
if (WIFEXITED(status))
{
status = WEXITSTATUS(status);
//printf("--- errorlevel %d\n", status);
}
else if (WIFSIGNALED(status))
{
error(Loc.initial, "program killed by signal %d", WTERMSIG(status));
status = 1;
}
return status;
}
else
{
assert(0);
}
}
version (Windows)
{
struct VSOptions
{
// evaluated once at startup, reflecting the result of vcvarsall.bat
// from the current environment or the latest Visual Studio installation
const(char)* WindowsSdkDir;
const(char)* WindowsSdkVersion;
const(char)* UCRTSdkDir;
const(char)* UCRTVersion;
const(char)* VSInstallDir;
const(char)* VCInstallDir;
const(char)* VCToolsInstallDir; // used by VS 2017+
/**
* fill member variables from environment or registry
*/
void initialize()
{
detectWindowsSDK();
detectUCRT();
detectVSInstallDir();
detectVCInstallDir();
detectVCToolsInstallDir();
}
/**
* retrieve the name of the default C runtime library
* Params:
* x64 = target architecture (x86 if false)
* Returns:
* name of the default C runtime library
*/
const(char)* defaultRuntimeLibrary(bool x64)
{
if (VCInstallDir is null)
{
detectVCInstallDir();
detectVCToolsInstallDir();
}
if (getVCLibDir(x64))
return "libcmt";
else
return "msvcrt100"; // mingw replacement
}
/**
* retrieve options to be passed to the Microsoft linker
* Params:
* x64 = target architecture (x86 if false)
* Returns:
* allocated string of options to add to the linker command line
*/
const(char)* linkOptions(bool x64)
{
OutBuffer cmdbuf;
if (auto vclibdir = getVCLibDir(x64))
{
cmdbuf.writestring(" /LIBPATH:\"");
cmdbuf.writestring(vclibdir);
cmdbuf.writeByte('\"');
if (FileName.exists(FileName.combine(vclibdir, "legacy_stdio_definitions.lib")))
{
// VS2015 or later use UCRT
cmdbuf.writestring(" legacy_stdio_definitions.lib");