-
Notifications
You must be signed in to change notification settings - Fork 47
/
Block.pm
487 lines (411 loc) · 15.7 KB
/
Block.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
package Perlito5::Grammar::Block;
use Perlito5::Grammar::Expression;
use Perlito5::Grammar::Scope;
use Perlito5::AST::BeginScratchpad;
use Perlito5::AST::Captures;
use Perlito5::FoldConstant;
use strict;
our %Named_block = (
BEGIN => 1,
UNITCHECK => 1,
CHECK => 1,
INIT => 1,
END => 1,
AUTOLOAD => 1,
DESTROY => 1,
);
sub block {
my $str = $_[0];
my $pos = $_[1];
my $m = Perlito5::Grammar::Space::opt_ws($str, $pos);
$pos = $m->{to};
if ( $str->[$pos] ne '{' ) {
return
}
$pos++;
# when parsing a command like "for my $x ..." register the loop variable
# before entering the block, so that it can be seen immediately
Perlito5::Grammar::Scope::check_variable_declarations();
Perlito5::Grammar::Scope::create_new_compile_time_scope();
$m = Perlito5::Grammar::exp_stmts($str, $pos);
if (!$m) {
Perlito5::Compiler::error "syntax error";
}
$pos = $m->{to};
my $capture = Perlito5::Match::flat($m);
$m = Perlito5::Grammar::Space::opt_ws($str, $pos);
$pos = $m->{to};
if ( $str->[$pos] ne '}' ) {
Perlito5::Compiler::error "syntax error";
}
$m->{to} = $pos + 1;
$m->{capture} = Perlito5::AST::Block->new( stmts => $capture, sig => undef );
# end of lexical scope
Perlito5::Grammar::Scope::end_compile_time_scope();
return $m;
}
sub closure_block {
my $str = $_[0];
my $pos = $_[1];
my $m = Perlito5::Grammar::Space::opt_ws($str, $pos);
$pos = $m->{to};
if ( $str->[$pos] ne '{' ) {
return
}
$pos++;
# when parsing a command like "for my $x ..." register the loop variable
# before entering the block, so that it can be seen immediately
Perlito5::Grammar::Scope::check_variable_declarations();
Perlito5::Grammar::Scope::create_new_compile_time_scope();
local $Perlito5::CLOSURE_SCOPE = $#Perlito5::BASE_SCOPE; # this is the only diff from plain <block>
$m = Perlito5::Grammar::exp_stmts($str, $pos);
if (!$m) {
Perlito5::Compiler::error "syntax error";
}
$pos = $m->{to};
my $capture = Perlito5::Match::flat($m);
$m = Perlito5::Grammar::Space::opt_ws($str, $pos);
$pos = $m->{to};
if ( $str->[$pos] ne '}' ) {
Perlito5::Compiler::error "syntax error";
}
$m->{to} = $pos + 1;
$m->{capture} = Perlito5::AST::Block->new( stmts => $capture, sig => undef );
# end of lexical scope
Perlito5::Grammar::Scope::end_compile_time_scope();
return $m;
}
sub eval_end_block {
# execute "eval" on this block,
# without access to compile-time lexical variables.
# compile-time globals are still a problem.
my ($block, $phase) = @_;
$block = Perlito5::AST::Block->new(
stmts => [
Perlito5::AST::Sub->new(
'attributes' => [],
'block' => $block,
'name' => undef,
'namespace' => $Perlito5::PKG_NAME,
'sig' => undef,
'pos' => Perlito5::Compiler::compiler_pos(),
)
]
);
return Perlito5::Grammar::Block::eval_begin_block($block, 'BEGIN');
}
sub eval_begin_block {
# execute "eval" on this block,
# without access to compile-time lexical variables.
# compile-time globals are still a problem.
my $block = shift;
local ${^GLOBAL_PHASE};
Perlito5::set_global_phase("BEGIN");
# get list of captured variables, including inner blocks
my @captured = $block->get_captures();
my %dont_capture = map { $_->{dont} ? ( $_->{dont} => 1 ) : () } @captured;
my %capture = map { $_->{dont} ? ()
: $dont_capture{ $_->{_id} } ? ()
: ($_->{_decl} eq 'local' || $_->{_decl} eq 'global' || $_->{_decl} eq 'our' || $_->{_decl} eq '') ? ()
: ( $_->{_id} => $_ )
} @captured;
# print STDERR "CAPTURES ", Perlito5::Dumper::Dumper(\%capture);
# %capture == (
# '100' => ...,
# '101' => ...,,
# )
%Perlito5::BEGIN_SCRATCHPAD = ( %Perlito5::BEGIN_SCRATCHPAD, %capture );
# use lexicals from BEGIN scratchpad
$block = $block->emit_begin_scratchpad();
# emit_compile_time() adds instrumentation to inspect captured variables
$block = $block->emit_compile_time();
local $@;
my $result = Perlito5::eval_ast($block);
if ($@) {
Perlito5::Compiler::error "Error in BEGIN block: " . $@;
}
# "use MODULE" wants a true return value
return $result;
}
token opt_continue_block {
<.Perlito5::Grammar::Space::opt_ws> 'continue' <block>
{
$MATCH->{capture} = Perlito5::Match::flat($MATCH->{block});
$MATCH->{capture}{is_continue} = 1;
}
|
{
$MATCH->{capture} = Perlito5::AST::Block->new( stmts => [], sig => undef )
}
};
sub anon_block {
my $str = $_[0];
my $pos = $_[1];
my $p = $pos;
local $Perlito5::BLOCK_HAS_SEMICOLON;
my $m = Perlito5::Grammar::block( $str, $p );
return if !$m;
$p = $m->{to};
my $block = Perlito5::Match::flat($m);
# anonymous blocks can have a 'continue' block
$m = Perlito5::Grammar::opt_continue_block( $str, $p );
$p = $m->{to};
my $continue = Perlito5::Match::flat($m);
my $v = $block;
# TODO - this is not recognized as a statement: { 123 => 4;}
# TODO - this is not recognized as a syntax error: { 123 => 4 }{2}
$v = Perlito5::Grammar::Expression::block_or_hash($v)
if !$continue->{is_continue}
&& !$Perlito5::BLOCK_HAS_SEMICOLON;
$m->{capture} = $v;
if ( $continue->{is_continue} ) {
$m->{capture}{continue} = $continue;
}
return $m;
}
sub ast_nop {
Perlito5::AST::Apply->new(
code => 'nop',
namespace => 'Perlito5',
arguments => []
);
}
sub special_named_block {
my $str = $_[0];
my $pos = $_[1];
my $p = $pos;
my $block_name;
my $m_name = Perlito5::Grammar::ident( $str, $p );
return if !$m_name;
$p = $m_name->{to};
$block_name = Perlito5::Match::flat($m_name);
my $ws = Perlito5::Grammar::Space::opt_ws( $str, $p );
$p = $ws->{to};
my $block_start = $p;
my $m = Perlito5::Grammar::Block::closure_block( $str, $p );
return if !$m;
$p = $m->{to};
my $block = Perlito5::Match::flat($m);
if ($block_name eq 'INIT') {
push @Perlito5::INIT_BLOCK, eval_end_block( $block, 'INIT' );
$m->{capture} = ast_nop();
}
elsif ($block_name eq 'END') {
unshift @Perlito5::END_BLOCK, eval_end_block( $block, 'END' );
$m->{capture} = ast_nop();
}
elsif ($block_name eq 'CHECK') {
unshift @Perlito5::CHECK_BLOCK, eval_end_block( $block, 'CHECK' );
$m->{capture} = ast_nop();
}
elsif ($block_name eq 'UNITCHECK') {
unshift @Perlito5::UNITCHECK_BLOCK, eval_end_block( $block, 'UNITCHECK' );
$m->{capture} = ast_nop();
}
elsif ($block_name eq 'BEGIN') {
# say "BEGIN $block_start ", $m->{to}, "[", substr($str, $block_start, $m->{to} - $block_start), "]";
# local $Perlito5::PKG_NAME = $Perlito5::PKG_NAME; # BUG - this doesn't work
local $Perlito5::PHASE = 'BEGIN';
eval_begin_block( $block );
$m->{capture} = ast_nop();
}
elsif ($block_name eq 'AUTOLOAD' || $block_name eq 'DESTROY') {
my $sub = Perlito5::AST::Sub->new(
'attributes' => [],
'block' => $block,
'name' => $block_name,
'namespace' => $Perlito5::PKG_NAME,
'sig' => undef,
'pos' => Perlito5::Compiler::compiler_pos(),
);
# add named sub to SCOPE
my $full_name = $sub->{namespace} . "::" . $sub->{name};
$Perlito5::PROTO->{$full_name} = undef;
$Perlito5::GLOBAL->{$full_name} = $sub;
# evaluate the sub definition in a BEGIN block
$block = Perlito5::AST::Block->new( stmts => [$sub] );
Perlito5::Grammar::Block::eval_begin_block($block, 'BEGIN');
# runtime effect of subroutine declaration is "undef"
$m->{capture} = ast_nop();
}
else {
$m->{capture} = $block;
$m->{capture}{name} = $block_name;
}
return $m;
}
token named_sub_def {
<Perlito5::Grammar::optional_namespace_before_ident> <Perlito5::Grammar::ident>
<Perlito5::Grammar::Block::prototype_> <.Perlito5::Grammar::Space::opt_ws>
<Perlito5::Grammar::Attribute::opt_attribute> <.Perlito5::Grammar::Space::opt_ws>
[
<Perlito5::Grammar::Block::closure_block>
{
$MATCH->{_tmp} = Perlito5::Match::flat($MATCH->{"Perlito5::Grammar::Block::closure_block"});
}
|
<.Perlito5::Grammar::Statement::statement_parse>
{
Perlito5::Compiler::error 'Illegal declaration of subroutine \'', Perlito5::Match::flat($MATCH->{"Perlito5::Grammar::ident"}), '\''
}
|
{
# subroutine predeclaration - there is no block
$MATCH->{_tmp} = undef;
}
]
{
my $name = Perlito5::Match::flat($MATCH->{"Perlito5::Grammar::ident"});
my $sig = Perlito5::Match::flat($MATCH->{"Perlito5::Grammar::Block::prototype_"});
$sig = undef if $sig eq '*undef*';
my $attributes = Perlito5::Match::flat($MATCH->{"Perlito5::Grammar::Attribute::opt_attribute"});
my ($proto) = grep { $_->[0] eq 'prototype' } @$attributes;
if ($proto) {
$attributes = [grep { $_->[0] ne 'prototype' } @$attributes];
$sig = $proto->[1];
}
my $namespace = Perlito5::Match::flat($MATCH->{"Perlito5::Grammar::optional_namespace_before_ident"});
if ( $name ) {
# say "sub $Perlito5::PKG_NAME :: $name ( $sig )";
if (!$namespace) {
# perl -MO=Deparse -e ' package X; sub _ { 123 } ' # sub main::_
$namespace = $name eq '_'
? 'main'
: $Perlito5::PKG_NAME;
}
my $full_name = "${namespace}::$name";
# TODO - check if the previous definition was a predeclaration
# warn "Subroutine $full_name redefined"
# if exists $Perlito5::PROTO->{$full_name};
$Perlito5::PROTO->{$full_name} = $sig; # TODO - cleanup - replace $PROTO with prototype()
}
my $sub = Perlito5::AST::Sub->new(
name => $name,
namespace => $namespace,
sig => $sig,
block => $MATCH->{_tmp},
attributes => $attributes,
pos => Perlito5::Compiler::compiler_pos(),
);
if ($name && defined $sig && $sig eq '' && $sub->{block} && @{ $sub->{block}{stmts} } == 1 ) {
my $expr = $sub->{block}{stmts}[0];
$expr = Perlito5::FoldConstant::fold_constant($expr);
my $ref = ref($expr);
if ( $ref eq 'Perlito5::AST::Int'
|| $ref eq 'Perlito5::AST::Num'
|| $ref eq 'Perlito5::AST::Buf'
)
{
# looks like a constant declaration
# TODO - "Constant subroutine xx redefined"
# print STDERR "maybe constant $namespace :: $name ($sig)\n";
$Perlito5::CONSTANT{"${namespace}::$name"} = $expr;
}
}
if ( $Perlito5::EXPAND_USE && $name ) {
# named sub in the normal compiler (not "bootstrapping")
my $full_name = "${namespace}::$name";
# evaluate the sub definition in a BEGIN block
my $block = Perlito5::AST::Block->new( stmts => [$sub] );
Perlito5::Grammar::Block::eval_begin_block($block, 'BEGIN');
# add named sub to SCOPE
$Perlito5::GLOBAL->{$full_name} = $sub;
# runtime effect of subroutine declaration is "undef"
$sub = ast_nop();
$MATCH->{capture} = $sub;
}
else {
# bootstrapping mode
# the subroutine AST is directly added to the global AST
$MATCH->{capture} = $sub;
}
}
};
sub named_sub {
my $str = $_[0];
my $pos = $_[1];
return
unless $str->[$pos] eq 's' && $str->[$pos+1] eq 'u' && $str->[$pos+2] eq 'b';
my $ws = Perlito5::Grammar::Space::ws( $str, $pos + 3 );
return
unless $ws;
my $p = $ws->{to};
my $m_name = Perlito5::Grammar::ident( $str, $p );
return
unless $m_name;
my $block_name = Perlito5::Match::flat($m_name);
if (exists $Named_block{$block_name}) {
return Perlito5::Grammar::Block::special_named_block($str, $p);
}
return Perlito5::Grammar::Block::named_sub_def($str, $p);
}
token term_anon_sub {
'sub' <.Perlito5::Grammar::Space::opt_ws> <Perlito5::Grammar::Block::anon_sub_def>
{ $MATCH->{capture} = [ 'term', Perlito5::Match::flat($MATCH->{"Perlito5::Grammar::Block::anon_sub_def"}) ] }
};
token term_do {
# Note: this is do-block; do-string is parsed as a normal subroutine
'do' <Perlito5::Grammar::block>
{ $MATCH->{capture} = [ 'term', Perlito5::AST::Apply->new(
code => 'do',
arguments => [ Perlito5::Match::flat($MATCH->{'Perlito5::Grammar::block'}) ]
)
]
}
};
token args_sig {
[ ';' | \\ | '[' | ']' | '*' | '+' | '@' | '%' | '$' | '&' ]*
};
token prototype_ {
| <.Perlito5::Grammar::Space::opt_ws> \( <.Perlito5::Grammar::Space::opt_ws> '_' <.Perlito5::Grammar::Space::opt_ws> \)
{ $MATCH->{capture} = "_" }
| <.Perlito5::Grammar::Space::opt_ws> \( <.Perlito5::Grammar::Space::opt_ws> <args_sig> <.Perlito5::Grammar::Space::opt_ws> \)
{ $MATCH->{capture} = "" . Perlito5::Match::flat($MATCH->{args_sig}) }
| { $MATCH->{capture} = '*undef*' } # default signature
};
token anon_sub_def {
<prototype_> <.Perlito5::Grammar::Space::opt_ws>
<Perlito5::Grammar::Attribute::opt_attribute>
<Perlito5::Grammar::Block::closure_block>
{
my $sig = Perlito5::Match::flat($MATCH->{prototype_});
$sig = undef if $sig eq '*undef*';
my $attributes = Perlito5::Match::flat($MATCH->{"Perlito5::Grammar::Attribute::opt_attribute"});
my ($proto) = grep { $_->[0] eq 'prototype' } @$attributes;
if ($proto) {
$attributes = [grep { $_->[0] ne 'prototype' } @$attributes];
$sig = $proto->[1];
}
$MATCH->{capture} = Perlito5::AST::Sub->new(
name => undef,
namespace => undef,
sig => $sig,
block => Perlito5::Match::flat($MATCH->{'Perlito5::Grammar::Block::closure_block'}),
attributes => $attributes,
pos => Perlito5::Compiler::compiler_pos(),
)
}
};
Perlito5::Grammar::Precedence::add_term( 'do' => \&term_do );
Perlito5::Grammar::Precedence::add_term( 'sub' => \&term_anon_sub );
Perlito5::Grammar::Statement::add_statement( '{' => \&anon_block );
Perlito5::Grammar::Statement::add_statement( 'sub' => \&named_sub );
Perlito5::Grammar::Statement::add_statement( $_ => \&special_named_block )
for keys %Named_block;
1;
=begin
=head1 NAME
Perlito5::Grammar::Block - Parser and AST generator for Perlito
=head1 SYNOPSIS
anon_block($str)
=head1 DESCRIPTION
This module parses source code for Perl 5 statements and generates Perlito5 AST.
=head1 AUTHORS
Flavio Soibelmann Glock <fglock@gmail.com>.
The Pugs Team.
=head1 COPYRIGHT
Copyright 2010, 2011, 2012 by Flavio Soibelmann Glock and others.
This program is free software; you can redistribute it and/or modify it
under the same terms as Perl itself.
See L<http://www.perl.com/perl/misc/Artistic.html>
=end