firefoxLocaleWrapper: takes care of firefox localization

This patch adds a locale-wrapper for firefoxWrapper. The new wrapper does two
tings: 1) adds corresponding -UILocale <lang> option 2) Downloads language pack
in the background when it thinks language pack is not installed. Use it like
following:

  environment.systemPackages = with pkgs ; [
    ...
    (firefoxLocaleWrapper "ru")
    ...
  ];

pkgs/applications/networking/browsers/firefox/localeWrapper.nix

@@ -0,0 +1,58 @@
+{ stdenv, language, firefoxWrapper, firefoxPkgs, gnused, bash, wget }:
+let
+
+  version = firefoxPkgs.xulVersion;
+
+  mkscript = name : text : ''
+    mkdir -pv $out/bin
+    cat > $out/bin/${name} <<"EOF"
+    #!${bash}/bin/bash
+    ${text}
+    EOF
+    chmod +x $out/bin/${name}
+  '';
+
+  # FIXME: encode more archs. Check
+  # ftp://ftp.mozilla.org/pub/mozilla.org/firefox/releases/${version} for naming
+  # pattern.
+  arch = assert stdenv.isLinux;
+    if stdenv.is64bit
+      then "linux-x86_64"
+      else "linux-i686";
+
+  langurl = "ftp://ftp.mozilla.org/pub/mozilla.org/firefox/releases/${version}/${arch}/xpi/${language}.xpi";
+
+  wrapper = mkscript "firefox" ''
+    LANGPACK=~/.firefox-${version}-langpack-${language}.xpi
+    if ! test -f "$LANGPACK" ; then
+      (
+        # Downloads language pack in separate process
+        ${wget}/bin/wget ${langurl} -O "$LANGPACK" &&
+        ${firefoxWrapper}/bin/firefox -UILocale ${language} "$LANGPACK"
+      ) &
+    fi
+    exec ${firefoxWrapper}/bin/firefox -UILocale ${language} "''${extraFlagsArray[@]}" "$@"
+  '';
+in
+stdenv.mkDerivation {
+
+  name = firefoxWrapper.name + "-with-localeWrapper";
+
+  buildCommand = ''
+    mkdir -pv $out/bin
+    ${wrapper}
+
+    mkdir -pv $out/share/applications
+    cp ${firefoxWrapper}/share/applications/* $out/share/applications
+
+    mkdir -pv $out/nix-support
+    echo ${firefoxWrapper} > $out/nix-support/propagated-user-env-packages
+  '';
+
+  meta = {
+    description =
+      firefoxWrapper.meta.description
+      + " (with ${language} locale wrapper) ";
+  };
+}
+

pkgs/top-level/all-packages.nix

@@ -7875,6 +7875,12 @@ let
 
   firefoxWrapper = wrapFirefox { browser = firefoxPkgs.firefox; };
 
+  # Language is a two-letter country code (with several exceptions for "en-GB" ,
+  # "en-US", etc.)
+  firefoxLocaleWrapper = language : callPackage ../applications/networking/browsers/firefox/localeWrapper.nix {
+    inherit language;
+  };
+
   flac = callPackage ../applications/audio/flac { };
 
   flashplayer = callPackage ../applications/networking/browsers/mozilla-plugins/flashplayer-11 {