How do you specify HCL in the env0_enviroment resource configuration?

[mmclane]

I have a module I use to create all of my projects and environments. My environments sub-module looks like this:

data "env0_template" "this" {
  name = var.template
}

data "env0_project" "this" {
  name = var.project
}

resource "env0_environment" "this" {
  name                       = var.name
  project_id                 = data.env0_project.this.id
  template_id                = data.env0_template.this.id
  workspace                  = var.workspace == "---" ? var.name : var.workspace
  approve_plan_automatically = var.approve_plan_automatically
  deploy_on_push             = var.deploy_on_push
  force_destroy              = var.force_destroy
  run_plan_on_pull_requests  = var.run_plan_on_pull_requests

  dynamic "configuration" {
    for_each = var.configuration
    content {
      name  = configuration.key
      value = configuration.value
      type  = "terraform"
    }
  }
}

I have recently create a template that has HCL formatted variables. When I create the environment by hand I can input a multi-line list and everything is good. How can I achieve the same thing with the terraform provider? So far I have tried to something like this:

config = {
    items =<<END
    [
    "item1",
    "item2",
    "item3"
    ]
   END
}

But when env0 runs that deployment the format is switch to String and I think the formatting is getting in the way.

I have tried a few things including creating a second dynamic configuration block and setting format = "HCL" or schema_format= "HCL" but got an error about it not being appropriate or valid or something.

How can I achieve this? The documentation doesn't have an example.

[yaronya]

Hi @mmclane
Thanks for reaching out on this one!

This is indeed unsupported at the moment, but we'll make sure to add such support soon in the upcoming version

[TomerHeber]

@mmclane

Could you please retry?

I can confirm the following example now works:

resource "env0_environment" "environment123" {
  name                             = "environment"
  project_id                       = "3189ee49-5093-4790-951d-c89f98f8fe13"
  template_id                      = "565e8626-8c2e-4174-a8b8-a1de259376f3"
  workspace                        = "env04d60cf"
  auto_deploy_on_path_changes_only = false

  configuration {
    name          = "TEST1234"
    type          = "terraform"
    value         = <<EOF
      {
        a = "world11111"
        b = {
          c = "d"
        }
      }
    EOF
    schema_format = "HCL"
  }
}

[mmclane]

I can verify that what you have works with the latest version of the provider. Thanks

[TomerHeber]

@mmclane thank you for confirming.
I will add this example to the documentation.