-
-
Notifications
You must be signed in to change notification settings - Fork 701
/
aligned_block_list.d
699 lines (588 loc) · 21.1 KB
/
aligned_block_list.d
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
// Written in the D programming language.
/**
`AlignedBlockList` represents a wrapper around a chain of allocators, allowing for fast deallocations
and preserving a low degree of fragmentation by means of aligned allocations.
Source: $(PHOBOSSRC std/experimental/allocator/building_blocks/aligned_block_list.d)
*/
module std.experimental.allocator.building_blocks.aligned_block_list;
import std.experimental.allocator.common;
import std.experimental.allocator.building_blocks.null_allocator;
// Common function implementation for thread local and shared AlignedBlockList
private mixin template AlignedBlockListImpl(bool isShared)
{
import std.traits : hasMember;
import std.typecons : Ternary;
static if (isShared)
import core.internal.spinlock : SpinLock;
private:
// Doubly linked list of 'AlignedBlockNode'
// Each node contains an `Allocator` followed by its payload
static struct AlignedBlockNode
{
AlignedBlockNode* next, prev;
Allocator bAlloc;
static if (isShared)
{
shared(size_t) bytesUsed;
// Since the lock is not taken when allocating, this acts like a refcount
// keeping the node alive
uint keepAlive;
}
else
{
size_t bytesUsed;
}
}
// Root of the internal doubly linked list
AlignedBlockNode* root;
// Number of active nodes
uint numNodes;
// If the numNodes exceeds this limit, we will start deallocating nodes
enum uint maxNodes = 64;
// This lock is always taken when changing the list
// To improve performance, the lock is not taken when the allocation logic is called
static if (isShared)
SpinLock lock = SpinLock(SpinLock.Contention.brief);
// Moves a node to the front of the list, allowing for quick allocations
void moveToFront(AlignedBlockNode* tmp)
{
auto localRoot = cast(AlignedBlockNode*) root;
if (tmp == localRoot)
return;
if (tmp.prev) tmp.prev.next = tmp.next;
if (tmp.next) tmp.next.prev = tmp.prev;
if (localRoot) localRoot.prev = tmp;
tmp.next = localRoot;
tmp.prev = null;
root = cast(typeof(root)) tmp;
}
// Removes a node from the list, including its payload
// The payload is deallocated by calling 'parent.deallocate'
void removeNode(AlignedBlockNode* tmp)
{
auto next = tmp.next;
if (tmp.prev) tmp.prev.next = tmp.next;
if (tmp.next) tmp.next.prev = tmp.prev;
parent.deallocate((cast(void*) tmp)[0 .. theAlignment]);
if (tmp == cast(AlignedBlockNode*) root)
root = cast(typeof(root)) next;
static if (isShared)
{
import core.atomic : atomicOp;
atomicOp!"-="(numNodes, 1);
}
else
{
numNodes--;
}
}
// If the nodes do not have available space, a new node is created
// by drawing memory from the parent allocator with aligned allocations.
// The new node is inserted at the front of the list
bool insertNewNode()
{
void[] buf = parent.alignedAllocate(theAlignment, theAlignment);
if (buf is null)
return false;
auto localRoot = cast(AlignedBlockNode*) root;
auto newNode = cast(AlignedBlockNode*) buf;
// The first part of the allocation represent the node contents
// followed by the actual payload
ubyte[] payload = cast(ubyte[]) buf[AlignedBlockNode.sizeof .. $];
newNode.bAlloc = Allocator(payload);
newNode.next = localRoot;
newNode.prev = null;
if (localRoot)
localRoot.prev = newNode;
root = cast(typeof(root)) newNode;
static if (isShared)
{
import core.atomic : atomicOp;
atomicOp!"+="(numNodes, 1);
}
else
{
numNodes++;
}
return true;
}
public:
static if (stateSize!ParentAllocator) ParentAllocator parent;
else alias parent = ParentAllocator.instance;
enum ulong alignment = Allocator.alignment;
// Since all memory is drawn from ParentAllocator, we can
// forward this to the parent
static if (hasMember!(ParentAllocator, "owns"))
Ternary owns(void[] b)
{
return parent.owns(b);
}
// Use `theAlignment` to find the node which allocated this block
bool deallocate(void[] b)
{
if (b is null)
return true;
// Round buffer to nearest `theAlignment` multiple to quickly find
// the `parent` `AlignedBlockNode`
enum ulong mask = ~(theAlignment - 1);
ulong ptr = ((cast(ulong) b.ptr) & mask);
AlignedBlockNode *node = cast(AlignedBlockNode*) ptr;
if (node.bAlloc.deallocate(b))
{
static if (isShared)
{
import core.atomic : atomicOp;
atomicOp!"-="(node.bytesUsed, b.length);
}
else
{
node.bytesUsed -= b.length;
}
return true;
}
return false;
}
// Allocate works only if memory can be provided via `alignedAllocate` from the parent
static if (hasMember!(ParentAllocator, "alignedAllocate"))
void[] allocate(size_t n)
{
static if (isShared)
import core.atomic : atomicOp, atomicLoad;
if (n == 0 || n > theAlignment)
return null;
static if (isShared)
{
lock.lock();
scope(exit) lock.unlock();
}
auto tmp = cast(AlignedBlockNode*) root;
// Iterate through list and find first node which has memory available
while (tmp)
{
auto next = tmp.next;
static if (isShared)
{
// Allocations can happen outside the lock
// Make sure nobody deletes this node while using it
tmp.keepAlive++;
if (next) next.keepAlive++;
lock.unlock();
}
auto result = tmp.bAlloc.allocate(n);
if (result.length == n)
{
// Success
static if (isShared)
{
atomicOp!"+="(tmp.bytesUsed, n);
lock.lock();
}
else
{
tmp.bytesUsed += n;
}
// Most likely this node has memory for more allocations
// Move it to the front
moveToFront(tmp);
static if (isShared)
{
tmp.keepAlive--;
if (next) next.keepAlive--;
}
return result;
}
// This node can now be removed if necessary
static if (isShared)
{
lock.lock();
tmp.keepAlive--;
if (next) next.keepAlive--;
}
if (!next)
break;
tmp = next;
next = tmp.next;
// If there are too many nodes, free memory by removing empty nodes
static if (isShared)
{
if (atomicLoad(numNodes) > maxNodes &&
atomicLoad(tmp.bytesUsed) == 0 &&
tmp.keepAlive == 0)
{
removeNode(tmp);
}
}
else
{
if (numNodes > maxNodes && tmp.bytesUsed == 0)
{
removeNode(tmp);
}
}
tmp = next;
}
// Cannot create new AlignedBlockNode. Most likely the ParentAllocator ran out of resources
if (!insertNewNode())
return null;
tmp = cast(typeof(tmp)) root;
void[] result = tmp.bAlloc.allocate(n);
static if (isShared)
{
atomicOp!"+="(root.bytesUsed, result.length);
}
else
{
root.bytesUsed += result.length;
}
return result;
}
// goodAllocSize should not use state
size_t goodAllocSize(const size_t n)
{
Allocator a = null;
return a.goodAllocSize(n);
}
}
/**
`AlignedBlockList` represents a wrapper around a chain of allocators, allowing for fast deallocations
and preserving a low degree of fragmentation.
The allocator holds internally a doubly linked list of `Allocator` objects, which will serve allocations
in a most-recently-used fashion. Most recent allocators used for `allocate` calls, will be
moved to the front of the list.
Although allocations are in theory served in linear searching time, `deallocate` calls take
$(BIGOH 1) time, by using aligned allocations. `ParentAllocator` must implement `alignedAllocate`
and it must be able to allocate `theAlignment` bytes at the same alignment. Each aligned allocation
done by `ParentAllocator` will contain metadata for an `Allocator`, followed by its payload.
Params:
Allocator = the allocator which is used to manage each node; it must have a constructor which receives
`ubyte[]` and it must not have any parent allocators, except for the `NullAllocator`
ParentAllocator = each node draws memory from the parent allocator; it must support `alignedAllocate`
theAlignment = alignment of each block and at the same time length of each node
*/
struct AlignedBlockList(Allocator, ParentAllocator, ulong theAlignment = (1 << 21))
{
version (StdDdoc)
{
import std.typecons : Ternary;
import std.traits : hasMember;
/**
Returns a chunk of memory of size `n`
It finds the first node in the `AlignedBlockNode` list which has available memory,
and moves it to the front of the list.
All empty nodes which cannot return new memory, are removed from the list.
Params:
n = bytes to allocate
Returns:
A chunk of memory of the required length or `null` on failure or
*/
static if (hasMember!(ParentAllocator, "alignedAllocate"))
void[] allocate(size_t n);
/**
Deallocates the buffer `b` given as parameter. Deallocations take place in constant
time, regardless of the number of nodes in the list. `b.ptr` is rounded down
to the nearest multiple of the `alignment` to quickly find the corresponding
`AlignedBlockNode`.
Params:
b = buffer candidate for deallocation
Returns:
`true` on success and `false` on failure
*/
bool deallocate(void[] b);
/**
Returns `Ternary.yes` if the buffer belongs to the parent allocator and
`Ternary.no` otherwise.
Params:
b = buffer tested if owned by this allocator
Returns:
`Ternary.yes` if owned by this allocator and `Ternary.no` otherwise
*/
static if (hasMember!(ParentAllocator, "owns"))
Ternary owns(void[] b);
}
else
{
import std.math.traits : isPowerOf2;
static assert(isPowerOf2(alignment));
mixin AlignedBlockListImpl!false;
}
}
///
@system unittest
{
import std.experimental.allocator.building_blocks.ascending_page_allocator : AscendingPageAllocator;
import std.experimental.allocator.building_blocks.segregator : Segregator;
import std.experimental.allocator.building_blocks.bitmapped_block : BitmappedBlock;
import std.typecons : Ternary;
/*
In this example we use 'AlignedBlockList' in conjunction with other allocators
in order to create a more complex allocator.
The 'SuperAllocator' uses a 'Segregator' to distribute allocations to sub-allocators,
based on the requested size.
Each sub-allocator is represented by an 'AlignedBlockList' of 'BitmappedBlocks'.
Each 'AlignedBlockList' draws memory from a root allocator which in this case is an 'AscendingPageAllocator'
Such an allocator not only provides good performance, but also a low degree of memory fragmentation.
*/
alias SuperAllocator = Segregator!(
32,
AlignedBlockList!(BitmappedBlock!32, AscendingPageAllocator*, 1 << 12),
Segregator!(
64,
AlignedBlockList!(BitmappedBlock!64, AscendingPageAllocator*, 1 << 12),
Segregator!(
128,
AlignedBlockList!(BitmappedBlock!128, AscendingPageAllocator*, 1 << 12),
AscendingPageAllocator*
)));
SuperAllocator a;
auto pageAlloc = AscendingPageAllocator(128 * 4096);
// Set the parent allocator for all the sub allocators
a.allocatorForSize!256 = &pageAlloc;
a.allocatorForSize!128.parent = &pageAlloc;
a.allocatorForSize!64.parent = &pageAlloc;
a.allocatorForSize!32.parent = &pageAlloc;
enum testNum = 10;
void[][testNum] buf;
// Allocations of size 32 will go to the first 'AlignedBlockList'
foreach (j; 0 .. testNum)
{
buf[j] = a.allocate(32);
assert(buf[j].length == 32);
// This is owned by the first 'AlignedBlockList'
assert(a.allocatorForSize!32.owns(buf[j]) == Ternary.yes);
}
// Free the memory
foreach (j; 0 .. testNum)
assert(a.deallocate(buf[j]));
// Allocations of size 64 will go to the second 'AlignedBlockList'
foreach (j; 0 .. testNum)
{
buf[j] = a.allocate(64);
assert(buf[j].length == 64);
// This is owned by the second 'AlignedBlockList'
assert(a.allocatorForSize!64.owns(buf[j]) == Ternary.yes);
}
// Free the memory
foreach (j; 0 .. testNum)
assert(a.deallocate(buf[j]));
// Allocations of size 128 will go to the third 'AlignedBlockList'
foreach (j; 0 .. testNum)
{
buf[j] = a.allocate(128);
assert(buf[j].length == 128);
// This is owned by the third 'AlignedBlockList'
assert(a.allocatorForSize!128.owns(buf[j]) == Ternary.yes);
}
// Free the memory
foreach (j; 0 .. testNum)
assert(a.deallocate(buf[j]));
// Allocations which exceed 128, will go to the 'AscendingPageAllocator*'
void[] b = a.allocate(256);
assert(b.length == 256);
a.deallocate(b);
}
/**
`SharedAlignedBlockList` is the threadsafe version of `AlignedBlockList`.
The `Allocator` template parameter must refer a shared allocator.
Also, `ParentAllocator` must be a shared allocator, supporting `alignedAllocate`.
Params:
Allocator = the shared allocator which is used to manage each node; it must have a constructor which receives
`ubyte[]` and it must not have any parent allocators, except for the `NullAllocator`
ParentAllocator = each node draws memory from the parent allocator; it must be shared and support `alignedAllocate`
theAlignment = alignment of each block and at the same time length of each node
*/
shared struct SharedAlignedBlockList(Allocator, ParentAllocator, ulong theAlignment = (1 << 21))
{
version (StdDdoc)
{
import std.typecons : Ternary;
import std.traits : hasMember;
/**
Returns a chunk of memory of size `n`
It finds the first node in the `AlignedBlockNode` list which has available memory,
and moves it to the front of the list.
All empty nodes which cannot return new memory, are removed from the list.
Params:
n = bytes to allocate
Returns:
A chunk of memory of the required length or `null` on failure or
*/
static if (hasMember!(ParentAllocator, "alignedAllocate"))
void[] allocate(size_t n);
/**
Deallocates the buffer `b` given as parameter. Deallocations take place in constant
time, regardless of the number of nodes in the list. `b.ptr` is rounded down
to the nearest multiple of the `alignment` to quickly find the corresponding
`AlignedBlockNode`.
Params:
b = buffer candidate for deallocation
Returns:
`true` on success and `false` on failure
*/
bool deallocate(void[] b);
/**
Returns `Ternary.yes` if the buffer belongs to the parent allocator and
`Ternary.no` otherwise.
Params:
b = buffer tested if owned by this allocator
Returns:
`Ternary.yes` if owned by this allocator and `Ternary.no` otherwise
*/
static if (hasMember!(ParentAllocator, "owns"))
Ternary owns(void[] b);
}
else
{
import std.math.traits : isPowerOf2;
static assert(isPowerOf2(alignment));
mixin AlignedBlockListImpl!true;
}
}
///
@system unittest
{
import std.experimental.allocator.building_blocks.region : SharedBorrowedRegion;
import std.experimental.allocator.building_blocks.ascending_page_allocator : SharedAscendingPageAllocator;
import std.experimental.allocator.building_blocks.null_allocator : NullAllocator;
import core.thread : ThreadGroup;
enum numThreads = 8;
enum size = 2048;
enum maxIter = 10;
/*
In this example we use 'SharedAlignedBlockList' together with
'SharedBorrowedRegion', in order to create a fast, thread-safe allocator.
*/
alias SuperAllocator = SharedAlignedBlockList!(
SharedBorrowedRegion!(1),
SharedAscendingPageAllocator,
4096);
SuperAllocator a;
// The 'SuperAllocator' will draw memory from a 'SharedAscendingPageAllocator'
a.parent = SharedAscendingPageAllocator(4096 * 1024);
// Launch 'numThreads', each performing allocations
void fun()
{
foreach (i; 0 .. maxIter)
{
void[] b = a.allocate(size);
assert(b.length == size);
}
}
auto tg = new ThreadGroup;
foreach (i; 0 .. numThreads)
{
tg.create(&fun);
}
tg.joinAll();
}
version (StdUnittest)
{
static void testrw(void[] b)
{
ubyte* buf = cast(ubyte*) b.ptr;
size_t len = (b.length).roundUpToMultipleOf(4096);
for (int i = 0; i < len; i += 4096)
{
buf[i] = (cast(ubyte) i % 256);
assert(buf[i] == (cast(ubyte) i % 256));
}
}
}
@system unittest
{
import std.experimental.allocator.building_blocks.region;
import std.experimental.allocator.building_blocks.ascending_page_allocator;
import std.random;
import std.algorithm.sorting : sort;
import core.thread : ThreadGroup;
import core.internal.spinlock : SpinLock;
enum pageSize = 4096;
enum numThreads = 10;
enum maxIter = 20;
enum totalAllocs = maxIter * numThreads;
size_t count = 0;
SpinLock lock = SpinLock(SpinLock.Contention.brief);
alias SuperAllocator = SharedAlignedBlockList!(
SharedBorrowedRegion!(1),
SharedAscendingPageAllocator,
1 << 16);
void[][totalAllocs] buf;
SuperAllocator a;
a.parent = SharedAscendingPageAllocator(4096 * 1024);
void fun()
{
auto rnd = Random(1000);
foreach (i; 0 .. maxIter)
{
auto size = uniform(1, pageSize + 1, rnd);
void[] b = a.allocate(size);
assert(b.length == size);
testrw(b);
lock.lock();
buf[count++] = b;
lock.unlock();
}
}
auto tg = new ThreadGroup;
foreach (i; 0 .. numThreads)
{
tg.create(&fun);
}
tg.joinAll();
sort!((a, b) => a.ptr < b.ptr)(buf[0 .. totalAllocs]);
foreach (i; 0 .. totalAllocs - 1)
{
assert(buf[i].ptr + a.goodAllocSize(buf[i].length) <= buf[i + 1].ptr);
}
foreach (i; 0 .. totalAllocs)
{
assert(a.deallocate(buf[totalAllocs - 1 - i]));
}
}
@system unittest
{
import std.experimental.allocator.building_blocks.ascending_page_allocator : AscendingPageAllocator;
import std.experimental.allocator.building_blocks.segregator : Segregator;
import std.experimental.allocator.building_blocks.bitmapped_block : BitmappedBlock;
import std.random;
alias SuperAllocator = Segregator!(
256,
AlignedBlockList!(BitmappedBlock!256, AscendingPageAllocator*, 1 << 16),
Segregator!(
512,
AlignedBlockList!(BitmappedBlock!512, AscendingPageAllocator*, 1 << 16),
Segregator!(
1024,
AlignedBlockList!(BitmappedBlock!1024, AscendingPageAllocator*, 1 << 16),
Segregator!(
2048,
AlignedBlockList!(BitmappedBlock!2048, AscendingPageAllocator*, 1 << 16),
AscendingPageAllocator*
))));
SuperAllocator a;
auto pageAlloc = AscendingPageAllocator(4096 * 4096);
a.allocatorForSize!4096 = &pageAlloc;
a.allocatorForSize!2048.parent = &pageAlloc;
a.allocatorForSize!1024.parent = &pageAlloc;
a.allocatorForSize!512.parent = &pageAlloc;
a.allocatorForSize!256.parent = &pageAlloc;
auto rnd = Random(1000);
size_t maxIter = 10;
enum testNum = 10;
void[][testNum] buf;
int maxSize = 8192;
foreach (i; 0 .. maxIter)
{
foreach (j; 0 .. testNum)
{
auto size = uniform(1, maxSize + 1, rnd);
buf[j] = a.allocate(size);
assert(buf[j].length == size);
testrw(buf[j]);
}
randomShuffle(buf[]);
foreach (j; 0 .. testNum)
{
assert(a.deallocate(buf[j]));
}
}
}