esp now and Wifi client both are not working simultaneously

[James-sjec]

Hardware:

Board: ?ESP32 Dev Module?
Core Installation/update date: ?11/jul/2017?
IDE name: ?Arduino IDE? ?Platform.io? ?IDF component?
Flash Frequency: ?40Mhz?
Upload Speed: ?115200?

Description:

I am using mqtt protocol and sending data to AWS server.
and simultaneously receiving data from other esp32 and sending that data to the server.

The problem is before Wifi client connects to AWS , esp now is working(I am receiving data from other esp32) , but after WiFi client connects to AWS , esp now stops working (No data is received) . And when Wifi client disconnects from AWS , esp now is working.

I loaded esp_now Slave code in the esp32 which to connects AWS and the devices is configured as AP_STA mode. Esp_now Mater code in other esp32 which send its data.

My doubt : Is AP and STA cannot work simultaneously. If it is not possible tell me is there any way to receive data from other esp32 through AP and send data to the server

[me-no-dev]

This sounds really strange. Generally ESP-NOW has nothing to do with TCP/UDP and runs underneath that stack. Can you please post a minimal sketch that shows this issue so we can run it internally and try to figure out what might be going wrong

[auladinamica]

Can you publish a code that work like James-sjec describe ?

i have a esp32(server) that is conected to the wifi , also have a esp_now avaiable and five sensors(esp32 now master) publish data to the server and the server send this data to the web,,, can you publish a code to do this scenario ?

thanks

[beegee-tokyo]

On ESP8266 you can either use ESPNow or connect the module to an AP. Both together doesn't work. I just tested it (after reading about it). I can send and receive data over ESPNow until I connect the WiFi to an AP. After successful connection to AP, ESPNow send fails and I receive no more data.

Reference

My guess is that on the ESP32 it is the same.

[me-no-dev]

@beegee-tokyo I raised this question to the team and they confirmed that this is not the expected behaviour on ESP32 and ESP-NOW should work together with WiFi

[beegee-tokyo]

I build up a small test configuration with an ESP8266 sending data over ESPNow and an ESP32 receiving data over ESPNow. Then the ESP32 send the received data over MQTT to an MQTT broker and it works.

But there is one condition:

The Wifi you connect to must be on the same Wifi channel that is used for ESPNow.
In my case I tested with ESPNow sending/receiving on channel 1 and the ESP32 connected to a WiFi which is using channel 1 as well.
If I connect to another WiFi that uses e.g. channel 13, the ESP32 does not receive any ESPNow data anymore.
I tried to change the ESPNow channel to 13, but I didn't get the connection between the ESP8266 and ESP32 to work (with or without a WiFi connection). That might be a limitation on the ESP8266 (???) but I have only one ESP32 to test.
Here is the code that worked for me:
ESP8266 code adapted from ESP32 ESPNow example:

#include <Arduino.h>
#include <ESP8266WiFi.h>
#include <Ticker.h>
extern "C" {
  #include <espnow.h>
  #include <user_interface.h>
}

/**
   ESPNOW - Basic communication - Master
   Date: 26th September 2017
   Author: Arvind Ravulavaru <https://github.com/arvindr21>
*/

typedef struct esp_now_peer_info {
    u8 peer_addr[6];    /**< ESPNOW peer MAC address that is also the MAC address of station or softap */
    uint8_t channel;                        /**< Wi-Fi channel that peer uses to send/receive ESPNOW data. If the value is 0,
                                                 use the current channel which station or softap is on. Otherwise, it must be
                                                 set as the channel that station or softap is on. */
} esp_now_peer_info_t;

// Global copy of slave
#define NUMSLAVES 20
esp_now_peer_info_t slaves[NUMSLAVES] = {};
int SlaveCnt = 0;

#define CHANNEL 1

void printMacAddress(uint8_t* macaddr) {
  Serial.print("{");
  for (int i = 0; i < 6; i++) {
    Serial.print("0x");
    Serial.print(macaddr[i], HEX);
    if (i < 5) Serial.print(',');
  }
  Serial.println("};");
}

// Init ESP Now with fallback
void InitESPNow() {
  if (esp_now_init() == 0) {
    Serial.println("ESPNow Init Success");
  }
  else {
    Serial.println("ESPNow Init Failed");
    ESP.restart();
  }
  esp_now_set_self_role(ESP_NOW_ROLE_CONTROLLER);
}

// Scan for slaves in AP mode
void ScanForSlave() {
  int8_t scanResults = WiFi.scanNetworks();
  //reset slaves
  memset(slaves, 0, sizeof(slaves));
  SlaveCnt = 0;
  Serial.println("");
  if (scanResults == 0) {
    Serial.println("No WiFi devices in AP Mode found");
  } else {
    Serial.print("Found "); Serial.print(scanResults); Serial.println(" devices ");
    for (int i = 0; i < scanResults; ++i) {
      // Print SSID and RSSI for each device found
      String SSID = WiFi.SSID(i);
      int32_t RSSI = WiFi.RSSI(i);
      String BSSIDstr = WiFi.BSSIDstr(i);
      delay(10);
      // Check if the current device starts with `Slave`
      if (SSID.indexOf("Slave") == 0) {
        // SSID of interest
        Serial.print(i + 1); Serial.print(": ");
        Serial.print(SSID); Serial.print(" [");
        Serial.print(BSSIDstr); Serial.print("]");
        Serial.print(" ("); Serial.print(RSSI);
        Serial.print(")"); Serial.println("");
        // Get BSSID => Mac Address of the Slave
        char macPart[4];
        macPart[0] = '0';
        macPart[1] = 'x';

        macPart[2] = (char)BSSIDstr[0];
        macPart[3] = (char)BSSIDstr[1];
        slaves[SlaveCnt].peer_addr[0] = strtol(macPart,0,16);
        macPart[2] = (char)BSSIDstr[3];
        macPart[3] = (char)BSSIDstr[4];
        slaves[SlaveCnt].peer_addr[1] = strtol(macPart,0,16);
        macPart[2] = (char)BSSIDstr[6];
        macPart[3] = (char)BSSIDstr[7];
        slaves[SlaveCnt].peer_addr[2] = strtol(macPart,0,16);
        macPart[2] = (char)BSSIDstr[9];
        macPart[3] = (char)BSSIDstr[10];
        slaves[SlaveCnt].peer_addr[3] = strtol(macPart,0,16);
        macPart[2] = (char)BSSIDstr[12];
        macPart[3] = (char)BSSIDstr[13];
        slaves[SlaveCnt].peer_addr[4] = strtol(macPart,0,16);
        macPart[2] = (char)BSSIDstr[15];
        macPart[3] = (char)BSSIDstr[16];
        slaves[SlaveCnt].peer_addr[5] = strtol(macPart,0,16);

        SlaveCnt++;
      }
    }
  }

  if (SlaveCnt > 0) {
    Serial.print(SlaveCnt); Serial.println(" Slave(s) found, processing..");
  } else {
    Serial.println("No Slave Found, trying again.");
  }

  // clean up ram
  WiFi.scanDelete();
}

// Check if the slave is already paired with the master.
// If not, pair the slave with master
void manageSlave() {
  if (SlaveCnt > 0) {
    for (int i = 0; i < SlaveCnt; i++) {
      const esp_now_peer_info_t *peer = &slaves[i];
      u8 *peer_addr = slaves[i].peer_addr;
      Serial.print("Processing: ");
      for (int ii = 0; ii < 6; ++ii ) {
        Serial.print((uint8_t) slaves[i].peer_addr[ii], HEX);
        if (ii != 5) Serial.print(":");
      }
      Serial.print(" Status: ");
      // check if the peer exists
      bool exists = esp_now_is_peer_exist((u8*)peer_addr);
      if (exists) {
        // Slave already paired.
        Serial.println("Already Paired");
      } else {
        // Slave not paired, attempt pair
        int addStatus = esp_now_add_peer((u8*)peer_addr, ESP_NOW_ROLE_CONTROLLER, CHANNEL, NULL, 0);
        if (addStatus == 0) {
          // Pair success
          Serial.println("Pair success");
        } else {
          Serial.println("Pair failed");
        }
        delay(100);
      }
    }
  } else {
    // No slave found to process
    Serial.println("No Slave found to process");
  }
}


uint8_t data = 0;
// send data
void sendData() {
  data++;
  for (int i = 0; i < SlaveCnt; i++) {
    u8 *peer_addr = slaves[i].peer_addr;
    if (i == 0) { // print only for first slave
      Serial.print("Sending: ");
      Serial.println(data);
    }
    int result = esp_now_send(peer_addr, &data, sizeof(data));
    Serial.print("Send Status: ");
    if (result ==0) {
      Serial.println("Success " + String(result));
    } else {
      Serial.println("Failed " + String(result));
    }
    delay(100);
  }
}

// callback when data is sent from Master to Slave
esp_now_send_cb_t OnDataSent(const uint8_t *mac_addr, u8 status) {
  char macStr[18];
  snprintf(macStr, sizeof(macStr), "%02x:%02x:%02x:%02x:%02x:%02x",
           mac_addr[0], mac_addr[1], mac_addr[2], mac_addr[3], mac_addr[4], mac_addr[5]);
  Serial.print("Last Packet Sent to: "); Serial.println(macStr);
  Serial.print("Last Packet Send Status: "); Serial.println(status == 0 ? "Delivery Success" : "Delivery Fail");
}

void setup() {
  Serial.begin(115200);
  //Set device in STA mode to begin with
  WiFi.mode(WIFI_STA);
  Serial.println("ESPNow/Multi-Slave/Master Example");
  // This is the mac address of the Master in Station Mode
  Serial.print("STA MAC: "); Serial.println(WiFi.macAddress());
  // Init ESPNow with a fallback logic
  InitESPNow();
  // Once ESPNow is successfully Init, we will register for Send CB to
  // get the status of Trasnmitted packet
  // esp_now_register_send_cb(OnDataSent);
  esp_now_register_send_cb([](uint8_t* macaddr, uint8_t status) {
    printMacAddress(macaddr);
    static uint32_t ok = 0;
    static uint32_t fail = 0;
    if (status == 0) {
      Serial.println("ESPNOW: SEND_OK");
      ok++;
    }
    else {
      Serial.println("ESPNOW: SEND_FAILED");
      fail++;
    }
    Serial.printf("[SUCCESS] = %lu/%lu \r\n", ok, ok+fail);
  });
}

void loop() {
  // In the loop we scan for slave
  ScanForSlave();
  // If Slave is found, it would be populate in `slave` variable
  // We will check if `slave` is defined and then we proceed further
  if (SlaveCnt > 0) { // check if slave channel is defined
    // `slave` is defined
    // Add slave as peer if it has not been added already
    manageSlave();
    // pair success or already paired
    // Send data to device
    sendData();
  } else {
    // No slave found to process
  }

  // wait for 3seconds to run the logic again
  delay(1000);
}

ESP32 code adapted from ESP32 ESPNow example:

/**
   ESPNOW - Basic communication - Slave
   Date: 26th September 2017
   Author: Arvind Ravulavaru <https://github.com/arvindr21>
*/

#include <esp_now.h>
#include <WiFi.h>
#include <MQTTClient.h>

#define CHANNEL 1

/** MQTT client class to access mqtt broker */
MQTTClient mqttClient(2560);
/** MQTT broker URL */
static const char * mqttBroker = "xx.xx.xx.xx";
/** MQTT connection id */
static const char * mqttID = "ESP32";
/** MQTT user name */
static const char * mqttUser = "esp32";
/** MQTT password */
static const char * mqttPwd = "PASSWORD";
/** WiFi client class to receive messages from mqtt broker */
WiFiClient mqttReceiver;

void OnDataRecv(const uint8_t *mac_addr, const uint8_t *data, int data_len);

// Init ESP Now with fallback
void InitESPNow() {
  if (esp_now_init() == ESP_OK) {
    Serial.println("ESPNow Init Success");
  }
  else {
    Serial.println("ESPNow Init Failed");
    ESP.restart();
  }
}

// config AP SSID
void configDeviceAP() {
  String Prefix = "Slave:";
  String Mac = WiFi.macAddress();
  String SSID = Prefix + Mac;
  String Password = "123456789";
  bool result = WiFi.softAP(SSID.c_str(), Password.c_str(), CHANNEL, 0);
  if (!result) {
    Serial.println("AP Config failed.");
  } else {
    Serial.println("AP Config Success. Broadcasting with AP: " + String(SSID));
  }
}

void setup() {
  Serial.begin(115200);
  Serial.println("ESPNow/Basic/Slave Example");

  //Set device in AP mode to begin with
  WiFi.mode(WIFI_AP_STA);
  WiFi.begin("MYWIFI", "MYWIFIPW");
  // configure device AP mode
  configDeviceAP();
  // This is the mac address of the Slave in AP Mode
  Serial.print("AP MAC: "); Serial.println(WiFi.softAPmacAddress());

  // Start connection to MQTT broker
  // Connect to MQTT broker
  mqttClient.begin(mqttBroker, mqttReceiver);

  Serial.println("Connecting to MQTT broker");

  int connectTimeout = 0;

  while (!mqttClient.connect(mqttID, mqttUser, mqttPwd)) {
    delay(100);
    connectTimeout++;
    if (connectTimeout > 10) { // Wait for 1 seconds to connect
      Serial.println("Can't connect to MQTT broker");
      ESP.restart();
    }
  }
  Serial.println("Connected to MQTT");

  // Init ESPNow with a fallback logic
  InitESPNow();
  // Once ESPNow is successfully Init, we will register for recv CB to
  // get recv packer info.
  esp_now_register_recv_cb(OnDataRecv);
}

// callback when data is recv from Master
void OnDataRecv(const uint8_t *mac_addr, const uint8_t *data, int data_len) {
  char macStr[18];
  snprintf(macStr, sizeof(macStr), "%02x:%02x:%02x:%02x:%02x:%02x",
           mac_addr[0], mac_addr[1], mac_addr[2], mac_addr[3], mac_addr[4], mac_addr[5]);
  Serial.print("Last Packet Recv from: "); Serial.println(macStr);
  Serial.print("Last Packet Recv Data: "); Serial.println(*data);
  Serial.println("");
  mqttClient.publish("/debug","[INFO] Last Packet Recv from: " + tftMsg);
  mqttClient.publish("/debug","[INFO] Last Packet Recv Data: " + tftMsg);
  recvMsgNum++;
}

void loop() {
  // Chill
}

Output on Serial from ESP32:

ESPNow/Basic/Slave Example
AP Config Success. Broadcasting with AP: Slave:24:0A:C4:81:CE:9C
AP MAC: 24:0A:C4:81:CE:9D
Connecting to MQTT broker
[E][WiFiClient.cpp:97] connect(): lwip_connect_r: 113
Connected to MQTT
ESPNow Init Success
Last Packet Recv from: 5c:cf:7f:01:5a:5d
Last Packet Recv Data: 91

Last Packet Recv from: 5c:cf:7f:01:5a:5d
Last Packet Recv Data: 92

Last Packet Recv from: 5c:cf:7f:01:5a:5d
Last Packet Recv Data: 93

Last Packet Recv from: 5c:cf:7f:01:5a:5d
Last Packet Recv Data: 94

Output on Serial from ESP8266:

ESPNow/Multi-Slave/Master Example
STA MAC: 5C:CF:7F:01:5A:5D
ESPNow Init Success

Found 6 devices 
2: Slave:24:0A:C4:81:CE:9C [24:0A:C4:81:CE:9D] (-55)
1 Slave(s) found, processing..
Processing: 24:A:C4:81:CE:9D Status: Pair success
Sending: 1
Send Status: Success 0
{0x24,0xA,0xC4,0x81,0xCE,0x9D};
ESPNOW: SEND_OK
[SUCCESS] = 1/1 

Output from my MQTT broker:

[INFO] Last Packet Recv from: 5c:cf:7f:01:5a:5d
[INFO] Last Packet Recv Data: 42
[INFO] Last Packet Recv from: 5c:cf:7f:01:5a:5d
[INFO] Last Packet Recv Data: 43
[INFO] Last Packet Recv from: 5c:cf:7f:01:5a:5d
[INFO] Last Packet Recv Data: 44

[auladinamica]

Hi guys :

I have many problems with ESP_NOW sometimes works and sometimes not..
here i describe my situation .

I have an esp sending data via esp_now, i have a server that receive this data, but sometimes the server not receive the data, i change only one function and the program fail..

this is a working code !!!

---

#include <esp_now.h>
#include <WiFi.h>

struct attribute((packed)) SENSOR_DATA_HIGROW {

int     tipo_sensor;
int     id_sensor;
float   temp_aire;
float   hum_aire;
int     hum_tierra;

} ;

#define max_Cant_sensores 10
int hume[max_Cant_sensores];
SENSOR_DATA_HIGROW sensorData_Higrow;
#define CHANNEL 1

void InitESPNow() {
if (esp_now_init() == ESP_OK) {
Serial.println("ESPNow Init Success");
}
else {
Serial.println("ESPNow Init Failed");
ESP.restart();
}
}

// config AP SSID
void configDeviceAP() {
String Prefix = "OMMA_Slave_";
String Mac = WiFi.macAddress();
String SSID = Prefix + Mac;
String Password = "123456789";
bool result = WiFi.softAP(SSID.c_str(), Password.c_str(), CHANNEL, 0);
if (!result) {
Serial.println("AP Config failed.");
} else {
Serial.println("AP Config Success. Broadcasting with AP: " + String(SSID));
}
}

void setup() {
Serial.begin(115200);
Serial.println("ESPNow/Basic/Slave Example");
WiFi.mode(WIFI_AP_STA);
WiFi.begin("auladinamica", "ABABABABa1");
/*
if( !checkConnection()){

ESP.restart();

}
*/
configDeviceAP();

Serial.print("AP MAC: "); Serial.println(WiFi.softAPmacAddress());
InitESPNow();
esp_now_register_recv_cb(OnDataRecv);
}

boolean checkConnection() {
int count = 0;
Serial.print("Waiting for Wi-Fi connection");
while ( count < 30 ) {
if (WiFi.status() == WL_CONNECTED) {
Serial.println("Connected!");
return (true);
}
delay(500);
Serial.print(".");
count++;
}
Serial.println("Timed out.");
return false;
}

void OnDataRecv(const uint8_t *mac_addr, const uint8_t *data, int data_len) {

char macStr[18];
String str = (char*)data;
snprintf(macStr, sizeof(macStr), "%02x:%02x:%02x:%02x:%02x:%02x",
mac_addr[0], mac_addr[1], mac_addr[2], mac_addr[3], mac_addr[4], mac_addr[5]);
Serial.print("Last Packet Recv from: "); Serial.println(macStr);
Serial.print("Last Packet Recv Data: "); Serial.println(*data);
Serial.print("largo data : "); Serial.println(String(data_len));

memcpy(&sensorData_Higrow, data, sizeof(sensorData_Higrow));

if (sensorData_Higrow.tipo_sensor==1){  
  Serial.println("-----------------------------------------------------------------------");
  Serial.print("Id    Sensor     :" ); Serial.println(String(sensorData_Higrow.id_sensor));
  Serial.print("Tipo Sensor      :" ); Serial.println(String(sensorData_Higrow.tipo_sensor));
  Serial.print("Temp Aire        :" ); Serial.println(String(sensorData_Higrow.temp_aire));
  Serial.print("Hume Aire        :" ); Serial.println(String(sensorData_Higrow.hum_aire));
  Serial.print("Hume Tierra      :" ); Serial.println(String(sensorData_Higrow.hum_tierra));
  Serial.println("-----------------------------------------------------------------------");
}

hume[sensorData_Higrow.id_sensor]=sensorData_Higrow.hum_tierra;
}

void loop() {

}

But if i use the checkConnection() function the esp not receive data !!!!!

Uncoment this code in the setup function and the system fail

/*
if( !checkConnection()){

ESP.restart();

}
*/

Can somebody explainme how to solve this issue ?

Thanks

[f2knpw]

I have exactly the same behavior 👍

either I can connect to wifi router and not get the data from ESP-NOW
or if I don't wait for wifi connection then I may receive data fromESP-NOW

I have even tried to connect to wifi only when received data but it never works... Connection always failed

// callback when data is recv from Master
void OnDataRecv(const uint8_t *mac_addr, const uint8_t *data, int data_len) {
  char macStr[18];
  snprintf(macStr, sizeof(macStr), "%02x:%02x:%02x:%02x:%02x:%02x",
           mac_addr[0], mac_addr[1], mac_addr[2], mac_addr[3], mac_addr[4], mac_addr[5]);
  Serial.print("Last Packet Recv from: "); Serial.println(macStr);
  Serial.print("Last Packet Recv Data: "); Serial.println(*data);
  Serial.println("");
 // mqttClient.publish("/debug","[INFO] Last Packet Recv from: " + tftMsg);
 // mqttClient.publish("/debug","[INFO] Last Packet Recv Data: " + tftMsg);
 // recvMsgNum++;

  WiFi.disconnect();
   WiFi.mode(WIFI_STA);
delay(1000);
  WiFi.begin("MySSID", "MyPassWord");
   while (WiFi.status() != WL_CONNECTED) {
        delay(500);
        Serial.print(".");
    }

    Serial.println("");
    Serial.println("WiFi connected");
    Serial.println("IP address: ");
    Serial.println(WiFi.localIP());
    
}

[beegee-tokyo]

Is your WiFi AP on the same channel as ESPNow? Check ESPNow and connection to WiFi AP. It seems ESPNow is only working when using the same WiFi channel.

[f2knpw]

Yes I tried with channel 6 which is my Wifi's channel. But does not work.

I tried as well to connect to my wifi router on the "master side"set in STA mode. As soon as it connected messages from ESPnow do not get the slave...
That's really a pity as I need this to connect the slave as a gateway to internet.

For the moment I will save the message with the "Preference Libary" and restart the ESP to connect to wifi. -> (Ugly solution)
(The Preferences library is a wrapper around the Non-volatile storage on ESP32 processor.)

[f2knpw]

What I find surprising is that even if I try to Wifi.disconnect() it does not work either...
I have tried directly from the API, but same result...
...

esp_now_deinit();
 esp_wifi_disconnect();
esp_wifi_stop();
esp_wifi_restore();
   WiFi.mode(WIFI_STA);
delay(1000);
  WiFi.begin("mySSID", "myPassword");
   while (WiFi.status() != WL_CONNECTED) {
        delay(500);
        Serial.print(WiFi.status());
    }

[beegee-tokyo]

Try to set everything to channel 0. That was the only way I got it to work.

[f2knpw]

When you say "everything" is it :
Master channel
Slave channel
And wifi router channel ?

[beegee-tokyo]

Yes,that was the only way I got it working.

[f2knpw]

Well, I have tried to set my wifi box on channel 0... It doesn't exist and starts at 1.
Put all to 1
but still does not work :-(

[auladinamica]

Can you publish the code? El lun., 26 mar. 2018 4:41 p. m., f2knw <notifications@github.com> escribió:

…

Well, I have tried to set my wifi box on channel 0... It doesn't exist and starts at 1. Put all to 1 but still does not work :-( — You are receiving this because you commented. Reply to this email directly, view it on GitHub <#878 (comment)>, or mute the thread <https://github.com/notifications/unsubscribe-auth/AFwNp8dzmVQDlRdGBGwgY4xnEw2SJIGpks5tiUR2gaJpZM4Qqw4R> .