-
Notifications
You must be signed in to change notification settings - Fork 25
/
impact.jl
143 lines (111 loc) · 4.52 KB
/
impact.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
"""
ImpactContact{T,N} <: Contact{T,N}
contact object for impact (i.e., no friction)
collision: Collision
"""
mutable struct ImpactContact{T,N} <: Contact{T,N}
friction_parameterization::SMatrix{0,2,T,0}
collision::Collision{T,0,3,0}
end
# function Base.show(io::IO, mime::MIME{Symbol("text/plain")}, contact::ImpactContact)
# summary(io, contact)
# println(io, "")
# println(io, "friction_parameterization: "*string(contact.friction_parameterization))
# println(io, "collision: "*string(contact.collision))
# end
function ImpactContact(body::Body{T}, normal::AbstractVector;
contact_origin=szeros(T, 3),
contact_radius=0.0) where T
# contact directions
V1, V2, V3 = orthogonal_columns(normal) #
A = [V1 V2 V3]
Ainv = inv(A)
contact_normal = Ainv[3, SA[1; 2; 3]]'
# friction parametrization
parameterization = szeros(T, 0, 2)
# collision
collision = SphereHalfSpaceCollision(szeros(T, 0, 3), contact_normal, SVector{3}(contact_origin), contact_radius)
ImpactContact{Float64,2}(parameterization, collision)
end
function constraint(mechanism, contact::ContactConstraint{T,N,Nc,Cs}) where {T,N,Nc,Cs<:ImpactContact{T,N}}
# contact model
model = contact.model
# parent
pbody = get_body(mechanism, contact.parent_id)
xp, qp = next_configuration(pbody.state, mechanism.timestep)
# child
cbody = get_body(mechanism, contact.child_id)
xc, qc = next_configuration(cbody.state, mechanism.timestep)
# constraint
SVector{1,T}(distance(model.collision, xp, qp, xc, qc) - contact.impulses_dual[2][1])
end
function constraint_jacobian(contact::ContactConstraint{T,N,Nc,Cs,N½}) where {T,N,Nc,Cs<:ImpactContact{T,N},N½}
γ = contact.impulses[2] + REG * neutral_vector(contact.model)
s = contact.impulses_dual[2] + REG * neutral_vector(contact.model)
∇s = hcat(γ, -Diagonal(sones(N½)))
∇γ = hcat(s, -Diagonal(szeros(N½)))
return [∇s ∇γ]
end
function constraint_jacobian_configuration(relative::Symbol, model::ImpactContact,
xp::AbstractVector, vp::AbstractVector, qp::Quaternion, ωp::AbstractVector,
xc::AbstractVector, vc::AbstractVector, qc::Quaternion, ωc::AbstractVector,
timestep)
X = ∂distance∂x(relative, model.collision, xp, qp, xc, qc)
Q = ∂distance∂q(relative, model.collision, xp, qp, xc, qc)
return [X Q]
end
function constraint_jacobian_velocity(relative::Symbol, model::ImpactContact,
xp::AbstractVector, vp::AbstractVector, qp::Quaternion, ωp::AbstractVector,
xc::AbstractVector, vc::AbstractVector, qc::Quaternion, ωc::AbstractVector,
timestep)
# recover current orientation
if relative == :parent
x = next_position(xp, -vp, timestep)
∂x∂v = linear_integrator_jacobian_velocity(x, vp, timestep)
q = next_orientation(qp, -ωp, timestep)
∂q∂ω = rotational_integrator_jacobian_velocity(q, ωp, timestep)
elseif relative == :child
x = next_position(xc, -vc, timestep)
∂x∂v = linear_integrator_jacobian_velocity(x, vc, timestep)
q = next_orientation(qc, -ωc, timestep)
∂q∂ω = rotational_integrator_jacobian_velocity(q, ωc, timestep)
end
# Jacobian
V = ∂distance∂x(relative, model.collision, xp, qp, xc, qc) * ∂x∂v
Ω = ∂distance∂q(relative, model.collision, xp, qp, xc, qc) * ∂q∂ω
return [V Ω]
end
function force_mapping(relative::Symbol, model::ImpactContact,
xp::AbstractVector, qp::Quaternion,
xc::AbstractVector, qc::Quaternion)
X = contact_normal(model.collision, xp, qp, xc, qc)'
if relative == :parent
return X
elseif relative == :child
return -1.0 * X
end
end
function ∂force_mapping_jvp∂x(relative::Symbol, jacobian::Symbol,
model::ImpactContact,
xp::AbstractVector, qp::Quaternion,
xc::AbstractVector, qc::Quaternion,
λ::AbstractVector)
X = ∂contact_normal_transpose∂x(jacobian, model.collision, xp, qp, xc, qc) * λ[1]
if relative == :parent
return X
elseif relative == :child
return -1.0 * X
end
end
function ∂force_mapping_jvp∂q(relative::Symbol, jacobian::Symbol,
model::ImpactContact,
xp::AbstractVector, qp::Quaternion,
xc::AbstractVector, qc::Quaternion,
λ::AbstractVector)
X = ∂contact_normal_transpose∂q(jacobian, model.collision, xp, qp, xc, qc) * λ[1]
if relative == :parent
return X
elseif relative == :child
return -1.0 * X
end
end