-
Notifications
You must be signed in to change notification settings - Fork 4.6k
/
AllocFast.S
312 lines (230 loc) · 10.1 KB
/
AllocFast.S
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
// Licensed to the .NET Foundation under one or more agreements.
// The .NET Foundation licenses this file to you under the MIT license.
.intel_syntax noprefix
#include <AsmOffsets.inc> // generated by the build from AsmOffsets.cpp
#include <unixasmmacros.inc>
// Allocate non-array, non-finalizable object. If the allocation doesn't fit into the current thread's
// allocation context then automatically fallback to the slow allocation path.
// RDI == MethodTable
NESTED_ENTRY RhpNewFast, _TEXT, NoHandler
push_nonvol_reg rbx
mov rbx, rdi
// rax = GetThread()
INLINE_GETTHREAD
//
// rbx contains MethodTable pointer
//
mov edx, [rbx + OFFSETOF__MethodTable__m_uBaseSize]
//
// rax: Thread pointer
// rbx: MethodTable pointer
// rdx: base size
//
mov rsi, [rax + OFFSETOF__Thread__m_alloc_context__alloc_ptr]
add rdx, rsi
cmp rdx, [rax + OFFSETOF__Thread__m_alloc_context__alloc_limit]
ja LOCAL_LABEL(RhpNewFast_RarePath)
// set the new alloc pointer
mov [rax + OFFSETOF__Thread__m_alloc_context__alloc_ptr], rdx
mov rax, rsi
// set the new object's MethodTable pointer
mov [rsi], rbx
.cfi_remember_state
pop_nonvol_reg rbx
ret
.cfi_restore_state
.cfi_def_cfa_offset 16 // workaround cfi_restore_state bug
LOCAL_LABEL(RhpNewFast_RarePath):
mov rdi, rbx // restore MethodTable
xor esi, esi
pop_nonvol_reg rbx
jmp C_FUNC(RhpNewObject)
NESTED_END RhpNewFast, _TEXT
// Allocate non-array object with finalizer
// RDI == MethodTable
LEAF_ENTRY RhpNewFinalizable, _TEXT
mov esi, GC_ALLOC_FINALIZE
jmp C_FUNC(RhpNewObject)
LEAF_END RhpNewFinalizable, _TEXT
// Allocate non-array object
// RDI == MethodTable
// ESI == alloc flags
NESTED_ENTRY RhpNewObject, _TEXT, NoHandler
PUSH_COOP_PINVOKE_FRAME rcx
END_PROLOGUE
// RCX: transition frame
// Preserve the MethodTable in RBX
mov rbx, rdi
xor edx, edx // numElements
// Call the rest of the allocation helper.
// void* RhpGcAlloc(MethodTable *pEEType, uint32_t uFlags, uintptr_t numElements, void * pTransitionFrame)
call C_FUNC(RhpGcAlloc)
test rax, rax
jz LOCAL_LABEL(NewOutOfMemory)
.cfi_remember_state
POP_COOP_PINVOKE_FRAME
ret
.cfi_restore_state
.cfi_def_cfa_offset 96 // workaround cfi_restore_state bug
LOCAL_LABEL(NewOutOfMemory):
// This is the OOM failure path. We're going to tail-call to a managed helper that will throw
// an out of memory exception that the caller of this allocator understands.
mov rdi, rbx // MethodTable pointer
xor esi, esi // Indicate that we should throw OOM.
POP_COOP_PINVOKE_FRAME
jmp EXTERNAL_C_FUNC(RhExceptionHandling_FailedAllocation)
NESTED_END RhpNewObject, _TEXT
// Allocate a string.
// RDI == MethodTable
// ESI == character/element count
NESTED_ENTRY RhNewString, _TEXT, NoHandler
// we want to limit the element count to the non-negative 32-bit int range
cmp rsi, MAX_STRING_LENGTH
ja LOCAL_LABEL(StringSizeOverflow)
push_nonvol_reg rbx
push_nonvol_reg r12
push_register rcx // padding
mov rbx, rdi // save MethodTable
mov r12, rsi // save element count
// rax = GetThread()
INLINE_GETTHREAD
mov rcx, rax // rcx = Thread*
// Compute overall allocation size (align(base size + (element size * elements), 8)).
lea rax, [r12 * STRING_COMPONENT_SIZE + STRING_BASE_SIZE + 7]
and rax, -8
// rax == string size
// rbx == MethodTable
// rcx == Thread*
// r12 == element count
mov rdx, rax
add rax, [rcx + OFFSETOF__Thread__m_alloc_context__alloc_ptr]
jc LOCAL_LABEL(RhNewString_RarePath)
// rax == new alloc ptr
// rbx == MethodTable
// rcx == Thread*
// rdx == string size
// r12 == element count
cmp rax, [rcx + OFFSETOF__Thread__m_alloc_context__alloc_limit]
ja LOCAL_LABEL(RhNewString_RarePath)
mov [rcx + OFFSETOF__Thread__m_alloc_context__alloc_ptr], rax
// calc the new object pointer
sub rax, rdx
mov [rax + OFFSETOF__Object__m_pEEType], rbx
mov [rax + OFFSETOF__String__m_Length], r12d
.cfi_remember_state
pop_register rcx // padding
pop_nonvol_reg r12
pop_nonvol_reg rbx
ret
.cfi_restore_state
.cfi_def_cfa_offset 32 // workaround cfi_restore_state bug
LOCAL_LABEL(RhNewString_RarePath):
mov rdi, rbx // restore MethodTable
mov rsi, r12 // restore element count
// passing string size in rdx
pop_register rcx // padding
pop_nonvol_reg r12
pop_nonvol_reg rbx
jmp C_FUNC(RhpNewArrayRare)
LOCAL_LABEL(StringSizeOverflow):
// We get here if the size of the final string object can't be represented as an unsigned
// 32-bit value. We're going to tail-call to a managed helper that will throw
// an OOM exception that the caller of this allocator understands.
// rdi holds MethodTable pointer already
xor esi, esi // Indicate that we should throw OOM.
jmp EXTERNAL_C_FUNC(RhExceptionHandling_FailedAllocation)
NESTED_END RhNewString, _TEXT
// Allocate one dimensional, zero based array (SZARRAY).
// RDI == MethodTable
// ESI == element count
NESTED_ENTRY RhpNewArray, _TEXT, NoHandler
// we want to limit the element count to the non-negative 32-bit int range
cmp rsi, 0x07fffffff
ja LOCAL_LABEL(ArraySizeOverflow)
push_nonvol_reg rbx
push_nonvol_reg r12
push_register rcx // padding
mov rbx, rdi // save MethodTable
mov r12, rsi // save element count
// rax = GetThread()
INLINE_GETTHREAD
mov rcx, rax // rcx = Thread*
// Compute overall allocation size (align(base size + (element size * elements), 8)).
movzx eax, word ptr [rbx + OFFSETOF__MethodTable__m_usComponentSize]
mul r12
mov edx, [rbx + OFFSETOF__MethodTable__m_uBaseSize]
add rax, rdx
add rax, 7
and rax, -8
// rax == array size
// rbx == MethodTable
// rcx == Thread*
// r12 == element count
mov rdx, rax
add rax, [rcx + OFFSETOF__Thread__m_alloc_context__alloc_ptr]
jc LOCAL_LABEL(RhpNewArray_RarePath)
// rax == new alloc ptr
// rbx == MethodTable
// rcx == Thread*
// rdx == array size
// r12 == element count
cmp rax, [rcx + OFFSETOF__Thread__m_alloc_context__alloc_limit]
ja LOCAL_LABEL(RhpNewArray_RarePath)
mov [rcx + OFFSETOF__Thread__m_alloc_context__alloc_ptr], rax
// calc the new object pointer
sub rax, rdx
mov [rax + OFFSETOF__Object__m_pEEType], rbx
mov [rax + OFFSETOF__Array__m_Length], r12d
.cfi_remember_state
pop_register rcx // padding
pop_nonvol_reg r12
pop_nonvol_reg rbx
ret
.cfi_restore_state
.cfi_def_cfa_offset 32 // workaround cfi_restore_state bug
LOCAL_LABEL(RhpNewArray_RarePath):
mov rdi, rbx // restore MethodTable
mov rsi, r12 // restore element count
// passing array size in rdx
pop_register rcx // padding
pop_nonvol_reg r12
pop_nonvol_reg rbx
jmp C_FUNC(RhpNewArrayRare)
LOCAL_LABEL(ArraySizeOverflow):
// We get here if the size of the final array object can't be represented as an unsigned
// 32-bit value. We're going to tail-call to a managed helper that will throw
// an overflow exception that the caller of this allocator understands.
// rdi holds MethodTable pointer already
mov esi, 1 // Indicate that we should throw OverflowException
jmp EXTERNAL_C_FUNC(RhExceptionHandling_FailedAllocation)
NESTED_END RhpNewArray, _TEXT
NESTED_ENTRY RhpNewArrayRare, _TEXT, NoHandler
// rdi == MethodTable
// rsi == element count
PUSH_COOP_PINVOKE_FRAME rcx
END_PROLOGUE
// rcx: transition frame
// Preserve the MethodTable in RBX
mov rbx, rdi
mov rdx, rsi // numElements
// passing MethodTable in rdi
xor rsi, rsi // uFlags
// passing pTransitionFrame in rcx
// Call the rest of the allocation helper.
// void* RhpGcAlloc(MethodTable *pEEType, uint32_t uFlags, uintptr_t numElements, void * pTransitionFrame)
call C_FUNC(RhpGcAlloc)
test rax, rax
jz LOCAL_LABEL(ArrayOutOfMemory)
.cfi_remember_state
POP_COOP_PINVOKE_FRAME
ret
.cfi_restore_state
.cfi_def_cfa_offset 96 // workaround cfi_restore_state bug
LOCAL_LABEL(ArrayOutOfMemory):
// This is the OOM failure path. We're going to tail-call to a managed helper that will throw
// an out of memory exception that the caller of this allocator understands.
mov rdi, rbx // MethodTable pointer
xor esi, esi // Indicate that we should throw OOM.
POP_COOP_PINVOKE_FRAME
jmp EXTERNAL_C_FUNC(RhExceptionHandling_FailedAllocation)
NESTED_END RhpNewArrayRare, _TEXT