forked from modelica/ModelicaStandardLibrary
-
Notifications
You must be signed in to change notification settings - Fork 1
/
IM_SquirrelCage.mo
95 lines (92 loc) · 4.48 KB
/
IM_SquirrelCage.mo
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
within Modelica.Magnetic.QuasiStatic.FundamentalWave.BasicMachines.InductionMachines;
model IM_SquirrelCage "Induction machine with squirrel cage"
// Removed from extension of FUNDAMENTAL WAVE model: is(start=zeros(m)) ##
extends BaseClasses.Machine(
Rs(start=0.03*ZsRef),
Lssigma(start=3*ZsRef*(1 - sqrt(1 - 0.0667))/(2*pi*fsNominal)),
final L0(d=2.0*Lm/m/effectiveStatorTurns^2, q=2.0*Lm/m/
effectiveStatorTurns^2),
redeclare final
Modelica.Electrical.Machines.Thermal.InductionMachines.ThermalAmbientIMC
thermalAmbient(final Tr=TrOperational),
redeclare final
Modelica.Electrical.Machines.Interfaces.InductionMachines.ThermalPortIMC
thermalPort,
redeclare final
Modelica.Electrical.Machines.Interfaces.InductionMachines.ThermalPortIMC
internalThermalPort,
redeclare final
Modelica.Electrical.Machines.Interfaces.InductionMachines.PowerBalanceIMC
powerBalance(final lossPowerRotorWinding=sum(rotorCage.resistor.resistor.LossPower),
final lossPowerRotorCore=0));
parameter SI.Inductance Lm(start=3*ZsRef*sqrt(1 - 0.0667)/(2*pi
*fsNominal)) "Stator main field inductance per phase" annotation (
Dialog(tab="Nominal resistances and inductances", groupImage=
"modelica://Modelica/Resources/Images/Electrical/Machines/IMC.png"));
parameter SI.Inductance Lrsigma(start=3*ZsRef*(1 - sqrt(1 -
0.0667))/(2*pi*fsNominal))
"Rotor leakage inductance of equivalent m phase winding w.r.t. stator side"
annotation (Dialog(tab="Nominal resistances and inductances"));
parameter SI.Resistance Rr(start=0.04*ZsRef)
"Rotor resistance of equivalent m phase winding w.r.t. stator side"
annotation (Dialog(tab="Nominal resistances and inductances"));
parameter SI.Temperature TrRef(start=293.15)
"Reference temperature of rotor resistance"
annotation (Dialog(tab="Nominal resistances and inductances"));
parameter
Modelica.Electrical.Machines.Thermal.LinearTemperatureCoefficient20
alpha20r(start=0)
"Temperature coefficient of rotor resistance at 20 degC"
annotation (Dialog(tab="Nominal resistances and inductances"));
parameter SI.Temperature TrOperational(start=293.15)
"Operational temperature of rotor resistance" annotation (Dialog(
group="Operational temperatures", enable=not useThermalPort));
output SI.ComplexCurrent ir[m]=rotorCage.i
"Rotor current";
SI.Current abs_ir[m]=Modelica.ComplexMath.abs(ir)
"Magnitude of complex rotor current";
SI.Angle arg_ir[m]=Modelica.ComplexMath.arg(ir)
"Argument of complex rotor current";
Components.SymmetricPolyphaseCageWinding rotorCage(
final Lsigma=Lrsigma,
final effectiveTurns=effectiveStatorTurns,
final useHeatPort=true,
final RRef=Rr,
final TRef=TrRef,
final TOperational=TrRef,
final m=m,
final alpha20=alpha20r)
"Symmetric rotor cage winding including resistances and stray inductances"
annotation (Placement(transformation(extent={{-10,-40},{10,-20}})));
equation
connect(rotorCage.heatPortWinding, internalThermalPort.heatPortRotorWinding)
annotation (Line(
points={{0,-40},{-40,-40},{-40,-90}}, color={191,0,0}));
connect(airGap.port_rn, rotorCage.port_p) annotation (Line(
points={{-10,-10},{-10,-30}}, color={255,170,85}));
connect(airGap.port_rp, rotorCage.port_n) annotation (Line(
points={{10,-10},{10,-30}}, color={255,170,85}));
annotation (
defaultComponentName="imc",
Documentation(info="<html>
<p>
Resistances and stray inductances of the machine refer to an <code>m</code>-phase stator. The symmetry of the stator, rotor and supply are assumed. The machine models take the following loss effects into account:
</p>
<ul>
<li>heat losses in the temperature dependent stator winding resistances</li>
<li>heat losses in the temperature dependent cage resistances</li>
<li>friction losses</li>
<li>core losses (only eddy current losses, no hysteresis losses)</li>
<li>stray load losses</li>
</ul>
<h4>See also</h4>
<p>
<a href=\"modelica://Modelica.Magnetic.QuasiStatic.FundamentalWave.BasicMachines.InductionMachines.IM_SlipRing\">
IM_SlipRing</a>,
<a href=\"modelica://Modelica.Magnetic.FundamentalWave.BasicMachines.InductionMachines.IM_SlipRing\">
Magnetic.FundamentalWave.BasicMachines.InductionMachines.IM_SlipRing</a>,
<a href=\"modelica://Modelica.Magnetic.FundamentalWave.BasicMachines.InductionMachines.IM_SquirrelCage\">
Magnetic.FundamentalWave.BasicMachines.InductionMachines.IM_SquirrelCage</a>,
</p>
</html>"));
end IM_SquirrelCage;