-
Notifications
You must be signed in to change notification settings - Fork 197
/
HibernateGormInstanceApi.groovy
152 lines (133 loc) · 5.41 KB
/
HibernateGormInstanceApi.groovy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
/*
* Copyright 2013 the original author or authors.
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
package org.grails.orm.hibernate
import grails.core.GrailsDomainClass
import groovy.transform.CompileStatic
import org.grails.orm.hibernate.cfg.GrailsHibernateUtil
import org.grails.core.artefact.DomainClassArtefactHandler
import org.hibernate.engine.spi.EntityEntry
import org.hibernate.engine.spi.SessionImplementor
/**
* The implementation of the GORM instance API contract for Hibernate.
*
* @author Graeme Rocher
* @since 1.0
*/
@CompileStatic
class HibernateGormInstanceApi<D> extends AbstractHibernateGormInstanceApi<D> {
protected GrailsHibernateTemplate hibernateTemplate
protected InstanceApiHelper instanceApiHelper
HibernateGormInstanceApi(Class<D> persistentClass, HibernateDatastore datastore, ClassLoader classLoader) {
super(persistentClass, datastore, classLoader, null)
def grailsApplication = datastore.getGrailsApplication()
if (grailsApplication) {
GrailsDomainClass domainClass = (GrailsDomainClass)grailsApplication.getArtefact(DomainClassArtefactHandler.TYPE, persistentClass.name)
config = (Map)grailsApplication.getConfig().getProperty('grails.gorm',Map)
hibernateTemplate = new GrailsHibernateTemplate(sessionFactory, grailsApplication, datastore.getDefaultFlushMode())
}
else {
hibernateTemplate = new GrailsHibernateTemplate(sessionFactory)
hibernateTemplate.setFlushMode(datastore.getDefaultFlushMode())
}
super.hibernateTemplate = hibernateTemplate
instanceApiHelper = new InstanceApiHelper(hibernateTemplate)
}
/**
* Checks whether a field is dirty
*
* @param instance The instance
* @param fieldName The name of the field
*
* @return true if the field is dirty
*/
boolean isDirty(D instance, String fieldName) {
SessionImplementor session = (SessionImplementor)sessionFactory.currentSession
def entry = findEntityEntry(instance, session)
if (!entry || !entry.loadedState) {
return false
}
Object[] values = entry.persister.getPropertyValues(instance)
int[] dirtyProperties = entry.persister.findDirty(values, entry.loadedState, instance, session)
if(!dirtyProperties) return false
int fieldIndex = entry.persister.propertyNames.findIndexOf { fieldName == it }
return fieldIndex in dirtyProperties
}
/**
* Checks whether an entity is dirty
*
* @param instance The instance
* @return true if it is dirty
*/
boolean isDirty(D instance) {
SessionImplementor session = (SessionImplementor)sessionFactory.currentSession
def entry = findEntityEntry(instance, session)
if (!entry || !entry.loadedState) {
return false
}
Object[] values = entry.persister.getPropertyValues(instance)
def dirtyProperties = entry.persister.findDirty(values, entry.loadedState, instance, session)
return dirtyProperties != null
}
/**
* Obtains a list of property names that are dirty
*
* @param instance The instance
* @return A list of property names that are dirty
*/
List getDirtyPropertyNames(D instance) {
SessionImplementor session = (SessionImplementor)sessionFactory.currentSession
def entry = findEntityEntry(instance, session)
if (!entry || !entry.loadedState) {
return []
}
Object[] values = entry.persister.getPropertyValues(instance)
int[] dirtyProperties = entry.persister.findDirty(values, entry.loadedState, instance, session)
def names = []
for (index in dirtyProperties) {
names << entry.persister.propertyNames[index]
}
names
}
/**
* Gets the original persisted value of a field.
*
* @param fieldName The field name
* @return The original persisted value
*/
Object getPersistentValue(D instance, String fieldName) {
SessionImplementor session = (SessionImplementor)sessionFactory.currentSession
def entry = findEntityEntry(instance, session, false)
if (!entry || !entry.loadedState) {
return null
}
int fieldIndex = entry.persister.propertyNames.findIndexOf { fieldName == it }
return fieldIndex == -1 ? null : entry.loadedState[fieldIndex]
}
protected EntityEntry findEntityEntry(D instance, SessionImplementor session, boolean forDirtyCheck = true) {
def entry = session.persistenceContext.getEntry(instance)
if (!entry) {
return null
}
if (forDirtyCheck && !entry.requiresDirtyCheck(instance) && entry.loadedState) {
return null
}
entry
}
@Override
void setObjectToReadWrite(Object target) {
GrailsHibernateUtil.setObjectToReadWrite(target, sessionFactory)
}
}