-
-
Notifications
You must be signed in to change notification settings - Fork 456
/
install.iss
503 lines (434 loc) · 15 KB
/
install.iss
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
#define APP_NAME 'git-cola'
#define APP_LONGNAME 'git-cola: A highly caffeinated git GUI'
#define APP_VERSION '%APPVERSION%'
#define APP_URL 'http://cola.tuxfamily.org/'
[Setup]
; Compiler-related
InternalCompressLevel=max
OutputBaseFilename={#emit APP_NAME+'-'+APP_VERSION}
OutputDir=%OUTPUTDIR%
SolidCompression=yes
; Installer-related
AllowNoIcons=yes
AppName={#emit APP_LONGNAME}
AppPublisherURL={#emit APP_URL}
AppVersion={#emit APP_VERSION}
AppVerName={#emit APP_LONGNAME+' '+APP_VERSION}
ChangesEnvironment=yes
DefaultDirName={pf}\{#emit APP_NAME}
DefaultGroupName={#emit APP_LONGNAME}
DisableReadyPage=yes
InfoBeforeFile=etc\gpl-2.0.rtf
PrivilegesRequired=none
UninstallDisplayIcon=etc\git.ico
; Cosmetic
SetupIconFile=etc\git.ico
WizardSmallImageFile=etc\git.bmp
[Tasks]
Name: quicklaunchicon; Description: "Create a &Quick Launch icon"; GroupDescription: "Additional icons:"; Flags: checkedonce
Name: desktopicon; Description: "Create a &Desktop icon"; GroupDescription: "Additional icons:"; Flags: checkedonce
Name: guiextension; Description: "Add ""Git &Cola Here"""; GroupDescription: "Windows Explorer integration:"; Flags: checkedonce
[Files]
Source: "*"; DestDir: "{app}"; Excludes: "\*.bmp, \install.*, \tmp.*, \bin\*install*"; Flags: recursesubdirs
Source: "etc\ReleaseNotes.txt"; DestDir: "{app}\etc"; Flags: isreadme
[Icons]
Name: "{group}\Git Cola"; Filename: "{app}\bin\git-cola.pyw"; Parameters: "--git-path ""{code:GetGitExe}"""; WorkingDir: "%USERPROFILE%"; IconFilename: "{app}\etc\git.ico"
Name: "{group}\License"; Filename: "{app}\etc\gpl-2.0.rtf"; WorkingDir: "%USERPROFILE%";
Name: "{group}\Release Notes"; Filename: "{app}\etc\ReleaseNotes.txt"; WorkingDir: "%USERPROFILE%";
Name: "{group}\Git Cola Homepage"; Filename: "{#emit APP_URL}"; WorkingDir: "%USERPROFILE%";
Name: "{group}\Uninstall Git Cola"; Filename: "{uninstallexe}"
Name: "{userappdata}\Microsoft\Internet Explorer\Quick Launch\Git Cola"; Filename: "{app}\bin\git-cola.pyw"; Parameters: "--git-path ""{code:GetGitExe}"""; WorkingDir: "%USERPROFILE%"; IconFilename: "{app}\etc\git.ico"; Tasks: quicklaunchicon
Name: "{code:GetShellFolder|desktop}\Git Cola"; Filename: "{app}\bin\git-cola.pyw"; Parameters: "--git-path ""{code:GetGitExe}"""; WorkingDir: "%USERPROFILE%"; IconFilename: "{app}\etc\git.ico"; Tasks: desktopicon
[Messages]
BeveledLabel={#emit APP_URL}
SetupAppTitle={#emit APP_NAME} Setup
SetupWindowTitle={#emit APP_NAME} Setup
[UninstallDelete]
Type: files; Name: "{app}\bin\*"
Type: files; Name: "{app}\etc\*"
Type: files; Name: "{app}\libexec\git-cola\*"
Type: files; Name: "{app}\share\git-cola\lib\cola\*"
Type: files; Name: "{app}\share\git-cola\lib\cola\models\*"
Type: files; Name: "{app}\share\git-cola\lib\cola\controllers\*"
Type: files; Name: "{app}\share\git-cola\lib\cola\views\*"
Type: files; Name: "{app}\share\git-cola\lib\jsonpickle\*"
Type: files; Name: "{app}\share\git-cola\lib\simplejson\*"
Type: dirifempty; Name: "{app}\share\git-cola\lib\cola\models"
Type: dirifempty; Name: "{app}\share\git-cola\lib\cola\controllers"
Type: dirifempty; Name: "{app}\share\git-cola\lib\cola\views"
Type: dirifempty; Name: "{app}\share\git-cola\lib\cola"
Type: dirifempty; Name: "{app}\share\git-cola\lib\simplejson"
Type: dirifempty; Name: "{app}\share\git-cola\lib\jsonpickle"
Type: dirifempty; Name: "{app}\share\git-cola\lib"
Type: dirifempty; Name: "{app}\libexec\git-cola"
Type: dirifempty; Name: "{app}\etc"
Type: dirifempty; Name: "{app}\bin"
[Code]
{
Helper methods
}
var
PythonPage:TWizardPage;
GitPage:TWizardPage;
EdtPython:TEdit;
EdtGit:TEdit;
function GetEnvStrings(VarName:string;AllUsers:Boolean):TArrayOfString;
var
Path:string;
i:Longint;
p:Integer;
begin
Path:='';
// See http://www.jrsoftware.org/isfaq.php#env
if AllUsers then begin
// We ignore errors here. The resulting array of strings will be empty.
RegQueryStringValue(HKEY_LOCAL_MACHINE,'SYSTEM\CurrentControlSet\Control\Session Manager\Environment',VarName,Path);
end else begin
// We ignore errors here. The resulting array of strings will be empty.
RegQueryStringValue(HKEY_CURRENT_USER,'Environment',VarName,Path);
end;
// Make sure we have at least one semicolon.
Path:=Path+';';
// Split the directories in PATH into an array of strings.
i:=0;
SetArrayLength(Result,0);
p:=Pos(';',Path);
while p>0 do begin
SetArrayLength(Result,i+1);
if p>1 then begin
Result[i]:=Copy(Path,1,p-1);
i:=i+1;
end;
Path:=Copy(Path,p+1,Length(Path));
p:=Pos(';',Path);
end;
end;
function SetEnvStrings(VarName:string;AllUsers,DeleteIfEmpty:Boolean;DirStrings:TArrayOfString):Boolean;
var
Path,KeyName:string;
i:Longint;
begin
// Merge all non-empty directory strings into a PATH variable.
Path:='';
for i:=0 to GetArrayLength(DirStrings)-1 do begin
if Length(DirStrings[i])>0 then begin
if Length(Path)>0 then begin
Path:=Path+';'+DirStrings[i];
end else begin
Path:=DirStrings[i];
end;
end;
end;
// See http://www.jrsoftware.org/isfaq.php#env
if AllUsers then begin
KeyName:='SYSTEM\CurrentControlSet\Control\Session Manager\Environment';
if DeleteIfEmpty and (Length(Path)=0) then begin
Result:=(not RegValueExists(HKEY_LOCAL_MACHINE,KeyName,VarName))
or RegDeleteValue(HKEY_LOCAL_MACHINE,KeyName,VarName);
end else begin
Result:=RegWriteStringValue(HKEY_LOCAL_MACHINE,KeyName,VarName,Path);
end;
end else begin
KeyName:='Environment';
if DeleteIfEmpty and (Length(Path)=0) then begin
Result:=(not RegValueExists(HKEY_CURRENT_USER,KeyName,VarName))
or RegDeleteValue(HKEY_CURRENT_USER,KeyName,VarName);
end else begin
Result:=RegWriteStringValue(HKEY_CURRENT_USER,KeyName,VarName,Path);
end;
end;
end;
procedure BrowseForPythonFolder(Sender:TObject);
var
Path:string;
begin
Path:=GetPreviousData('PythonPath', 'C:\Python26');
EdtPython.Text:=Path;
Path:=ExtractFilePath(EdtPython.Text);
BrowseForFolder('Please select the Python folder:',Path,False);
Path:=Path+'\pythonw.exe';
if FileExists(Path) then begin
EdtPython.Text:=Path;
end else begin
MsgBox('Please enter a valid path to pythonw.exe.',mbError,MB_OK);
end;
end;
function GetPythonExe(Param: String): String;
begin
Result:=EdtPython.Text;
end;
procedure BrowseForGitFolder(Sender:TObject);
var
Path:string;
OldPath:string;
begin
Path:=GetPreviousData('GitPath', 'C:\Program Files\Git');
EdtGit.Text:=Path;
Path:=ExtractFilePath(EdtGit.Text);
BrowseForFolder('Please select the Git folder:',Path,False);
OldPath:=Path;
{
Check for both $DIR\git.exe and $DIR\bin\git.exe
}
Path:=OldPath+'\bin\git.exe';
if FileExists(Path) then begin
EdtGit.Text:=Path;
Exit;
end;
Path:=OldPath+'\git.exe';
if FileExists(Path) then begin
EdtGit.Text:=Path;
end else begin
MsgBox('Please enter a valid path to git.exe.',mbError,MB_OK);
end;
end;
function GetGitExe(Param: String): String;
begin
Result:=EdtGit.Text;
end;
procedure RegisterPreviousData(PreviousDataKey:Integer);
var
Path:string;
begin
Path:=ExtractFilePath(EdtPython.Text);
SetPreviousData(PreviousDataKey, 'PythonPath', Path);
Path:=ExtractFilePath(ExtractFilePath(EdtGit.Text));
SetPreviousData(PreviousDataKey, 'GitPath', Path);
end;
{
Installer code
}
procedure InitializeWizard;
var
BtnPython:TButton;
BtnGit:TButton;
LblPython:TLabel;
LblGit:TLabel;
begin
// Create a custom page for finding Python
PythonPage:=CreateCustomPage(
wpSelectTasks,
'Setup Python',
'Where is your Python folder?'
);
LblPython:=TLabel.Create(PythonPage);
with LblPython do begin
Parent:=PythonPage.Surface;
Caption:= 'Please provide the path to pythonw.exe.';
Left:=ScaleX(28);
Top:=ScaleY(100);
Width:=ScaleX(316);
Height:=ScaleY(39);
end;
EdtPython:=TEdit.Create(PythonPage);
with EdtPython do begin
Parent:=PythonPage.Surface;
Text:='C:\Python26\pythonw.exe';
if not FileExists(Text) then begin
Text:='';
end;
Left:=ScaleX(28);
Top:=ScaleY(148);
Width:=ScaleX(316);
Height:=ScaleY(13);
end;
BtnPython:=TButton.Create(PythonPage);
with BtnPython do begin
Parent:=PythonPage.Surface;
Caption:='...';
OnClick:=@BrowseForPythonFolder;
Left:=ScaleX(348);
Top:=ScaleY(148);
Width:=ScaleX(21);
Height:=ScaleY(21);
end;
// Create a custom page for finding Git
GitPage:=CreateCustomPage(
wpSelectTasks,
'Setup Git',
'Where is your Git folder?'
);
LblGit:=TLabel.Create(GitPage);
with LblGit do begin
Parent:=GitPage.Surface;
Caption:= 'Please provide the path to git.exe.';
Left:=ScaleX(28);
Top:=ScaleY(100);
Width:=ScaleX(316);
Height:=ScaleY(39);
end;
EdtGit:=TEdit.Create(GitPage);
with EdtGit do begin
Parent:=GitPage.Surface;
Text:='C:\Program Files\Git\bin\git.exe';
if not FileExists(Text) then begin
Text:='';
end;
Left:=ScaleX(28);
Top:=ScaleY(148);
Width:=ScaleX(316);
Height:=ScaleY(13);
end;
BtnGit:=TButton.Create(GitPage);
with BtnGit do begin
Parent:=GitPage.Surface;
Caption:='...';
OnClick:=@BrowseForGitFolder;
Left:=ScaleX(348);
Top:=ScaleY(148);
Width:=ScaleX(21);
Height:=ScaleY(21);
end;
end;
function NextButtonClick(CurPageID:Integer):Boolean;
begin
if CurPageID = PythonPage.ID then begin
Result:=FileExists(EdtPython.Text);
if not Result then begin
MsgBox('Please enter a valid path to pythonw.exe.',mbError,MB_OK);
end;
Exit;
end;
if CurPageID = GitPage.ID then begin
Result:=FileExists(EdtGit.Text);
if not Result then begin
MsgBox('Please enter a valid path to git.exe.',mbError,MB_OK);
end;
Exit;
end;
Result:=True;
end;
procedure CurStepChanged(CurStep:TSetupStep);
var
AppDir,BinDir,Msg:string;
EnvPath:TArrayOfString;
i:Longint;
RootKey:Integer;
begin
if CurStep<>ssPostInstall then begin
Exit;
end;
AppDir:=ExpandConstant('{app}');
BinDir:=ExpandConstant('{app}\bin');
{
Modify the environment
This must happen no later than ssPostInstall to make
"ChangesEnvironment=yes" not happend before the change!
}
// Get the current user's directories in PATH.
EnvPath:=GetEnvStrings('PATH',IsAdminLoggedOn);
// First, remove the installation directory from PATH in any case.
for i:=0 to GetArrayLength(EnvPath)-1 do begin
if Pos(AppDir,EnvPath[i])=1 then begin
EnvPath[i]:='';
end;
end;
// Modify the PATH variable as requested by the user.
i:=GetArrayLength(EnvPath);
SetArrayLength(EnvPath,i+1);
// Add \bin to the path
EnvPath[i]:=BinDir
// Set the current user's PATH directories.
if not SetEnvStrings('PATH',IsAdminLoggedOn,True,EnvPath) then begin
Msg:='Line {#emit __LINE__}: Unable to set the PATH environment variable.';
MsgBox(Msg,mbError,MB_OK);
Log(Msg);
// This is not a critical error, the user can probably fix it manually,
// so we continue.
end;
{
Create the Windows Explorer shell extensions
}
if IsAdminLoggedOn then begin
RootKey:=HKEY_LOCAL_MACHINE;
end else begin
RootKey:=HKEY_CURRENT_USER;
end;
if IsTaskSelected('guiextension') then begin
if (not RegWriteStringValue(RootKey,'SOFTWARE\Classes\Directory\shell\git_cola','','Git &Cola Here'))
or (not RegWriteStringValue(RootKey,'SOFTWARE\Classes\Directory\shell\git_cola\command','','"'+EdtPython.Text+'" "'+AppDir+'\bin\git-cola.pyw" "--repo" "%1" "--git-path" "'+EdtGit.Text+'"')) then begin
Msg:='Line {#emit __LINE__}: Unable to create "Git Cola Here" shell extension.';
MsgBox(Msg,mbError,MB_OK);
Log(Msg);
// This is not a critical error, the user can probably fix it manually,
// so we continue.
end;
end;
end;
{
Uninstaller code
}
function InitializeUninstall:Boolean;
begin
Result:=True;
end;
procedure CurUninstallStepChanged(CurUninstallStep:TUninstallStep);
var
AppDir,Command,Msg:string;
EnvPath:TArrayOfString;
i:Longint;
RootKey:Integer;
begin
if CurUninstallStep<>usUninstall then begin
Exit;
end;
{
Modify the environment
This must happen no later than usUninstall to make
"ChangesEnvironment=yes" not happend before the change!
}
AppDir:=ExpandConstant('{app}');
Command:=AppDir+'\setup.ini';
// Get the current user's directories in PATH.
EnvPath:=GetEnvStrings('PATH',IsAdminLoggedOn);
// Remove the installation directory from PATH in any case, even if it
// was not added by the installer.
for i:=0 to GetArrayLength(EnvPath)-1 do begin
if Pos(AppDir,EnvPath[i])=1 then begin
EnvPath[i]:='';
end;
end;
// Reset the current user's directories in PATH.
if not SetEnvStrings('PATH',IsAdminLoggedOn,True,EnvPath) then begin
Msg:='Line {#emit __LINE__}: Unable to revert any possible changes to PATH.';
MsgBox(Msg,mbError,MB_OK);
Log(Msg);
// This is not a critical error, the user can probably fix it manually,
// so we continue.
end;
if (FileExists(Command) and (not DeleteFile(Command))) then begin
Msg:='Line {#emit __LINE__}: Unable to delete file "'+Command+'".';
MsgBox(Msg,mbError,MB_OK);
Log(Msg);
// This is not a critical error, the user can probably fix it manually,
// so we continue.
end;
{
Delete the Windows Explorer shell extensions
}
if IsAdminLoggedOn then begin
RootKey:=HKEY_LOCAL_MACHINE;
end else begin
RootKey:=HKEY_CURRENT_USER;
end;
Command:='';
RegQueryStringValue(RootKey,'SOFTWARE\Classes\Directory\shell\git_cola\command','',Command);
if Pos(AppDir,Command)>0 then begin
if not RegDeleteKeyIncludingSubkeys(RootKey,'SOFTWARE\Classes\Directory\shell\git_cola') then begin
Msg:='Line {#emit __LINE__}: Unable to remove "Git Cola Here" shell extension.';
MsgBox(Msg,mbError,MB_OK);
Log(Msg);
// This is not a critical error, the user can probably fix it manually,
// so we continue.
end;
end;
end;
function GetShellFolder(Param:string):string;
begin
if IsAdminLoggedOn then begin
Param:='{common'+Param+'}';
end else begin
Param:='{user'+Param+'}';
end;
Result:=ExpandConstant(Param);
end;