eaf cannot be installed via straight?

[lsth]

I cannot install eaf via straight. Does someone know how to do that?

I tried

emacs -q -l eaf-straight.el 

where eaf-straigh.el is

(defvar bootstrap-version)
(let ((bootstrap-file
       (expand-file-name "straight/repos/straight.el/bootstrap.el" user-emacs-directory))
      (bootstrap-version 5))
  (unless (file-exists-p bootstrap-file)
    (with-current-buffer
        (url-retrieve-synchronously
         "https://raw.githubusercontent.com/raxod502/straight.el/develop/install.el"
         'silent 'inhibit-cookies)
      (goto-char (point-max))
      (eval-print-last-sexp)))
  (load bootstrap-file nil 'nomessage))

(straight-use-package 'use-package)

(use-package eaf 
  :straight (eaf
             :type git :repo "https://github.com/manateelazycat/emacs-application-framework.git"))

but this throws

Error (use-package): eaf/:catch: Opening directory: No such file or directory, /home/lst/.emacs.d/straight/build/eaf/app

and indeed the two subdirectories ~/.emacs.d/straight/build/eaf/app and .../core are missing.

[nasyxx]

(straight-use-package '(eaf :type git
                            :host github
                            :repo "manateelazycat/emacs-application-framework"
                            :files ("*.el" "*.py" "core" "app")))

[lsth]

thanks a lot, this solved it!

[bevsxyz]

In case it helps.

I got installation working with the following lines of use-package with straight.el

  (use-package eaf
    :straight (eaf
               :type git
               :host github
               :repo "emacs-eaf/emacs-application-framework"           
               :files ("*.el" "*.py" "core" "app" "*.json")
               :includes (eaf-pdf-viewer eaf-browser) ; Straight won't try to search for these packages when we make further use-package invocations for them
               :pre-build (("python" "install-eaf.py" "--install" "pdf-viewer" "browser" "--ignore-sys-deps"))
               )
    :init (evil-set-initial-state 'eaf-mode 'emacs)) ; Evil mode doesn't work well with eaf keybindings.

Load the apps separately with different use-package invocations.

 (use-package eaf-browser
    :custom
    (eaf-browser-continue-where-left-off t)
    (eaf-browser-enable-adblocker t))
(use-package eaf-pdf-viewer)

I am not sure about the :pre-build as I installed it in the terminal from the repo directory.

edit: :pre-build works very well now! Yay!!!! The code has been updated.

I deleted the emacs-application-framework directory from straight and restarted emacs to test. straight handles the cloning and building with grace.

Discussion link