-
-
Notifications
You must be signed in to change notification settings - Fork 49
/
MainWindow.vala
251 lines (203 loc) · 8.55 KB
/
MainWindow.vala
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
/*
* SPDX-License-Identifier: LGPL-3.0-or-later
* SPDX-FileCopyrightText: 2021 elementary, Inc. (https://elementary.io)
*/
public class Music.MainWindow : Gtk.ApplicationWindow {
private Gtk.Button repeat_button;
private Gtk.Button shuffle_button;
private Settings settings;
construct {
var playback_manager = PlaybackManager.get_default ();
var start_window_controls = new Gtk.WindowControls (Gtk.PackType.START);
shuffle_button = new Gtk.Button.from_icon_name ("media-playlist-shuffle-symbolic") {
action_name = Application.ACTION_PREFIX + Application.ACTION_SHUFFLE,
tooltip_text = _("Shuffle")
};
repeat_button = new Gtk.Button ();
var queue_header = new Gtk.HeaderBar () {
show_title_buttons = false,
title_widget = new Gtk.Label ("")
};
queue_header.add_css_class (Granite.STYLE_CLASS_DEFAULT_DECORATION);
queue_header.pack_start (start_window_controls);
queue_header.pack_end (shuffle_button);
queue_header.pack_end (repeat_button);
var queue_placeholder = new Granite.Placeholder (_("Queue is Empty")) {
description = _("Audio files opened from Files will appear here"),
icon = new ThemedIcon ("playlist-queue")
};
var queue_listbox = new Gtk.ListBox () {
hexpand = true,
vexpand = true
};
queue_listbox.bind_model (playback_manager.queue_liststore, create_queue_row);
queue_listbox.set_placeholder (queue_placeholder);
var scrolled = new Gtk.ScrolledWindow () {
child = queue_listbox
};
var drop_target = new Gtk.DropTarget (typeof (Gdk.FileList), Gdk.DragAction.COPY);
var add_button_label = new Gtk.Label (_("Open Files…"));
var add_button_box = new Gtk.Box (HORIZONTAL, 0);
add_button_box.append (new Gtk.Image.from_icon_name ("document-open-symbolic"));
add_button_box.append (add_button_label);
var add_button = new Gtk.Button () {
child = add_button_box,
};
add_button.add_css_class (Granite.STYLE_CLASS_FLAT);
add_button_label.mnemonic_widget = add_button;
var queue_action_bar = new Gtk.ActionBar ();
queue_action_bar.pack_start (add_button);
var queue = new Adw.ToolbarView () {
bottom_bar_style = RAISED,
content = scrolled
};
queue.add_controller (drop_target);
queue.add_css_class (Granite.STYLE_CLASS_VIEW);
queue.add_top_bar (queue_header);
queue.add_bottom_bar (queue_action_bar);
var error_toast = new Granite.Toast ("");
var queue_overlay = new Gtk.Overlay () {
child = queue
};
queue_overlay.add_overlay (error_toast);
var queue_handle = new Gtk.WindowHandle () {
child = queue_overlay
};
var end_window_controls = new Gtk.WindowControls (Gtk.PackType.END);
var end_header = new Gtk.HeaderBar () {
show_title_buttons = false,
title_widget = new Gtk.Label ("")
};
end_header.add_css_class (Granite.STYLE_CLASS_FLAT);
end_header.add_css_class (Granite.STYLE_CLASS_DEFAULT_DECORATION);
end_header.pack_end (end_window_controls);
var now_playing_view = new NowPlayingView () {
margin_top = 12,
margin_end = 12,
margin_bottom = 24,
margin_start = 12,
vexpand = true
};
var now_playing = new Gtk.Box (VERTICAL, 0);
now_playing.append (end_header);
now_playing.append (now_playing_view);
var now_playing_handle = new Gtk.WindowHandle () {
child = now_playing
};
var paned = new Gtk.Paned (Gtk.Orientation.HORIZONTAL) {
start_child = queue_handle,
end_child = now_playing_handle,
resize_end_child = false,
shrink_end_child = false,
shrink_start_child = false
};
child = paned;
// We need to hide the title area for the split headerbar
var null_title = new Gtk.Grid () {
visible = false
};
set_titlebar (null_title);
settings = new Settings ("io.elementary.music");
settings.bind ("pane-position", paned, "position", SettingsBindFlags.DEFAULT);
settings.changed["repeat-mode"].connect (update_repeat_button);
update_repeat_button ();
drop_target.drop.connect ((target, value, x, y) => {
if (value.type () == typeof (Gdk.FileList)) {
var list = (Gdk.FileList)value;
File[] file_array = {};
foreach (unowned var file in list.get_files ()) {
file_array += file;
}
var files_to_play = Application.loop_through_files (file_array);
PlaybackManager.get_default ().queue_files (files_to_play);
return true;
}
return false;
});
playback_manager.invalids_found.connect ((count) => {
error_toast.title = ngettext (
"%d invalid file was not added to the queue",
"%d invalid files were not added to the queue",
count).printf (count);
error_toast.send_notification ();
});
add_button.clicked.connect (action_open);
repeat_button.clicked.connect (() => {
var enum_step = settings.get_enum ("repeat-mode");
if (enum_step < 2) {
settings.set_enum ("repeat-mode", enum_step + 1);
} else {
settings.set_enum ("repeat-mode", 0);
}
});
queue_listbox.row_activated.connect ((row) => {
playback_manager.current_audio = ((TrackRow) row).audio_object;
});
}
private void action_open () {
var all_files_filter = new Gtk.FileFilter () {
name = _("All files"),
};
all_files_filter.add_pattern ("*");
var music_files_filter = new Gtk.FileFilter () {
name = _("Music files"),
};
music_files_filter.add_mime_type ("audio/*");
var filter_model = new ListStore (typeof (Gtk.FileFilter));
filter_model.append (all_files_filter);
filter_model.append (music_files_filter);
var file_dialog = new Gtk.FileDialog () {
accept_label = _("Open"),
default_filter = music_files_filter,
filters = filter_model,
modal = true,
title = _("Open audio files")
};
file_dialog.open_multiple.begin (this, null, (obj, res) => {
try {
var files = file_dialog.open_multiple.end (res);
File[] file_array = {};
for (int i = 0; i < files.get_n_items (); i++) {
file_array += (File)(files.get_item (i));
}
var files_to_play = Application.loop_through_files (file_array);
PlaybackManager.get_default ().queue_files (files_to_play);
} catch (Error e) {
if (e.matches (Gtk.DialogError.quark (), Gtk.DialogError.DISMISSED)) {
return;
}
var dialog = new Granite.MessageDialog (
"Couldn't add audio files",
e.message,
new ThemedIcon ("document-open")
) {
badge_icon = new ThemedIcon ("dialog-error"),
modal = true,
transient_for = this
};
dialog.present ();
dialog.response.connect (dialog.destroy);
}
});
}
private void update_repeat_button () {
switch (settings.get_string ("repeat-mode")) {
case "disabled":
repeat_button.icon_name = "media-playlist-no-repeat-symbolic";
repeat_button.tooltip_text = _("Repeat None");
break;
case "all":
repeat_button.icon_name = "media-playlist-repeat-symbolic";
repeat_button.tooltip_text = _("Repeat All");
break;
case "one":
repeat_button.icon_name = "media-playlist-repeat-song-symbolic";
repeat_button.tooltip_text = _("Repeat One");
break;
}
}
private Gtk.Widget create_queue_row (GLib.Object object) {
unowned var audio_object = (AudioObject) object;
return new TrackRow (audio_object);
}
}