-
Notifications
You must be signed in to change notification settings - Fork 3
/
term_cache_trees.erl
335 lines (284 loc) · 11.5 KB
/
term_cache_trees.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
% Copyright 2010, Filipe David Manana <fdmanana@apache.org>
% Web site: http://github.com/fdmanana/term_cache
%
% Licensed under the Apache License, Version 2.0 (the "License"); you may not
% use this file except in compliance with the License. You may obtain a copy of
% the License at
%
% http://www.apache.org/licenses/LICENSE-2.0
%
% Unless required by applicable law or agreed to in writing, software
% distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
% WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
% License for the specific language governing permissions and limitations under
% the License.
% A simple, configurable and generic Erlang term cache.
% Keys and values can be any Erlang term.
%
% This implementation uses trees (from gb_trees module) instead of ets tables.
% The reason for trees is that the maximum number of ets tables allowed by the
% Erlang VM is limited.
-module(term_cache_trees).
-behaviour(gen_server).
% public API
-export([start_link/1, stop/1]).
-export([get/2, put/3]).
-export([flush/1]).
% gen_server callbacks
-export([init/1, handle_call/3, handle_info/2, handle_cast/2]).
-export([code_change/3, terminate/2]).
-record(state, {
max_cache_size = 100,
policy = lru,
timeout = 0, % milliseconds
items_tree,
atimes_tree
}).
%% @type cache() = pid() | atom()
%% @type key() = term()
%% @type item() = term()
%% @spec get(cache(), key()) -> {ok, item()} | not_found
get(Cache, Key) ->
gen_server:call(Cache, {get, Key}, infinity).
%% @spec put(cache(), key(), item()) -> ok
put(Cache, Key, Item) ->
ok = gen_server:cast(Cache, {put, Key, Item}).
%% @spec flush(cache()) -> ok
flush(Cache) ->
ok = gen_server:cast(Cache, flush).
%% @spec start_link(options()) -> {ok, pid()}
%% @type options() = [ option() ]
%% @type option() = {name, atom()} | {policy, policy()} | {size, int()} |
%% {ttl, int()}
%% @type policy() = lru | mru
start_link(Options) ->
case value(name, Options, undefined) of
undefined ->
gen_server:start_link(?MODULE, Options, []);
Name ->
gen_server:start_link({local, Name}, ?MODULE, Options, [])
end.
%% @spec stop(cache()) -> ok
stop(Cache) ->
catch gen_server:call(Cache, stop),
ok.
init(Options) ->
State = #state{
policy = value(policy, Options, lru),
max_cache_size = value(size, Options, 100),
timeout = value(ttl, Options, 0), % 0 means no timeout
items_tree = gb_trees:empty(),
atimes_tree = gb_trees:empty()
},
{ok, State}.
handle_cast({put, _Key, _Item}, #state{max_cache_size = 0} = State) ->
{noreply, State};
handle_cast({put, Key, Item}, #state{timeout = Timeout} = State) ->
#state{
max_cache_size = MaxSize,
items_tree = Items,
atimes_tree = ATimes
} = State,
{NewItems, NewATimes} = case gb_trees:lookup(Key, Items) of
{value, {_OldItem, OldATime, OldTimer}} ->
cancel_timer(Key, OldTimer),
NewATime = erlang:now(),
NewTimer = set_timer(Key, Timeout),
Items2 = gb_trees:enter(Key, {Item, NewATime, NewTimer}, Items),
ATimes2 = gb_trees:delete(OldATime, ATimes),
{Items2, gb_trees:insert(NewATime, Key, ATimes2)};
none ->
{Items2, ATimes2} = case gb_trees:size(Items) >= MaxSize of
true ->
free_cache_entry(State);
false ->
{Items, ATimes}
end,
NewATime = erlang:now(),
NewTimer = set_timer(Key, Timeout),
ATimes3 = gb_trees:insert(NewATime, Key, ATimes2),
Items3 = gb_trees:insert(Key, {Item, NewATime, NewTimer}, Items2),
{Items3, ATimes3}
end,
{noreply, State#state{items_tree = NewItems, atimes_tree = NewATimes}};
handle_cast(flush, #state{items_tree = Items} = State) ->
lists:foldl(
fun({Key, {_Item, _ATime, Timer}}, _) -> cancel_timer(Key, Timer) end,
ok,
gb_trees:to_list(Items)
),
NewState = State#state{
items_tree = gb_trees:empty(),
atimes_tree = gb_trees:empty()
},
{noreply, NewState}.
handle_call({get, Key}, _From, #state{timeout = Timeout} = State) ->
#state{items_tree = Items, atimes_tree = ATimes} = State,
case gb_trees:lookup(Key, Items) of
{value, {Item, ATime, Timer}} ->
cancel_timer(Key, Timer),
NewATime = erlang:now(),
ATimes2 = gb_trees:delete(ATime, ATimes),
ATimes3 = gb_trees:insert(NewATime, Key, ATimes2),
NewTimer = set_timer(Key, Timeout),
Items2 = gb_trees:update(Key, {Item, NewATime, NewTimer}, Items),
NewState = State#state{
items_tree = Items2,
atimes_tree = ATimes3
},
{reply, {ok, Item}, NewState};
none ->
{reply, not_found, State}
end;
handle_call(stop, _From, State) ->
{stop, normal, ok, State}.
handle_info({expired, Key}, State) ->
#state{items_tree = Items, atimes_tree = ATimes} = State,
{_Item, ATime, _Timer} = gb_trees:get(Key, Items),
Items2 = gb_trees:delete(Key, Items),
ATimes2 = gb_trees:delete(ATime, ATimes),
{noreply, State#state{items_tree = Items2, atimes_tree = ATimes2}}.
terminate(_Reason, _State) ->
ok.
code_change(_OldVsn, State, _Extra) ->
{ok, State}.
free_cache_entry(#state{policy = lru} = State) ->
#state{atimes_tree = ATimes, items_tree = Items} = State,
{ATime, Key, ATimes2} = gb_trees:take_smallest(ATimes),
{_Item, ATime, Timer} = gb_trees:get(Key, Items),
cancel_timer(Key, Timer),
{gb_trees:delete(Key, Items), ATimes2};
free_cache_entry(#state{policy = mru} = State) ->
#state{atimes_tree = ATimes, items_tree = Items} = State,
{ATime, Key, ATimes2} = gb_trees:take_largest(ATimes),
{_Item, ATime, Timer} = gb_trees:get(Key, Items),
cancel_timer(Key, Timer),
{gb_trees:delete(Key, Items), ATimes2}.
set_timer(_Key, 0) ->
undefined;
set_timer(Key, Interval) when Interval > 0 ->
erlang:send_after(Interval, self(), {expired, Key}).
cancel_timer(_Key, undefined) ->
ok;
cancel_timer(Key, Timer) ->
case erlang:cancel_timer(Timer) of
false ->
ok;
_TimeLeft ->
receive {expired, Key} -> ok after 0 -> ok end
end.
% helper functions
value(Key, List, Default) ->
case lists:keysearch(Key, 1, List) of
{value, {Key, Value}} ->
Value;
false ->
Default
end.
% TESTS
-ifdef(TEST).
-include_lib("eunit/include/eunit.hrl").
simple_lru_test() ->
{ok, Cache} = ?MODULE:start_link(
[{name, foobar}, {size, 3}, {policy, lru}]
),
?assertEqual(Cache, whereis(foobar)),
?assertEqual(not_found, ?MODULE:get(Cache, key1)),
?assertEqual(ok, ?MODULE:put(Cache, key1, value1)),
?assertEqual({ok, value1}, ?MODULE:get(Cache, key1)),
?assertEqual(ok, ?MODULE:put(Cache, <<"key_2">>, [1, 2, 3])),
?assertEqual({ok, [1, 2, 3]}, ?MODULE:get(Cache, <<"key_2">>)),
?assertEqual(ok, ?MODULE:put(Cache, {key, "3"}, {ok, 666})),
?assertEqual({ok, {ok, 666}}, ?MODULE:get(Cache, {key, "3"})),
?assertEqual(ok, ?MODULE:put(Cache, "key4", "hello")),
?assertEqual({ok, "hello"}, ?MODULE:get(Cache, "key4")),
?assertEqual(not_found, ?MODULE:get(Cache, key1)),
?assertEqual({ok, [1, 2, 3]}, ?MODULE:get(Cache, <<"key_2">>)),
?assertEqual({ok, {ok, 666}}, ?MODULE:get(Cache, {key, "3"})),
?assertEqual(ok, ?MODULE:put(Cache, 666, "the beast")),
?assertEqual({ok, "the beast"}, ?MODULE:get(Cache, 666)),
?assertEqual(ok, ?MODULE:put(Cache, 666, <<"maiden">>)),
?assertEqual({ok, <<"maiden">>}, ?MODULE:get(Cache, 666)),
?assertEqual(not_found, ?MODULE:get(Cache, "key4")),
?assertEqual(ok, ?MODULE:put(Cache, 999, <<"the saint">>)),
?assertEqual({ok, <<"the saint">>}, ?MODULE:get(Cache, 999)),
?assertEqual(ok, ?MODULE:put(Cache, 666, "the beast")),
?assertEqual({ok, "the beast"}, ?MODULE:get(Cache, 666)),
?assertEqual(ok, ?MODULE:flush(Cache)),
?assertEqual(not_found, ?MODULE:get(Cache, 666)),
?assertEqual(not_found, ?MODULE:get(Cache, <<"key_2">>)),
?assertEqual(not_found, ?MODULE:get(Cache, {key, "3"})),
?assertEqual(ok, ?MODULE:stop(Cache)).
simple_mru_test() ->
{ok, Cache} = ?MODULE:start_link(
[{name, foobar_mru}, {size, 3}, {policy, mru}]
),
?assertEqual(Cache, whereis(foobar_mru)),
?assertEqual(not_found, ?MODULE:get(Cache, key1)),
?assertEqual(ok, ?MODULE:put(Cache, key1, value1)),
?assertEqual({ok, value1}, ?MODULE:get(Cache, key1)),
?assertEqual(ok, ?MODULE:put(Cache, <<"key_2">>, [1, 2, 3])),
?assertEqual({ok, [1, 2, 3]}, ?MODULE:get(Cache, <<"key_2">>)),
?assertEqual(ok, ?MODULE:put(Cache, {key, "3"}, {ok, 666})),
?assertEqual({ok, {ok, 666}}, ?MODULE:get(Cache, {key, "3"})),
?assertEqual(ok, ?MODULE:put(Cache, "key4", "hello")),
?assertEqual({ok, "hello"}, ?MODULE:get(Cache, "key4")),
?assertEqual(not_found, ?MODULE:get(Cache, {key, "3"})),
?assertEqual({ok, value1}, ?MODULE:get(Cache, key1)),
?assertEqual(ok, ?MODULE:put(Cache, keyboard, "qwerty")),
?assertEqual({ok, "qwerty"}, ?MODULE:get(Cache, keyboard)),
?assertEqual(ok, ?MODULE:put(Cache, keyboard, "azwerty")),
?assertEqual({ok, "azwerty"}, ?MODULE:get(Cache, keyboard)),
?assertEqual(not_found, ?MODULE:get(Cache, key1)),
?assertEqual(ok, ?MODULE:flush(Cache)),
?assertEqual(not_found, ?MODULE:get(Cache, keyboard)),
?assertEqual(not_found, ?MODULE:get(Cache, "key4")),
?assertEqual(not_found, ?MODULE:get(Cache, <<"key_2">>)),
?assertEqual(ok, ?MODULE:stop(Cache)).
timed_lru_test_() ->
{timeout, 60, [{?LINE, fun do_test_timed_lru/0}]}.
do_test_timed_lru() ->
{ok, Cache} = ?MODULE:start_link(
[{name, timed_foobar}, {size, 3}, {policy, lru}, {ttl, 3000}]
),
?assertEqual(Cache, whereis(timed_foobar)),
?assertEqual(ok, ?MODULE:put(Cache, key1, value1)),
timer:sleep(1000),
?assertEqual(ok, ?MODULE:put(Cache, key2, value2)),
?assertEqual(ok, ?MODULE:put(Cache, key3, value3)),
timer:sleep(2100),
?assertEqual(not_found, ?MODULE:get(Cache, key1)),
?assertEqual({ok, value2}, ?MODULE:get(Cache, key2)),
?assertEqual({ok, value3}, ?MODULE:get(Cache, key3)),
?assertEqual(ok, ?MODULE:put(Cache, key4, value4)),
?assertEqual(ok, ?MODULE:put(Cache, key5, value5)),
timer:sleep(1000),
?assertEqual(not_found, ?MODULE:get(Cache, key2)),
?assertEqual({ok, value3}, ?MODULE:get(Cache, key3)),
timer:sleep(3100),
?assertEqual(not_found, ?MODULE:get(Cache, key3)),
?assertEqual(ok, ?MODULE:stop(Cache)).
timed_mru_test_() ->
{timeout, 60, [{?LINE, fun do_test_timed_mru/0}]}.
do_test_timed_mru() ->
{ok, Cache} = ?MODULE:start_link(
[{name, timed_foobar}, {size, 3}, {policy, mru}, {ttl, 3000}]
),
?assertEqual(Cache, whereis(timed_foobar)),
?assertEqual(ok, ?MODULE:put(Cache, key1, value1)),
timer:sleep(1000),
?assertEqual(ok, ?MODULE:put(Cache, key2, value2)),
?assertEqual(ok, ?MODULE:put(Cache, key3, value3)),
timer:sleep(2100),
?assertEqual(not_found, ?MODULE:get(Cache, key1)),
?assertEqual({ok, value2}, ?MODULE:get(Cache, key2)),
?assertEqual({ok, value3}, ?MODULE:get(Cache, key3)),
?assertEqual(ok, ?MODULE:put(Cache, key4, value4)),
?assertEqual(ok, ?MODULE:put(Cache, key5, value5)),
timer:sleep(1000),
?assertEqual(not_found, ?MODULE:get(Cache, key4)),
?assertEqual({ok, value3}, ?MODULE:get(Cache, key3)),
timer:sleep(3100),
?assertEqual(not_found, ?MODULE:get(Cache, key3)),
?assertEqual(ok, ?MODULE:stop(Cache)).
-endif.