Refactor GTK-related autoconf checks

- Move to separate file geany-gtk.m4
- Merge gthread checks into the main gtk ones

configure.ac

@@ -88,24 +88,7 @@ AC_CHECK_DECLS([_NSGetEnviron],,,[[#include <crt_externs.h>]])
 GEANY_CHECK_REVISION([dnl force debug mode for a VCS working copy
 					  CFLAGS="-g -DGEANY_DEBUG $CFLAGS"])
 
-# GTK/GLib/GIO checks
-gtk_modules="gtk+-3.0 >= 3.0 glib-2.0 >= 2.32"
-gtk_modules_private="gio-2.0 >= 2.32 gmodule-no-export-2.0"
-PKG_CHECK_MODULES([GTK], [$gtk_modules $gtk_modules_private])
-AC_SUBST([DEPENDENCIES], [$gtk_modules])
-AS_VAR_APPEND([GTK_CFLAGS], [" -DGLIB_VERSION_MIN_REQUIRED=GLIB_VERSION_2_32"])
-dnl Disable all GTK deprecations
-AS_VAR_APPEND([GTK_CFLAGS], [" -DGDK_DISABLE_DEPRECATION_WARNINGS"])
-AC_SUBST([GTK_CFLAGS])
-AC_SUBST([GTK_LIBS])
-GTK_VERSION=`$PKG_CONFIG --modversion gtk+-3.0`
-AC_SUBST([GTK_VERSION])
-GEANY_STATUS_ADD([Using GTK version], [${GTK_VERSION}])
-# GTHREAD checks
-gthread_modules="gthread-2.0"
-PKG_CHECK_MODULES([GTHREAD], [$gthread_modules])
-AC_SUBST([GTHREAD_CFLAGS])
-AC_SUBST([GTHREAD_LIBS])
+GEANY_CHECK_GTK
 
 # --disable-deprecated switch for GTK purification
 AC_ARG_ENABLE([deprecated],

m4/geany-gtk.m4

@@ -0,0 +1,18 @@
+dnl GEANY_CHECK_GTK
+dnl Checks whether the GTK stack is available and new enough. Sets GTK_CFLAGS and GTK_LIBS.
+AC_DEFUN([GEANY_CHECK_GTK],
+[
+	gtk_modules="gtk+-3.0 >= 3.0 glib-2.0 >= 2.32"
+	gtk_modules_private="gio-2.0 >= 2.32 gmodule-no-export-2.0 gthread-2.0"
+
+	PKG_CHECK_MODULES([GTK], [$gtk_modules $gtk_modules_private])
+	AC_SUBST([DEPENDENCIES], [$gtk_modules])
+	AS_VAR_APPEND([GTK_CFLAGS], [" -DGLIB_VERSION_MIN_REQUIRED=GLIB_VERSION_2_32"])
+	dnl Disable all GTK deprecations
+	AS_VAR_APPEND([GTK_CFLAGS], [" -DGDK_DISABLE_DEPRECATION_WARNINGS"])
+	AC_SUBST([GTK_CFLAGS])
+	AC_SUBST([GTK_LIBS])
+	AC_SUBST([GTK_VERSION],[`$PKG_CONFIG --modversion gtk+-3.0`])
+
+	GEANY_STATUS_ADD([Using GTK version], [${GTK_VERSION}])
+])