-
Notifications
You must be signed in to change notification settings - Fork 3k
/
interfaces.hhi
923 lines (898 loc) · 31 KB
/
interfaces.hhi
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
<?hh // partial
/**
* Copyright (c) 2014, Facebook, Inc.
* All rights reserved.
*
* This source code is licensed under the MIT license found in the
* LICENSE file in the "hack" directory of this source tree.
*
*/
/**
* This file provides type information for some of PHP's predefined interfaces
*
* YOU SHOULD NEVER INCLUDE THIS FILE ANYWHERE!!!
*/
/**
* Represents an entity that can be iterated over using `foreach`, without
* requiring a key.
*
* The iteration variable will have a type of `T`.
*
* In addition to Hack collections, PHP `array`s and anything that implement
* `Iterator` are `Traversable`.
*
* In general, if you are implementing your own Hack class, you will want to
* implement `Iterable` instead of `Traversable` since `Traversable` is more
* of a bridge for PHP `array`s to work well with Hack collections.
*
* @guide /hack/collections/introduction
* @guide /hack/collections/interfaces
*/
<<__Sealed(
ArrayObject::class,
DOMNodeList::class,
Imagick::class,
Iterator::class,
IteratorAggregate::class,
KeyedTraversable::class,
ResourceBundle::class,
SplHeap::class,
SplObjectStorage::class,
\HH\Rx\Traversable::class
)>>
interface Traversable<+Tv> {}
/**
* Represents an entity that can be iterated over using `foreach`, allowing
* a key.
*
* The iteration variables will have a type of `Tk` for the key and `Tv` for the
* value.
*
* In addition to Hack collections, PHP `array`s and anything that implement
* `KeyedIterator` are `KeyedTraversable`.
*
* In general, if you are implementing your own Hack class, you will want to
* implement `KeyedIterable` instead of `KeyedTraversable` since
* `KeyedTraversable` is more of a bridge for PHP `array`s to work well with
* Hack collections.
*
* @guide /hack/collections/introduction
* @guide /hack/collections/interfaces
*/
<<__Sealed(
ArrayIterator::class,
AsyncMysqlRowBlock::class,
DOMNamedNodeMap::class,
ImagickPixelIterator::class,
IntlBreakIterator::class,
KeyedIterable::class,
KeyedIterator::class,
MysqlRow::class,
\HH\Rx\KeyedTraversable::class
)>>
interface KeyedTraversable<+Tk, +Tv> extends Traversable<Tv> {}
/**
* Represents an entity that can be iterated over using `foreach`, without
* requiring a key, except it does not include objects that implement
* `Iterator`.
*
* The iteration variable will have a type of `T`.
*
* In addition to Hack collections, PHP `array`s are `Container`s.
*
* @guide /hack/collections/introduction
* @guide /hack/collections/interfaces
*/
<<__Sealed(KeyedContainer::class)>>
interface Container<+Tv> extends \HH\Rx\Traversable<Tv> {}
/**
* Represents an entity that can be iterated over using `foreach`, allowing
* a key, except it does not include objects that implement `KeyedIterator` nor
* `Set` and `ImmSet`.
*
* The iteration variables will have a type of `Tk` for the key and `Tv` for the
* value.
*
* In addition to Hack collections, PHP `array`s are `KeyedContainer`s.
*
* @guide /hack/collections/introduction
* @guide /hack/collections/interfaces
*/
<<__Sealed(Indexish::class)>>
interface KeyedContainer<+Tk, +Tv> extends \HH\Rx\KeyedTraversable<Tk, Tv>, Container<Tv> {}
/**
* Represents an entity that can be indexed using square-bracket syntax.
*
* Square bracket syntax is:
*
* ```
* $indexish[$key]
* ```
*
* At this point, this includes entities with keys of `int` and `string`.
*
* In addition to Hack collections, PHP `array`s are `Indexish`.
*
* @guide /hack/collections/introduction
* @guide /hack/collections/interfaces
* @guide /hack/collections/read-write
*/
<<__Sealed(ConstVector::class, ConstMap::class, ImmMap::class, ConstSet::class, dict::class, keyset::class, vec::class)>>
interface Indexish<+Tk, +Tv> extends KeyedContainer<Tk, Tv> {}
/**
* For those entities that are `Traversable`, the `Iterator` interfaces provides
* the methods of iteration.
*
* If a class implements `Iterator`, then it provides the infrastructure to be
* iterated over using a `foreach` loop.
*
* @guide /hack/collections/introduction
* @guide /hack/collections/interfaces
*
* @link http://php.net/manual/en/class.iterator.php
*/
interface Iterator<+Tv> extends Traversable<Tv> {
/**
* Return the current value at the current iterator position.
*
* @return - The current value of type `Tv`.
*/
public function current(): Tv;
/**
* Move the iterator position to the next element.
*
*/
public function next(): void;
/**
* Rewind the iterator position to its beginning.
*
* This rewinds back to the first element of the `Iterator`.
*/
public function rewind(): void;
/**
* Checks to see if the current iterator position is valid.
*
* This method is called after `rewind()` and `next()` to check if the
* current iterator position is valid.
*
* @return - `true` if the position is valid; `false` otherwise.
*/
public function valid(): bool;
}
/**
* Allows for the iteration over the values provided by an `async` function.
*
* If an `async` function returns an `AsyncIterator<T>`, then you can iterate
* over the `T` values returned from that function.
*
* ```
* async function countdown(int $start): AsyncIterator<int> { ... }
*
* async function use_countdown(): Awaitable<void> {
* $async_iter = countdown(100);
* foreach ($async_iter await as $value) { ... }
* }
* ```
*
* @guide /hack/async/introduction
* @guide /hack/async/guidelines
*/
interface AsyncIterator<+Tv> {
/**
* Move the async iterator to the next `Awaitable` position.
*
* ```
* foreach ($async_iter await $async_iter->next() $value)
* ```
*
* The above is the longhand syntax for `await as $value`.
*
* @return - The next `Awaitable` in the iterator sequence.
*/
public function next(): Awaitable<?(mixed, Tv)>;
}
/**
* Allows for the iteration over the keys and values provided by an `async`
* function.
*
* If an `async` function returns an `AsyncIterator<Tk, Tv>`, then you can
* iterate over the `Tk` and `Tv` values returned from that function.
*
* ```
* async function countdown(int $start): AsyncIterator<int, string> { ... }
*
* async function use_countdown(): Awaitable<void> {
* $async_iter = countdown(100);
* foreach ($async_gen await as $num => $str) { ... }
* }
* ```
*
* @guide /hack/async/introduction
* @guide /hack/async/guidelines
*/
interface AsyncKeyedIterator<+Tk, +Tv> extends AsyncIterator<Tv> {
/**
* Move the async iterator to the next `Awaitable` position.
*
* ```
* foreach ($async_iter await $async_iter->next() $key=>$value)
* ```
*
* The above is the longhand syntax for `await as $key=>$value`.
*
* @return - The next `Awaitable` in the iterator sequence.
*/
public function next(): Awaitable<?(Tk, Tv)>;
}
/**
* For those entities that are `KeyedTraversable`, the `KeyedIterator`
* interfaces provides the methods of iteration, included being able to get
* the key.
*
* If a class implements `KeyedIterator`, then it provides the infrastructure
* to be iterated over using a `foreach` loop.
*
* @guide /hack/collections/introduction
* @guide /hack/collections/interfaces
*/
interface KeyedIterator<+Tk, +Tv> extends KeyedTraversable<Tk,Tv>, Iterator<Tv> {
/**
* Return the current key at the current iterator position.
*
* @return - The current key of type `Tk`.
*/
public function key(): Tk;
}
/**
* Represents objects that can produce an `Iterator` object to iterate over
* their contents using `foreach`.
*
* Normally, this interface won't be used in type annotations; rather `Iterable`
* or `Traversable` will be the better interface.
*
* @guide /hack/collections/introduction
* @guide /hack/collections/interfaces
*
* @link http://php.net/manual/en/class.iteratoraggregate.php
*/
interface IteratorAggregate<+Tv> extends Traversable<Tv> {
/**
* Returns an iterator to be used to iterate over the object's elements.
*
* @return - An `Iterator` for iteration.
*/
public function getIterator(): Iterator<Tv>;
}
/**
* Represents any entity that can be iterated over using something like
* `foreach`. The entity does not necessarily have to have a key, just values.
*
* `Iterable` does not include `array`s.
*
* @guide /hack/collections/introduction
* @guide /hack/collections/interfaces
*/
interface Iterable<+Tv> extends IteratorAggregate<Tv> {
/**
* Returns an iterator that points to beginning of the current `Iterable`.
*
* @return - An `Iterator` that allows you to traverse the current `Iterable`.
*/
public function getIterator(): Iterator<Tv>;
/**
* Returns an `array` converted from the current `Iterable`.
*
* @return - an array converted from the current `Iterable`.
*/
<<__PHPStdLib>>
public function toArray(): array;
/**
* Returns an `array` with the values from the current `Iterable`.
*
* The keys in the current `Iterable` are discarded and replaced with integer
* indices, starting with 0.
*
* @return - an `array` containing the values from the current `Iterable`.
*/
public function toValuesArray(): varray;
/* HH_FIXME[4120]: While this violates our variance annotations, we are
* returning a copy of the underlying collection, so it is actually safe
* See #6853603. */
/**
* Returns a `Vector` converted from the current `Iterable`.
*
* Any keys in the current `Iterable` are discarded and replaced with integer
* indices, starting with 0.
*
* @return - a `Vector` converted from the current `Iterable`.
*/
public function toVector(): Vector<Tv>;
/**
* Returns an immutable vector (`ImmVector`) converted from the current
* `Iterable`.
*
* Any keys in the current `Iterable` are discarded and replaced with integer
* indices, starting with 0.
*
* @return - an `ImmVector` converted from the current `Iterable`.
*/
public function toImmVector(): ImmVector<Tv>;
/* HH_FIXME[4120]: While this violates our variance annotations, we are
* returning a copy of the underlying collection, so it is actually safe.
* See #6853603. */
/**
* Returns a `Set` converted from the current `Iterable`.
*
* Any keys in the current `Iterable` are discarded.
*
* @return - a `Set` converted from the current `Iterable`.
*/
public function toSet(): Set<Tv>;
/**
* Returns an immutable set (`ImmSet`) converted from the current `Iterable`.
*
* Any keys in the current `Iterable` are discarded.
*
* @return - an `ImmSet` converted from the current `Iterable`.
*/
public function toImmSet(): ImmSet<Tv>;
/**
* Returns a lazy, access elements only when needed view of the current
* `Iterable`.
*
* Normally, memory is allocated for all of the elements of the `Iterable`.
* With a lazy view, memory is allocated for an element only when needed or
* used in a calculation like in `map()` or `filter()`.
*
* @return - an `Iterable` representing the lazy view into the current
* `Iterable`.
*
* @guide /hack/collections/examples
*/
public function lazy(): Iterable<Tv>;
/**
* Returns an `Iterable` containing the current `Iterable`'s values.
*
* Any keys are discarded.
*
* @return An `Iterable` with the values of the current `Iterable`.
*/
public function values(): Iterable<Tv>;
/**
* Returns an `Iterable` containing the values after an operation has been
* applied to each value in the current `Iterable`.
*
* Every value in the current `Iterable` is affected by a call to `map()`,
* unlike `filter()` where only values that meet a certain criteria are
* affected.
*
* @param $fn - The callback containing the operation to apply to the
* `Iterable` values.
*
* @return - an `Iterable` containing the values after a user-specified
* operation is applied.
*
* @guide /hack/collections/examples
*/
public function map<Tu>((function(Tv): Tu) $fn): Iterable<Tu>;
/**
* Returns an `Iterable` containing the values of the current `Iterable` that
* meet a supplied condition.
*
* Only values that meet a certain criteria are affected by a call to
* `filter()`, while all values are affected by a call to `map()`.
*
* @param $fn - The callback containing the condition to apply to the
* `Itearble` values.
*
* @return - an `Iterable` containing the values after a user-specified
* condition is applied.
*
* @guide /hack/collections/examples
*/
public function filter((function(Tv): bool) $fn): Iterable<Tv>;
/**
* Returns an `Iterable` where each element is a `Pair` that combines the
* element of the current `Iterable` and the provided `Traversable`.
*
* If the number of elements of the `Iterable` are not equal to the number of
* elements in the `Traversable`, then only the combined elements up to and
* including the final element of the one with the least number of elements
* is included.
*
* @param $traversable - The `Traversable` to use to combine with the
* elements of the current `Iterable`.
*
* @return - The `Iterable` that combines the values of the current
* `Itearable` with the provided `Traversable`.
*/
public function zip<Tu>(Traversable<Tu> $traversable): Iterable<Pair<Tv, Tu>>;
/**
* Returns an `Iterable` containing the first `n` values of the current
* `Iterable`.
*
* The returned `Iterable` will always be a proper subset of the current
* `Iterable`.
*
* `$n` is 1-based. So the first element is 1, the second 2, etc.
*
* @param $n - The last element that will be included in the returned
* `Iterable`.
*
* @return - An `Iterable that is a proper subset of the current `Iterable`
* up to `n` elements.
*/
public function take(int $n): Iterable<Tv>;
/**
* Returns an `Iterable` containing the values of the current `Iterable` up
* to but not including the first value that produces `false` when passed to
* the specified callback.
*
* The returned `Iterable` will always be a proper subset of the current
* `Iterable`.
*
* @param $fn - The callback that is used to determine the stopping
* condition.
*
* @return - An `Iterable` that is a proper subset of the current `Iterable`
* up until the callback returns `false`.
*/
public function takeWhile((function(Tv): bool) $fn): Iterable<Tv>;
/**
* Returns an `Iterable` containing the values after the `n`-th element of the
* current `Iterable`.
*
* The returned `Iterable` will always be a proper subset of the current
* `Iterable`.
*
* `$n` is 1-based. So the first element is 1, the second 2, etc.
*
* @param $n - The last element to be skipped; the `$n+1` element will be
* the first one in the returned `Iterable`.
*
* @return - An `Iterable` that is a proper subset of the current `Iterable`
* containing values after the specified `n`-th element.
*/
public function skip(int $n): Iterable<Tv>;
/**
* Returns an `Iterable` containing the values of the current `Iterable`
* starting after and including the first value that produces `true` when
* passed to the specified callback.
*
* The returned `Iterable` will always be a proper subset of the current
* `Iterable`.
*
* @param $fn - The callback used to determine the starting element for the
* returned `Iterable`.
*
* @return - An `Iterable` that is a proper subset of the current `Iterable`
* starting after the callback returns `true`.
*/
public function skipWhile((function(Tv): bool) $fn): Iterable<Tv>;
/**
* Returns a subset of the current `Iterable` starting from a given key up
* to, but not including, the element at the provided length from the
* starting key.
*
* `$start` is 0-based. `$len` is 1-based. So `slice(0, 2)` would return the
* elements at key 0 and 1.
*
* The returned `Iterable` will always be a proper subset of the current
* `Iterable`.
*
* @param $start - The starting key of the current `Iterable` to begin the
* returned `Iterable`.
* @param $len - The length of the returned `Iterable`.
*
* @return - An `Iterable` that is a proper subset of the current `Iterable`
* starting at `$start` up to but not including the element
* `$start + $len`.
*/
public function slice(int $start, int $len): Iterable<Tv>;
/**
* Returns an `Iterable` that is the concatenation of the values of the
* current `Iterable` and the values of the provided `Traversable`.
*
* The values of the provided `Traversable` is concatenated to the end of the
* current `Iterable` to produce the returned `Iterable`.
*
* @param $traversable - The `Traversable` to concatenate to the current
* `Iterable`.
*
* @return - The concatenated `Iterable`.
*
* @guide /hack/generics/constraints
*/
public function concat<Tu super Tv>(
Traversable<Tu> $traversable
): Iterable<Tu>;
/**
* Returns the first value in the current `Iterable`.
*
* @return - The first value in the current `Iterable`, or `null` if the
* current `Iterable` is empty.
*/
public function firstValue(): ?Tv;
/**
* Returns the last value in the current `Iterable`.
*
* @return - The last value in the current `Iterable`, or `null` if the
* current `Iterable` is empty.
*/
public function lastValue(): ?Tv;
}
/**
* Represents any entity that can be iterated over using something like
* `foreach`. The entity is required to have a key in addition to values.
*
* `KeyedIterable` does not include `array`s.
*
* @guide /hack/collections/introduction
* @guide /hack/collections/interfaces
*/
interface KeyedIterable<Tk, +Tv> extends KeyedTraversable<Tk, Tv>, Iterable<Tv> {
/**
* Returns an iterator that points to beginning of the current
* `KeyedIterable`.
*
* @return - A `KeyedIterator` that allows you to traverse the current
* `KeyedIterable`.
*/
public function getIterator(): KeyedIterator<Tk, Tv>;
/**
* Returns an `array` with the keys from the current `KeyedIterable`.
*
* @return - an `array` containing the values from the current
* `KeyedIterable`.
*/
public function toKeysArray(): varray;
/* HH_FIXME[4120]: While this violates our variance annotations, we are
* returning a copy of the underlying collection, so it is actually safe
* See #6853603. */
/**
* Returns a `Map` based on the keys and values of the current
* `KeyedIterable`.
*
* @return - a `Map` that has the keys and associated values of the current
* `KeyedIterable`.
*/
public function toMap(): Map<Tk, Tv>;
/**
* Returns an immutable map (`ImmMap`) based on the keys and values of the
* current `KeyedIterable`.
*
* @return - an `ImmMap` that has the keys and associated values of the
* current `KeyedIterable`.
*/
public function toImmMap(): ImmMap<Tk, Tv>;
/**
* Returns a lazy, access elements only when needed view of the current
* `KeyedIterable`.
*
* Normally, memory is allocated for all of the elements of the
* `KeyedIterable`. With a lazy view, memory is allocated for an element only
* when needed or used in a calculation like in `map()` or `filter()`.
*
* @return - a `KeyedIterable` representing the lazy view into the current
* `KeyedIterable`.
*
* @guide /hack/collections/examples
*/
public function lazy(): KeyedIterable<Tk, Tv>;
/**
* Returns an `Iterable` containing the current `KeyedIterable`'s values.
*
* Any keys are discarded.
*
* @return An `Iterable` with the values of the current `KeyedIterable`.
*/
public function values(): Iterable<Tv>;
/**
* Returns an `Iterable` containing the current `KeyedIterable`'s keys.
*
* Any values are discarded.
*
* @return An `Iterable` with the keys of the current `KeyedIterable`.
*/
public function keys(): Iterable<Tk>;
/**
* Returns a `KeyedIterable` containing the values after an operation has been
* applied to each value in the current `KeyedIterable`.
*
* Every value in the current `KeyedIterable` is affected by a call to
* `map()`, unlike `filter()` where only values that meet a certain criteria
* are affected.
*
* @param $fn - The callback containing the operation to apply to the
* `KeyedIterable` values.
*
* @return - a `KeyedIterable` containing the values after a user-specified
* operation is applied.
*
* @guide /hack/collections/examples
*/
public function map<Tu>((function(Tv): Tu) $fn): KeyedIterable<Tk, Tu>;
/**
* Returns a `KeyedIterable` containing the values after an operation has
* been applied to each key and value in the current `KeyedIterable`.
*
* Every key and value in the current `KeyedIterable` is affected by a call to
* `mapWithKey()`, unlike `filterWithKey()` where only values that meet a
* certain criteria are affected.
*
* @param $fn - The callback containing the operation to apply to the
* `KeyedIterable` keys and values.
*
* @return - a `KeyedIterable` containing the values after a user-specified
* operation on the current `KeyedIterable`'s keys and values is
* applied.
*/
public function mapWithKey<Tu>((function(Tk, Tv): Tu) $fn):
KeyedIterable<Tk, Tu>;
/**
* Returns a `KeyedIterable` containing the values of the current
* `KeyedIterable` that meet a supplied condition.
*
* Only values that meet a certain criteria are affected by a call to
* `filter()`, while all values are affected by a call to `map()`.
*
* @param $fn - The callback containing the condition to apply to the
* `KeyedItearble` values.
*
* @return - a `KeyedIterable` containing the values after a user-specified
* condition is applied.
*
* @guide /hack/collections/examples
*/
public function filter((function(Tv): bool) $fn): KeyedIterable<Tk, Tv>;
/**
* Returns a `KeyedIterable` containing the values of the current
* `KeyedIterable` that meet a supplied condition applied to its keys and
* values.
*
* Only keys and values that meet a certain criteria are affected by a call to
* `filterWithKey()`, while all values are affected by a call to
* `mapWithKey()`.
*
* @param $fn - The callback containing the condition to apply to the
* `KeyedIterable` keys and values.
*
* @return - a `KeyedIterable` containing the values after a user-specified
* condition is applied to the keys and values of the current
* `KeyedIterable`.
*
*/
public function filterWithKey((function(Tk, Tv): bool) $fn):
KeyedIterable<Tk, Tv>;
/**
* Returns a `KeyedIterable` where each element is a `Pair` that combines the
* element of the current `KeyedIterable` and the provided `Traversable`.
*
* If the number of elements of the `KeyedIterable` are not equal to the
* number of elements in the `Traversable`, then only the combined elements
* up to and including the final element of the one with the least number of
* elements is included.
*
* @param $traversable - The `Traversable` to use to combine with the
* elements of the current `KeyedIterable`.
*
* @return - The `KeyedIterable` that combines the values of the current
* `KeyedItearable` with the provided `Traversable`.
*/
public function zip<Tu>(Traversable<Tu> $traversable):
KeyedIterable<Tk, Pair<Tv, Tu>>;
/**
* Returns a `KeyedIterable` containing the first `n` values of the current
* `KeyedIterable`.
*
* The returned `KeyedIterable` will always be a proper subset of the current
* `Iterable`.
*
* `$n` is 1-based. So the first element is 1, the second 2, etc.
*
* @param $n - The last element that will be included in the returned
* `KeyedIterable`.
*
* @return - A `KeyedIterable that is a proper subset of the current
* `KeyedIterable` up to `n` elements.
*/
public function take(int $n): KeyedIterable<Tk, Tv>;
/**
* Returns a `KeyedIterable` containing the values of the current
* `KeyedIterable` up to but not including the first value that produces
* `false` when passed to the specified callback.
*
* The returned `KeyedIterable` will always be a proper subset of the current
* `KeyedIterable`.
*
* @param $fn - The callback that is used to determine the stopping
* condition.
*
* @return - A `KeyedIterable` that is a proper subset of the current
* `KeyedIterable` up until the callback returns `false`.
*/
public function takeWhile((function(Tv): bool) $fn): KeyedIterable<Tk, Tv>;
/**
* Returns a `KeyedIterable` containing the values after the `n`-th element
* of the current `KeyedIterable`.
*
* The returned `KeyedIterable` will always be a proper subset of the current
* `KeyedIterable`.
*
* `$n` is 1-based. So the first element is 1, the second 2, etc.
*
* @param $n - The last element to be skipped; the `$n+1` element will be
* the first one in the returned `KeyedIterable`.
*
* @return - A `KeyedIterable` that is a proper subset of the current
* `KeyedIterable` containing values after the specified `n`-th
* element.
*/
public function skip(int $n): KeyedIterable<Tk, Tv>;
/**
* Returns a `KeyedIterable` containing the values of the current
* `KeyedIterable` starting after and including the first value that produces
* `true` when passed to the specified callback.
*
* The returned `KeyedIterable` will always be a proper subset of the current
* `KeyedIterable`.
*
* @param $fn - The callback used to determine the starting element for the
* returned `KeyedIterable`.
*
* @return - A `KeyedIterable` that is a proper subset of the current
* `KeyedIterable` starting after the callback returns `true`.
*/
public function skipWhile((function(Tv): bool) $fn): KeyedIterable<Tk, Tv>;
/**
* Returns a subset of the current `KeyedIterable` starting from a given key
* up to, but not including, the element at the provided length from the
* starting key.
*
* `$start` is 0-based. `$len` is 1-based. So `slice(0, 2)` would return the
* elements at key 0 and 1.
*
* The returned `KeyedIterable` will always be a proper subset of the current
* `KeyedIterable`.
*
* @param $start - The starting key of the current `KeyedIterable` to begin
* the returned `KeyedIterable`.
* @param $len - The length of the returned `KeyedIterable`.
*
* @return - A `KeyedIterable` that is a proper subset of the current
* `KeyedIterable` starting at `$start` up to but not including the
* element `$start + $len`.
*/
public function slice(int $start, int $len): KeyedIterable<Tk, Tv>;
/**
* Returns an `Iterable` that is the concatenation of the values of the
* current `KeyedIterable` and the values of the provided `Traversable`.
*
* The values of the provided `Traversable` is concatenated to the end of the
* current `KeyedIterable` to produce the returned `Iterable`.
*
* @param $traversable - The `Traversable` to concatenate to the current
* `KeyedIterable`.
*
* @return - The concatenated `Iterable`.
*
* @guide /hack/generics/constraints
*/
public function concat<Tu super Tv>(
Traversable<Tu> $traversable
): Iterable<Tu>;
/**
* Returns the first value in the current `KeyedIterable`.
*
* @return - The first value in the current `KeyedIterable`, or `null` if the
* current `KeyedIterable` is empty.
*/
public function firstValue(): ?Tv;
/**
* Returns the first key in the current `KeyedIterable`.
*
* @return - The first key in the current `KeyedIterable`, or `null` if the
* current `KeyedIterable` is empty.
*/
public function firstKey(): ?Tk;
/**
* Returns the last value in the current `KeyedIterable`.
*
* @return - The last value in the current `KeyedIterable`, or `null` if the
* current `KeyedIterable` is empty.
*/
public function lastValue(): ?Tv;
/**
* Returns the last key in the current `KeyedIterable`.
*
* @return - The last key in the current `KeyedIterable`, or `null` if the
* current `KeyedIterable` is empty.
*/
public function lastKey(): ?Tk;
}
interface Serializable {
public function serialize(): string;
public function unserialize($serialized): void;
}
interface Countable {
public function count(): int;
}
interface RecursiveIterator<+Tv> extends Iterator<Tv> {
public function getChildren(): this;
public function hasChildren(): bool;
}
interface SeekableIterator<+Tv> extends Iterator<Tv> {
public function seek(int $position): void;
}
interface OuterIterator<+Tv> extends Iterator<Tv> {
public function getInnerIterator(): Iterator<Tv>;
}
interface ArrayAccess<Tk, Tv> {
public function offsetExists(Tk $key): bool;
public function offsetGet(Tk $key): Tv;
public function offsetSet(Tk $key, Tv $val): void;
public function offsetUnset(Tk $key): void;
}
/**
* @see http://www.php.net/manual/en/jsonserializable.jsonserialize.php
*/
interface JsonSerializable {
/**
* Return data which can be serialized with json_encode.
*/
public function jsonSerialize(): mixed;
}
/**
* XHPChild is the base type of values that can be children of XHP elements.
* Most primitive types implement XHPChild: string, int, float, and array.
*
* Classes that implement XHPChild must do so by implementing the XHPChildClass
* subinterface.
*/
interface XHPChild {}
/**
* Stringish is a type that matches strings as well as string-convertible
* objects: that is, objects that provide the __toString method
*/
<<__HipHopSpecific>>
interface Stringish extends XHPChild {
<<__Deprecated('Use `stringish_cast(<expression>)` instead.')>>
public function __toString(): string;
}
/**
* Classes that implement IMemoizeParam may be used as parameters on
* <<__Memoize>> functions
*
* @guide /hack/attributes/introduction
* @guide /hack/attributes/special
*/
<<__HipHopSpecific>>
interface IMemoizeParam {
/**
* Serialize this object to a string that can be used as a
* dictionary key to differentiate instances of this class.
*/
public function getInstanceKey(): string;
}
/**
* Objects that implement IDisposable may be used in using statements
*/
<<__HipHopSpecific>>
interface IDisposable {
/**
* This method is invoked exactly once at the end of the scope of the
* using statement, unless the program terminates with a fatal error.
*/
public function __dispose(): void;
}
/**
* Objects that implement IAsyncDisposable may be used in await using statements
*/
<<__HipHopSpecific>>
interface IAsyncDisposable {
/**
* This method is invoked exactly once at the end of the scope of the
* await using statement, unless the program terminates with a fatal error.
*/
public function __disposeAsync(): Awaitable<void>;
}