-
Notifications
You must be signed in to change notification settings - Fork 71
/
mcx_core.cu
2278 lines (2042 loc) · 101 KB
/
mcx_core.cu
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/***************************************************************************//**
** \mainpage Monte Carlo eXtreme - GPU accelerated Monte Carlo Photon Migration
**
** \author Qianqian Fang <q.fang at neu.edu>
** \copyright Qianqian Fang, 2009-2018
**
** \section sref Reference:
** \li \c (\b Fang2009) Qianqian Fang and David A. Boas,
** <a href="http://www.opticsinfobase.org/abstract.cfm?uri=oe-17-22-20178">
** "Monte Carlo Simulation of Photon Migration in 3D Turbid Media Accelerated
** by Graphics Processing Units,"</a> Optics Express, 17(22) 20178-20190 (2009).
** \li \c (\b Yu2018) Leiming Yu, Fanny Nina-Paravecino, David Kaeli, and Qianqian Fang,
** "Scalable and massively parallel Monte Carlo photon transport
** simulations for heterogeneous computing platforms," J. Biomed. Optics, 23(1), 010504, 2018.
**
** \section slicense License
** GPL v3, see LICENSE.txt for details
*******************************************************************************/
/***************************************************************************//**
\file mcx_core.cu
@brief GPU kernel for MC simulations and CUDA host code
*******************************************************************************/
#define _USE_MATH_DEFINES
#include <cmath>
#include "br2cu.h"
#include "mcx_core.h"
#include "tictoc.h"
#include "mcx_const.h"
#ifdef USE_HALF ///< use half-precision for ray-tracing
#include "cuda_fp16.h"
#endif
#ifdef USE_DOUBLE
typedef double OutputType;
#define SHADOWCOUNT 1
#define ZERO 0.0
#else
typedef float OutputType;
#define SHADOWCOUNT 2
#define ZERO 0.f
#endif
#if defined(USE_XOROSHIRO128P_RAND)
#include "xoroshiro128p_rand.cu" ///< use xorshift128+ RNG (XORSHIFT128P)
#elif defined(USE_LL5_RAND)
#include "logistic_rand.cu" ///< use Logistic Lattice ring 5 RNG (LL5)
#elif defined(USE_POSIX_RAND)
#include "posix_rand.cu" ///< use POSIX erand48 RNG (POSIX)
#else ///< default RNG method: USE_XORSHIFT128P_RAND
#include "xorshift128p_rand.cu" ///< use xorshift128+ RNG (XORSHIFT128P)
#endif
#ifdef _OPENMP ///< use multi-threading for running simulation on multiple GPUs
#include <omp.h>
#endif
#define CUDA_ASSERT(a) mcx_cu_assess((a),__FILE__,__LINE__) ///< macro to report CUDA errors
/**
* @brief Concatenated optical properties and det positions, stored in constant memory
*
* The first cfg.maxmedia elements of this array contain the optical properties of the
* domains. Format: {x}:mua,{y}:mus,{z}:anisotropy (g),{w}:refractive index (n).
* The following cfg.detnum elements of this array contains the detector information.
* Format: {x,y,z}: the x/y/z coord. of the detector, and {w}: radius; all in grid unit.
* The total length (both media properties and detector) is defined by
* MAX_PROP_AND_DETECTORS, which is 4000 to fully utilize the constant memory space
* (64kb=4096 float4)
*/
__constant__ float4 gproperty[MAX_PROP_AND_DETECTORS];
/**
* @brief Simulation constant parameters stored in the constant memory
*
* This variable stores all constants used in the simulation.
*/
__constant__ MCXParam gcfg[1];
/**
* @brief Global variable to store the number of photon movements for debugging purposes
*/
__device__ uint gjumpdebug[1];
/**
* @brief Pointer to the shared memory (storing photon data and spilled registers)
*/
extern __shared__ char sharedmem[];
/**
* @brief Texture memory for storing media indices
*
* Tested with texture memory for media, only improved 1% speed
* to keep code portable, use global memory for now
* also need to change all media[idx1d] to tex1Dfetch() below
*/
//texture<uchar, 1, cudaReadModeElementType> texmedia;
/**
* @brief Floating-point atomic addition
*/
__device__ inline OutputType atomicadd(OutputType* address, OutputType value){
#if __CUDA_ARCH__ >= 200 ///< for Fermi, atomicAdd supports floats
return atomicAdd(address,value);
#else
// float-atomic-add from
// http://forums.nvidia.com/index.php?showtopic=158039&view=findpost&p=991561
float old = value;
while ((old = atomicExch(address, atomicExch(address, 0.0f)+old))!=0.0f);
return old;
#endif
}
/**
* @brief Reset shared memory buffer to store photon partial-path data for a new photon
* @param[in] p: pointer to the partial-path buffer
* @param[in] maxmediatype: length of the buffer to be reset
*/
__device__ inline void clearpath(float *p,int maxmediatype){
uint i;
for(i=0;i<maxmediatype;i++)
p[i]=0.f;
}
#ifdef SAVE_DETECTORS
/**
* @brief Testing which detector detects an escaping photon
* @param[in] p0: the position of the escaping photon
* @return the index of the photon that captures this photon; 0 if none.
*/
__device__ inline uint finddetector(MCXpos *p0){
uint i;
for(i=gcfg->maxmedia+1;i<gcfg->maxmedia+gcfg->detnum+1;i++){
if((gproperty[i].x-p0->x)*(gproperty[i].x-p0->x)+
(gproperty[i].y-p0->y)*(gproperty[i].y-p0->y)+
(gproperty[i].z-p0->z)*(gproperty[i].z-p0->z) < gproperty[i].w*gproperty[i].w){
return i-gcfg->maxmedia;
}
}
return 0;
}
/**
* @brief Recording detected photon information at photon termination
* @param[in] n_det: pointer to the detector position array
* @param[in] detectedphoton: variable in the global-mem recording the total detected photons
* @param[in] ppath: buffer in the shared-mem to store the photon partial-pathlengths
* @param[in] p0: the position/weight of the current photon packet
* @param[in] v: the direction vector of the current photon packet
* @param[in] t: random number generator (RNG) states
* @param[in] seeddata: the RNG seed of the photon at launch, need to save for replay
*/
__device__ inline void savedetphoton(float n_det[],uint *detectedphoton,float *ppath,MCXpos *p0,MCXdir *v,RandType t[RAND_BUF_LEN],RandType *seeddata){
uint detid=finddetector(p0);
if(detid){
uint baseaddr=atomicAdd(detectedphoton,1);
if(baseaddr<gcfg->maxdetphoton){
uint i;
for(i=0;i<gcfg->issaveseed*RAND_BUF_LEN;i++)
seeddata[baseaddr*RAND_BUF_LEN+i]=t[i]; ///< save photon seed for replay
baseaddr*=2+gcfg->maxmedia*(2+gcfg->ismomentum)+(gcfg->issaveexit>0)*6;
n_det[baseaddr++]=detid;
for(i=0;i<gcfg->maxmedia*(2+gcfg->ismomentum);i++)
n_det[baseaddr++]=ppath[i]; ///< save partial pathlength to the memory
if(gcfg->issaveexit){
*((float3*)(n_det+baseaddr))=float3(p0->x,p0->y,p0->z);
baseaddr+=3;
*((float3*)(n_det+baseaddr))=float3(v->x,v->y,v->z);
baseaddr+=3;
}
n_det[baseaddr++]=ppath[gcfg->maxmedia*(2+gcfg->ismomentum)+2];
}
}
}
#endif
/**
* @brief Saving photon trajectory data for debugging purposes
* @param[in] p: the position/weight of the current photon packet
* @param[in] id: the global index of the photon
* @param[in] gdebugdata: pointer to the global-memory buffer to store the trajectory info
*/
__device__ inline void savedebugdata(MCXpos *p,uint id,float *gdebugdata){
uint pos=atomicAdd(gjumpdebug,1);
if(pos<gcfg->maxjumpdebug){
pos*=MCX_DEBUG_REC_LEN;
((uint *)gdebugdata)[pos++]=id;
gdebugdata[pos++]=p->x;
gdebugdata[pos++]=p->y;
gdebugdata[pos++]=p->z;
gdebugdata[pos++]=p->w;
gdebugdata[pos++]=0;
}
}
/**
* @brief A simplified nextafterf() to ensure a photon moves outside of the current voxel after each move
* @param[in] a: a floating point number
* @param[in] dir: 1: change 1 bit in the positive direction; 0: no change, -1: change 1 bit in the negative direction
*/
__device__ inline float mcx_nextafterf(float a, int dir){
union{
float f;
uint i;
} num;
num.f=a+gcfg->maxvoidstep; /** First, shift coordinate by 1000 to make sure values are always positive */
num.i+=dir ^ (num.i & SIGN_BIT);/** Then make 1 bit difference along the direction indicated by dir */
return num.f-gcfg->maxvoidstep; /** Last, undo the offset, and return */
}
#ifndef USE_HALF
/**
* @brief Core function for photon-voxel ray-tracing
*
* This is the heart of the MCX simulation algorithm. It calculates the nearest intersection
* of the ray inside the current cubic voxel.
*
* @param[in] p0: the x/y/z position of the current photon
* @param[in] v: the direction vector of the photon
* @param[out] htime: the intersection x/y/z position on the bounding box, right outside of this voxel
* @param[in] rv: pre-computed reciprocal of the velocity vector (v)
* @param[out] id: 0: intersect with x=x0 plane; 1: intersect with y=y0 plane; 2: intersect with z=z0 plane first
* @return the distance to the intersection to the voxel bounding box
*/
__device__ inline float hitgrid(float3 *p0, float3 *v, float *htime,float* rv,int *id){
float dist;
///< time-of-flight to hit the wall in each direction
htime[0]=fabs((floorf(p0->x)+(v->x>0.f)-p0->x)*rv[0]); ///< time-of-flight in x
htime[1]=fabs((floorf(p0->y)+(v->y>0.f)-p0->y)*rv[1]);
htime[2]=fabs((floorf(p0->z)+(v->z>0.f)-p0->z)*rv[2]);
///< get the direction with the smallest time-of-flight
dist=fminf(fminf(htime[0],htime[1]),htime[2]);
(*id)=(dist==htime[0]?0:(dist==htime[1]?1:2));
///< p0 is inside, htime is the 1st intersection point
htime[0]=p0->x+dist*v->x;
htime[1]=p0->y+dist*v->y;
htime[2]=p0->z+dist*v->z;
///< make sure the intersection point htime is immediately outside of the current voxel (i.e. not within the current voxel)
int index = (*id & (int)3);
if(index == 0) htime[0] = mcx_nextafterf(roundf(htime[0]), (v->x > 0.f)-(v->x < 0.f));
if(index == 1) htime[1] = mcx_nextafterf(roundf(htime[1]), (v->y > 0.f)-(v->y < 0.f));
if(index == 2) htime[2] = mcx_nextafterf(roundf(htime[2]), (v->z > 0.f)-(v->z < 0.f));
return dist;
}
#else
/**
* @brief Half-precision version of the simplified nextafter
*
* @param[in] a: a half-precision floating point number
* @param[in] dir: 1: change 1 bit in the positive direction; 0: no change, -1: change 1 bit in the negative direction
*/
__device__ inline half mcx_nextafter_half(const half a, const short dir){
union{
half f;
short i;
} num;
num.f=a;
((num.i & 0x7FFFU) == 0) ? (num.i = ((dir & 0x8000U) ) | 1) : ((num.i & 0x8000U) ? num.i-= dir: num.i+= dir);
return num.f;
}
/**
* @brief Core function for photon-voxel ray-tracing (half-precision version)
*
* This is the heart of the MCX simulation algorithm. It calculates the nearest intersection
* of the ray inside the current cubic voxel.
*
* @param[in] p0: the x/y/z position of the current photon
* @param[in] v: the direction vector of the photon
* @param[out] htime: the intersection x/y/z position on the bounding box, right outside of this voxel
* @param[in] rv: pre-computed reciprocal of the velocity vector (v)
* @param[out] id: 0: intersect with x=x0 plane; 1: intersect with y=y0 plane; 2: intersect with z=z0 plane first
* @return the distance to the intersection to the voxel bounding box
*/
__device__ inline float hitgrid(float3 *p0, float3 *v, float *htime,float* rv,int *id){
float dist;
union {
unsigned int i;
float f;
half2 h2;
half h[2];
} pxy, pzw, vxy, vzw, h1, h2, temp;
pxy.h2=__floats2half2_rn(floorf(p0->x) - p0->x, floorf(p0->y) - p0->y);
pzw.h2=__floats2half2_rn(floorf(p0->z) - p0->z, 1e5f);
vxy.h2=__floats2half2_rn(rv[0],rv[1]);
vzw.h2=__floats2half2_rn(rv[2],1.f);
temp.h2 = __floats2half2_rn(0.f, 0.f);
h1.h2 = __hmul2(__hadd2(pxy.h2,__hgt2(vxy.h2, temp.h2 )), vxy.h2);
h2.h2 = __hmul2(__hadd2(pzw.h2,__hgt2(vzw.h2, temp.h2 )), vzw.h2);
// abs
h1.i &= 0x7FFF7FFF;
h2.i &= 0x7FFF7FFF;
temp.h[0]=(__hlt(h1.h[0], h1.h[1])) ? (*id=0,h1.h[0]) : (*id=1,h1.h[1]);
temp.h[1]=(__hlt(temp.h[0], h2.h[0])) ? temp.h[0] : (*id=2,h2.h[0]);
dist=__half2float(temp.h[1]);
//p0 is inside, p is outside, move to the 1st intersection pt, now in the air side, to be corrected in the else block
vxy.h2=__floats2half2_rn(v->x,v->y);
vzw.h2=__floats2half2_rn(v->z,0.f);
pxy.h2=__floats2half2_rn(p0->x, p0->y);
pzw.h2=__floats2half2_rn(p0->z, 0.f);
h1.h2 =__hfma2(vxy.h2,__floats2half2_rn(dist,dist),pxy.h2);
h2.h2 =__hfma2(vzw.h2,__floats2half2_rn(dist,dist),pzw.h2);
htime[0]=__half2float(h1.h[0]);
htime[1]=__half2float(h1.h[1]);
htime[2]=__half2float(h2.h[0]);
temp.h2 = __floats2half2_rn(0.f, 0.f);
pxy.h2=__hgt2(vxy.h2, temp.h2 );
pzw.h2=__hlt2(vxy.h2, temp.h2 );
pxy.h2=__hsub2(pxy.h2, pzw.h2 );
pzw.h2=__hlt2(vzw.h2, temp.h2 );
temp.h2=__hgt2(vzw.h2, temp.h2 );
pzw.h2=__hsub2(temp.h2,pzw.h2 );
if((*id) == 0) htime[0] = __half2float(mcx_nextafter_half(hrint(h1.h[0]), __half2short_rn(pxy.h[0])));
if((*id) == 1) htime[1] = __half2float(mcx_nextafter_half(hrint(h1.h[1]), __half2short_rn(pxy.h[1])));
if((*id) == 2) htime[2] = __half2float(mcx_nextafter_half(hrint(h2.h[0]), __half2short_rn(pzw.h[0])));
return dist;
}
#endif
/**
* @brief Calculating the direction vector after transmission
*
* This function updates the direction vector after the photon passing
* an interface of different refrective indicex (n1/n2). Because MCX only
* handles voxelated domain, transmission is applied only to 1 of the components,
* and then the vector is normalized.
*
* @param[in,out] v: the direction vector of the photon
* @param[in] n1: the refrective index of the voxel the photon leaves
* @param[in] n2: the refrective index of the voxel the photon enters
* @param[in] flipdir: 0: transmit through x=x0 plane; 1: through y=y0 plane; 2: through z=z0 plane
*/
__device__ inline void transmit(MCXdir *v, float n1, float n2,int flipdir){
float tmp0=n1/n2;
v->x*=tmp0;
v->y*=tmp0;
v->z*=tmp0;
(flipdir==0) ?
(v->x= ((tmp0 = v->y*v->y + v->z*v->z) <1.f) ? sqrtf(1.f - tmp0)*((v->x>0.f)-(v->x<0.f)) : 0.f):
((flipdir==1) ?
(v->y=((tmp0 = v->x*v->x + v->z*v->z) <1.f) ? sqrtf(1.f - tmp0)*((v->y>0.f)-(v->y<0.f)) : 0.f):
(v->z=((tmp0 = v->x*v->x + v->y*v->y) <1.f) ? sqrtf(1.f - tmp0)*((v->z>0.f)-(v->z<0.f)) : 0.f));
tmp0=rsqrtf(v->x*v->x + v->y*v->y + v->z*v->z);
v->x*=tmp0;
v->y*=tmp0;
v->z*=tmp0;
}
/**
* @brief Calculating the reflection coefficient at an interface
*
* This function calculates the reflection coefficient at
* an interface of different refrective indicex (n1/n2)
*
* @param[in] v: the direction vector of the photon
* @param[in] n1: the refrective index of the voxel the photon leaves
* @param[in] n2: the refrective index of the voxel the photon enters
* @param[in] flipdir: 0: transmit through x=x0 plane; 1: through y=y0 plane; 2: through z=z0 plane
* @return the reflection coefficient R=(Rs+Rp)/2, Rs: R of the perpendicularly polarized light, Rp: parallelly polarized light
*/
__device__ inline float reflectcoeff(MCXdir *v, float n1, float n2, int flipdir){
float Icos=fabs((flipdir==0) ? v->x : (flipdir==1 ? v->y : v->z));
float tmp0=n1*n1;
float tmp1=n2*n2;
float tmp2=1.f-tmp0/tmp1*(1.f-Icos*Icos); /** 1-[n1/n2*sin(si)]^2 = cos(ti)^2*/
if(tmp2>0.f){ ///< partial reflection
float Re,Im,Rtotal;
Re=tmp0*Icos*Icos+tmp1*tmp2;
tmp2=sqrtf(tmp2); /** to save one sqrt*/
Im=2.f*n1*n2*Icos*tmp2;
Rtotal=(Re-Im)/(Re+Im); /** Rp*/
Re=tmp1*Icos*Icos+tmp0*tmp2*tmp2;
Rtotal=(Rtotal+(Re-Im)/(Re+Im))*0.5f; /** (Rp+Rs)/2*/
return Rtotal;
}else{ ///< total reflection
return 1.f;
}
}
/**
* @brief Advance photon to the 1st non-zero voxel if launched in the backgruond
*
* This function advances the photon to the 1st non-zero voxel along the direction
* of v if the photon is launched outside of the cubic domain or in a zero-voxel.
* To avoid large overhead, photon can only advance gcfg->minaccumtime steps, which
* can be set using the --maxvoidstep flag; by default, this limit is 1000.
*
* @param[in] v: the direction vector of the photon
* @param[in] n1: the refrective index of the voxel the photon leaves
* @param[in] n2: the refrective index of the voxel the photon enters
* @param[in] flipdir: 0: transmit through x=x0 plane; 1: through y=y0 plane; 2: through z=z0 plane
* @return the reflection coefficient R=(Rs+Rp)/2, Rs: R of the perpendicularly polarized light, Rp: parallelly polarized light
*/
__device__ inline int skipvoid(MCXpos *p,MCXdir *v,MCXtime *f,float3* rv,uint media[]){
int count=1,idx1d;
while(1){
if(p->x>=0.f && p->y>=0.f && p->z>=0.f && p->x < gcfg->maxidx.x
&& p->y < gcfg->maxidx.y && p->z < gcfg->maxidx.z){
idx1d=(int(floorf(p->z))*gcfg->dimlen.y+int(floorf(p->y))*gcfg->dimlen.x+int(floorf(p->x)));
if(media[idx1d] & MED_MASK){ ///< if enters a non-zero voxel
GPUDEBUG(("inside volume [%f %f %f] v=<%f %f %f>\n",p->x,p->y,p->z,v->x,v->y,v->z));
float3 htime;
int flipdir;
p->x-=v->x;
p->y-=v->y;
p->z-=v->z;
f->t-=gcfg->minaccumtime;
idx1d=(int(floorf(p->z))*gcfg->dimlen.y+int(floorf(p->y))*gcfg->dimlen.x+int(floorf(p->x)));
GPUDEBUG(("look for entry p0=[%f %f %f] rv=[%f %f %f]\n",p->x,p->y,p->z,rv->x,rv->y,rv->z));
count=0;
while(!(p->x>=0.f && p->y>=0.f && p->z>=0.f && p->x < gcfg->maxidx.x
&& p->y < gcfg->maxidx.y && p->z < gcfg->maxidx.z) || !(media[idx1d] & MED_MASK)){ // at most 3 times
f->t+=gcfg->minaccumtime*hitgrid((float3*)p,(float3*)v,&htime.x,&rv->x,&flipdir);
*((float4*)(p))=float4(htime.x,htime.y,htime.z,p->w);
idx1d=(int(floorf(p->z))*gcfg->dimlen.y+int(floorf(p->y))*gcfg->dimlen.x+int(floorf(p->x)));
GPUDEBUG(("entry p=[%f %f %f] flipdir=%d\n",p->x,p->y,p->z,flipdir));
if(count++>3){
GPUDEBUG(("fail to find entry point after 3 iterations, something is wrong, abort!!"));
break;
}
}
f->t= (gcfg->voidtime) ? f->t : 0.f;
if(gcfg->isspecular && gproperty[media[idx1d] & MED_MASK].w!=gproperty[0].w){
p->w*=1.f-reflectcoeff(v, gproperty[0].w,gproperty[media[idx1d] & MED_MASK].w,flipdir);
GPUDEBUG(("transmitted intensity w=%e\n",p->w));
if(p->w>EPS){
transmit(v, gproperty[0].w,gproperty[media[idx1d] & MED_MASK].w,flipdir);
GPUDEBUG(("transmit into volume v=<%f %f %f>\n",v->x,v->y,v->z));
}
}
GPUDEBUG(("entry from voxel [%d]\n",idx1d));
return idx1d;
}
}
if( (p->x<0.f) && (v->x<=0.f) || (p->x >= gcfg->maxidx.x) && (v->x>=0.f)
|| (p->y<0.f) && (v->y<=0.f) || (p->y >= gcfg->maxidx.y) && (v->y>=0.f)
|| (p->z<0.f) && (v->z<=0.f) || (p->z >= gcfg->maxidx.z) && (v->z>=0.f))
return -1;
*((float4*)(p))=float4(p->x+v->x,p->y+v->y,p->z+v->z,p->w);
GPUDEBUG(("inside void [%f %f %f]\n",p->x,p->y,p->z));
f->t+=gcfg->minaccumtime;
if(count++>gcfg->maxvoidstep)
return -1;
}
}
/**
* @brief Compute 2D-scattering if the domain has a dimension of 1 in x/y or z
*
* This function performs 2D scattering calculation if the domain is only a sheet of voxels
*
* @param[in,out] v: the direction vector of the photon
* @param[in] stheta: the sine of the rotation angle
* @param[in] ctheta: the cosine of the rotation angle
*/
__device__ inline void rotatevector2d(MCXdir *v, float stheta, float ctheta){
if(gcfg->is2d==1)
*((float4*)v)=float4(
0.f,
v->y*ctheta - v->z*stheta,
v->y*stheta + v->z*ctheta,
v->nscat
);
else if(gcfg->is2d==2)
*((float4*)v)=float4(
v->x*ctheta - v->z*stheta,
0.f,
v->x*stheta + v->z*ctheta,
v->nscat
);
else if(gcfg->is2d==3)
*((float4*)v)=float4(
v->x*ctheta - v->y*stheta,
v->x*stheta + v->y*ctheta,
0.f,
v->nscat
);
GPUDEBUG(("new dir: %10.5e %10.5e %10.5e\n",v->x,v->y,v->z));
}
/**
* @brief Compute 3D-scattering direction vector
*
* This function updates the direction vector after a 3D scattering event
*
* @param[in,out] v: the direction vector of the photon
* @param[in] stheta: the sine of the azimuthal angle
* @param[in] ctheta: the cosine of the azimuthal angle
* @param[in] sphi: the sine of the zenith angle
* @param[in] cphi: the cosine of the zenith angle
*/
__device__ inline void rotatevector(MCXdir *v, float stheta, float ctheta, float sphi, float cphi){
if( v->z>-1.f+EPS && v->z<1.f-EPS ) {
float tmp0=1.f-v->z*v->z;
float tmp1=stheta*rsqrtf(tmp0);
*((float4*)v)=float4(
tmp1*(v->x*v->z*cphi - v->y*sphi) + v->x*ctheta,
tmp1*(v->y*v->z*cphi + v->x*sphi) + v->y*ctheta,
-tmp1*tmp0*cphi + v->z*ctheta,
v->nscat
);
}else{
*((float4*)v)=float4(stheta*cphi,stheta*sphi,(v->z>0.f)?ctheta:-ctheta,v->nscat);
}
GPUDEBUG(("new dir: %10.5e %10.5e %10.5e\n",v->x,v->y,v->z));
}
/**
* @brief Terminate a photon and launch a new photon according to specified source form
*
* This function terminates the current photon and launches a new photon according
* to the source type selected. Currently, over a dozen source types are supported,
* including pencil, isotropic, planar, fourierx, gaussian, zgaussian etc.
*
* @param[in,out] p: the 3D position and weight of the photon
* @param[in,out] v: the direction vector of the photon
* @param[in,out] f: the parameter vector of the photon
* @param[in,out] rv: the reciprocal direction vector of the photon (rv[i]=1/v[i])
* @param[out] prop: the optical properties of the voxel the photon is launched into
* @param[in,out] idx1d: the linear index of the voxel containing the photon at launch
* @param[in] field: the 3D array to store photon weights
* @param[in,out] mediaid: the medium index at the voxel at launch
* @param[in,out] w0: initial weight, reset here after launch
* @param[in] isdet: whether the previous photon being terminated lands at a detector
* @param[in,out] ppath: pointer to the shared-mem buffer to store photon partial-path data
* @param[in,out] n_det: array in the constant memory where detector positions are stored
* @param[in,out] dpnum: global-mem variable where the count of detected photons are stored
* @param[in] t: RNG state
* @param[in,out] photonseed: RNG state stored at photon's launch time if replay is needed
* @param[in] media: domain medium index array, read-only
* @param[in] srcpattern: user-specified source pattern array if pattern source is used
* @param[in] threadid: the global index of the current thread
* @param[in] rngseed: in the replay mode, pointer to the saved detected photon seed data
* @param[in,out] seeddata: pointer to the buffer to save detected photon seeds
* @param[in,out] gdebugdata: pointer to the buffer to save photon trajectory positions
* @param[in,out] gprogress: pointer to the host variable to update progress bar
*/
template <int mcxsource>
__device__ inline int launchnewphoton(MCXpos *p,MCXdir *v,MCXtime *f,float3* rv,Medium *prop,uint *idx1d, OutputType *field,
uint *mediaid,OutputType *w0,uint isdet, float ppath[],float n_det[],uint *dpnum,
RandType t[RAND_BUF_LEN],RandType photonseed[RAND_BUF_LEN],
uint media[],float srcpattern[],int threadid,RandType rngseed[],RandType seeddata[],float gdebugdata[],volatile int gprogress[]){
*w0=1.f; ///< reuse to count for launchattempt
int canfocus=1; ///< non-zero: focusable, zero: not focusable
*rv=float3(gcfg->ps.x,gcfg->ps.y,gcfg->ps.z); ///< reuse as the origin of the src, needed for focusable sources
/**
* First, let's terminate the current photon and perform detection calculations
*/
if(p->w>=0.f){
ppath[gcfg->maxmedia*(2+gcfg->ismomentum)]+=p->w; ///< sum all the remaining energy
if(gcfg->debuglevel & MCX_DEBUG_MOVE)
savedebugdata(p,((uint)f->ndone)+threadid*gcfg->threadphoton+umin(threadid,(threadid<gcfg->oddphotons)*threadid),gdebugdata);
#ifdef SAVE_DETECTORS
// let's handle detectors here
if(gcfg->savedet){
if((isdet&DET_MASK)==DET_MASK && *mediaid==0)
savedetphoton(n_det,dpnum,ppath,p,v,photonseed,seeddata);
clearpath(ppath,gcfg->maxmedia*(2+gcfg->ismomentum));
}
#endif
if(*mediaid==0 && *idx1d!=OUTSIDE_VOLUME_MIN && *idx1d!=OUTSIDE_VOLUME_MAX && gcfg->issaveref){
int tshift=MIN(gcfg->maxgate-1,(int)(floorf((f->t-gcfg->twin0)*gcfg->Rtstep)));
if(mcxsource!=MCX_SRC_PATTERN && mcxsource!=MCX_SRC_PATTERN3D){
#ifdef USE_ATOMIC
atomicAdd(& field[*idx1d+tshift*gcfg->dimlen.z],-p->w);
#else
field[*idx1d+tshift*gcfg->dimlen.z]+=-p->w;
#endif
}else{
for(int i=0;i<gcfg->srcnum;i++){
if(ppath[gcfg->maxmedia*(2+gcfg->ismomentum)+3+i]>0.f){
#ifdef USE_ATOMIC
atomicAdd(& field[(*idx1d+tshift*gcfg->dimlen.z)*gcfg->srcnum+i],-p->w*ppath[gcfg->maxmedia*(2+gcfg->ismomentum)+3+i]);
#else
field[(*idx1d+tshift*gcfg->dimlen.z)*gcfg->srcnum+i]+=-p->w*ppath[gcfg->maxmedia*(2+gcfg->ismomentum)+3+i];
#endif
}
}
}
}
}
/**
* If the thread completes all assigned photons, terminate this thread.
*/
if((int)(f->ndone)>=(gcfg->threadphoton+(threadid<gcfg->oddphotons))-1){
return 1; // all photos complete
}
ppath+= gcfg->maxmedia*(2+gcfg->ismomentum);
/**
* If this is a replay of a detected photon, initilize the RNG with the stored seed here.
*/
if(gcfg->seed==SEED_FROM_FILE){
int seedoffset=(threadid*gcfg->threadphoton+min(threadid,gcfg->oddphotons-1)+max(0,(int)f->ndone+1))*RAND_BUF_LEN;
for(int i=0;i<RAND_BUF_LEN;i++)
t[i]=rngseed[seedoffset+i];
}
/**
* Attempt to launch a new photon until success
*/
do{
*((float4*)p)=gcfg->ps;
*((float4*)v)=gcfg->c0;
*((float4*)f)=float4(0.f,0.f,gcfg->minaccumtime,f->ndone);
*idx1d=gcfg->idx1dorig;
*mediaid=gcfg->mediaidorig;
if(gcfg->issaveseed)
copystate(t,photonseed);
/**
* Only one branch is taken because of template, this can reduce thread divergence
*/
switch(mcxsource) {
case(MCX_SRC_PLANAR):
case(MCX_SRC_PATTERN):
case(MCX_SRC_PATTERN3D):
case(MCX_SRC_FOURIER):
case(MCX_SRC_PENCILARRAY): { /*a rectangular grid over a plane*/
float rx=rand_uniform01(t);
float ry=rand_uniform01(t);
float rz;
if(gcfg->srctype==MCX_SRC_PATTERN3D){
rz=rand_uniform01(t);
*((float4*)p)=float4(p->x+rx*gcfg->srcparam1.x,
p->y+ry*gcfg->srcparam1.y,
p->z+rz*gcfg->srcparam1.z,
p->w);
}else{
*((float4*)p)=float4(p->x+rx*gcfg->srcparam1.x+ry*gcfg->srcparam2.x,
p->y+rx*gcfg->srcparam1.y+ry*gcfg->srcparam2.y,
p->z+rx*gcfg->srcparam1.z+ry*gcfg->srcparam2.z,
p->w);
}
if(gcfg->srctype==MCX_SRC_PATTERN){ // need to prevent rx/ry=1 here
if(gcfg->srcnum<=1){
p->w=srcpattern[(int)(ry*JUST_BELOW_ONE*gcfg->srcparam2.w)*(int)(gcfg->srcparam1.w)+(int)(rx*JUST_BELOW_ONE*gcfg->srcparam1.w)];
ppath[3]=p->w;
}else{
for(int i=0;i<gcfg->srcnum;i++)
ppath[i+3]=srcpattern[((int)(ry*JUST_BELOW_ONE*gcfg->srcparam2.w)*(int)(gcfg->srcparam1.w)+(int)(rx*JUST_BELOW_ONE*gcfg->srcparam1.w))*gcfg->srcnum+i];
p->w=1.f;
}
}else if(gcfg->srctype==MCX_SRC_PATTERN3D){
if(gcfg->srcnum<=1){
p->w=srcpattern[(int)(rz*JUST_BELOW_ONE*gcfg->srcparam1.z)*(int)(gcfg->srcparam1.y)*(int)(gcfg->srcparam1.x)+
(int)(ry*JUST_BELOW_ONE*gcfg->srcparam1.y)*(int)(gcfg->srcparam1.x)+(int)(rx*JUST_BELOW_ONE*gcfg->srcparam1.x)];
ppath[3]=p->w;
}else{
for(int i=0;i<gcfg->srcnum;i++)
ppath[i+3]=srcpattern[((int)(rz*JUST_BELOW_ONE*gcfg->srcparam1.z)*(int)(gcfg->srcparam1.y)*(int)(gcfg->srcparam1.x)+
(int)(ry*JUST_BELOW_ONE*gcfg->srcparam1.y)*(int)(gcfg->srcparam1.x)+(int)(rx*JUST_BELOW_ONE*gcfg->srcparam1.x))*gcfg->srcnum+i];
p->w=1.f;
}
}else if(gcfg->srctype==MCX_SRC_FOURIER)
p->w=(cosf((floorf(gcfg->srcparam1.w)*rx+floorf(gcfg->srcparam2.w)*ry
+gcfg->srcparam1.w-floorf(gcfg->srcparam1.w))*TWO_PI)*(1.f-gcfg->srcparam2.w+floorf(gcfg->srcparam2.w))+1.f)*0.5f; //between 0 and 1
else if(gcfg->srctype==MCX_SRC_PENCILARRAY){
p->x=gcfg->ps.x+ floorf(rx*gcfg->srcparam1.w)*gcfg->srcparam1.x/(gcfg->srcparam1.w-1.f)+floorf(ry*gcfg->srcparam2.w)*gcfg->srcparam2.x/(gcfg->srcparam2.w-1.f);
p->y=gcfg->ps.y+ floorf(rx*gcfg->srcparam1.w)*gcfg->srcparam1.y/(gcfg->srcparam1.w-1.f)+floorf(ry*gcfg->srcparam2.w)*gcfg->srcparam2.y/(gcfg->srcparam2.w-1.f);
p->z=gcfg->ps.z+ floorf(rx*gcfg->srcparam1.w)*gcfg->srcparam1.z/(gcfg->srcparam1.w-1.f)+floorf(ry*gcfg->srcparam2.w)*gcfg->srcparam2.z/(gcfg->srcparam2.w-1.f);
}
*idx1d=(int(floorf(p->z))*gcfg->dimlen.y+int(floorf(p->y))*gcfg->dimlen.x+int(floorf(p->x)));
if(p->x<0.f || p->y<0.f || p->z<0.f || p->x>=gcfg->maxidx.x || p->y>=gcfg->maxidx.y || p->z>=gcfg->maxidx.z){
*mediaid=0;
}else{
*mediaid=media[*idx1d];
}
*rv=float3(rv->x+(gcfg->srcparam1.x+gcfg->srcparam2.x)*0.5f,
rv->y+(gcfg->srcparam1.y+gcfg->srcparam2.y)*0.5f,
rv->z+(gcfg->srcparam1.z+gcfg->srcparam2.z)*0.5f);
break;
}
case(MCX_SRC_FOURIERX):
case(MCX_SRC_FOURIERX2D): { // [v1x][v1y][v1z][|v2|]; [kx][ky][phi0][M], unit(v0) x unit(v1)=unit(v2)
float rx=rand_uniform01(t);
float ry=rand_uniform01(t);
float4 v2=gcfg->srcparam1;
// calculate v2 based on v2=|v2| * unit(v0) x unit(v1)
v2.w*=rsqrt(gcfg->srcparam1.x*gcfg->srcparam1.x+gcfg->srcparam1.y*gcfg->srcparam1.y+gcfg->srcparam1.z*gcfg->srcparam1.z);
v2.x=v2.w*(gcfg->c0.y*gcfg->srcparam1.z - gcfg->c0.z*gcfg->srcparam1.y);
v2.y=v2.w*(gcfg->c0.z*gcfg->srcparam1.x - gcfg->c0.x*gcfg->srcparam1.z);
v2.z=v2.w*(gcfg->c0.x*gcfg->srcparam1.y - gcfg->c0.y*gcfg->srcparam1.x);
*((float4*)p)=float4(p->x+rx*gcfg->srcparam1.x+ry*v2.x,
p->y+rx*gcfg->srcparam1.y+ry*v2.y,
p->z+rx*gcfg->srcparam1.z+ry*v2.z,
p->w);
if(gcfg->srctype==MCX_SRC_FOURIERX2D)
p->w=(sinf((gcfg->srcparam2.x*rx+gcfg->srcparam2.z)*TWO_PI)*sinf((gcfg->srcparam2.y*ry+gcfg->srcparam2.w)*TWO_PI)+1.f)*0.5f; //between 0 and 1
else
p->w=(cosf((gcfg->srcparam2.x*rx+gcfg->srcparam2.y*ry+gcfg->srcparam2.z)*TWO_PI)*(1.f-gcfg->srcparam2.w)+1.f)*0.5f; //between 0 and 1
*idx1d=(int(floorf(p->z))*gcfg->dimlen.y+int(floorf(p->y))*gcfg->dimlen.x+int(floorf(p->x)));
if(p->x<0.f || p->y<0.f || p->z<0.f || p->x>=gcfg->maxidx.x || p->y>=gcfg->maxidx.y || p->z>=gcfg->maxidx.z){
*mediaid=0;
}else{
*mediaid=media[*idx1d];
}
*rv=float3(rv->x+(gcfg->srcparam1.x+v2.x)*0.5f,
rv->y+(gcfg->srcparam1.y+v2.y)*0.5f,
rv->z+(gcfg->srcparam1.z+v2.z)*0.5f);
break;
}
case(MCX_SRC_DISK):
case(MCX_SRC_GAUSSIAN): { // uniform disk distribution or Gaussian-beam
// Uniform disk point picking
// http://mathworld.wolfram.com/DiskPointPicking.html
float sphi, cphi;
float phi=TWO_PI*rand_uniform01(t);
sincosf(phi,&sphi,&cphi);
float r;
if(gcfg->srctype==MCX_SRC_DISK)
r=sqrtf(rand_uniform01(t))*gcfg->srcparam1.x;
else if(fabs(gcfg->c0.w) < 1e-5f || fabs(gcfg->srcparam1.y) < 1e-5f)
r=sqrtf(-0.5f*logf(rand_uniform01(t)))*gcfg->srcparam1.x;
else{
r=gcfg->srcparam1.x*gcfg->srcparam1.x*M_PI/gcfg->srcparam1.y; //Rayleigh range
r=sqrtf(-0.5f*logf(rand_uniform01(t))*(1.f+(gcfg->c0.w*gcfg->c0.w/(r*r))))*gcfg->srcparam1.x;
}
if( v->z>-1.f+EPS && v->z<1.f-EPS ) {
float tmp0=1.f-v->z*v->z;
float tmp1=r*rsqrtf(tmp0);
*((float4*)p)=float4(
p->x+tmp1*(v->x*v->z*cphi - v->y*sphi),
p->y+tmp1*(v->y*v->z*cphi + v->x*sphi),
p->z-tmp1*tmp0*cphi ,
p->w
);
GPUDEBUG(("new dir: %10.5e %10.5e %10.5e\n",v->x,v->y,v->z));
}else{
p->x+=r*cphi;
p->y+=r*sphi;
GPUDEBUG(("new dir-z: %10.5e %10.5e %10.5e\n",v->x,v->y,v->z));
}
*idx1d=(int(floorf(p->z))*gcfg->dimlen.y+int(floorf(p->y))*gcfg->dimlen.x+int(floorf(p->x)));
if(p->x<0.f || p->y<0.f || p->z<0.f || p->x>=gcfg->maxidx.x || p->y>=gcfg->maxidx.y || p->z>=gcfg->maxidx.z){
*mediaid=0;
}else{
*mediaid=media[*idx1d];
}
break;
}
case(MCX_SRC_CONE):
case(MCX_SRC_ISOTROPIC):
case(MCX_SRC_ARCSINE): {
// Uniform point picking on a sphere
// http://mathworld.wolfram.com/SpherePointPicking.html
float ang,stheta,ctheta,sphi,cphi;
ang=TWO_PI*rand_uniform01(t); //next arimuth angle
sincosf(ang,&sphi,&cphi);
if(gcfg->srctype==MCX_SRC_CONE){ // a solid-angle section of a uniform sphere
do{
ang=(gcfg->srcparam1.y>0) ? TWO_PI*rand_uniform01(t) : acosf(2.f*rand_uniform01(t)-1.f); //sine distribution
}while(ang>gcfg->srcparam1.x);
}else{
if(gcfg->srctype==MCX_SRC_ISOTROPIC) // uniform sphere
ang=acosf(2.f*rand_uniform01(t)-1.f); //sine distribution
else
ang=ONE_PI*rand_uniform01(t); //uniform distribution in zenith angle, arcsine
}
sincosf(ang,&stheta,&ctheta);
rotatevector(v,stheta,ctheta,sphi,cphi);
canfocus=0;
break;
}
case(MCX_SRC_ZGAUSSIAN): {
float ang,stheta,ctheta,sphi,cphi;
ang=TWO_PI*rand_uniform01(t); //next arimuth angle
sincosf(ang,&sphi,&cphi);
ang=sqrtf(-2.f*logf(rand_uniform01(t)))*(1.f-2.f*rand_uniform01(t))*gcfg->srcparam1.x;
sincosf(ang,&stheta,&ctheta);
rotatevector(v,stheta,ctheta,sphi,cphi);
canfocus=0;
break;
}
case(MCX_SRC_LINE):
case(MCX_SRC_SLIT): {
float r=rand_uniform01(t);
*((float4*)p)=float4(p->x+r*gcfg->srcparam1.x,
p->y+r*gcfg->srcparam1.y,
p->z+r*gcfg->srcparam1.z,
p->w);
if(gcfg->srctype==MCX_SRC_LINE){
float s,q;
r=1.f-2.f*rand_uniform01(t);
s=1.f-2.f*rand_uniform01(t);
q=sqrt(1.f-v->x*v->x-v->y*v->y)*(rand_uniform01(t)>0.5f ? 1.f : -1.f);
*((float4*)v)=float4(v->y*q-v->z*s,v->z*r-v->x*q,v->x*s-v->y*r,v->nscat);
}
*rv=float3(rv->x+(gcfg->srcparam1.x)*0.5f,
rv->y+(gcfg->srcparam1.y)*0.5f,
rv->z+(gcfg->srcparam1.z)*0.5f);
canfocus=(gcfg->srctype==MCX_SRC_SLIT);
break;
}
}
/**
* If beam focus is set, determine the incident angle
*/
if(canfocus){
if(isnan(gcfg->c0.w)){ // isotropic if focal length is nan
float ang,stheta,ctheta,sphi,cphi;
ang=TWO_PI*rand_uniform01(t); //next arimuth angle
sincosf(ang,&sphi,&cphi);
ang=acosf(2.f*rand_uniform01(t)-1.f); //sine distribution
sincosf(ang,&stheta,&ctheta);
rotatevector(v,stheta,ctheta,sphi,cphi);
}else if(gcfg->c0.w!=0.f){
float Rn2=(gcfg->c0.w > 0.f) - (gcfg->c0.w < 0.f);
rv->x+=gcfg->c0.w*v->x;
rv->y+=gcfg->c0.w*v->y;
rv->z+=gcfg->c0.w*v->z;
v->x=Rn2*(rv->x-p->x);
v->y=Rn2*(rv->y-p->y);
v->z=Rn2*(rv->z-p->z);
Rn2=rsqrtf(v->x*v->x+v->y*v->y+v->z*v->z); // normalize
v->x*=Rn2;
v->y*=Rn2;
v->z*=Rn2;
}
}
/**
* Compute the reciprocal of the velocity vector
*/
*rv=float3(__fdividef(1.f,v->x),__fdividef(1.f,v->y),__fdividef(1.f,v->z));
/**
* If a photon is launched outside of the box, or inside a zero-voxel, move it until it hits a non-zero voxel
*/
if((*mediaid & MED_MASK)==0){
int idx=skipvoid(p, v, f, rv, media); /** specular reflection of the bbx is taken care of here*/
if(idx>=0){
*idx1d=idx;
*mediaid=media[*idx1d];
}
}
*w0+=1.f;
GPUDEBUG(("retry %f: mediaid=%d idx=%d w0=%e\n",*w0, *mediaid, *idx1d, p->w));
/**
* if launch attempted for over 1000 times, stop trying and return
*/
if(*w0>gcfg->maxvoidstep)
return -1; // launch failed
}while((*mediaid & MED_MASK)==0 || p->w<=gcfg->minenergy);
/**
* Now a photon is successfully launched, perform necssary initialization for a new trajectory
*/
f->ndone++;
*((float4*)(prop))=gproperty[*mediaid & MED_MASK]; //always use mediaid to read gproperty[]
if(gcfg->debuglevel & MCX_DEBUG_MOVE)
savedebugdata(p,(uint)f->ndone+threadid*gcfg->threadphoton+umin(threadid,(threadid<gcfg->oddphotons)*threadid),gdebugdata);
/**
total energy enters the volume. for diverging/converting
beams, this is less than nphoton due to specular reflection
loss. This is different from the wide-field MMC, where the
total launched energy includes the specular reflection loss
*/
ppath[1]+=p->w;
*w0=p->w;
ppath[2]=p->w; // store initial weight
v->nscat=EPS;
f->pathlen=0.f;
/**
* If a progress bar is needed, only sum completed photons from the 1st, last and middle threads to determine progress bar
*/
if((gcfg->debuglevel & MCX_DEBUG_PROGRESS) && ((int)(f->ndone) & 1) && (threadid==0 || threadid==blockDim.x * gridDim.x - 1
|| threadid==((blockDim.x * gridDim.x)>>1))) { ///< use the 1st, middle and last thread for progress report
gprogress[0]++;
}
return 0;
}
/**
* @brief A stand-alone kernel to test random number generators
*
* This function fills the domain with the random numbers generated from
* the GPU. One can use this function to dump RNG values and test for quality.
* use -D R in the command line to enable this output.
*
* @param[out] field: the array to be filled with RNG values
* @param[in] n_seed: the seed to the RNG
*/
kernel void mcx_test_rng(OutputType field[],uint n_seed[]){
int idx= blockDim.x * blockIdx.x + threadIdx.x;
int i;
int len=gcfg->maxidx.x*gcfg->maxidx.y*gcfg->maxidx.z*(int)((gcfg->twin1-gcfg->twin0)*gcfg->Rtstep+0.5f);
RandType t[RAND_BUF_LEN];
gpu_rng_init(t,n_seed,idx);
for(i=0;i<len;i++){
field[i]=rand_uniform01(t);
}
}
/**
* @brief The core Monte Carlo photon simulation kernel (!!!Important!!!)
*
* This is the core Monte Carlo simulation kernel, please see Fig. 1 in Fang2009.
* everything in the GPU kernels is in grid-unit. To convert back to length, use
* cfg->unitinmm (scattering/absorption coeff, T, speed etc)
*
* @param[in] media: domain medium index array, read-only
* @param[out] field: the 3D/4D array where the fluence/energy-deposit are accummulated
* @param[in,out] genergy: the array storing the total launched and escaped energy for each thread
* @param[in] n_seed: the seed to the RNG of this thread
* @param[in,out] n_pos: the initial position state of the photon for each thread
* @param[in,out] n_dir: the initial direction state of the photon for each thread
* @param[in,out] n_len: the initial parameter state of the photon for each thread
* @param[in,out] detectedphoton: the buffer where the detected photon data are stored
* @param[in] srcpattern: user-specified source pattern array if pattern source is used
* @param[in] replayweight: the pre-computed detected photon weight for replay
* @param[in] photontof: the pre-computed detected photon time-of-fly for replay
* @param[in,out] seeddata: pointer to the buffer to save detected photon seeds
* @param[in,out] gdebugdata: pointer to the buffer to save photon trajectory positions
* @param[in,out] gprogress: pointer to the host variable to update progress bar
*/
template <int mcxsource>
kernel void mcx_main_loop(uint media[],OutputType field[],float genergy[],uint n_seed[],
float4 n_pos[],float4 n_dir[],float4 n_len[],float n_det[], uint detectedphoton[],
float srcpattern[],float replayweight[],float photontof[],int photondetid[],
RandType *seeddata,float *gdebugdata,volatile int *gprogress){
/** the 1D index of the current thread */
int idx= blockDim.x * blockIdx.x + threadIdx.x;
if(idx>=gcfg->threadphoton*(blockDim.x * gridDim.x)+gcfg->oddphotons)
return;
MCXpos p={0.f,0.f,0.f,-1.f}; ///< Photon position state: {x,y,z}: coordinates in grid unit, w:packet weight
MCXdir v={0.f,0.f,0.f, 0.f}; ///< Photon direction state: {x,y,z}: unitary direction vector in grid unit, nscat:total scat event
MCXtime f={0.f,0.f,0.f,-1.f}; ///< Photon parameter state: pscat: remaining scattering probability,t: photon elapse time, pathlen: total pathlen in one voxel, ndone: completed photons