Sugar for collections

[alari]

Fixes #273

This pull request introduces a new syntax to the Aqua language that helps to create collections.

Make an array

Syntax: [a, b, ...] -> []intersection type of a, b, ...

Creates a stream, writes all values into that stream, and than canonicalizes the stream into a scalar array.

--- old way:
func makeArray(a: string, b: string, c: string) -> []string:
  result: *string

  result <<- a
  result <<- b
  result <<- c

  <- result

-- new way:
func makeArray(a: string, b: string, c: string) -> []string:
  <- [a, b, c]

Make an option

Syntax: ?[a, b, ...] -> ?intersection type of a, b, ...

Tries to yield values one by one, once a value yields, stops calculations. The result can have no more than 1 element.

--- old way:
func makeOption(a: ?u32, b: ?u32) -> ?u32:
  result: *u32
  try:
    result <<- a!
  otherwise:
    try:
      result <<- b!

  <- result

-- new way:
func makeOption(a: ?u32, b: ?u32) -> ?u32:
  <- ?[a!, b!]

Make a stream

Syntax: *[a, b, ...] -> *intersection type of a, b, ...

Creates a stream and fulfills it with values, pushing them one by one.

--- old way:
func makeStream(a: bool, b: bool, c: bool) -> *bool:
  result: *bool

  result <<- a
  result <<- b
  result <<- c
  result <<- true

  <- result

-- new way:
func makeStream(a: bool, b: bool, c: bool) -> *bool:
  <- *[a, b, c, true]

---

All these expressions can be used in any place where you can put a value. E.g.:

--- Should work
for x <- [1, 2, 3]: ...

--- Should work
z <- foo(?[a, b, c])

--- and so on