-
Notifications
You must be signed in to change notification settings - Fork 951
/
GrailsUrlMappingsTestCase.groovy
209 lines (179 loc) · 8.18 KB
/
GrailsUrlMappingsTestCase.groovy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
/*
* Copyright 2004-2005 the original author or authors.
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
package grails.test
import org.apache.commons.lang.StringUtils
import org.codehaus.groovy.grails.commons.GrailsClassUtils
import org.codehaus.groovy.grails.commons.GrailsControllerClass
import org.codehaus.groovy.grails.web.mapping.DefaultUrlMappingEvaluator
import org.codehaus.groovy.grails.web.mapping.DefaultUrlMappingsHolder
import org.springframework.beans.BeanUtils
import org.springframework.core.io.FileSystemResourceLoader
import org.springframework.core.io.support.PathMatchingResourcePatternResolver
import org.springframework.web.context.request.RequestContextHolder
/**
* @author Luke Daley
*/
class GrailsUrlMappingsTestCase extends GroovyTestCase {
def webRequest
def mappingsHolder
def controllers
def assertionKeys = ["controller", "action", "view"]
def patternResolver = new PathMatchingResourcePatternResolver(new FileSystemResourceLoader())
def classLoader = new GroovyClassLoader()
def mappingEvaluator
def grailsApplication
def createMappingsHolder() {
new DefaultUrlMappingsHolder(
urlMappingEvaluatees.collect {
mappingEvaluator.evaluateMappings((it instanceof Closure) ? it : GrailsClassUtils.getStaticPropertyValue(it, "mappings"))
}.flatten())
}
def createControllerMap() {
controllers = [:]
grailsApplication.controllerClasses.each { GrailsControllerClass cc ->
controllers[cc.logicalPropertyName] = cc.newInstance()
}
controllers
}
def getUrlMappingEvaluatees() {
def m = GrailsClassUtils.getPropertyOrStaticPropertyOrFieldValue(this, "mappings")
if (m == null) {
return grailsApplication.urlMappingsClasses*.clazz
}
if (mappings instanceof Closure || mappings instanceof Class) {
return [mappings]
}
return mappings
}
void setUp() {
webRequest = RequestContextHolder.currentRequestAttributes()
mappingEvaluator = new DefaultUrlMappingEvaluator(webRequest.servletContext)
mappingsHolder = createMappingsHolder()
controllers = createControllerMap()
}
void tearDown() {
RequestContextHolder.resetRequestAttributes()
}
def getActions(controller) {
def instance = controllers[controller]
BeanUtils.getPropertyDescriptors(instance.class).findAll {
GrailsClassUtils.getPropertyOrStaticPropertyOrFieldValue(instance, it.name) instanceof Closure
}.collect {
StringUtils.substringBeforeLast(it.name, "Flow")
}
}
def getDefaultAction(controllerName) {
def controller = controllers[controllerName]
(controller.class.declaredFields.find { it.name == "defaultAction" }) ? controller.defaultAction : "index"
}
def assertController(controller, url) {
if (!controllers.containsKey(controller)) {
throw new IllegalArgumentException("Url mapping assertion for '$url' failed, '$controller' is not a valid controller")
}
}
def assertAction(controller, action, url) {
if (!getActions(controller).contains(action)) {
throw new IllegalArgumentException("Url mapping assertion for '$url' failed, '$action' is not a valid action of controller '$controller'")
}
}
def assertView(controller, view, url) {
def pathPattern = "grails-app/views/" + ((controller) ? "$controller/" : "") + "${view}.*"
if (!patternResolver.getResources(pathPattern)) {
throw new IllegalArgumentException(
(controller) ? "Url mapping assertion for '$url' failed, '$view' is not a valid view of controller '$controller'" : "Url mapping assertion for '$url' failed, '$view' is not a valid view")
}
}
void assertUrlMapping(assertions, url) {
assertUrlMapping(assertions, url, null)
}
void assertUrlMapping(assertions, url, paramAssertions) {
assertForwardUrlMapping(assertions, url, paramAssertions)
if (assertions.controller && !(url instanceof Integer)) {
assertReverseUrlMapping(assertions, url, paramAssertions)
}
}
void assertForwardUrlMapping(assertions, url) {
assertForwardUrlMapping(assertions, url, null)
}
void assertForwardUrlMapping(assertions, url, paramAssertions) {
if (assertions.action && !assertions.controller) {
throw new IllegalArgumentException("Cannot assert action for url mapping without asserting controller")
}
if (assertions.controller) assertController(assertions.controller, url)
if (assertions.action) assertAction(assertions.controller, assertions.action, url)
if (assertions.view) assertView(assertions.controller, assertions.view, url)
def mappingInfos
if (url instanceof Integer) {
mappingInfos = []
def mapping = mappingsHolder.matchStatusCode(url)
if (mapping) mappingInfos << mapping
}
else {
mappingInfos = mappingsHolder.matchAll(url)
}
def mappingMatched = mappingInfos.any {mapping ->
mapping.configure(webRequest)
for (key in assertionKeys) {
if (assertions.containsKey(key)) {
def expected = assertions[key]
def actual = mapping."${key}Name"
switch (key) {
case "controller":
if (actual && !controllers.containsKey(actual)) return false
break
case "view":
if (actual[0] == "/") actual = actual.substring(1)
if (expected[0] == "/") expected = expected.substring(1)
break
case "action":
if (key == "action" && actual == null) actual = getDefaultAction(assertions.controller)
break
}
assertEquals("Url mapping $key assertion for '$url' failed", expected, actual)
}
}
if (paramAssertions) {
def params = [:]
paramAssertions.delegate = params
paramAssertions.resolveStrategy = Closure.DELEGATE_ONLY
paramAssertions.call()
params.each {name, value ->
assertEquals("Url mapping '$name' parameter assertion for '$url' failed", value.toString(), mapping.params[name])
}
}
return true
}
if (!mappingMatched) throw new IllegalArgumentException("url '$url' did not match any mappings")
}
void assertReverseUrlMapping(assertions, url) {
assertReverseUrlMapping(assertions, url, null)
}
void assertReverseUrlMapping(assertions, url, paramAssertions) {
def controller = assertions.controller
def action = assertions.action
def plugin = assertions.plugin
def params = [:]
if (paramAssertions) {
paramAssertions.delegate = params
paramAssertions.resolveStrategy = Closure.DELEGATE_ONLY
paramAssertions.call()
}
def urlCreator = mappingsHolder.getReverseMapping(controller, action, plugin, params)
assertNotNull("could not create reverse mapping of '$url' for {controller = $controller, action = $action, params = $params}", urlCreator)
def createdUrl = urlCreator.createRelativeURL(controller, action, params, "UTF-8")
assertEquals("reverse mapping assertion for {controller = $controller, action = $action, params = $params}", url, createdUrl)
}
}