-
Notifications
You must be signed in to change notification settings - Fork 4.6k
/
ScalaCompileIntegrationTest.groovy
122 lines (100 loc) · 3.84 KB
/
ScalaCompileIntegrationTest.groovy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
/*
* Copyright 2022 the original author or authors.
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
package org.gradle.scala.compile
import org.gradle.api.JavaVersion
import org.gradle.integtests.fixtures.MultiVersionIntegrationSpec
import org.gradle.integtests.fixtures.ScalaCoverage
import org.gradle.integtests.fixtures.TargetCoverage
import org.gradle.integtests.fixtures.jvm.JavaToolchainFixture
import org.gradle.internal.jvm.Jvm
import org.gradle.util.Requires
import org.gradle.util.TestPrecondition
import static org.gradle.scala.ScalaCompilationFixture.scalaDependency
@TargetCoverage({ ScalaCoverage.DEFAULT })
class ScalaCompileIntegrationTest extends MultiVersionIntegrationSpec implements JavaToolchainFixture {
def setup() {
buildFile << """
apply plugin: "scala"
${mavenCentralRepository()}
dependencies {
implementation "${scalaDependency(version)}"
}
"""
}
def "can compile sources"() {
def currentJdk = Jvm.current()
file("src/main/scala/JavaThing.java") << "public class JavaThing {}"
file("src/main/scala/ScalaHall.scala") << "class ScalaHall(name: String)"
when:
run ":compileScala"
then:
executedAndNotSkipped(":compileScala")
outputDoesNotContain("[Warn]")
JavaVersion.forClass(scalaClassFile("JavaThing.class").bytes) == currentJdk.javaVersion
JavaVersion.forClass(scalaClassFile("ScalaHall.class").bytes) == JavaVersion.VERSION_1_8
}
def "fail in case of errors and print correct positions"() {
given:
file("src/main/scala/Person.scala") << """
class Person {
def getName(): String = 42
}
"""
expect:
fails(":compileScala")
if (versionNumber.major >= 3) {
result.assertHasErrorOutput("src/main/scala/Person.scala:3:29: Found: (42 : Int)\nRequired: String")
} else {
result.assertHasErrorOutput("src/main/scala/Person.scala:3:29: type mismatch;\n found : Int(42)\n required: String")
}
}
def "can assign #value to additional parameters"() {
file("src/main/scala/ScalaHall.scala") << "class ScalaHall(name: String)"
buildFile << """
tasks.withType(ScalaCompile) {
scalaCompileOptions.additionalParameters = $expression
}
"""
when:
run ":compileScala"
then:
executedAndNotSkipped(":compileScala")
outputDoesNotContain("[Warn]")
JavaVersion.forClass(scalaClassFile("ScalaHall.class").bytes) == JavaVersion.VERSION_1_8
where:
value | expression
"null" | "null"
"mutable list" | "[]"
"immutable list" | "[].asImmutable()"
}
@Requires(TestPrecondition.JDK11_OR_LATER)
def "can compile sources using later JDK APIs"() {
file("src/main/scala/App.scala") << """
object App {
def main(args: Array[String]): Unit = {
var x : String = "Test String"
// isBlank is from JDK 11
println(x.isBlank)
}
}
"""
when:
run ":compileScala"
then:
executedAndNotSkipped(":compileScala")
JavaVersion.forClass(scalaClassFile("App.class").bytes) == JavaVersion.VERSION_1_8
}
}