-
Notifications
You must be signed in to change notification settings - Fork 9
/
calculus.clj
1299 lines (1150 loc) · 54.6 KB
/
calculus.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(ns fastmath.calculus
"Integration and derivatives
Integrate univariate and multivariate functions.
* VEGAS / VEGAS+ - Monte Carlo integration of multivariate function
* h-Cubature - h-adaptive integration of multivariate function
* Guass-Kronrod and Gauss-Legendre - quadrature integration of univariate functions
* Romberg, Simpson, MidPoint and Trapezoid
Integrant is substituted in case of improper integration bounds.
Derivatives (finite differences method):
* derivatives of any degree and any order of accuracy
* gradient and hessian for multivariate functions"
(:require [fastmath.core :as m]
[fastmath.random :as r]
[fastmath.vector :as v]
[fastmath.stats :as stats]
[clojure.math.combinatorics :as combo])
(:import [org.apache.commons.math3.analysis UnivariateFunction]
[org.apache.commons.math3.analysis.integration UnivariateIntegrator
IterativeLegendreGaussIntegrator MidPointIntegrator
RombergIntegrator SimpsonIntegrator TrapezoidIntegrator
BaseAbstractUnivariateIntegrator]
[java.util TreeSet Comparator]
[fastmath.vector Vec2 Vec3]
[org.apache.commons.math3.linear Array2DRowRealMatrix LUDecomposition ArrayRealVector
EigenDecomposition]
[org.apache.commons.math3.exception MaxCountExceededException TooManyEvaluationsException]
[fastmath.java Array]))
#_(set! *warn-on-reflection* true)
#_(set! *unchecked-math* :warn-on-boxed)
(defn- subst-upper
[f ^double lower]
(fn [^double t]
(let [inv (m// (m/- 1.0 t))]
(m/* ^double (f (m/+ lower (m/* t inv))) (m/sq inv)))))
(defn- subst-lower
[f ^double upper]
(fn [^double t]
(let [inv (m// (m/inc t))]
(m/* ^double (f (m/+ upper (m/* t inv))) (m/sq inv)))))
(defn- subst-both
[f]
(fn [^double t]
(let [t2 (m/* t t)
den (m// (m/- 1.0 t2))]
(m/* ^double (f (m/* t den))
(m/* (m/inc t2)
(m/sq den))))))
(defn- subst-1d
"Substitute integrant and bounds for improper integrals, 1-d version"
[f ^double lower ^double upper]
(cond
(and (m/neg-inf? lower)
(m/pos-inf? upper)) [(subst-both f)
(m/next-double -1.0)
(m/prev-double 1.0)]
(m/neg-inf? lower) [(subst-lower f upper)
(m/next-double -1.0) 0.0]
(m/pos-inf? upper) [(subst-upper f lower)
0.0 (m/prev-double 1.0)]
:else [f lower upper]))
;; multivariate
(defn- subst-upper-v [^double lower] (fn [^double vi] (m/+ lower (m// vi (m/- 1.0 vi)))))
(defn- subst-lower-v [^double upper] (fn [^double vi] (m/+ upper (m// vi (m/+ 1.0 vi)))))
(defn- subst-both-v ^double [^double vi] (m// vi (m/- 1.0 (m/* vi vi))))
(defn- subst-multiplier-upper ^double [^double vi] (m// (m/sq (m/- 1.0 vi))))
(defn- subst-multiplier-lower ^double [^double vi] (m// (m/sq (m/+ 1.0 vi))))
(defn- subst-multiplier-both ^double [^double vi] (let [vi2 (m/* vi vi)]
(m// (m/+ 1.0 vi2)
(m/sq (m/- 1.0 vi2)))))
(defn- subst-multi-
[lower upper]
(let [[subst-v subst-m nbounds]
(->> (map (fn [^double a ^double b]
(cond
(and (m/inf? a)
(m/inf? b)) [subst-both-v subst-multiplier-both [-1.0 1.0]]
(m/neg-inf? a) [(subst-lower-v b) subst-multiplier-lower [-1.0 0.0]]
(m/pos-inf? b) [(subst-upper-v a) subst-multiplier-upper [0.0 1.0]]
:else [identity (constantly 1.0) [a b]])) lower upper)
(apply map vector))]
[(fn [v] (mapv (fn [f ^double vi] (f vi)) subst-v v))
(fn [v] (->> (mapv (fn [f ^double vi] (f vi)) subst-m v)
(reduce m/fast*)))
(apply map vector nbounds)]))
(defn- subst-multi
"Substitute integrant and bounds for improper integrals, multivariate version"
[f lower upper]
(if (and (every? m/valid-double? lower)
(every? m/valid-double? upper))
[f lower upper]
(let [[subst-v multiplier [nlower nupper]] (subst-multi- lower upper)]
[(fn [v]
(let [nv (subst-v v)
^double m (multiplier v)]
(m/* m ^double (f nv))))
nlower nupper])))
;; vegas / vegas+
;; https://arxiv.org/pdf/2009.05112.pdf
;; https://github.com/ranjanan/MonteCarloIntegration.jl/blob/master/src/vegas.jl
(defn- vegas-build-initial-grid
[lower upper ^long nintervals]
(let [pairs (map vector lower upper)]
[(mapv (fn [[^double lb ^double ub]]
(m/seq->double-array (m/slice-range lb ub (m/inc nintervals)))) pairs)
(mapv (fn [[^double lb ^double ub]]
(m/seq->double-array (repeat nintervals (m// (m/- ub lb) nintervals)))) pairs)]))
(defn- vegas-random-sequence
[^long dims {:keys [random-sequence ^double jitter]
:or {random-sequence :uniform jitter 0.75}}]
(if (and (not (= random-sequence :uniform))
(m/pos? jitter))
(r/jittered-sequence-generator random-sequence dims jitter)
(r/sequence-generator random-sequence dims)))
(defn- Itot-sd
[integrals rev-sigma-squares]
(let [sum-rev-sigma-squares (v/sum rev-sigma-squares)]
[(m// (v/sum (v/emult integrals rev-sigma-squares)) sum-rev-sigma-squares)
(m// (m/sqrt sum-rev-sigma-squares))]))
(defn- normalize-and-compress-d!
[^doubles d ^double sumd ^double alpha]
(dotimes [i (alength d)]
(let [v (m// (aget d i) sumd)]
(aset d i (m/pow (m// (m/- 1.0 v)
(m/log (m// v))) alpha)))))
(defn- smooth-d
[^doubles d ^long nintervals ^double alpha]
(let [nintervals-1 (dec nintervals)
buff (double-array nintervals)
sumd (m/* 8.0 (v/sum d))]
(aset buff 0 (m/+ (m/* 7.0 (aget d 0))
(aget d 1)))
(doseq [^long id (range 1 nintervals-1)]
(aset buff id (m/+ (aget d (dec id))
(m/* 6.0 (aget d id))
(aget d (inc id)))))
(aset buff nintervals-1 (m/+ (aget d (dec nintervals-1))
(m/* 7.0 (aget d nintervals-1))))
(normalize-and-compress-d! buff sumd alpha)
buff))
(defn- calculate-d
[dims Jsf ssamples nintervals alpha]
(let [nevals (count Jsf)
ni (m// nevals (double nintervals))
Jsf22 (mapv (fn [idxs ^double v]
[(int-array idxs) (m// (m/sq v) ni)]) ssamples Jsf)]
(->> (for [dim (range dims)]
(let [buffer (double-array nintervals)]
(run! (fn [in]
(let [id (aget ^ints (in 0) dim)]
(aset buffer id (m/+ (aget buffer id)
(double (in 1)))))) Jsf22)
buffer))
(mapv #(smooth-d % nintervals alpha)))))
(defn- update-grid-dim [^doubles x ^doubles dx ^doubles d ^long nintervals]
(let [cx (count x)
end (m/dec cx)
buff (double-array cx)
delta-d (stats/mean d)]
(aset buff 0 (aget x 0))
(aset buff end (aget x end))
(loop [i (long 1)
j (long 0)
sd 0.0]
(when (m/< i nintervals)
(let [^Vec2 nj-nsd (loop [nsd sd
nj j]
(if (m/< nsd delta-d)
(recur (m/+ nsd (aget d nj))
(m/inc nj))
(Vec2. nj nsd)))
nj (long (.x nj-nsd))
nsd (.y nj-nsd)
nsd (m/- nsd delta-d)
nj- (m/dec nj)]
(aset buff i (m/- (aget x nj)
(m// (m/* nsd (aget dx nj-))
(aget d nj-))))
(recur (m/inc i) (long nj) nsd))))
buff))
(defn- calc-dx [x]
(m/seq->double-array (map (fn [[^double a ^double b]]
(m/- b a)) (partition 2 1 x))))
(defn- update-grid [xs dxs ds ^long nintervals]
(let [nxs (mapv (fn [x dx d]
(update-grid-dim x dx d nintervals)) xs dxs ds)
ndxs (mapv calc-dx nxs)]
[nxs ndxs]))
;; strata
(defn- stratifications-number
"Calculate optimal number of stratas per dimension, eq 41"
^long [^long nev ^long dims]
(-> (m// nev 4.0)
(m/pow (m// dims))
(m/floor)
(unchecked-int)
(m/max 1)))
(defn- ensure-bins-count
"Make grid size divisible by number of stratas, comment to eq 41"
^long [^long nintervals ^long nst]
(if (m/zero? (m/mod nintervals nst))
nintervals
(m/* (m/inc (m// nintervals nst)) nst)))
(defn- reshape-hypercube [hc] (apply mapv vector hc))
(defn- volume
^double [[left right]]
(->> (map m/fast- right left)
(reduce m/fast*)))
(defn- build-hypercubes
[{:keys [nstrats ^long nevals ^long nintervals ^long dims]
:or {nstrats -1 nintervals 1000}}]
(let [nstrats (->> (cond
(= -1 nstrats) [(stratifications-number nevals dims)]
(number? nstrats) [(m/max 1 (unchecked-long nstrats))]
(sequential? nstrats) (map unchecked-long nstrats)
:else [(stratifications-number nevals dims)])
(cycle)
(take dims))
nintervals (->> nstrats
(reduce m/lcm)
(ensure-bins-count nintervals))
strata-1d (map (fn [^long n]
(->> (m/slice-range 0.0 1.0 (inc n))
(partition 2 1)))
nstrats)
hypercubes (->> strata-1d
(apply combo/cartesian-product)
(map reshape-hypercube))
nhcubes (count hypercubes)
nhs (repeat nhcubes (-> (m// nevals (double nhcubes))
(m/floor)
(unchecked-int)
(m/+ 2)))]
{:nstrats nstrats
:nintervals nintervals
:nhs nhs
:hcubes hypercubes
:nhcubes nhcubes
:volume (volume (first hypercubes))}))
(defn- random-sequence-samples
[random-sequence hcubes nhs ^long nhcubes]
(if (m/one? nhcubes)
(split-at (first nhs) random-sequence)
(loop [[nh & rest-nhs] nhs
[[left right] & rest-hcubes] hcubes
rs random-sequence
res []]
(if left
(let [[samples rest-samples] (split-at nh rs)
interpolated (map (partial v/einterpolate left right) samples) ]
(recur rest-nhs rest-hcubes rest-samples (conj res interpolated)))
[(mapcat identity res) rs]))))
(defn- sigmas-in-hypercubes-and-integral-mc
[Jsf nhs ^double volume]
(loop [jsf Jsf
[^long nh & nhrest] nhs
sigmas []
Imc 0.0]
(if (seq jsf)
(let [[jsf0 rst] (split-at nh jsf)
fdv (map (fn [^double jsf] (m/* jsf volume)) jsf0)
fdv-sum (v/sum fdv)
fdv2-sum (v/sum (map m/sq fdv))
I (m// fdv-sum nh)
nsigmas (conj sigmas (m/+ (m/abs (m/- (m// fdv2-sum nh) (m/* I I)))
m/EPSILON))]
(recur rst nhrest nsigmas (m/+ Imc I)))
[sigmas Imc])))
(defn- recalculate-nhs
[hcsigmas ^long nevals ^double hbeta]
(let [dhs (->> hcsigmas
(map (fn [^double s] (m/pow s hbeta))))
dhssum (v/sum dhs)]
(map (fn [^double dh]
(unchecked-int (m/+ (m/floor (m/* nevals (m// dh dhssum))) 2))) dhs)))
;;
(defn vegas
"VEGAS+ - Monte Carlo integration of multivariate function, n>1 dimensions.
Improper integrals with infinite bounds are handled by a substitution.
Arguments:
* `f` - integrant
* `lower` - seq of lower bounds
* `upper` - seq of upper bounds
Additional options:
* `:max-iters` - maximum number of iterations, default: 10
* `:nevals` - number of evaluations per iteration, default: 10000
* `:nintervals` - number of grid intervals per dimension (default: 1000)
* `:nstrats` - number of stratifications per dimension (calculated)
* `:warmup` - number of warmup iterations (results are used to train stratification and grid spacings, default: 0
* `:alpha` - grid refinement parameter, 0.5 slow (default for vegas+), 1.5 moderate/fast (defatult for vegas)
* `:beta` - stratification damping parameter for startification adaptation, default: 0.75
* `:rel` - relative accuracy, default: 5.0e-4
* `:abs` - absolute accuracy, default: 5.0e-4
* `:random-sequence` - random sequence used for generating samples: `:uniform` (default), low-discrepancy sequences: `:r2`, `:sobol` and `:halton`.
* `:jitter` - jittering factor for low-discrepancy random sequence, default: 0.75
* `:info?` - return full information about integration, default: false
* `:record-data?` - stores samples, number of strata, x and dx, default: false (requires, `:info?` to be set to `true`)
For original VEGAS algorithm set `:nstrats` to `1`.
`:nstrats` can be also a list, then each dimension is divided independently according to a given number. If list is lower then number of dimensions, then it's cycled.
Function returns a map with following keys (if info? is true, returns result otherwise):
* `:result` - value of integral
* `:iterations` - number of iterations (excluding warmup)
* `:sd` - standard deviation of results
* `:nintervals` - actual grid size
* `:nstrats` - number of stratitfications per dimension
* `:nhcubes` - number of hypercubes
* `:evaluations` - number of function calls
* `:chi2-avg` - average of chi2
* `:dof` - degrees of freedom
* `:Q` - goodness of fit indicator, 1 - very good, <0.25 very poor
* `:data` - recorded data (if available)"
([f lower upper] (vegas f lower upper nil))
([f lower upper {:keys [^long max-iters ^double rel ^double abs ^long nevals
alpha ^double beta ^long warmup info? record-data?]
:or {max-iters 10 rel 5.0e-4 abs 5.0e-4 nevals 10000 beta 0.75 warmup 0
info? false record-data? false}
:as options}]
(let [[f lower upper] (subst-multi f lower upper)
dims (count lower)
max-iters (m/+ (m/max 1 max-iters)
(m/max 0 warmup))
random-sequence (vegas-random-sequence dims options)
{:keys [^long nintervals nstrats ^long nhcubes
hcubes nhs ^double volume]} (build-hypercubes (assoc options
:dims dims
:nevals nevals))
;; lower damping alpha for statified sampling
alpha (double (or alpha (if (and (= (count nstrats) 1)
(= (first nstrats) 1)) 1.5 0.5)))
hbeta (m// beta 2.0)]
(loop [iter (long 1)
evaluations (long 1)
[x dx] (vegas-build-initial-grid lower upper nintervals)
random-sequence random-sequence
nhs nhs
integrals []
rev-sigma-squares []
data []]
(let [[samples rst] (random-sequence-samples random-sequence hcubes nhs nhcubes)
scaled-samples (mapv #(v/mult % nintervals) samples)
ndata (when (and record-data? info?)
(conj data {:x x :dx dx :nhs nhs
:samples (map (fn [ys]
(mapv (fn [^doubles ax ^doubles adx ^double ny]
(let [iy (unchecked-int ny)]
(m/+ (Array/get ^doubles ax iy)
(m/* (Array/get adx iy)
(m/frac ny))))) x dx ys)) scaled-samples)}))
buff (double-array dims)
Jsf (mapv (fn [ys]
(loop [dim (long 0)
Js 1.0]
(if (m/< dim dims)
(let [ny (double (ys dim))
iy (unchecked-int ny)
^doubles adx (dx dim)]
;; write mapped y->x to a buffer
(aset ^doubles buff dim (m/+ (Array/get ^doubles (x dim) iy)
(m/* (Array/get adx iy)
(m/frac ny))))
(recur (m/inc dim)
;; calculate Jacobian
(m/* Js nintervals (Array/get adx iy))))
(m/* Js (double (f buff))))))
scaled-samples)
real-calls (count Jsf)
evaluations (+ evaluations real-calls)
[hcsigmas integral-mc] (sigmas-in-hypercubes-and-integral-mc Jsf nhs volume)
nhs (recalculate-nhs hcsigmas nevals hbeta) ]
(if (m/<= iter warmup)
(let [d (calculate-d dims Jsf scaled-samples nintervals alpha)
x-dx (update-grid x dx d nintervals)]
(recur (m/inc iter) evaluations
x-dx rst nhs integrals rev-sigma-squares ndata))
(let [variance-mc (m/+ (v/sum (map (fn [^double s ^double nh]
(m// s nh)) hcsigmas nhs)))
new-integrals (conj integrals integral-mc)
new-rev-sigma-squares (conj rev-sigma-squares (m// variance-mc))
[^double Itot ^double sd] (Itot-sd new-integrals new-rev-sigma-squares)]
(if (or (m/== iter max-iters)
(and (m/< (m/abs (m// sd Itot)) rel)
(m/< (m/abs sd) abs)))
(if info?
(let [chisq (-> new-integrals
(v/shift (m/- Itot))
(v/sq)
(v/emult new-rev-sigma-squares)
(v/sum))
dof (m/dec (count new-integrals))
res {:iterations (m/- iter warmup)
:result Itot
:sd sd
:nintervals nintervals
:nstrats nstrats
:nhcubes nhcubes
:evaluations evaluations
:chi2-avg (/ chisq dof)
:dof dof
:Q (m/regularized-gamma-q (m// dof 2.0) (m// chisq 2.0))}]
(if record-data?
(assoc res :data ndata :hcubes hcubes)
res))
Itot)
(let [d (calculate-d dims Jsf scaled-samples nintervals alpha)
x-dx (update-grid x dx d nintervals)]
(recur (m/inc iter) evaluations
x-dx rst nhs new-integrals new-rev-sigma-squares ndata))))))))))
;;
;; hcubature
;; https://github.com/JuliaMath/HCubature.jl/blob/master/src/HCubature.jl
;; https://www.sciencedirect.com/science/article/pii/0771050X8090039X
(defn- combos
[^long k ^double lambda ^long n]
(mapv vec (combo/permutations (concat (repeat k lambda)
(repeat (m/- n k) 0.0)))))
(defn- signcombos
[^long k ^double lambda ^long n]
(->> (apply combo/cartesian-product (repeat k [lambda (m/- lambda)]))
(map (partial concat (repeat (m/- n k) 0.0)))
(mapcat combo/permutations)
(distinct)
(mapv vec)))
(defn- genz-malik-
[^long n]
(let [twon (m/<< 1 n)]
{:p [(combos 1 0.35856858280031806 n) ;; sqrt(9/70)
(combos 1 0.9486832980505138 n) ;; sqrt(9/10)
(signcombos 2 0.9486832980505138 n) ;; sqrt(9/10)
(signcombos n 0.6882472016116853 n)] ;; sqrt(9/19)
:w [(m/* twon (m// (m/+ 12824.0
(m/* -9120.0 n)
(m/* 400.0 n n)) 19683.0))
(m/* twon 0.14936747447035512) ;; 980/6561
(m/* twon (m// (m/- 1820.0 (m/* 400.0 n)) 19683.0))
(m/* twon 0.010161052685058172) ;; 200/19683
0.34847330183407] ;; 6859/19683
:w' (v/mult [(m// (m/+ 729.0 (m/* -950 n) (m/* 50.0 n n)) 729.0)
0.5041152263374485 ;; 245/486
(m// (m/- 265.0 (m/* 100.0 n)) 1458.0)
0.03429355281207133] ;; 25/729
twon)
:gm-evals (m/inc (m/+ (m/* 4 n)
(m/* 2 n (m/dec n))
(m/<< 1 n)))}))
(def ^:private genz-malik (memoize genz-malik-))
(deftype CubatureBox [a b ^double I ^double E ^long kdiv])
(defn- integrate-gm
^CubatureBox [f lower upper dims gp1 gp2 gp3 gp4 w w']
(let [c (v/mult (v/add lower upper) 0.5)
delta (vec (v/mult (v/abs (v/sub upper lower)) 0.5))
V (v/prod delta)
^double f1 (f c)
twelfef1 (m/* 12.0 f1)
f23s (map (fn [^long i]
(let [p2 (v/emult delta (gp1 i))
f2i (m/+ ^double (f (v/add c p2))
^double (f (v/sub c p2)))
p3 (v/emult delta (gp2 i))
f3i (m/+ ^double (f (v/add c p3))
^double (f (v/sub c p3)))]
(Vec2. f2i f3i))) (range dims))
divdiff (mapv (fn [^Vec2 v]
(m/abs (m/+ (.y v) twelfef1 (m/* -7.0 (.x v))))) f23s)
^Vec2 f23 (reduce v/add f23s)
f4 (->> gp3
(map #(f (v/add c (v/emult delta %))))
(v/sum))
f5 (->> gp4
(map #(f (v/add c (v/emult delta %))))
(v/sum))
I (m/* V (m/+ (m/* ^double (w 0) f1)
(m/* ^double (w 1) (.x f23))
(m/* ^double (w 2) (.y f23))
(m/* ^double (w 3) f4)
(m/* ^double (w 4) f5)))
I' (m/* V (m/+ (m/* ^double (w' 0) f1)
(m/* ^double (w' 1) (.x f23))
(m/* ^double (w' 2) (.y f23))
(m/* ^double (w' 3) f4)))
E (m/abs (- I I'))
deltaf (m// E (m/* (m/pow 10.0 dims) V))
kdivide (->> (range dims)
(reduce (fn [[^double mx ^long kdv] ^long dim]
(let [^double dd (divdiff dim)
d (m/- dd mx)
pred (m/> d deltaf)
nkdv (if pred dim kdv)
nmx (if pred dd dim)
nkdv (if (and (m/<= (m/abs d) deltaf)
(m/> ^double (delta dim)
^double (delta nkdv))) dim nkdv)]
[nmx nkdv])) [0.0 0])
(second))]
(CubatureBox. lower upper I E kdivide)))
(def ^:private cb-comparator (comparator (fn [^CubatureBox x ^CubatureBox y]
(compare (.E x) (.E y)))))
(defn- enumerate-boxes
[lower upper ^long div]
(->> (map (fn [^double a ^double b]
(->> (m/slice-range a b (m/inc div))
(partition 2 1))) lower upper)
(apply combo/cartesian-product)
(map (partial apply map vector))))
(defn- build-initial-boxes
[f lower upper div dims gp1 gp2 gp3 gp4 w w']
(let [^TreeSet boxes (TreeSet. ^Comparator cb-comparator)]
(doseq [[a b] (enumerate-boxes lower upper div)]
(.add boxes (integrate-gm f a b dims gp1 gp2 gp3 gp4 w w')))
boxes))
(defn- sum-boxes
[boxes]
(reduce (fn [[^double I ^double E] ^CubatureBox b]
[(m/+ I (.I b))
(m/+ E (.E b))]) [0.0 0.0] boxes))
(defn- split-box
[^CubatureBox box]
(let [split-id (.kdiv box)
a (.a box)
b (.b box)
^double ida (a split-id)
^double idb (b split-id)
mid (* 0.5 (m/+ ida idb))]
[a (assoc b split-id mid)
(assoc a split-id mid) b]))
(defn cubature
"Cubature - h-adaptive integration of multivariate function, n>1 dimensions.
Algorithm uses Genz Malik method.
In each iteration a box with biggest error is subdivided and reevaluated.
Improper integrals with infinite bounds are handled by a substitution.
Arguments:
* `f` - integrant
* `lower` - seq of lower bounds
* `upper` - seq of upper bounds
Options:
* `:initvid` - initial subdivision per dimension, default: 2.
* `:max-evals` - maximum number of evaluations, default: max integer value.
* `:max-iters` - maximum number of iterations, default: 64.
* `:rel` - relative error, 1.0e-7
* `:abs` - absolute error, 1.0e-7
* `:info?` - return full information about integration, default: false
Function returns a map containing (if info? is true, returns result otherwise):
* `:result` - integration value
* `:error` - integration error
* `:iterations` - number of iterations
* `:evaluations` - number of evaluations
* `:subdivisions` - final number of boxes
* `:fail?` - set to `:max-evals` or `:max-iters` when one of the limits has been reached without the convergence."
([f lower upper] (cubature f lower upper nil))
([f lower upper {:keys [^double rel ^double abs ^int max-evals ^int max-iters ^int initdiv info?]
:or {rel 1.0e-7 abs 1.0e-7 max-evals Integer/MAX_VALUE max-iters 64 initdiv 2 info? false}}]
(let [[f lower upper] (subst-multi f lower upper)
dims (count lower)
{:keys [^long gm-evals p w w']} (genz-malik dims)
[gp1 gp2 gp3 gp4] p
^TreeSet boxes (build-initial-boxes f lower upper initdiv dims gp1 gp2 gp3 gp4 w w')
initial-evals (m/* gm-evals (count boxes))
[^double I ^double E] (sum-boxes boxes)]
(if (or (m/<= E (m/max (m/* rel (m/abs I)) abs))
(m/>= initial-evals max-evals))
(if info?
{:result I :error E
:evaluations initial-evals
:iterations 1
:subdivisions (count boxes)}
I)
(loop [iters (long 1)
evals initial-evals
I I
E E]
(let [niters (m/inc iters)
nevals (m/+ evals gm-evals)
^CubatureBox max-E-box (.pollLast boxes)
[a1 b1 a2 b2] (split-box max-E-box)
^CubatureBox nbox1 (integrate-gm f a1 b1 dims gp1 gp2 gp3 gp4 w w')
^CubatureBox nbox2 (integrate-gm f a2 b2 dims gp1 gp2 gp3 gp4 w w')
nI (m/+ (.I nbox1) (.I nbox2) (m/- I (.I max-E-box)))
nE (m/+ (.E nbox1) (.E nbox2) (m/- E (.E max-E-box)))
fail? (cond
(m/>= nevals max-evals) :max-evals
(m/>= niters max-iters) :max-iters
:else false)]
(.add boxes nbox1)
(.add boxes nbox2)
(if (or (m/<= nE (m/max (m/* rel (m/abs nI)) abs)) fail?)
(let [[^double I ^double E] (sum-boxes boxes)]
(if info?
{:result I :error E
:evaluations nevals
:iterations niters
:subdivisions (count boxes)
:fail? fail?}
I))
(recur niters nevals nI nE))))))))
;; quadgk
;; https://github.com/JuliaMath/QuadGK.jl/blob/master/src/gausskronrod.jl
;; https://github.com/ESSS/cquadpack/blob/master/src/
(defn- eigpoly
^double [b ^double z]
(let [[^double p
^double pderiv] (reduce (fn [[^double d1 ^double d1deriv ^double d2 ^double d2deriv] ^double Hev]
(let [b2 (m/sq Hev)
a z
d (m/- (m/* a d1)
(m/* b2 d2))
dderiv (m/+ d1 (m/- (m/* a d1deriv)
(m/* b2 d2deriv)))]
[d dderiv d1 d1deriv])) [z 1.0 1.0 0.0] b)]
(m// p pderiv)))
(defn- newton-iterations
[nb ^double lambda]
(reduce (fn [^double lambda _]
(let [dlambda (eigpoly nb lambda)]
(if (m/valid-double? dlambda)
(let [nlambda (m/- lambda dlambda)]
(if (m/< (m/abs dlambda)
(m/ulp nlambda))
(let [dlambda (eigpoly nb nlambda)]
(reduced (if (m/valid-double? dlambda)
(m/- nlambda dlambda)
nlambda)))
nlambda))
(reduced lambda)))) lambda (range 1000)))
(defn- get-quadrature-points
[b ^long n]
(let [cb (count b)
m (m/inc cb)
buff (double-array (m/sq m))]
(doseq [^long i (range cb)
:let [^double v (b i)]]
(Array/set2d buff m i (m/inc i) v)
(Array/set2d buff m (m/inc i) i v))
(let [lambdas (->> buff
(partition m)
(m/seq->double-double-array)
(Array2DRowRealMatrix.)
(EigenDecomposition.)
(.getRealEigenvalues)
(reverse)
(take n))]
(mapv (partial newton-iterations b) lambdas))))
(defn- eigvec
^double [b ^double lambda]
(let [v1 (m// lambda ^double (b 0))]
(->> (partition 2 1 b)
(reduce (fn [[curr ^double v-2 ^double v-1] [^double b-2 ^double b-1]]
(let [newv (m// (m/- (m/* lambda v-1)
(m/* b-2 v-2)) b-1)]
[(conj curr newv) v-1 newv])) [[1.0 v1] 1.0 v1])
(first)
(v/mag)
(m//))))
;; https://github.com/JuliaMath/QuadGK.jl/blob/master/src/gausskronrod.jl#L448-L497
(defn- kronrodjacobi
[b ^long n]
(let [s (vec (repeat (m/+ (m/quot n 2) 2) 0.0))
t (assoc (vec (repeat (count s) 0.0)) 1 (b n))
[s t] (reduce (fn [[s t] ^long m]
[t (->> (range (m/quot (m/inc m) 2) -1 -1)
(reduce (fn [[s ^double u] ^long k]
(let [nu (m/+ u (m/- (m/* ^double (b (m/+ k n))
^double (s k))
(if (m/> m k)
(m/* ^double (b (m/- m k 1))
^double (s (m/inc k)))
0.0)))]
[(assoc s (m/inc k) nu) nu]))
[s 0.0])
(first))])
[s t] (range (m/dec n)))
s (reduce (fn [s ^long j]
(assoc s (m/inc j) (s j))) s (range (m/quot n 2) -1 -1))
nb (->> (range (m/dec n) (m/+ n n -2))
(reduce (fn [[b s t] ^long m]
(let [news (->> (range (m/- m n -1) (m/inc (m/quot (m/dec m) 2)))
(reduce (fn [[s ^double u] ^long k]
(let [j (m/dec (m/- n (m/- m k)))
nu (m/- u (m/- (m/* ^double (b (m/+ k n))
^double (s (m/inc j)))
(m/* ^double (b (m/- m k 1))
^double (s (m/+ j 2)))))]
[(assoc s (m/inc j) nu) nu]))
[s 0.0])
(first))
k (m/quot (m/inc m) 2)
j (m/- n (m/+ (m/- m k) 2))
nb (if (m/not== (m/* 2 k) m)
(assoc b (m/+ k n) (m// ^double (news (m/+ j 1))
^double (news (m/+ j 2))))
b)]
[nb t news]))
[b s t])
(first)
(v/sqrt))
x (get-quadrature-points nb (m/inc n))
w (mapv (fn [^double x] (m/* 2.0 (m/sq (eigvec nb x)))) x)
nb (map-indexed (fn [^long j ^double b]
(let [j (m/inc j)]
(if (m/< j n)
(m// j (m/sqrt (m/dec (m/* 4.0 j j))))
b))) nb)
gw (mapv (fn [^double x]
(m/* 2.0 (m/sq (eigvec (vec (take (m/dec n) nb)) x))))(->> x rest (take-nth 2)))]
{:x x :w w :gw gw :gk-evals (m/+ (m/* 4 n) 2)}))
(defn- kronrod-
[^long n]
(let [last-j (m/quot (m/inc (m/* 3 n)) 2)
b (mapv (fn [^double j]
(if (m/<= j last-j)
(let [j2 (m/sq j)]
(m// j2 (m/dec (m/* 4.0 j2)) ))
0.0)) (range 1 (inc (m/* 2 n))))]
(kronrodjacobi b n)))
(def ^:private kronrod (memoize kronrod-))
(deftype QuadGKSegment [^Vec2 ab ^double I ^double E])
(defn- integrate-gk
^QuadGKSegment [f ^Vec2 ab x w gw]
(let [s (m/* 0.5 (m/- (.y ab) (.x ab)))
lastxw (m/dec (count w))
lastxw- (m/dec lastxw)
lastgw (m/dec (count gw))
n1 (m/- 1 (m/bit-and (m/inc lastxw) 1))
a (.x ab)
^double f0 (f (m/+ a s))
Igk (if (m/zero? n1)
(Vec2. 0.0 (m/* f0 ^double (w lastxw)))
(let [^double x-1 (x lastxw-)]
(Vec2. (m/* f0 ^double (gw lastgw))
(m/+ (m/* f0 ^double (w lastxw))
(m/* (m/+ ^double (f (m/+ a (m/* (m/+ 1.0 x-1) s)))
^double (f (m/+ a (m/* (m/- 1.0 x-1) s))))
^double (w lastxw-))))))
^Vec2 Igk (-> (->> (if (m/zero? n1) gw (butlast gw))
(map-indexed (fn [^long i ^double gwi]
(let [i (m/inc i)
ii (m/dec (m/* 2 i))
ii- (m/dec ii)
^double x2i (x ii)
^double x2i-1 (x ii-)
^double w2i (w ii)
^double w2i-1 (w ii-)
fg (m/+ ^double (f (m/+ a (m/* (m/+ 1.0 x2i) s)))
^double (f (m/+ a (m/* (m/- 1.0 x2i) s))))
fk (m/+ ^double (f (m/+ a (m/* (m/+ 1.0 x2i-1) s)))
^double (f (m/+ a (m/* (m/- 1.0 x2i-1) s))))]
(Vec2. (m/* fg gwi)
(m/+ (m/* fg w2i)
(m/* fk w2i-1))))))
(reduce v/add Igk))
(v/mult s))
E (m/abs (m/- (.y Igk) (.x Igk)))]
(QuadGKSegment. ab (.y Igk) E)))
(def ^:private gk-comparator (comparator (fn [^QuadGKSegment x ^QuadGKSegment y]
(compare (.E x) (.E y)))))
(defn- build-initial-segments
[f lower upper initdiv x w gw]
(let [^TreeSet boxes (TreeSet. ^Comparator gk-comparator)
segments (->> (m/slice-range lower upper (m/inc ^long initdiv))
(partition 2 1))]
(doseq [[a b] segments]
(.add boxes (integrate-gk f (Vec2. a b) x w gw)))
boxes))
(defn- sum-segments
[segments]
(reduce (fn [[^double I ^double E] ^QuadGKSegment s]
[(m/+ I (.I s))
(m/+ E (.E s))]) [0.0 0.0] segments))
(defn- split-segment
[^QuadGKSegment s]
(let [^Vec2 ab (.ab s)
mid (m/* 0.5 (v/sum ab))]
[(Vec2. (.x ab) mid)
(Vec2. mid (.y ab))]))
(defn- integrate-gk-final
([f lower upper] (integrate-gk-final f lower upper nil))
([f lower upper {:keys [^double rel ^double abs ^int max-evals ^int max-iters
^int integration-points ^int initdiv info?]
:or {rel 1.0e-8 abs 1.0e-8 max-evals Integer/MAX_VALUE max-iters 64
integration-points 7 initdiv 1 info? false}}]
(let [{:keys [^long gk-evals x w gw]} (kronrod integration-points)
^TreeSet segments (build-initial-segments f lower upper initdiv x w gw)
initial-evals (m/* gk-evals (count segments))
[^double I ^double E] (sum-segments segments)]
(if (or (m/<= E (m/max (m/* rel (m/abs I)) abs))
(m/>= initial-evals max-evals))
(if info?
{:result I :error E
:evaluations initial-evals
:iterations 1
:subdivisions (count segments)}
I)
(loop [iters (long 1)
evals initial-evals
I I
E E]
(let [niters (m/inc iters)
nevals (m/+ evals gk-evals)
^QuadGKSegment max-E-segment (.pollLast segments)
[ab1 ab2] (split-segment max-E-segment)
^QuadGKSegment nsegment1 (integrate-gk f ab1 x w gw)
^QuadGKSegment nsegment2 (integrate-gk f ab2 x w gw)
nI (m/+ (.I nsegment1) (.I nsegment2) (m/- I (.I max-E-segment)))
nE (m/+ (.E nsegment1) (.E nsegment2) (m/- E (.E max-E-segment)))
fail? (cond
(m/>= nevals max-evals) :max-evals
(m/>= niters max-iters) :max-iters
:else false)]
(.add segments nsegment1)
(.add segments nsegment2)
(if (or (m/<= nE (m/max (m/* rel (m/abs nI)) abs)) fail?)
(let [[^double I ^double E] (sum-segments segments)]
(if info?
{:result I :error E
:evaluations nevals
:iterations niters
:subdivisions (count segments)
:fail? fail?}
I))
(recur niters nevals nI nE))))))))
;;
(defn- make-integrant
[f]
(reify UnivariateFunction
(value [_ x] (f x))))
(defn integrate
"Univariate integration.
Improper integrals with infinite bounds are handled by a substitution.
Arguments:
* `f` - integrant
* `lower` - lower bound
* `upper` - upper bound
Options:
* `:integrator` - integration algorithm, one of: `:romberg`, `:trapezoid`, `:midpoint`, `:simpson`, `:gauss-legendre` and `:gauss-kronrod` (default).
* `:min-iters` - minimum number of iterations (default: 3), not used in `:gauss-kronrod`
* `:max-iters` - maximum number of iterations (default: 32 or 64)
* `:max-evals` - maximum number of evaluations, (default: maximum integer)
* `:rel` - relative error
* `:abs` - absolute error
* `:integration-points` - number of integration (quadrature) points for `:gauss-legendre` and `:gauss-kronrod`, default 7
* `:initdiv` - initial number of subdivisions for `:gauss-kronrod`, default: 1
* `:info?` - return full information about integration, default: false
`:gauss-kronrod` is h-adaptive implementation
Function returns a map containing (if info? is true, returns result otherwise):
* `:result` - integration value
* `:error` - integration error (`:gauss-kronrod` only)
* `:iterations` - number of iterations
* `:evaluations` - number of evaluations
* `:subdivisions` - final number of boxes (`:gauss-kronrod` only)
* `:fail?` - set to `:max-evals` or `:max-iters` when one of the limits has been reached without the convergence."
([f] (integrate f 0.0 1.0))
([f ^double lower ^double upper] (integrate f lower upper nil))
([f ^double lower ^double upper
{:keys [^double rel ^double abs max-iters ^int min-iters ^int max-evals info?
integrator ^long integration-points]
:or {rel BaseAbstractUnivariateIntegrator/DEFAULT_RELATIVE_ACCURACY
abs BaseAbstractUnivariateIntegrator/DEFAULT_ABSOLUTE_ACCURACY
min-iters BaseAbstractUnivariateIntegrator/DEFAULT_MIN_ITERATIONS_COUNT
max-evals Integer/MAX_VALUE
integration-points 7
integrator :gauss-kronrod
info? false}
:as options}]
(let [max-iters (unchecked-int (or max-iters
(case integrator
:romberg RombergIntegrator/ROMBERG_MAX_ITERATIONS_COUNT
:trapezoid TrapezoidIntegrator/TRAPEZOID_MAX_ITERATIONS_COUNT
:midpoint MidPointIntegrator/MIDPOINT_MAX_ITERATIONS_COUNT
:simpson SimpsonIntegrator/SIMPSON_MAX_ITERATIONS_COUNT
:gauss-legendre 64
BaseAbstractUnivariateIntegrator/DEFAULT_MAX_ITERATIONS_COUNT)))
integrator-obj (if (keyword? integrator)
(case integrator
:romberg (RombergIntegrator. rel abs min-iters max-iters)
:trapezoid (TrapezoidIntegrator. rel abs min-iters max-iters)
:midpoint (MidPointIntegrator. rel abs min-iters max-iters)
:simpson (SimpsonIntegrator. rel abs min-iters max-iters)
:gauss-legendre (IterativeLegendreGaussIntegrator. integration-points