wpart_csv.erl

%% The contents of this file are subject to the Erlang Web Public License,
%% Version 1.0, (the "License"); you may not use this file except in
%% compliance with the License. You should have received a copy of the
%% Erlang Web Public License along with this software. If not, it can be
%% retrieved via the world wide web at http://www.erlang-consulting.com/.
%%
%% Software distributed under the License is distributed on an "AS IS"
%% basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
%% the License for the specific language governing rights and limitations
%% under the License.
%%
%% The Initial Developer of the Original Code is Erlang Training & Consulting
%% Ltd. Portions created by Erlang Training & Consulting Ltd are Copyright 2008,
%% Erlang Training & Consulting Ltd. All Rights Reserved.

%%%-------------------------------------------------------------------
%%% @author Michal Zajda <info@erlang-consulting.com>
%%% @doc 
%%% @end
%%%-------------------------------------------------------------------
-module(wpart_csv).
-behaviour(wpart).

-export([handle_call/1, build_html_tag/4, build_html_tag/3, load_tpl/0]).

-deprecated([build_html_tag/3]).

-include_lib("xmerl/include/xmerl.hrl").

handle_call(#xmlElement{attributes = Attrs0}) ->
    Attrs = wpart:xml2proplist(Attrs0),
    
    #xmlText{value=get_html_tag(Attrs, ""),
	     type=cdata}.

build_html_tag(Id, Params, Default) ->
    Attrs0 = wpart:normalize_html_attrs(proplists:get_value(html_attrs, Params, [])),
    Delimiter = proplists:get_value(delimiter, Params, ","),
    Attrs = [{"name", Id}, {"id", Id}, {"delimiter", Delimiter} |
	     proplists:delete("name", Attrs0)],
    
    get_html_tag(Attrs, Default).

build_html_tag(Name, Prefix, Params, Default) ->
    N = wpart_derived:generate_long_name(Prefix, Name),
    Description = wpart_derived:get_description(Name, Params),
    D = wpart_derived:find(N, Default),

    Attrs0 = wpart:normalize_html_attrs(proplists:get_value(html_attrs, Params, [])),
    Delimiter = proplists:get_value(delimiter, Params, ","),
    Attrs = [{"name", N}, {"delimiter", Delimiter} | proplists:delete("name", Attrs0)],

    wpart_derived:surround_with_table(N, get_html_tag(Attrs, D), Description).

get_html_tag(Attrs, Default) ->
    Ready = get_default(proplists:get_value("delimiter", Attrs, ","), Default),
    
    wpart_gen:build_html(wpart_gen:tpl_get(csv),
			 [{"html", wpart:proplist2html(proplists:delete("delimiter", Attrs))},
			  {"value", Ready}]).

get_default(Delimiter, Defaults) when length(Defaults) > 0 ->
    string:join(case hd(Defaults) of
		    {_D, _T} -> %% a datetime
			[wtype_datetime:format("Stamp", Tuple) || Tuple <- Defaults];
		    {_, _, _} = DT -> %% date or time
			case calendar:valid_date(DT) of
			    true ->
				[wtype_date:get_date("DD SMONTH YYYY", List) || List <- Defaults];
			    false ->
				case wtype_time:is_valid_time(DT) of
				    true ->
					[string:join(lists:map(fun integer_to_list/1, 
							       tuple_to_list(In)), 
						     [$:]) || In <- Defaults];
				    false ->
					Defaults
				end
			end;
		    _ ->
			Defaults
		end, Delimiter);
get_default(_Delimiter, Defaults) ->
    Defaults.
		   
load_tpl() ->
    wpart_gen:load_tpl(csv,
		       filename:join([code:priv_dir(wparts),"html","csv.tpl"])).