nouns.lexc

!! Noun inflection
!  ---------------
!! The Quenya language nouns inflect in cases.


! Standard declensions (nouns that end with -a, -i, -ie, -o, -u)

LEXICON NounSuffix
    +N: Cases ;
    +N:[-Voc] NounNoCase ;

LEXICON NounNoCase  ! number without case, e.g. axor ilcalannar
    +Sing:%>            NounNoCasePost ;
    +Dual:%>t           NounNoCasePost ;
    +Dual:%>{-V}u       NounNoCasePost ;
    +Plur:%>r           NounNoCasePost ;
    +Plur+Par:%>li{+}   NounNoCasePost ;

LEXICON NounNoCasePost
    +Voc:[+Voc] # ;
    :[-Voc] # ;

LEXICON Cases
    CasesNumber ;  ! no possessive suffix
    :| PossessiveSuffix ;

LEXICON CasesNumber
    +Sing:%>        CasesSing ;
    +Dual:%>        CasesDual ;
    +Plur:%>        CasesPlur ;
    +Plur+Par:%>    CasesPlurPar ;

LEXICON CasesSing
    +Nom: # ;
    +Acc: # ;
    +Gen:{o}{+}  # ;
    +Ins:nen{+} # ;
    +All:nna # ;
    +Dat:n # ;
    +Loc:sse # ;
    +Loc+Short:s # ;
    +Abl:llo # ;
    +Poss:{w}a{+} # ;  ! TODO: connect to adjectival endings?

LEXICON CasesDual
    +Nom:t # ;
    +Acc:t # ;
    +Gen:to{+}  # ;
    +Ins:nten # ;
    +All:nta # ;
    +Dat:nt # ;
    +Loc:tse # ;
    ! +Loc+Short:ts # ;  TODO: ???
    +Abl:lto # ;
    +Poss:t{w}a # ;  ! TODO: connect to adjectival endings?
    CasesDual-U ;  ! also go to the dual endings in -u

LEXICON CasesPlur
    +Nom:r # ;
    +Acc:r # ;
    +Gen:ron{+}  # ;
    +Ins:{i}nen # ;
    +All:nnar # ;
    +Dat:{i}n # ;
    +Loc:ssen # ;
    +Loc+Short:{i}s # ;
    +Abl:llon # ;
    +Abl:llor # ;  ! alternate ending
    +Poss:{i}{w}a # ;  ! TODO: connect to adjectival endings?

LEXICON CasesPlurPar
    +Nom:li{+} # ;
    +Acc:li{+} # ;
    +Gen:lion  # ;
    +Ins:línen # ;
    +All:linna # ;  ! r is optional for allative
    +All:linnar # ;
    +Dat:lin{+} # ;
    +Loc:lisse # ;  ! n is optional for locative
    +Loc:lissen # ;
    +Loc+Short:lis{+} # ;
    +Abl:lillo # ;  ! n/r is optional for ablative
    +Abl:lillon # ;
    +Abl:lillor # ;  ! alternate ending
    +Poss:lí{w}a # ;  ! TODO: connect to adjectival endings?


! -e declensions (nouns that end with -e)

LEXICON NounSuffix-E
    +N: Cases-E ;
    +N: NounNoCase-E ;

LEXICON NounNoCase-E  ! number without case, e.g. axor ilcalannar
    +Sing:%> # ;
    +Dual:%>t # ;
    +Dual:%>{-V}u # ;
    +Plur:%>{i} # ;
    +Plur+Par:%>li # ;

LEXICON Cases-E
    CasesNumber-E ;  ! no possessive suffix
    :| PossessiveSuffix ;

LEXICON CasesNumber-E
    +Sing:%>        CasesSing-E ;
    +Dual:%>        CasesDual-E ;
    +Plur:%>        CasesPlur-E ;
    +Plur+Par:%>    CasesPlurPar-E ;

LEXICON CasesSing-E
    +Nom: # ;
    +Acc: # ;
    +Gen:o  # ;
    +Ins:nen # ;
    +All:nna # ;
    +Dat:n # ;
    +Loc:sse # ;
    +Loc+Short:s # ;
    +Abl:llo # ;
    +Poss:{w}a # ;  ! TODO: connect to adjectival endings?

LEXICON CasesDual-E
    +Nom:t # ;
    +Acc:t # ;
    +Gen:to  # ;
    +Ins:nten # ;
    +All:nta # ;
    +Dat:nt # ;
    +Loc:tse # ;
    ! +Loc+Short:ts # ;  TODO: ???
    +Abl:lto # ;
    +Poss:t{w}a # ;  ! TODO: connect to adjectival endings?
    CasesDual-U ;  ! also go to the dual endings in -u

LEXICON CasesPlur-E
    +Nom:{i} # ;
    +Acc:{i} # ;
    +Gen:{i}on  # ;
    +Ins:{í}nen # ;
    +All:nnar # ;
    +Dat:{í}n # ;
    +Loc:ssen # ;
    +Loc+Short:{í}s # ;
    +Abl:llon # ;
    +Abl:llor # ;  ! alternate ending
    +Poss:{í}{w}a # ;  ! TODO: connect to adjectival endings?

LEXICON CasesPlurPar-E
    +Nom:li # ;
    +Acc:li # ;
    +Gen:lion  # ;
    +Ins:línen # ;
    +All:linna # ;  ! r is optional for allative
    +All:linnar # ;
    +Dat:lin # ;
    +Loc:lisse # ;  ! n is optional for locative
    +Loc:lissen # ;
    +Loc+Short:lis # ;
    +Abl:lillo # ;  ! n/r is optional for ablative
    +Abl:lillon # ;
    +Abl:lillor # ;  ! alternate ending
    +Poss:lí{w}a # ;  ! TODO: connect to adjectival endings?


! -Cons declensions (nouns that end with a consonant)

LEXICON NounSuffix-Cons
    +N: Cases-Cons ;
    +N: NounNoCase-Cons ;

LEXICON NounNoCase-Cons  ! number without case, e.g. axor ilcalannar
    +Sing:%> # ;
    +Dual:%>t # ;
    +Dual:%>{-V}u # ;
    +Plur:%>i # ;
    +Plur+Par:%>{l}i # ;

LEXICON Cases-Cons
    CasesNumber-Cons ;  ! no possessive suffix
    :| PossessiveSuffix ;

LEXICON CasesNumber-Cons
    +Sing:%>        CasesSing-Cons ;
    +Dual:%>        CasesDual-Cons ;
    +Plur:%>        CasesPlur-Cons ;
    +Plur+Par:%>    CasesPlurPar-Cons ;

LEXICON CasesSing-Cons
    +Nom: # ;
    +Acc: # ;
    +Gen:o  # ;
    +Ins:nen # ;
    +All:nna # ;
    +Dat:n # ;
    +Loc:sse # ;
    +Loc+Short:s # ;
    +Abl:llo # ;
    +Poss:{w}a # ;  ! TODO: connect to adjectival endings?

LEXICON CasesDual-Cons
    +Nom:t # ;
    +Acc:t # ;
    +Gen:to  # ;
    +Ins:nten # ;
    +All:nta # ;
    +Dat:nt # ;
    +Loc:tse # ;
    ! +Loc+Short:ts # ;  TODO: ???
    +Abl:lto # ;
    +Poss:t{w}a # ;  ! TODO: connect to adjectival endings?
    CasesDual-U ;  ! also go to the dual endings in -u

LEXICON CasesPlur-Cons
    +Nom:i # ;
    +Acc:i # ;
    +Gen:ion  # ;
    +Ins:inen # ;
    +All:innar # ;
    +Dat:in # ;
    +Loc:issen # ;
    +Loc+Short:is # ;
    +Abl:illon # ;
    +Abl:illor # ;  ! alternate ending
    +Poss:i{w}a # ;  ! TODO: connect to adjectival endings?

LEXICON CasesPlurPar-Cons
    +Nom:{l}i # ;
    +Acc:{l}i # ;
    +Gen:{l}ion  # ;
    +Ins:{l}ínen # ;
    +All:{l}inna # ;  ! r is optional for allative
    +All:{l}innar # ;
    +Dat:{l}in # ;
    +Loc:{l}isse # ;  ! n is optional for locative
    +Loc:{l}issen # ;
    +Loc+Short:{l}is # ;
    +Abl:{l}illo # ;  ! n/r is optional for ablative
    +Abl:{l}illon # ;
    +Abl:{l}illor # ;
    +Poss:{l}í{w}a # ;  ! TODO: connect to adjectival endings?


! possessive suffixes
LEXICON PossessiveSuffix
    +PxSg1:nya      CasesNumber ;
    +PxDu1+In:l{w}a CasesNumber ;
    +PxPl1+In:lma   CasesNumber ;
    +PxPl1+Ex:mma   CasesNumber ;  ! this form is also for +PxDu1+Ex but I'm not sure how to best represent that

    +PxSg2:lya      CasesNumber ;

    +PxSg3:rya      CasesNumber ;
    +PxPl3:nta      CasesNumber ;


! dual endings that use -u (not -t)
LEXICON CasesDual-U
    +Nom:{-V}u # ;
    +Acc:{-V}u # ;
    +Gen:{-V}uo  # ;
    +Ins:{-V}unen # ;
    +All:{-V}unna # ;
    +Dat:{-V}un # ;
    +Dat+Err/-Norm:{-V}uen # ;  ! poorly attested
    +Loc:{-V}usse # ;
    +Loc+Short:{-V}us # ;
    +Abl:{-V}ullo # ;
    +Poss:{-V}u{w}a # ;  ! TODO: connect to adjectival endings?

! vim: set ft=xfst-lexc: