-
Notifications
You must be signed in to change notification settings - Fork 10
/
configure.ac
1230 lines (1093 loc) · 37.6 KB
/
configure.ac
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
################################################################################
### Copyright 2007 VMware, Inc. All rights reserved.
###
### Configure script for building the VMware OSS Tools.
###
###
### This program is free software; you can redistribute it and/or modify
### it under the terms of version 2 of the GNU General Public License as
### published by the Free Software Foundation.
###
### This program is distributed in the hope that it will be useful,
### but WITHOUT ANY WARRANTY; without even the implied warranty of
### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
### GNU General Public License for more details.
###
### You should have received a copy of the GNU General Public License
### along with this program; if not, write to the Free Software
### Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
################################################################################
################################################################################
# In addition to the usual environment variables and command line
# arguments that a configure script usually takes (CFLAGS, LDFLAGS,
# etc.), this script also accepts variables of the form:
#
# CUSTOM_LIB_CPPFLAGS: compile-time flags for LIB
# CUSTOM_LIB_LIBS: link-time flags for LIB
# RPCGENFLAGS: extra flags to pass to rpcgen
#
# The following libraries are currently tested: DNET, FUSE, GLIB2, GMODULE,
# GOBJECT, GTHREAD, GTK, GTKMM, ICU, LIBPNG, PAM, PROCPS, URIPARSER, ZLIB
#
# For the procps library: you can provide the name of the procps library on
# your system by defining CUSTOM_PROCPS_NAME. By default the configure script
# will try both "-lproc" and "-lproc-3.2.7".
################################################################################
###
### Initialization
###
TOOLS_VERSION="9.2.2"
AC_INIT(
[open-vm-tools],
[9.2.2],
[open-vm-tools-devel@lists.sourceforge.net])
# In order to make this configure script auto-detect situations where
# people have a 32-bit userland running with a 64-bit kernel, we try to ask
# the compiler (assumedly gcc) for its default Target:.
# We have to set up $TEST_CC manually, since AC_PROG_CC hasn't yet been run (and can't be until AC_CANONICAL_HOST & AC_CANONICAL_BUILD are run)
# The purpose of all this is to set up $host_alias/$build_alias in a more
# intelligent way than config.guess currently does.
TEST_CC="$CC_FOR_BUILD"
test -z "$TEST_CC" && TEST_CC="$HOST_CC"
test -z "$TEST_CC" && TEST_CC="$CC"
if test -n "$TEST_CC" -a -z "$host_alias"; then
host_alias="`$TEST_CC -dumpmachine`"
if test -z "$build_alias" -a -n "$host_alias"; then
build_alias="$host_alias"
fi
fi
unset TEST_CC
# checkvm/checkvm.c has no special significance - we just need to pass in a file that
# helps autoconf verify that it really has found the source tree.
AC_CONFIG_SRCDIR([checkvm/checkvm.c])
# Keep the top-level directory tidy by putting auxiliary build tools and local
# macros in separate subdirectories.
AC_CONFIG_AUX_DIR([config])
AC_CONFIG_MACRO_DIR([m4])
AC_CANONICAL_HOST
AC_CANONICAL_BUILD
# Quote the regular expressions
case "$host_cpu" in
[i[3456]86])
userSpaceBitness="32"
;;
[x86_64])
userSpaceBitness="64"
;;
[*])
AC_MSG_ERROR([Unknown architecture.])
;;
esac
# Operational arguments.
AC_ARG_WITH([root-privileges],
[AS_HELP_STRING([--without-root-privileges],
[does not perform any operations that require root privileges])],
[],
[with_root_privileges=yes])
# Kernel arguments.
# The kernel args have to go here otherwise the KERNEL_RELEASE won't be visible
# to getOsVersion()
AC_ARG_WITH([kernel-modules],
[AS_HELP_STRING([--without-kernel-modules],
[does not compile or install the kernel modules])],
[],
[with_kernel_modules=yes])
AC_ARG_WITH([kernel-release],
[AS_HELP_STRING([--with-kernel-release],
[specifies the kernel release you want to build against])],
[KERNEL_RELEASE="$withval"],
[KERNEL_RELEASE=`uname -r`])
AC_ARG_WITH([linuxdir],
[AS_HELP_STRING([--with-linuxdir],
[specifies the Linux directory you want to use])],
[LINUXDIR="$withval"],
[LINUXDIR=/lib/modules/$KERNEL_RELEASE])
# Turn the uname output into something we can run comparisons on.
getOsVersion() {
major_version="`echo $KERNEL_RELEASE | cut -f1 -d. | cut -f1 -d-`"
minor_version="`echo $KERNEL_RELEASE | cut -f2 -d. | cut -f1 -d-`"
micro_version="`echo $KERNEL_RELEASE | cut -f3 -d. | cut -f1 -d-`"
printf '%02d%02d%03d' $major_version $minor_version $micro_version
}
case "$host_os" in
[linux*])
os="linux"
;;
[freebsd*])
os="freebsd"
;;
[solaris*])
os="solaris"
;;
[*])
AC_MSG_WARN([This is an untested and unsupported Operating System. Proceed at your own peril.])
;;
esac
osVersion="`getOsVersion`"
if test "$with_kernel_modules" = "yes"; then
case "$os" in
linux)
if test "$osVersion" -lt 206009; then
AC_MSG_ERROR([Kernels prior to 2.6.9 are not supported in this release of open-vm-tools. Configure using --without-kernel-modules to suppress building kernel drivers.])
fi
if test ! -d "$LINUXDIR/kernel/"; then
AC_MSG_ERROR([$LINUXDIR/kernel does not exist])
fi
LINUXINCLUDE="$LINUXDIR/build/include"
if test ! -d "$LINUXINCLUDE"; then
AC_MSG_ERROR([Can't find include dir under $LINUXDIR])
fi
;;
freebsd)
freebsd_sysdir=/usr/src/sys
if test -n "$SYSDIR"; then
freebsd_sysdir="$SYSDIR"
fi
if test ! -f "$freebsd_sysdir/conf/kmod.mk"; then
AC_MSG_ERROR([FreeBSD kernel tree not found. Please install the kernel sources (or provide the location using SYSDIR) or configure using --without-kernel-modules.])
fi
;;
esac
fi
# Arguments for disabling individual open-vm-tools features or libraries.
AC_ARG_ENABLE(
multimon,
AS_HELP_STRING(
[--disable-multimon],
[disables multimon, enabled by default]),
[enable_multimon="$enableval"],
[enable_multimon="yes"])
AC_ARG_WITH(
gtk2,
AS_HELP_STRING(
[--without-gtk2],
[compiles without Gtk 2.0]),
[with_gtk2="$withval"],
[with_gtk2="yes"])
AC_ARG_WITH(
gtkmm,
AS_HELP_STRING(
[--without-gtkmm],
[compiles without Gtkmm, sigc++, and related libs]),
[with_gtkmm="$withval"],
[with_gtkmm="yes"])
AC_ARG_ENABLE(
docs,
AS_HELP_STRING(
[--disable-docs],
[disables generation of API documentation; by default, docs are built if doxygen is available.]),
[enable_docs="$enableval"],
[enable_docs="yes"])
AC_ARG_ENABLE(
tests,
AS_HELP_STRING(
[--disable-tests],
[disable compilation of test code.]),
[enable_tests="$enableval"],
[enable_tests="auto"])
AM_INIT_AUTOMAKE
###
### Constants
###
# These need to be declared after initialization.
# Some of our macro call-sites require changes to
# CPPFLAGS/CFLAGS/LDFLAGS. In such places, we save the original value
# of CPPFLAGS/CFLAGS/LDFLAGS before the macro call and restore it when
# the call is done. We must perform this save at each macro site,
# because CPPFLAGS/CFLAGS/LDFLAGS may change over the course of
# configuration.
#
# CPPFLAGS is intended for preprocessor options (-D and -I mainly)
# CFLAGS is intended for compiler options (-O, -f, -W, and so forth)
CPPFLAGS="$CPPFLAGS -DUSING_AUTOCONF=1 -DOPEN_VM_TOOLS"
###
### Programs
###
# C preprocessor and compiler.
AC_PROG_CPP
AC_PROG_CC
# C++ compiler. Note that unlike AC_PROG_CC, this call does not trigger an
# error if no C++ compiler was found; it'll just set the variable CXX to 'g++'.
AC_PROG_CXX
# This allows features like per-target compiler flags. I.e., you can compile
# one copy of the same sources twice with different flags. (See lib/guestApp
# for an example.)
AM_PROG_CC_C_O
# Needed for the various install and uninstall hooks.
AC_PROG_INSTALL
AC_PROG_SED
AC_PROG_LN_S
AC_PROG_MKDIR_P
# Needed for creating the archives in lib/ and the shared libraries.
AC_PROG_LIBTOOL
if test "$ac_cv_prog_AR" = false; then
AC_MSG_ERROR([The 'ar' utility was not found. Please put ar on the path.])
fi
# We use pkg-config to set up the cflags and libs for gtk.
AC_CHECK_PROG(
[HAVE_PKG_CONFIG],
[pkg-config],
[yes],
[no])
if test "$GCC" != "yes"; then
AC_MSG_ERROR([Only GCC is currently supported. Please put gcc in the path.])
fi
###
### Libraries
###
AC_PATH_XTRA
#
# Check for libintl.h. When configuring using "--without-x", /usr/local/include
# may not be added to the include path, so code that use glib's i18n functions
# would fail to compile because it can't find libintl.h.
#
AC_CHECK_HEADER([libintl.h],
[],
[have_libintl=no],
[])
if test "$have_libintl" = "no"; then
unset ac_cv_header_libintl_h
CPPFLAGS="$CPPFLAGS -I/usr/local/include"
AC_CHECK_HEADER([libintl.h],
[],
[AC_MSG_ERROR([libintl.h not found. Make sure you have the gettext headers installed.])],
[])
fi
#
# Check for glib 2.6.0 or greater.
#
AC_VMW_CHECK_LIB([glib-2.0],
[GLIB2],
[glib-2.0],
[],
[2.6.0],
[glib.h],
[g_key_file_new],
[],
[AC_MSG_ERROR([glib >= 2.6.0 is required.])])
AC_VMW_CHECK_LIB([gmodule-2.0],
[GMODULE],
[gmodule-2.0],
[],
[2.6.0],
[],
[],
[],
[AC_MSG_ERROR([gmodule >= 2.6.0 is required.])])
AC_VMW_CHECK_LIB([gobject-2.0],
[GOBJECT],
[gobject-2.0],
[],
[2.6.0],
[glib-object.h],
[],
[],
[AC_MSG_ERROR([gobject >= 2.6.0 is required.])])
AC_VMW_CHECK_LIB([gthread-2.0],
[GTHREAD],
[gthread-2.0],
[],
[2.6.0],
[],
[],
[],
[AC_MSG_ERROR([glib >= 2.6.0 is required.])])
AC_CHECK_PROG([have_genmarshal],
[glib-genmarshal],
[yes],
[no])
if test "$have_genmarshal" != "yes"; then
AC_MSG_ERROR([glib-genmarshal is required; make sure it's available in your path.])
fi
#
# Parts of our Linux code require more recent version of glib
#
if test "$os" = "linux"; then
AC_VMW_CHECK_LIB([glib-2.0],
[GLIB2],
[glib-2.0],
[],
[2.14.0],
[glib.h],
[g_regex_new],
[have_glib_2_14=yes],
[AC_MSG_WARN([glib is not recent enough, some features will be disabled.])])
fi
#
# Check for fuse.
#
AC_VMW_CHECK_LIB([fuse],
[FUSE],
[fuse],
[],
[],
[fuse.h],
[fuse_main],
[have_fuse=yes],
[have_fuse=no;
AC_MSG_WARN([Fuse is missing, vmblock-fuse will be disabled.])])
#
# Check for PAM.
#
AC_ARG_WITH([pam],
[AS_HELP_STRING([--without-pam],
[compiles without PAM support.])],
[],
[with_pam=yes])
if test "$with_pam" = "yes"; then
AC_VMW_DEFAULT_FLAGS([PAM])
AC_VMW_CHECK_LIB([pam],
[PAM],
[],
[],
[],
[security/pam_appl.h],
[pam_start],
[PAM_CPPFLAGS="$PAM_CPPFLAGS -DUSE_PAM"],
[AC_VMW_LIB_ERROR([PAM], [pam])])
fi
#
# Check for CUnit and disable test code if not available.
#
if test "$enable_tests" = "auto" -o "$enable_tests" = "yes"; then
AC_VMW_DEFAULT_FLAGS([CUNIT])
AC_VMW_CHECK_LIB([cunit],
[CUNIT],
[],
[],
[],
[CUnit/CUnit.h],
[CU_initialize_registry],
[have_cunit=yes],
[have_cunit=no])
if test "$have_cunit" = "no"; then
if test "$enable_tests" = "yes"; then
AC_VMW_LIB_ERROR([CUNIT], [cunit])
else
AC_MSG_WARN([CUnit not found, tests won't be compiled.])
fi
fi
fi
# If the user explicitly disables X11, then don't try to detect the X-related libraries
if test "$have_x" = "disabled"; then
enable_multimon="no"
elif test "$have_x" != "yes"; then
AC_MSG_ERROR(
[The X11 libraries were not found. Please configure without X11 (using --without-x), or install the libX11 devel package(s).])
else
CPPFLAGS="$CPPFLAGS $X_CFLAGS"
COMMON_XLIBS="$X_PRE_LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
AC_CHECK_LIB(
[Xext],
[XeviQueryVersion],
[COMMON_XLIBS="-lXext $COMMON_XLIBS"],
[AC_MSG_ERROR(
[libXext not found. Please configure without X11 (using --without-x), or install the libXext devel package(s).])],
[$COMMON_XLIBS])
AC_CHECK_HEADER(
[X11/extensions/extutil.h],
[],
[AC_MSG_ERROR(
[X11/extensions/extutil.h header not found - you're probably on Solaris 10 or older. Please copy that header file onto your system manually, or configure without X11 (using --without-x).])],
[#include <X11/Xlib.h>
#include <X11/Xproto.h>])
if test "$enable_multimon" != "no"; then
AC_CHECK_LIB(
[Xinerama],
[XineramaQueryVersion],
[COMMON_XLIBS="-lXinerama $COMMON_XLIBS"],
[AC_MSG_ERROR(
[libXinerama not found. Please configure without multimon (using --disable-multimon), configure without X11 (using --without-x), or install the libXinerama devel package(s).])],
[$COMMON_XLIBS])
fi
AC_CHECK_LIB(
[Xi],
[XOpenDevice],
[COMMON_XLIBS="-lXi $COMMON_XLIBS"],
[AC_MSG_ERROR(
[libXi not found. Please configure without X11 (using --without-x), or install the libXi devel package(s).])],
[$COMMON_XLIBS])
AC_CHECK_LIB(
[Xrender],
[XRenderQueryVersion],
[COMMON_XLIBS="-lXrender $COMMON_XLIBS"],
[AC_MSG_ERROR(
[libXrender not found. Please configure without X11 (using --without-x), or install the libXrender devel package(s).])],
[$COMMON_XLIBS])
AC_CHECK_LIB(
[Xrandr],
[XRRQueryVersion],
[COMMON_XLIBS="-lXrandr $COMMON_XLIBS"],
[AC_MSG_ERROR(
[libXrandr not found. Please configure without X11 (using --without-x) or install the libXrandr devel package(s).])],
[$COMMON_XLIBS])
AC_CHECK_LIB(
[Xtst],
[XTestQueryExtension],
[COMMON_XLIBS="-lXtst $COMMON_XLIBS"],
[AC_MSG_ERROR(
[libXtst not found. Please configure without X11 (using --without-x) or install the libXtst devel package(s).])],
[$COMMON_XLIBS])
AC_CHECK_LIB(
[SM],
[SmcOpenConnection],
[XSM_LIBS="-lSM -lICE" && have_xsm_lib="yes"],
[]
[-lICE])
AC_CHECK_HEADERS([X11/SM/SMlib.h X11/ICE/ICElib.h],
[have_xsm_header="yes"],
[],
[])
if test "$have_xsm_lib" = "yes" -a "$have_xsm_header" = "yes"; then
have_xsm="yes"
fi
AC_CHECK_LIB(
[Xcomposite],
[XCompositeQueryExtension],
[XCOMPOSITE_LIBS="-lXcomposite"],
[have_xcomposite="no"]
[])
AC_CHECK_HEADERS([X11/extensions/Xcomposite.h],
[],
[have_xcomposite="no"],
[])
if test "$have_xcomposite" != "no"; then
have_xcomposite="yes"
fi
# Check whether we have gtk+ 2.0.
if test "$with_gtk2" != "no"; then
# gdk_display_get_default_group (added in gtk+ 2.4.0) is function currently
# needed by vmware-user.
AC_VMW_CHECK_LIB([gtk-x11-2.0],
[GTK],
[gtk+-2.0],
[],
[2.4.0],
[gtk/gtk.h],
[gdk_display_get_default_group],
[GTK_CPPFLAGS="$GTK_CPPFLAGS -DGTK2"],
[AC_MSG_ERROR([Gtk+ 2.0 library not found or too old. Please configure without Gtk+ support (using --without-gtk2) or install the Gtk+ 2.0 devel package.])])
fi
#
# Check for gtkmm 2.4.0 or greater.
#
if test "$with_gtkmm" != "no"; then
CUSTOM_GTKMM_CPPFLAGS="$CUSTOM_GTKMM_CPPFLAGS $GTK_CPPFLAGS"
AC_VMW_CHECK_LIBXX([gtkmm-2.4],
[GTKMM],
[gtkmm-2.4],
[],
[2.4.0],
[gtkmm.h],
[],
[GTKMM_CPPFLAGS="$GTKMM_CPPFLAGS -DHAVE_GTKMM"],
[AC_MSG_ERROR([gtkmm library not found. Please install the libgtkmm devel package(s), or re-configure using --without-gtkmm.])])
fi
fi # End of checks for X libraries
AC_CHECK_LIB(
[crypt],
[crypt],
[HAVE_CRYPT="yes"],
[AC_MSG_ERROR(
[libcrypt not found. Please install the libc/libcrypt devel package(s).])])
AC_CHECK_FUNCS(
dlopen,
,
[AC_CHECK_LIB(
dl,
dlopen,
[VIX_LIBADD="$VIX_LIBADD -ldl"
LIBVMTOOLS_LIBADD="$LIBVMTOOLS_LIBADD -ldl"],
[AC_MSG_ERROR(
[dlopen was not found, but is required for open-vm-tools to function properly. Please contact your OS vendor.])])])
AC_CHECK_FUNCS([ecvt])
AC_CHECK_FUNCS([fcvt])
if test "$os" = "freebsd" -a "$osVersion" -ge 600000; then
AC_CHECK_LIB(
[thr],
[pthread_mutex_init],
[THREAD_LIB=-lthr],
[AC_MSG_ERROR(
[Unable to locate required threading library libthr.])])
else
AC_CHECK_LIB(
[pthread],
[pthread_mutex_init],
[THREAD_LIB=-lpthread],
[AC_MSG_ERROR(
[libpthread not found. Please install the libc/libpthread devel package(s).])])
fi
# PAM prefix
AC_ARG_WITH([pam-prefix],
[AS_HELP_STRING([--with-pam-prefix],
[specifies where pam files go. Default is $(sysconfdir)])],
[PAM_PREFIX="$withval"],
[PAM_PREFIX='$(sysconfdir)'])
if test "$os" = "linux"; then
AC_ARG_WITH([procps],
[AS_HELP_STRING([--without-procps],
[compiles without libproc (disables support for meminfo)])],
[],
[with_procps=yes])
else
with_procps="no"
fi
if test "$with_procps" = "yes"; then
if test -z "$CUSTOM_PROCPS_NAME"; then
CUSTOM_PROCPS_NAME=proc
fi
# XXX: no pkg-config and no procps-config means we need to
# hard-code a sensible default.
if test -z "$CUSTOM_PROCPS_LIBS"; then
CUSTOM_PROCPS_LIBS="-L/lib"
fi
# Some distros provide libproc-${version}.so only, others provide the
# libproc.so symlink. Try both to see what sticks (but only try the 3.2.7
# and 3.2.8 versions - adding every possible version here would be a mess).
#
# Users can help by providing CUSTOM_PROCPS_NAME / CUSTOM_PROCPS_LIBS if
# necessary.
have_procps=no
AC_VMW_CHECK_LIB([$CUSTOM_PROCPS_NAME],
[PROCPS],
[],
[],
[],
[],
[getstat],
[
have_procps=yes;
],
[])
if test "$have_procps" = "no"; then
AC_VMW_CHECK_LIB([proc-3.2.8],
[PROCPS],
[],
[],
[],
[],
[getstat],
[
have_procps=yes;
],
[])
fi
if test "$have_procps" = "no"; then
AC_VMW_CHECK_LIB([proc-3.2.7],
[PROCPS],
[],
[],
[],
[],
[getstat],
[],
[AC_MSG_ERROR([libproc not found. Please configure without procps (using --without-procps) or install procps - http://procps.sourceforge.net])])
fi
fi
if test "$with_procps" != "yes"; then
AC_DEFINE([NO_PROCPS], 1, [Define to 1 if building without procps.])
fi
AC_ARG_WITH([dnet],
[AS_HELP_STRING([--without-dnet],
[compiles without libdnet (disables support for nicinfo)])],
[],
[with_dnet=yes])
have_dnet="no"
if test "$with_dnet" = "yes"; then
# On Debian, dnet is installed via the libdumbnet package. We need to
# detect this so that our source files include dumbnet.h instead of
# dnet.h, which is part of a different package altogether.
AC_VMW_CHECK_LIB([dumbnet],
[DNET],
[],
[dumbnet-config],
[],
[dumbnet.h],
[intf_open],
[have_dnet="yes";
AC_DEFINE([DNET_IS_DUMBNET], 1, [Define to 1 if substituting Debian's libdumbnet for libdnet.])],
[])
if test $have_dnet = "no"; then
AC_VMW_CHECK_LIB([dnet],
[DNET],
[],
[dnet-config],
[],
[dnet.h],
[intf_open],
[have_dnet="yes"],
[])
fi
if test $have_dnet = "no"; then
AC_MSG_ERROR(
[dnet-config was not found on your PATH. Please configure without dnet (using --without-dnet) or install dnet - http://libdnet.sourceforge.net])
fi
fi
if test "$with_dnet" != "yes"; then
AC_DEFINE([NO_DNET], 1, [Define to 1 if building without libdnet.])
fi
AC_ARG_WITH([icu],
[AS_HELP_STRING([--without-icu],
[disables support for ICU])],
[],
[with_icu=yes])
if test "$have_x" = "yes" -o "$with_icu" = "yes"; then
AC_CHECK_TOOL([have_cxx], [$CXX], [no])
if test "$have_cxx" = "no"; then
AC_MSG_ERROR([C++ compiler not found. Make sure you have a C++ compiler installed or configure without X11 (using --without-x) and without ICU (using --without-icu).])
fi
fi
if test "$with_icu" = "yes"; then
AC_VMW_CHECK_LIBXX([icuuc],
[ICU],
[],
[icu-config],
[],
[unicode/utf.h],
[],
[ICU_CPPFLAGS="$ICU_CPPFLAGS -DUSE_ICU"],
[AC_MSG_ERROR([ICU library not found. Please configure without ICU (using --without-icu) or install ICU - http://www.icu-project.org])])
# Check whether we have ICU >= 3.8.
AC_LANG_PUSH([C++])
AC_MSG_CHECKING([for ucasemap_utf8ToTitle in ICU])
ORIGINAL_CPPFLAGS="$CPPFLAGS"
CPPFLAGS="$CPPFLAGS $ICU_CPPFLAGS"
AC_TRY_COMPILE([#include <unicode/ucasemap.h>],
[
(void) &ucasemap_utf8ToTitle;
return 0;
],
[
ICU_CPPFLAGS="$ICU_CPPFLAGS -DHAVE_ICU_38"
AC_MSG_RESULT([yes])
],
[AC_MSG_RESULT([no])])
CPPFLAGS="$ORIGINAL_CPPFLAGS"
AC_LANG_POP([C++])
# Easier to give all modules the ICU defines/includes...
CPPFLAGS="$CPPFLAGS $ICU_CPPFLAGS"
else
CPPFLAGS="$CPPFLAGS -DNO_ICU"
fi
AC_PATH_PROG(
[RPCGEN],
[rpcgen],
[ AC_MSG_ERROR([rpcgen not found. Please install the libc devel package.]) ])
###
### Headers
###
AC_CHECK_HEADERS([crypt.h])
AC_CHECK_HEADERS([inttypes.h])
AC_CHECK_HEADERS([stdint.h])
AC_CHECK_HEADERS([stdlib.h])
AC_CHECK_HEADERS([wchar.h])
AC_CHECK_HEADERS([sys/inttypes.h])
AC_CHECK_HEADERS([sys/io.h])
AC_CHECK_HEADERS([sys/param.h]) # Required to make the sys/user.h check work correctly on FreeBSD
AC_CHECK_HEADERS([sys/sysinfo.h])
AC_CHECK_HEADERS([sys/types.h])
AC_CHECK_HEADERS([sys/user.h],
[],
[],
[
#ifdef HAVE_SYS_PARAM_H
# include <sys/param.h>
#endif
])
AC_CHECK_HEADERS([sys/vfs.h])
AC_CHECK_HEADERS([syslimits.h])
AC_CHECK_HEADERS([unwind.h])
AC_CHECK_HEADER(
[wchar.h],
[HAVE_WCHAR_H="yes"],
[HAVE_WCHAR_H="no"])
if test "$os" = "linux"; then
# Make sure kernel-headers package is installed.
AC_CHECK_HEADER(
[linux/unistd.h],
[],
[AC_MSG_ERROR(linux/unistd.h is not found. Please install kernel-headers/linux-userspace-headers/linux-libc-dev package.)])
fi
if test "$enable_multimon" != "no"; then
AC_CHECK_HEADER(
[X11/extensions/panoramiXproto.h],
[],
[AC_MSG_ERROR(
[panoramiXproto.h not found. Please configure without multimon (using --disable-multimon) or install the libXinerama devel package(s).])],
[#include <X11/X.h>
#include <X11/Xmd.h>])
fi
bsdPrintfWrappers=no
if test "$os" = "linux"; then
AC_CHECK_LIB([c],
[ecvt],
[bsdPrintfWrappers=yes],
[])
fi
###
### Typdefs, structs, and compiler quarks.
###
AC_HEADER_STDBOOL
AC_C_CONST
AC_TYPE_UID_T
AC_C_INLINE
AC_TYPE_MODE_T
AC_TYPE_OFF_T
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_CHECK_MEMBERS([struct stat.st_rdev])
AC_HEADER_TIME
AC_STRUCT_TM
AC_C_VOLATILE
###
### Specific features and OS/arch flags / actions
###
### General flags / actions
CFLAGS="$CFLAGS -Wall"
CFLAGS="$CFLAGS -Werror"
# -Wno-unknown-pragmas is due to gcc not understanding '#pragma ident' in Xlib.h on OpenSolaris.
for TEST_CFLAG in -Wno-pointer-sign -Wno-unused-value -fno-strict-aliasing \
-Wno-unknown-pragmas -Wno-uninitialized; do
AC_MSG_CHECKING([for GCC flag $TEST_CFLAG])
ORIGINAL_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS $TEST_CFLAG"
NEW_CFLAG=""
AC_TRY_COMPILE(
[],
[
return 0;
],
[NEW_CFLAG=" $TEST_CFLAG"
AC_MSG_RESULT(yes)],
[AC_MSG_RESULT(no)])
CFLAGS="$ORIGINAL_CFLAGS$NEW_CFLAG"
done
CPPFLAGS="$CPPFLAGS -DVMX86_TOOLS"
CPPFLAGS="$CPPFLAGS"
# -fvisibility is used by "core service" plugins, but not required.
ORIGINAL_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS -fvisibility=hidden"
AC_MSG_CHECKING([for GCC flag -fvisibility])
AC_TRY_COMPILE([],
[return 0;],
[PLUGIN_CPPFLAGS="-fvisibility=hidden -DGCC_EXPLICIT_EXPORT";
AC_MSG_RESULT(yes)],
[AC_MSG_RESULT(no)])
CFLAGS="$ORIGINAL_CFLAGS"
# Detect "unused-but-set-variable" gcc warning and disable it.
ORIGINAL_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS -Wno-unused-but-set-variable"
AC_MSG_CHECKING([for GCC flag -Wno-unused-but-set-variable])
AC_TRY_COMPILE([],
[return 0;],
[ORIGINAL_CFLAGS="$ORIGINAL_CFLAGS -Wno-unused-but-set-variable";
AC_MSG_RESULT(yes)],
[AC_MSG_RESULT(no)])
CFLAGS="$ORIGINAL_CFLAGS"
BUILDDIR="`pwd`"
INCLUDE_DIR="`cd $srcdir; pwd`/lib/include"
BLD_INCLUDE_DIR="$BUILDDIR/lib/include"
CPPFLAGS="-I$INCLUDE_DIR -I$BLD_INCLUDE_DIR $CPPFLAGS"
###
### Documentation.
###
if test "$enable_docs" = "yes"; then
AC_CHECK_PROG([have_doxygen],
[doxygen],
[yes],
[no])
if test "$have_doxygen" = "no"; then
AC_MSG_WARN([doxygen not found; API documentation will not be generated.])
else
AC_PATH_PROG([DOT], [dot], [])
if test "$DOT" = ""; then
HAVE_DOT=NO
else
DOT=`dirname $DOT`
HAVE_DOT=YES
fi
AC_SUBST([DOT])
AC_SUBST([HAVE_DOT])
AC_PATH_PROG([MSCGEN],
[mscgen],
[no])
if test "$MSCGEN" != "no"; then
MSCGEN_DIR="`dirname $MSCGEN`"
else
MSCGEN_DIR=
fi
AC_SUBST([MSCGEN_DIR])
fi
fi
###
### OS/arch-specific flags / actions
###
MODULES=""
MODULES_OS="$os"
TARGET_OS="$os"
MODULES_DIR=""
buildHgfsmounter=no
if test "$have_glib_2_14" = "yes"; then
CPPFLAGS="$CPPFLAGS -DHAVE_GLIB_REGEX"
fi
if test "$os" = "linux"; then
MODULES_DIR="$LINUXDIR/kernel/"
CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=64"
CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
CPPFLAGS="$CPPFLAGS -D_BSD_SOURCE"
CPPFLAGS="$CPPFLAGS -D_SVID_SOURCE"
LIBVMTOOLS_LIBADD="$LIBVMTOOLS_LIBADD -lrt"
MODULES="$MODULES vmci vsock"
MODULES="$MODULES vmxnet vmblock vmhgfs"
if test "$osVersion" -lt 300000; then
MODULES="$MODULES vmsync"
fi
buildHgfsmounter=yes
fi
if test "$os" = "freebsd"; then
LIBVMTOOLS_LIBADD="$LIBVMTOOLS_LIBADD -lkvm"
MODULES_DIR="/boot/modules"
if test "$osVersion" -ge 302000; then
MODULES="$MODULES vmmemctl"
fi
if test "$osVersion" -ge 409000; then
MODULES="$MODULES vmxnet"
fi
if test "$osVersion" -ge 600000; then
MODULES="$MODULES vmblock vmhgfs"
buildHgfsmounter=yes
fi
if test "$with_kernel_modules" = "yes"; then
echo "****************************************************************"
echo " You are building FreeBSD kernel modules. Make sure you use "
echo " 'make' to build open-vm-tools, and not GNU make ('gmake'). "
echo "****************************************************************"
fi
fi
if test "$os" = "solaris"; then
LIB_IMPERSONATE_CPPFLAGS="$LIB_IMPERSONATE_CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
LIB_USER_CPPFLAGS="$LIB_USER_CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
LIBVMTOOLS_LIBADD="$LIBVMTOOLS_LIBADD -lsocket"
LIBVMTOOLS_LIBADD="$LIBVMTOOLS_LIBADD -lnsl"
LIBVMTOOLS_LIBADD="$LIBVMTOOLS_LIBADD -lresolv"
LIBVMTOOLS_LIBADD="$LIBVMTOOLS_LIBADD -lrpcsvc"
# Setup defines to identify the OS version.
if test "$osVersion" -eq 509000; then
CPPFLAGS="$CPPFLAGS -DSOL9"
fi
if test "$osVersion" -eq 510000; then
CPPFLAGS="$CPPFLAGS -DSOL10"
fi
if test "$osVersion" -eq 511000; then
CPPFLAGS="$CPPFLAGS -DSOL11"
fi
MODULES="$MODULES vmxnet vmmemctl"
# HGFS and vmblock need Solaris 10 at least.
if test "$osVersion" -ge 510000; then
MODULES="$MODULES vmhgfs vmblock"