forked from sahana/eden
-
Notifications
You must be signed in to change notification settings - Fork 0
/
project.xsl
420 lines (368 loc) · 19.5 KB
/
project.xsl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
<?xml version="1.0"?>
<xsl:stylesheet
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
xmlns:project="http://eden.sahanafoundation.org/project">
<!-- **********************************************************************
Projects - CSV Import Stylesheet
CSV column...........Format..........Content
Organisation.........string..........Name of the Host Organisation
Name.................string..........Project Name
Code.................string..........Project Code (optional)
Description..........string..........Project short description
Objectives...........string..........Project objectives
Comments.............string..........Project comments
Status...............string..........Project status
Start Date...........YYYY-MM-DD......Start date of the project
End Date.............YYYY-MM-DD......End date of the project
Countries............comma-sep list..List of country names or ISO codes
Departments..........comma-sep list..List of Organisation Sectors (Departments)
Hazards..............comma-sep list..List of Hazard names
HFA..................comma-sep list..List of HFA priorities (integer numbers)
Budget:XXXX..........float...........Budget for year XXX (multiple allowed)
FPFirstName..........string..........First Name of Focal Person
FPLastName...........string..........Last Name of Focal Person
FPEmail..............string..........Email Address of Focal Person
FPMobilePhone........string..........Mobile Phone Number of Focal Person
theme_percentages=True:
Theme:XXXX...........string..........% of the Project targetting Theme XXX (multiple allowed)
theme_percentages=False:
Themes...............comma-sep list..List of Theme names
*********************************************************************** -->
<xsl:output method="xml"/>
<xsl:include href="../../xml/commons.xsl"/>
<xsl:include href="../../xml/countries.xsl"/>
<xsl:variable name="SectorPrefix" select="'Sector:'"/>
<xsl:variable name="HazardPrefix" select="'Hazard:'"/>
<xsl:variable name="ThemePrefix" select="'Theme:'"/>
<!-- ****************************************************************** -->
<xsl:key name="orgs"
match="row"
use="col[@field='Organisation']"/>
<xsl:key name="statuses"
match="row"
use="col[@field='Status']"/>
<!-- ****************************************************************** -->
<xsl:template match="/">
<s3xml>
<!-- Organisations -->
<xsl:for-each select="//row[generate-id(.)=
generate-id(key('orgs',
col[@field='Organisation'])[1])]">
<xsl:call-template name="Organisation"/>
</xsl:for-each>
<!-- Statuses -->
<xsl:for-each select="//row[generate-id(.)=
generate-id(key('statuses',
col[@field='Status'])[1])]">
<xsl:call-template name="Status"/>
</xsl:for-each>
<!-- Themes -->
<xsl:for-each select="//row[1]/col[starts-with(@field, 'Theme')]">
<xsl:call-template name="Theme"/>
</xsl:for-each>
<!-- Projects -->
<xsl:apply-templates select="./table/row"/>
</s3xml>
</xsl:template>
<!-- ****************************************************************** -->
<xsl:template match="row">
<xsl:variable name="OrgName" select="col[@field='Organisation']/text()"/>
<!-- Optional Classifications -->
<xsl:variable name="Status" select="col[@field='Status']"/>
<xsl:variable name="Countries" select="col[@field='Countries']"/>
<xsl:variable name="Sectors" select="col[@field='Departments']"/>
<xsl:variable name="Hazards" select="col[@field='Hazards']"/>
<xsl:variable name="Themes" select="col[@field='Themes']"/>
<xsl:variable name="HFA" select="col[@field='HFA']"/>
<xsl:variable name="FirstName" select="col[@field='FPFirstName']/text()"/>
<xsl:variable name="LastName" select="col[@field='FPLastName']/text()"/>
<!-- Projects -->
<resource name="project_project">
<data field="code"><xsl:value-of select="col[@field='Code']"/></data>
<data field="name"><xsl:value-of select="col[@field='Name']"/></data>
<data field="description"><xsl:value-of select="col[@field='Description']"/></data>
<data field="start_date"><xsl:value-of select="col[@field='Start Date']"/></data>
<data field="end_date"><xsl:value-of select="col[@field='End Date']"/></data>
<data field="comments"><xsl:value-of select="col[@field='Comments']"/></data>
<xsl:if test="col[@field='Objectives']!=''">
<data field="objectives"><xsl:value-of select="col[@field='Objectives']"/></data>
</xsl:if>
<!-- Status -->
<xsl:if test="$Status">
<reference field="status_id" resource="project_status">
<xsl:attribute name="tuid">
<xsl:value-of select="$Status"/>
</xsl:attribute>
</reference>
</xsl:if>
<!-- HFAs -->
<xsl:if test="$HFA!=''">
<data field="hfa">
<xsl:attribute name="value">
<xsl:value-of select="concat('[', $HFA, ']')"/>
</xsl:attribute>
</data>
</xsl:if>
<!-- Countries -->
<xsl:if test="$Countries!=''">
<reference field="countries_id" resource="gis_location">
<xsl:attribute name="uuid">
<xsl:variable name="CountryCodes">
<xsl:call-template name="splitList">
<xsl:with-param name="arg">countrycode</xsl:with-param>
<xsl:with-param name="list">
<xsl:value-of select="$Countries"/>
</xsl:with-param>
</xsl:call-template>
</xsl:variable>
<xsl:if test="starts-with($CountryCodes, ',"')">
<xsl:value-of select="concat('[', substring-after($CountryCodes, ','), ']')"/>
</xsl:if>
</xsl:attribute>
</reference>
</xsl:if>
<!-- Project Sectors -->
<xsl:if test="$Sectors!=''">
<reference field="multi_sector_id" resource="org_sector">
<xsl:attribute name="tuid">
<xsl:variable name="SectorList">
<xsl:call-template name="quoteList">
<xsl:with-param name="prefix"><xsl:value-of select="$SectorPrefix"/></xsl:with-param>
<xsl:with-param name="list"><xsl:value-of select="$Sectors"/></xsl:with-param>
</xsl:call-template>
</xsl:variable>
<xsl:value-of select="concat('[', $SectorList, ']')"/>
</xsl:attribute>
</reference>
</xsl:if>
<!-- Project Hazards -->
<xsl:if test="$Hazards!=''">
<reference field="multi_hazard_id" resource="project_hazard">
<xsl:attribute name="tuid">
<xsl:variable name="HazardList">
<xsl:call-template name="quoteList">
<xsl:with-param name="prefix"><xsl:value-of select="$HazardPrefix"/></xsl:with-param>
<xsl:with-param name="list"><xsl:value-of select="$Hazards"/></xsl:with-param>
</xsl:call-template>
</xsl:variable>
<xsl:value-of select="concat('[', $HazardList, ']')"/>
</xsl:attribute>
</reference>
</xsl:if>
<!-- Project Themes -->
<xsl:if test="$Themes!=''">
<!-- Embedded within record -->
<reference field="multi_theme_id" resource="project_theme">
<xsl:attribute name="tuid">
<xsl:variable name="ThemeList">
<xsl:call-template name="quoteList">
<xsl:with-param name="prefix"><xsl:value-of select="$ThemePrefix"/></xsl:with-param>
<xsl:with-param name="list"><xsl:value-of select="$Themes"/></xsl:with-param>
</xsl:call-template>
</xsl:variable>
<xsl:value-of select="concat('[', $ThemeList, ']')"/>
</xsl:attribute>
</reference>
</xsl:if>
<!-- As link-table/tab -->
<xsl:for-each select="col[starts-with(@field, 'Theme')]">
<xsl:variable name="Theme" select="normalize-space(substring-after(@field, ':'))"/>
<xsl:variable name="Percentage" select="text()"/>
<xsl:if test="$Theme!=''">
<xsl:if test="$Percentage!=''">
<resource name="project_theme_percentage">
<reference field="theme_id" resource="project_theme">
<xsl:attribute name="tuid">
<xsl:value-of select="concat($ThemePrefix, $Theme)"/>
</xsl:attribute>
</reference>
<data field="percentage"><xsl:value-of select="$Percentage"/></data>
</resource>
</xsl:if>
</xsl:if>
</xsl:for-each>
<!-- Project Organisations -->
<!-- Embedded within record -->
<reference field="organisation_id" resource="org_organisation">
<xsl:attribute name="tuid">
<xsl:value-of select="concat('ProjectOrganisation:', $OrgName)"/>
</xsl:attribute>
</reference>
<!-- As link-table on Tab -->
<resource name="project_organisation">
<!-- Host Organisation -->
<data field="role">1</data>
<reference field="organisation_id" resource="org_organisation">
<xsl:attribute name="tuid">
<xsl:value-of select="concat('ProjectOrganisation:', $OrgName)"/>
</xsl:attribute>
</reference>
</resource>
<!-- Project Budgets -->
<xsl:variable name="Currency" select="col[@field='Currency']"/>
<xsl:for-each select="col[starts-with(@field, 'Budget')]">
<xsl:variable name="Amount" select="text()"/>
<xsl:if test="$Amount!=''">
<resource name="project_annual_budget">
<data field="year"><xsl:value-of select="normalize-space(substring-after(@field, ':'))"/></data>
<data field="amount"><xsl:value-of select="$Amount"/></data>
<data field="currency_type"><xsl:value-of select="$Currency"/></data>
</resource>
</xsl:if>
</xsl:for-each>
<!-- Focal Point -->
<xsl:if test="$FirstName!=''">
<reference field="human_resource_id" resource="hrm_human_resource">
<xsl:attribute name="tuid">
<xsl:value-of select="concat('HR:', $LastName, ',', $FirstName)"/>
</xsl:attribute>
</reference>
</xsl:if>
</resource>
<xsl:call-template name="splitList">
<xsl:with-param name="list"><xsl:value-of select="$Sectors"/></xsl:with-param>
<xsl:with-param name="arg">sector</xsl:with-param>
</xsl:call-template>
<xsl:call-template name="splitList">
<xsl:with-param name="list"><xsl:value-of select="$Hazards"/></xsl:with-param>
<xsl:with-param name="arg">hazard</xsl:with-param>
</xsl:call-template>
<xsl:call-template name="splitList">
<xsl:with-param name="list"><xsl:value-of select="$Themes"/></xsl:with-param>
<xsl:with-param name="arg">theme</xsl:with-param>
</xsl:call-template>
<xsl:if test="$FirstName!=''">
<xsl:call-template name="FocalPerson"/>
</xsl:if>
</xsl:template>
<!-- ****************************************************************** -->
<xsl:template name="resource">
<xsl:param name="item"/>
<xsl:param name="arg"/>
<xsl:choose>
<!-- Country reference list -->
<xsl:when test="$arg='countrycode'">
<xsl:variable name="CountryCode">
<xsl:choose>
<xsl:when test="string-length($item)!=2">
<xsl:call-template name="countryname2iso">
<xsl:with-param name="country">
<xsl:value-of select="$item"/>
</xsl:with-param>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$item"/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:value-of select="concat(',"', 'urn:iso:std:iso:3166:-1:code:', $CountryCode, '"')"/>
</xsl:when>
<!-- Sector list -->
<xsl:when test="$arg='sector'">
<resource name="org_sector">
<xsl:attribute name="tuid">
<xsl:value-of select="concat($SectorPrefix, $item)"/>
</xsl:attribute>
<data field="name"><xsl:value-of select="$item"/></data>
<data field="abrv"><xsl:value-of select="$item"/></data>
</resource>
</xsl:when>
<!-- Hazard list -->
<xsl:when test="$arg='hazard'">
<resource name="project_hazard">
<xsl:attribute name="tuid">
<xsl:value-of select="concat($HazardPrefix, $item)"/>
</xsl:attribute>
<data field="name"><xsl:value-of select="$item"/></data>
</resource>
</xsl:when>
<!-- Theme list -->
<xsl:when test="$arg='theme'">
<resource name="project_theme">
<xsl:attribute name="tuid">
<xsl:value-of select="concat($ThemePrefix, $item)"/>
</xsl:attribute>
<data field="name"><xsl:value-of select="$item"/></data>
</resource>
</xsl:when>
</xsl:choose>
</xsl:template>
<!-- ****************************************************************** -->
<xsl:template name="Organisation">
<xsl:variable name="OrgName" select="col[@field='Organisation']/text()"/>
<resource name="org_organisation">
<xsl:attribute name="tuid">
<xsl:value-of select="concat('ProjectOrganisation:', $OrgName)"/>
</xsl:attribute>
<data field="name"><xsl:value-of select="$OrgName"/></data>
</resource>
</xsl:template>
<!-- ****************************************************************** -->
<xsl:template name="Status">
<xsl:variable name="Status" select="col[@field='Status']/text()"/>
<resource name="project_status">
<xsl:attribute name="tuid">
<xsl:value-of select="$Status"/>
</xsl:attribute>
<data field="name"><xsl:value-of select="$Status"/></data>
</resource>
</xsl:template>
<!-- ****************************************************************** -->
<xsl:template name="Theme">
<xsl:variable name="Theme" select="normalize-space(substring-after(@field, ':'))"/>
<xsl:if test="$Theme!=''">
<resource name="project_theme">
<xsl:attribute name="tuid">
<xsl:value-of select="concat($ThemePrefix, $Theme)"/>
</xsl:attribute>
<data field="name"><xsl:value-of select="$Theme"/></data>
</resource>
</xsl:if>
</xsl:template>
<!-- ****************************************************************** -->
<xsl:template name="FocalPerson">
<xsl:variable name="FirstName" select="col[@field='FPFirstName']/text()"/>
<xsl:variable name="LastName" select="col[@field='FPLastName']/text()"/>
<xsl:variable name="Email" select="col[@field='FPEmail']/text()"/>
<xsl:variable name="MobilePhone" select="col[@field='FPMobilePhone']/text()"/>
<xsl:variable name="OrgName" select="col[@field='Organisation']/text()"/>
<resource name="pr_person">
<xsl:attribute name="tuid">
<xsl:value-of select="concat('Person:', $LastName, ',', $FirstName)"/>
</xsl:attribute>
<data field="first_name"><xsl:value-of select="$FirstName"/></data>
<data field="last_name"><xsl:value-of select="$LastName"/></data>
<xsl:if test="$Email!=''">
<resource name="pr_contact">
<data field="contact_method" value="EMAIL"/>
<data field="value"><xsl:value-of select="$Email"/></data>
</resource>
</xsl:if>
<xsl:if test="$MobilePhone!=''">
<resource name="pr_contact">
<data field="contact_method" value="SMS"/>
<data field="value"><xsl:value-of select="$MobilePhone"/></data>
</resource>
</xsl:if>
</resource>
<resource name="hrm_human_resource">
<xsl:attribute name="tuid">
<xsl:value-of select="concat('HR:', $LastName, ',', $FirstName)"/>
</xsl:attribute>
<data field="type">1</data> <!-- Staff -->
<!-- Link to Organisation -->
<reference field="organisation_id" resource="org_organisation">
<xsl:attribute name="tuid">
<xsl:value-of select="concat('ProjectOrganisation:', $OrgName)"/>
</xsl:attribute>
</reference>
<reference field="person_id" resource="pr_person">
<xsl:attribute name="tuid">
<xsl:value-of select="concat('Person:', $LastName, ',', $FirstName)"/>
</xsl:attribute>
</reference>
</resource>
</xsl:template>
<!-- ****************************************************************** -->
</xsl:stylesheet>