-
Notifications
You must be signed in to change notification settings - Fork 320
/
earmark.ex
99 lines (79 loc) · 2.37 KB
/
earmark.ex
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
defmodule ExDoc.Markdown.Earmark do
@moduledoc """
ExDoc extension for the EarmarkParser Markdown parser.
"""
@behaviour ExDoc.Markdown
@doc """
Check if the EarmarkParser Markdown parser module is available.
"""
def available? do
match?({:ok, _}, Application.ensure_all_started(:earmark_parser)) and
Code.ensure_loaded?(EarmarkParser)
end
@doc """
Generate HTML AST.
## Options
* `:gfm` - boolean. Turns on Github Flavored Markdown extensions. True by default
* `:breaks` - boolean. Only applicable if `gfm` is enabled. Makes all line
breaks significant (so every line in the input is a new line in the output)
* `:smartypants` - boolean. Turns on smartypants processing, so quotes become curly,
two or three hyphens become en and em dashes, and so on. False by default
"""
@impl true
def to_ast(text, opts) do
options = [
gfm: Keyword.get(opts, :gfm, true),
line: Keyword.get(opts, :line, 1),
file: Keyword.get(opts, :file, "nofile"),
breaks: Keyword.get(opts, :breaks, false),
smartypants: Keyword.get(opts, :smartypants, false),
pure_links: true
]
case EarmarkParser.as_ast(text, options) do
{:ok, ast, messages} ->
print_messages(messages, options)
fixup(ast)
{:error, ast, messages} ->
print_messages(messages, options)
fixup(ast)
end
end
defp print_messages(messages, options) do
for {severity, line, message} <- messages do
file = options[:file]
IO.warn("#{inspect(__MODULE__)} (#{severity}) #{file}:#{line} #{message}", [])
end
end
defp fixup(list) when is_list(list) do
fixup_list(list, [])
end
defp fixup(binary) when is_binary(binary) do
binary
end
defp fixup({tag, attrs, ast}) when is_binary(tag) do
{fixup_tag(tag), Enum.map(attrs, &fixup_attr/1), fixup(ast)}
end
defp fixup({tag, attrs, ast, _meta}) when is_binary(tag) do
fixup({tag, attrs, ast})
end
defp fixup({:comment, _, _, _}) do
[]
end
defp fixup_list([head | tail], acc) do
fixed = fixup(head)
if fixed == [] do
fixup_list(tail, acc)
else
fixup_list(tail, [fixed | acc])
end
end
defp fixup_list([], acc) do
Enum.reverse(acc)
end
defp fixup_tag(tag) do
String.to_atom(tag)
end
defp fixup_attr({name, value}) do
{String.to_atom(name), value}
end
end