-
Notifications
You must be signed in to change notification settings - Fork 0
/
griffon-materialdesignicons-guide.gradle
209 lines (183 loc) · 7.16 KB
/
griffon-materialdesignicons-guide.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
buildscript {
repositories {
jcenter()
maven { url 'http://dl.bintray.com/content/bmuschko/maven' }
maven { url 'http://dl.bintray.com/content/bmuschko/gradle-plugins' }
}
dependencies {
classpath 'org.asciidoctor:asciidoctor-gradle-plugin:1.5.2'
classpath 'com.bmuschko:gradle-java2html-plugin:2.0'
}
}
apply plugin: 'org.asciidoctor.convert'
apply plugin: 'com.bmuschko.java2html'
ext.childProjects = [
':griffon-materialdesignicons-core',
':griffon-materialdesignicons-swing',
':griffon-materialdesignicons-javafx',
':griffon-materialdesignicons-swing-groovy',
':griffon-materialdesignicons-javafx-groovy'
]
ext.childProjects.each { evaluationDependsOn it }
dependencies {
java2html 'de.java2html:java2html:5.0'
}
task copyDocs(type: Copy) {
destinationDir = "${buildDir}/sources" as File
project.ext.childProjects.each { projectName ->
if (projectName.endsWith('-compile')) {
from(project(projectName).sourceSets.main.allSource) {
include 'griffon/transform/**/*'
include 'griffon/metadata/**/*'
}
} else {
from(project(projectName).sourceSets.main.allSource) {
include '**/*.java'
include '**/*.groovy'
include '**/*.html'
}
}
}
}
task apiDocs(type: Javadoc, dependsOn: copyDocs) {
source = copyDocs.destinationDir
destinationDir = file("${buildDir}/api")
title = "${pluginBaseName} ${project.version}"
classpath = project.ext.childProjects.collect { projectName ->
[project(projectName).sourceSets.main.output,
project(projectName).configurations.compile,
project(projectName).configurations.compileOnly]
}.flatten().sum() as FileCollection
excludes = ['**/*.html', 'META-INF/**', '**/*.groovy']
options.use = true
options.splitIndex = true
options.encoding = 'UTF-8'
options.author = true
options.version = true
options.source = project.sourceCompatibility
options.overview = file('src/javadoc/overview.html')
options.windowTitle = "${pluginBaseName} ${project.version}"
options.docTitle = "${pluginBaseName} ${project.version}"
options.footer = project.javadocFooter
options.links = ['http://www.slf4j.org/apidocs/',
'http://junit.org/junit4/javadoc/latest/',
'http://docs.oracle.com/javase/8/docs/api/',
'http://aalmiray.github.io/jsr-305/apidocs/',
'http://javax-inject.github.io/javax-inject/api/',
"http://griffon-framework.org/guide/${griffonVersion}/api".toString()]
doLast { task ->
copy {
into task.destinationDir
from file('src/javadoc/resources/img/griffon.ico'),
file('src/javadoc/resources/css/stylesheet.css')
}
copy {
into file("${task.destinationDir}/resources")
from file('src/javadoc/resources/img/')
}
}
}
task generateJava2html {
dependsOn apiDocs
dependsOn "java2htmlGenerateOverview"
dependsOn java2htmlConvertCode
}
task javadocJar(type: Jar, dependsOn: apiDocs) {
archiveName = "${pluginBaseName}-plugin-${version}-javadoc.jar"
destinationDir = "${buildDir}/assemble/jars" as File
from apiDocs.destinationDir
}
task sourceHtmlJar(type: Jar, dependsOn: java2html) {
archiveName = "${pluginBaseName}-plugin-${version}-sources-html.jar"
destinationDir = "${buildDir}/assemble/jars" as File
from java2htmlConvertCode.destDir
}
task docsJar(dependsOn: [javadocJar, sourceHtmlJar]) {}
java2html {
conversion {
srcDirs = files(copyDocs.destinationDir)
tabs = 4
style = 'kawa'
addLineAnchors = true
showFileName = true
useShortFileName = true
overwrite = true
showDefaultTitle = true
}
overview {
windowTitle = "${pluginBaseName} ${project.version}"
docTitle = "${pluginBaseName} ${project.version}"
docDescription = "${pluginBaseName} ${project.version}"
icon = file('src/javadoc/resources/img/griffon.ico')
stylesheet = file('src/javadoc/resources/css/stylesheet.css')
}
}
task generateIconCheatSheet << {
GroovyClassLoader gcl = new GroovyClassLoader()
project(':griffon-materialdesignicons-core').configurations.compile.files.each { jar -> gcl.addClasspath(jar.absolutePath) }
gcl.addClasspath(project(':griffon-materialdesignicons-core').file('build/classes/main').absolutePath)
def materialDesignIconFontClass = gcl.loadClass('griffon.plugins.materialdesignicons.MaterialDesignIconFont', true)
String document = '''
[[icon_cheat_cheet]]
= Icon Cheat Sheet
The following tables show all available icons.
[columns="3*", options="header"]
|===
| Enum | Name | Icon
'''.stripIndent(4)
materialDesignIconFontClass.values().each { font ->
document += "| ${font} "
document += "| ${font.description} "
document += "| pass:[<span class=\"mdi ${font.description}\"></span>] "
document += '\n'
}
document += '|===\n'
document += '\n\n'
File f = file("${buildDir}/tmp/icon-cheat-sheet.adoc")
f.parentFile.mkdirs()
f.text = document
}
generateIconCheatSheet.dependsOn(project(':griffon-materialdesignicons-core').classes)
asciidoctor {
dependsOn generateIconCheatSheet
sourceDir = file('src/asciidoc')
attributes = [
toc : 'left',
doctype : 'book',
icons : 'font',
encoding : 'utf-8',
sectlink : true,
sectanchors : true,
numbered : true,
linkattrs : true,
imagesdir : 'images',
linkcss : true,
stylesheet : 'css/style.css',
'source-highlighter' : 'coderay',
'coderay-linenums-mode' : 'table',
'project-title' : project.projectDescription,
'project-author' : 'Andres Almiray',
'project-url' : project.projectWebsiteUrl,
'project-vcs' : project.projectVcsUrl,
'project-issue-tracker' : project.projectIssueTrackerUrl,
'griffon-version' : rootProject.griffonVersion,
'materialdesignicons-version': rootProject.materialdesignIconsVersion
]
sources {
include 'index.adoc'
}
resources {
from file('src/resources')
from project(':griffon-materialdesignicons-core').file("src/main/resources/META-INF/resources/materialdesignicons/${materialdesignIconsVersion}")
}
}
task guide(type: Copy, dependsOn: [apiDocs, generateJava2html, asciidoctor]) {
destinationDir = "${buildDir}/guide" as File
from(apiDocs.destinationDir) { into 'api' }
from(java2htmlConvertCode.destDir) { into 'api-src' }
from("${asciidoctor.outputDir}/html5")
}
task guideZip(type: Zip, dependsOn: guide) {
baseName = "${pluginBaseName}-guide"
from guide.destinationDir
}