-
Notifications
You must be signed in to change notification settings - Fork 0
/
RBD.sml
3401 lines (3286 loc) · 144 KB
/
RBD.sml
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(* ========================================================================= *)
(* File Name: RBD.sml *)
(*---------------------------------------------------------------------------*)
(* Description: Reliability Block Diagrams in Higher-order Logic *)
(* *)
(* HOL4-Kananaskis 13 *)
(* *)
(* Author : Waqar Ahmed *)
(* ========================================================================= *)
app load ["arithmeticTheory", "realTheory", "prim_recTheory", "seqTheory",
"pred_setTheory","res_quanTheory", "res_quanTools", "listTheory",
"real_probabilityTheory",
"numTheory", "dep_rewrite", "transcTheory", "rich_listTheory", "pairTheory",
"combinTheory","limTheory","sortingTheory", "realLib", "optionTheory","satTheory",
"util_probTheory", "extrealTheory", "real_measureTheory","real_sigmaTheory",
"indexedListsTheory", "listLib", "bossLib", "metisLib", "realLib", "numLib",
"combinTheory", "arithmeticTheory","boolTheory", "listSyntax", "lebesgueTheory",
"real_sigmaTheory", "cardinalTheory", "ETreeTheory"];
open HolKernel Parse boolLib bossLib limTheory arithmeticTheory realTheory prim_recTheory
real_probabilityTheory seqTheory pred_setTheory res_quanTheory sortingTheory res_quanTools
listTheory transcTheory rich_listTheory pairTheory combinTheory realLib optionTheory
dep_rewrite util_probTheory extrealTheory real_measureTheory real_sigmaTheory
indexedListsTheory listLib satTheory numTheory bossLib metisLib realLib numLib
combinTheory arithmeticTheory boolTheory listSyntax lebesgueTheory real_sigmaTheory
cardinalTheory ETreeTheory;
val _ = new_theory "RBD";
(*------new tactics for set simplification----*)
(*--------------------*)
infixr 0 ++ << || ORELSEC ## --> THENC;
infix 1 >> |->;
fun parse_with_goal t (asms, g) =
let
val ctxt = free_varsl (g::asms)
in
Parse.parse_in_context ctxt t
end;
val PARSE_TAC = fn tac => fn q => W (tac o parse_with_goal q);
val Suff = PARSE_TAC SUFF_TAC;
val POP_ORW = POP_ASSUM (fn thm => ONCE_REWRITE_TAC [thm]);
val !! = REPEAT;
val op++ = op THEN;
val op<< = op THENL;
val op|| = op ORELSE;
val op>> = op THEN1;
val std_ss' = simpLib.++ (std_ss, boolSimps.ETA_ss);
(*---------------------------*)
fun SET_TAC L =
POP_ASSUM_LIST(K ALL_TAC) THEN REPEAT COND_CASES_TAC THEN
REWRITE_TAC (append [EXTENSION, SUBSET_DEF, PSUBSET_DEF, DISJOINT_DEF,
SING_DEF] L) THEN SIMP_TAC std_ss [NOT_IN_EMPTY, IN_UNIV, IN_UNION,
IN_INTER, IN_DIFF, IN_INSERT, IN_DELETE, IN_BIGINTER, IN_BIGUNION,
IN_IMAGE, GSPECIFICATION, IN_DEF] THEN METIS_TAC [];
fun SET_RULE tm = prove(tm,SET_TAC []);
val set_rewrs
= [INTER_EMPTY, INTER_UNIV, UNION_EMPTY, UNION_UNIV, DISJOINT_UNION,
DISJOINT_INSERT, DISJOINT_EMPTY, GSYM DISJOINT_EMPTY_REFL,
DISJOINT_BIGUNION, INTER_SUBSET, INTER_IDEMPOT, UNION_IDEMPOT,
SUBSET_UNION];
val UNIONL_def = Define `(UNIONL [] = {})
/\ (UNIONL (s::ss) = (s:'a ->bool) UNION UNIONL ss)`;
val IN_UNIONL = store_thm
("IN_UNIONL",
``!l (v:'a ). (v IN UNIONL l) = (?s. MEM s l /\ v IN s)``,
Induct >> RW_TAC std_ss [UNIONL_def, MEM, NOT_IN_EMPTY]
++ RW_TAC std_ss [UNIONL_def, MEM, NOT_IN_EMPTY, IN_UNION]
++ PROVE_TAC []);
val IN_o = store_thm
("IN_o", ``!x f s. x IN (s o f) <=> f x IN s``,
RW_TAC std_ss [SPECIFICATION, o_THM]);
val elt_rewrs
= [SUBSET_DEF, IN_COMPL, IN_DIFF, IN_UNIV, NOT_IN_EMPTY, IN_UNION,
IN_INTER, IN_IMAGE, IN_FUNSET, IN_DFUNSET, GSPECIFICATION,
DISJOINT_DEF, IN_BIGUNION, IN_BIGINTER, IN_COUNT, IN_o,
IN_UNIONL, IN_DELETE, IN_PREIMAGE, IN_SING, IN_INSERT];
(*--------------------*)
(*------------------------------*)
(* RBD datatypes *)
(*------------------------------*)
val _ = type_abbrev( "event" , ``:'a ->bool``);
val _ = Hol_datatype` rbd = series of rbd list |
parallel of rbd list |
atomic of 'a event `;
(*----------------------------------------------*)
(* RBD Structures Semantic Function *)
(*----------------------------------------------*)
val rbd_struct_def = Define `
(rbd_struct p ( atomic a) = a) /\
(rbd_struct p (series []) = p_space p) /\
(rbd_struct p (series (x::xs)) =
rbd_struct p (x:'a rbd) INTER rbd_struct p (series (xs))) /\
(rbd_struct p (parallel []) = {} ) /\
(rbd_struct p (parallel (x::xs)) =
rbd_struct p (x:'a rbd) UNION rbd_struct p (parallel (xs)))`;
(*---rbd list from atomic events---*)
val rbd_list_def = Define `
(rbd_list [] = []) /\
(rbd_list (h::t) = atomic h::rbd_list t)`;
(* -------------------- *)
(* Definitions *)
(* -------------------- *)
val of_DEF = Q.new_infixr_definition("of_DEF", `$of g f = (g o (\a. MAP f a))`, 800);
(* ------------------------------------------ *)
(* Compliment of a List of Sets *)
(* ------------------------------------------ *)
val compl_list_def = Define
` compl_list p L = MAP (\a. p_space p DIFF a) L`;
(* -------------------------------------------*)
(* one_minus_list *)
(* -------------------------------------------*)
val one_minus_list_def = Define
`(one_minus_list [] = []) /\
(!h t. one_minus_list (h::t) = (1 - (h:real)):: one_minus_list t)`;
(* ----------------------------------------- *)
(* complement prob space *)
(* ----------------------------------------- *)
val compl_pspace_def = Define `compl_pspace p s = p_space p DIFF s`;
(* ----------------------------------------- *)
(* Product of Complement of Reliabilities *)
(* ----------------------------------------- *)
val PROD_LIST_one_minus_rel_def = Define
`PROD_LIST_one_minus_rel p L = MAP (\a. PROD_LIST (one_minus_list (PROB_LIST p a)) ) L`;
(* -------------------------------------------------------------------------- *)
(* *)
(* list of product reliabilities *)
(* *)
(* -------------------------------------------------------------------------- *)
val PROD_LIST_rel_def = Define `PROD_LIST_rel p L = MAP (\a. PROD_LIST (PROB_LIST p a) ) L`;
(*----------------------Theorems-----------------------------*)
(*----------------------------------------------------------*)
(* Theorem: Series RBD Structure *)
(*--------------------------------------------------------*)
(*------------------------------------*)
(* Series Structure Lemma *)
(*------------------------------------*)
(*-------series_rbd_eq_PATH---*)
val series_rbd_eq_PATH = store_thm("series_rbd_eq_PATH",
``!p L. rbd_struct p (series (rbd_list L)) = PATH p L``,
GEN_TAC
++ Induct
>> (RW_TAC std_ss[rbd_list_def,rbd_struct_def,PATH_DEF])
++ RW_TAC std_ss[rbd_list_def,rbd_struct_def,PATH_DEF]);
(*------------------------------------- *)
(* Reliability of Series Structure *)
(*-------------------------------------*)
val series_struct_thm = store_thm("series_struct_thm",
``!p L. prob_space p /\ ~NULL L /\ (!x'. MEM x' L ==> x' IN events p ) /\
MUTUAL_INDEP p L ==>
(prob p (rbd_struct p (series (rbd_list L))) = PROD_LIST (PROB_LIST p L))``,
RW_TAC std_ss[] THEN
(`(rbd_struct p (series (rbd_list L))) = PATH p L ` by Induct_on `L`) THEN1
RW_TAC std_ss[rbd_list_def,rbd_struct_def,PATH_DEF] THENL[
RW_TAC std_ss[PATH_DEF] THEN
FULL_SIMP_TAC std_ss[NULL] THEN
RW_TAC std_ss[] THEN
Cases_on `L` THEN1
RW_TAC std_ss[rbd_list_def,rbd_struct_def,PATH_DEF] THEN
FULL_SIMP_TAC std_ss[NULL] THEN
(`(!x'. MEM x' ((h'::t):'a event list) ==> x' IN events p) /\
MUTUAL_INDEP p (h'::t)` by RW_TAC std_ss[]) THENL[
FULL_SIMP_TAC list_ss[],
MATCH_MP_TAC MUTUAL_INDEP_CONS THEN
EXISTS_TAC(``h:'a ->bool``) THEN
RW_TAC std_ss[],
FULL_SIMP_TAC std_ss[] THEN
FULL_SIMP_TAC std_ss[rbd_list_def,rbd_struct_def,PATH_DEF]],
FULL_SIMP_TAC std_ss[MUTUAL_INDEP_DEF] THEN
POP_ASSUM (K ALL_TAC) THEN
POP_ASSUM (MP_TAC o Q.SPEC `(L:'a event list)`) THEN
RW_TAC std_ss[] THEN
POP_ASSUM (MP_TAC o Q.SPEC `LENGTH((L:'a event list))`) THEN
RW_TAC std_ss[] THEN
FULL_SIMP_TAC std_ss[PERM_REFL] THEN
FULL_SIMP_TAC std_ss[GSYM LENGTH_NOT_NULL] THEN
(`1 <= LENGTH (L:'a event list)` by ONCE_REWRITE_TAC[ONE]) THENL[
MATCH_MP_TAC LESS_OR THEN
RW_TAC std_ss[],
FULL_SIMP_TAC std_ss[TAKE_LENGTH_ID]]]);
(*------------------------------------*)
(* Parallel RBD Structure *)
(*------------------------------------*)
(*----------------Definitions---------*)
(*------------------------------------*)
(* Lemmma's *)
(*------------------------------------*)
val parallel_rbd_lem1 = store_thm("parallel_rbd_lem1",
``!p L. prob_space p /\ (!x'. MEM x' L ==> x' IN events p ) ==> (one_minus_list (PROB_LIST p L) = PROB_LIST p ( compl_list p L))``,
GEN_TAC THEN
Induct THEN1
RW_TAC list_ss[compl_list_def,PROB_LIST_DEF,one_minus_list_def] THEN
RW_TAC list_ss[compl_list_def,PROB_LIST_DEF,one_minus_list_def] THEN
MATCH_MP_TAC EQ_SYM THEN
MATCH_MP_TAC PROB_COMPL THEN
RW_TAC std_ss[]);
(*----------in_events_PATH-----------------------*)
val in_events_PATH = store_thm("in_events_PATH",
``!L p. (!x. MEM x L ==> x IN events p) /\
prob_space p ==>
(PATH p L IN events p)``,
RW_TAC std_ss []
THEN Induct_on `L`
THENL[ RW_TAC std_ss[MEM, PATH_DEF,EVENTS_SPACE],
RW_TAC std_ss [MEM, PATH_DEF]
THEN MATCH_MP_TAC EVENTS_INTER
THEN RW_TAC std_ss []]);
(*-------parallel_rbd_lem2---------*)
val parallel_rbd_lem2 = store_thm("parallel_rbd_lem2",
``!L1 (L2:('a ->bool)list) Q. (LENGTH (L1 ++ ((Q::L2))) = LENGTH ((Q::L1) ++ (L2)))``,
RW_TAC list_ss[LENGTH_APPEND]);
(*-------parallel_rbd_lem3---------*)
val parallel_rbd_lem3 = store_thm("parallel_rbd_lem3",
``!A B C D. A INTER B INTER C INTER D = (B INTER C) INTER D INTER A ``,
SRW_TAC[][IN_INTER,EXTENSION,GSPECIFICATION]
THEN METIS_TAC[]
);
(*--------------parallel_rbd_lem4---------*)
val parallel_rbd_lem4 = store_thm("parallel_rbd_lem4",
``!A C. A INTER (p_space p DIFF C) = (A INTER p_space p DIFF (A INTER C)) ``,
SRW_TAC[][IN_INTER,EXTENSION,GSPECIFICATION]
THEN METIS_TAC[]
);
(*--------------parallel_rbd_lem5---------*)
val parallel_rbd_lem5 = store_thm("parallel_rbd_lem5",
``!m (L:('a ->bool)list) x. MEM x (TAKE m L) ==> MEM x L ``,
Induct
THEN1(Induct
THEN1 (RW_TAC std_ss[TAKE_def,MEM])
THEN RW_TAC std_ss[TAKE_def,MEM])
THEN Induct
THEN1( RW_TAC std_ss[TAKE_def,MEM])
THEN RW_TAC std_ss[TAKE_def,MEM]
THEN NTAC 2 (POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `L`)
THEN RW_TAC std_ss[] );
(*-------------parallel_rbd_lem6----------------*)
val parallel_rbd_lem6 = store_thm("parallel_rbd_lem6",``!A C. A INTER (p_space p DIFF C) = (A INTER p_space p DIFF (A INTER C))``,
SRW_TAC[][IN_INTER,EXTENSION,GSPECIFICATION]
THEN METIS_TAC[]);
(*-------------parallel_rbd_lem7----------------*)
val parallel_rbd_lem7 = store_thm("parallel_rbd_lem7",``!(L1:('a ->bool) list) p.
prob_space p /\
(!x. MEM x (L1) ==> x IN events p ) ==>
((L1:('a ->bool) list) = compl_list p (compl_list p L1)) ``,
Induct
>> (RW_TAC list_ss[compl_list_def,MAP])
++ RW_TAC std_ss[compl_list_def,MAP]
>> (MATCH_MP_TAC EQ_SYM
++ MATCH_MP_TAC DIFF_DIFF_SUBSET
++ (`h = h INTER p_space p` by MATCH_MP_TAC EQ_SYM)
>> (ONCE_REWRITE_TAC[INTER_COMM]
++ MATCH_MP_TAC INTER_PSPACE
++ FULL_SIMP_TAC list_ss[])
++ POP_ORW
++ RW_TAC std_ss[INTER_SUBSET])
++ NTAC 2 (POP_ASSUM MP_TAC)
++ POP_ASSUM (MP_TAC o Q.SPEC `p:( 'a -> bool) # (( 'a -> bool) -> bool) # (( 'a -> bool) -> real)`)
++ RW_TAC std_ss[]
++ FULL_SIMP_TAC std_ss[]
++ FULL_SIMP_TAC list_ss[compl_list_def]);
(*--------prob_B-------------------*)
val prob_B = store_thm("prob_B",``!p a b . prob_space p /\ (a IN events p /\ b IN events p) ==> ( prob p b = prob p ( a INTER b) + prob p (compl_pspace p a INTER b ))``,
RW_TAC std_ss[] THEN
(`(a INTER b) UNION ((compl_pspace p a) INTER (b )) = b` by ALL_TAC) THENL[
ONCE_REWRITE_TAC[INTER_COMM] THEN
RW_TAC std_ss[GSYM UNION_OVER_INTER] THEN
RW_TAC std_ss[compl_pspace_def,DIFF_SAME_UNION] THEN
(`a SUBSET p_space p` by ALL_TAC) THENL[
(`a = p_space p INTER a` by MATCH_MP_TAC EQ_SYM)THENL[
MATCH_MP_TAC INTER_PSPACE THEN
RW_TAC std_ss[],
ONCE_ASM_REWRITE_TAC[] THEN
RW_TAC std_ss[INTER_SUBSET]],
RW_TAC std_ss[UNION_DIFF] THEN
ONCE_REWRITE_TAC[INTER_COMM] THEN
MATCH_MP_TAC INTER_PSPACE THEN
RW_TAC std_ss[]],
(` prob p (a INTER b) + prob p (compl_pspace p a INTER b) = prob p ( a INTER b UNION (compl_pspace p a INTER b))` by MATCH_MP_TAC EQ_SYM ) THENL[
MATCH_MP_TAC PROB_ADDITIVE THEN
RW_TAC std_ss[] THENL[
MATCH_MP_TAC EVENTS_INTER THEN
RW_TAC std_ss[],
MATCH_MP_TAC EVENTS_INTER THEN
RW_TAC std_ss[compl_pspace_def] THEN
MATCH_MP_TAC EVENTS_COMPL THEN
RW_TAC std_ss[],
RW_TAC std_ss[DISJOINT_DEF] THEN
RW_TAC std_ss[INTER_COMM] THEN
RW_TAC std_ss[INTER_ASSOC] THEN
(`(a INTER b INTER b INTER compl_pspace p a) = (a INTER compl_pspace p a) INTER b` by SRW_TAC[][INTER_DEF,EXTENSION,GSPECIFICATION]) THENL[
EQ_TAC THENL[
RW_TAC std_ss[],
RW_TAC std_ss[]],
ONCE_ASM_REWRITE_TAC[] THEN
RW_TAC std_ss[compl_pspace_def] THEN
(`a INTER (p_space p DIFF a) = EMPTY` by ONCE_REWRITE_TAC[INTER_COMM]) THENL[
RW_TAC std_ss[DIFF_INTER] THEN
(`p_space p INTER a = a` by MATCH_MP_TAC INTER_PSPACE) THENL[
RW_TAC std_ss[],
ONCE_ASM_REWRITE_TAC[] THEN
RW_TAC std_ss[DIFF_EQ_EMPTY]],
ONCE_ASM_REWRITE_TAC[] THEN
RW_TAC std_ss[INTER_EMPTY]]]],
FULL_SIMP_TAC std_ss[]]]);
(*-------Prob_Incl_excl--------------------*)
val Prob_Incl_excl = store_thm("Prob_Incl_excl",``!p a b. prob_space p /\ a IN events p /\ b IN events p ==> ( prob p ((a ) UNION (b )) = prob p (a) + prob p (b) - prob p ((a) INTER (b)))``,
REPEAT GEN_TAC THEN
RW_TAC std_ss[] THEN
(` prob p (a UNION (compl_pspace p a INTER b)) = prob p (a ) + prob p (compl_pspace p a INTER b)` by MATCH_MP_TAC PROB_ADDITIVE) THENL[
RW_TAC std_ss[] THENL[
MATCH_MP_TAC EVENTS_INTER THEN
RW_TAC std_ss[compl_pspace_def] THEN
MATCH_MP_TAC EVENTS_COMPL THEN
RW_TAC std_ss[],
RW_TAC std_ss[DISJOINT_DEF] THEN
RW_TAC std_ss[INTER_ASSOC] THEN
RW_TAC std_ss[compl_pspace_def] THEN
(`a INTER (p_space p DIFF a) = EMPTY` by ONCE_REWRITE_TAC[INTER_COMM]) THENL[
RW_TAC std_ss[DIFF_INTER] THEN
(`p_space p INTER a = a` by MATCH_MP_TAC INTER_PSPACE) THENL[
RW_TAC std_ss[],
ONCE_ASM_REWRITE_TAC[] THEN
RW_TAC std_ss[DIFF_EQ_EMPTY]],
ONCE_ASM_REWRITE_TAC[] THEN
RW_TAC std_ss[INTER_EMPTY]
]],
(`(a UNION (compl_pspace p a INTER b) = a UNION b)` by RW_TAC std_ss[INTER_OVER_UNION]) THEN1(
RW_TAC std_ss[compl_pspace_def] THEN
(`(a UNION (p_space p DIFF a)) = p_space p` by ALL_TAC) THEN1(
(`a SUBSET p_space p` by ALL_TAC) THEN1(
(`a = p_space p INTER a` by MATCH_MP_TAC EQ_SYM) THEN1(
MATCH_MP_TAC INTER_PSPACE THEN
RW_TAC std_ss[]) THEN
ONCE_ASM_REWRITE_TAC[] THEN
RW_TAC std_ss[INTER_SUBSET]) THEN
RW_TAC std_ss[UNION_DIFF]) THEN
ONCE_ASM_REWRITE_TAC[] THEN
MATCH_MP_TAC INTER_PSPACE THEN
RW_TAC std_ss[] THEN
MATCH_MP_TAC EVENTS_UNION THEN
RW_TAC std_ss[]) THEN
FULL_SIMP_TAC std_ss[] THEN
(MP_TAC(Q.ISPECL [`p:('a -> bool) # (('a -> bool) -> bool) # (('a -> bool) -> real)`, `a:'a event`,`b:'a event` ]
prob_B)) THEN
RW_TAC std_ss[] THEN
REAL_ARITH_TAC]);
(*----------prob_compl_subset-----------------*)
val prob_compl_subset = store_thm("prob_compl_subset", ``!p s t. prob_space p /\ s IN events p /\ t IN events p /\ t SUBSET s ==> (prob p (s DIFF t) = prob p s - prob p t)``,
METIS_TAC [MEASURE_COMPL_SUBSET,prob_space_def,events_def,prob_def,p_space_def]);
(*-----------MUTUAL_INDEP_CONS_append----------------*)
val MUTUAL_INDEP_CONS_append = store_thm("MUTUAL_INDEP_CONS_append",``!L1 L2 h. MUTUAL_INDEP p (h::L1 ++ L2) ==> MUTUAL_INDEP p (L1 ++ h::L2)``,
RW_TAC std_ss[MUTUAL_INDEP_DEF]
THEN NTAC 3(POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `(L1'):'a event list`)
THEN RW_TAC std_ss[]
THEN NTAC 3(POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `n:num`)
THEN RW_TAC std_ss[]
THEN (`PERM (h::L1 ++ L2) ((L1'):('a -> bool)list)` by MATCH_MP_TAC PERM_TRANS)
THEN1( EXISTS_TAC (``(L1 ++ h::L2):'a event list``)
THEN RW_TAC std_ss[]
THEN RW_TAC std_ss[PERM_EQUIVALENCE_ALT_DEF]
THEN MATCH_MP_TAC EQ_SYM
THEN RW_TAC std_ss[PERM_FUN_APPEND_CONS])
THEN FULL_SIMP_TAC std_ss[]
THEN (` n <= LENGTH (h::((L1):('a -> bool)list) ++ L2)` by FULL_SIMP_TAC list_ss[LENGTH_APPEND])
THEN FULL_SIMP_TAC std_ss[]);
(*---------MUTUAL_INDEP_CONS_append1------------------*)
val MUTUAL_INDEP_CONS_append1 = store_thm("MUTUAL_INDEP_CONS_append1",``!L1 L2 Q h. MUTUAL_INDEP p (h::L1 ++ Q::L2) ==> MUTUAL_INDEP p (L1 ++ Q::h::L2)``,
RW_TAC std_ss[MUTUAL_INDEP_DEF]
THEN NTAC 3(POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `(L1'):'a event list`)
THEN RW_TAC std_ss[]
THEN NTAC 3(POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `n:num`)
THEN RW_TAC std_ss[]
THEN (`PERM (h::L1 ++ Q::L2) ((L1'):('a -> bool)list)` by MATCH_MP_TAC PERM_TRANS)
THEN1( EXISTS_TAC (``(L1 ++ Q::h::L2):'a event list``)
THEN RW_TAC std_ss[]
THEN RW_TAC std_ss[PERM_EQUIVALENCE_ALT_DEF]
THEN MATCH_MP_TAC EQ_SYM
THEN RW_TAC std_ss[PERM_FUN_APPEND_CONS,APPEND,PERM_FUN_SWAP_AT_FRONT]
THEN RW_TAC std_ss[])
THEN FULL_SIMP_TAC std_ss[]
THEN (` n <= LENGTH (h::L1 ++ Q::L2)` by FULL_SIMP_TAC list_ss[LENGTH_APPEND])
THEN FULL_SIMP_TAC std_ss[]);
(*--------MUTUAL_INDEP_CONS_SWAP---------------------*)
val MUTUAL_INDEP_CONS_SWAP = store_thm("MUTUAL_INDEP_CONS_SWAP",``!p L1 h. MUTUAL_INDEP p (h::L1) ==> MUTUAL_INDEP p (L1 ++ [h])``,
RW_TAC std_ss[MUTUAL_INDEP_DEF]
THEN NTAC 3(POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `(L1'):'a event list`)
THEN RW_TAC std_ss[]
THEN NTAC 3(POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `n:num`)
THEN RW_TAC std_ss[]
THEN (`PERM (h::L1) ((L1'):('a -> bool)list)` by MATCH_MP_TAC PERM_TRANS)
THEN1( EXISTS_TAC (``(L1 ++ [h]):'a event list``)
THEN RW_TAC std_ss[]
THEN (`((h::L1) :('a -> bool)list) = [h] ++ L1` by RW_TAC list_ss[])
THEN ONCE_ASM_REWRITE_TAC[]
THEN POP_ASSUM (K ALL_TAC)
THEN RW_TAC std_ss[PERM_APPEND])
THEN FULL_SIMP_TAC std_ss[]
THEN FULL_SIMP_TAC list_ss[LENGTH]);
(*-----------prob_indep_compl_event_PATH_list-----------------*)
val prob_indep_compl_event_PATH_list = store_thm("prob_indep_compl_event_PATH_list", ``!L1 n h p. MUTUAL_INDEP p (h::L1) /\ (!x. MEM x (h::L1) ==> x IN events p) /\ ( prob_space p) /\ (LENGTH L1 = 1) ==> ( prob p ((p_space p DIFF h) INTER PATH p (TAKE n (compl_list p L1))) =
prob p (p_space p DIFF (h:'a ->bool)) *
PROD_LIST (PROB_LIST p (TAKE n (compl_list p L1))))``,
Induct
THEN1(RW_TAC list_ss[])
THEN Induct_on `n`
THEN1(RW_TAC list_ss[TAKE_def,LENGTH]
THEN RW_TAC list_ss[PATH_DEF,PROB_LIST_DEF,PROD_LIST_DEF]
THEN RW_TAC std_ss[DIFF_INTER,INTER_IDEMPOT]
THEN REAL_ARITH_TAC )
THEN RW_TAC std_ss[LENGTH,LENGTH_NIL]
THEN RW_TAC real_ss[compl_list_def,MAP,TAKE_def,PATH_DEF,PROB_LIST_DEF,PROD_LIST_DEF]
THEN RW_TAC std_ss[DIFF_INTER,INTER_IDEMPOT]
THEN (`(p_space p INTER (p_space p DIFF ((h':('a ->bool))))) = ((p_space p DIFF (h':('a ->bool)))) ` by MATCH_MP_TAC INTER_PSPACE)
THEN1(RW_TAC std_ss[]
THEN MATCH_MP_TAC EVENTS_DIFF
THEN RW_TAC std_ss[EVENTS_SPACE]
THEN FULL_SIMP_TAC list_ss[])
THEN ONCE_ASM_REWRITE_TAC[] THEN POP_ASSUM (K ALL_TAC)
THEN RW_TAC std_ss[GSYM DIFF_UNION]
THEN (`prob p (p_space p DIFF (h' UNION h)) = 1 - prob p ((((h':('a ->bool))) UNION h)) `by MATCH_MP_TAC PROB_COMPL)
THEN1 (FULL_SIMP_TAC list_ss[EVENTS_UNION])
THEN ONCE_ASM_REWRITE_TAC[] THEN POP_ASSUM (K ALL_TAC)
THEN (`prob p ((h':('a ->bool)) UNION h) =
prob p h' + prob p ((h:('a ->bool))) -
prob p (h' INTER h) ` by MATCH_MP_TAC Prob_Incl_excl)
THEN1 (FULL_SIMP_TAC list_ss[])
THEN ONCE_ASM_REWRITE_TAC[] THEN POP_ASSUM (K ALL_TAC)
THEN FULL_SIMP_TAC std_ss[MUTUAL_INDEP_DEF]
THEN NTAC 2 (POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `[h; (h':('a ->bool))] `)
THEN RW_TAC std_ss[]
THEN NTAC 2 (POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `LENGTH [h; (h':('a ->bool))] `)
THEN RW_TAC std_ss[]
THEN FULL_SIMP_TAC std_ss[LENGTH,PERM_REFL]
THEN FULL_SIMP_TAC list_ss[TAKE]
THEN FULL_SIMP_TAC real_ss[PATH_DEF,PROB_LIST_DEF, PROD_LIST_DEF]
THEN (`h' INTER p_space p = h'` by ONCE_REWRITE_TAC[INTER_COMM])
THEN1 (MATCH_MP_TAC INTER_PSPACE
THEN FULL_SIMP_TAC list_ss[])
THEN FULL_SIMP_TAC std_ss[INTER_COMM]
THEN (POP_ASSUM (K ALL_TAC))
THEN (`(prob p (p_space p DIFF (h:('a ->bool))) =
1 - prob p (h)) /\ (prob p (p_space p DIFF (h':('a ->bool))) = 1 - prob p (h')) ` by RW_TAC std_ss[])
THEN1( FULL_SIMP_TAC list_ss[PROB_COMPL] )
THEN1 (FULL_SIMP_TAC list_ss[PROB_COMPL])
THEN ONCE_ASM_REWRITE_TAC[] THEN POP_ASSUM (K ALL_TAC)
THEN REAL_ARITH_TAC);
(*-----------prob_indep_PATH1------------------*)
val prob_indep_PATH1 = store_thm("prob_indep_PATH1",
``!(L1:('a ->bool) list) (L2:('a ->bool) list) Q n p.
prob_space p /\
MUTUAL_INDEP p (L1 ++ (Q::L2)) /\
(!x. MEM x (L1 ++ (Q::L2)) ==> x IN events p ) /\
1 <= (LENGTH (L1 ++ (Q::L2))) ==>
(prob p (PATH p (TAKE n (compl_list p L1)) INTER
PATH p ((Q::L2) )) =
PROD_LIST (PROB_LIST p (TAKE (n)(compl_list p L1) )) *
PROD_LIST (PROB_LIST p (( Q::L2) )))``,
Induct
THEN1(RW_TAC real_ss[compl_list_def,MAP,TAKE_def,PATH_DEF,PROB_LIST_DEF,PROD_LIST_DEF]
THEN FULL_SIMP_TAC std_ss[MUTUAL_INDEP_DEF]
THEN NTAC 2 (POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `((Q::L2):('a ->bool)list) `)
THEN RW_TAC real_ss[]
THEN NTAC 2 (POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `LENGTH ((Q::L2):('a ->bool)list)`)
THEN RW_TAC real_ss[]
THEN FULL_SIMP_TAC list_ss[PERM_REFL,PATH_DEF]
THEN (`(p_space p INTER (Q INTER PATH p ((L2:('a ->bool)list)))) = (Q INTER PATH p (L2))` by MATCH_MP_TAC INTER_PSPACE)
THEN1( RW_TAC std_ss[]
THEN MATCH_MP_TAC EVENTS_INTER
THEN RW_TAC std_ss[]
THEN MATCH_MP_TAC in_events_PATH
THEN FULL_SIMP_TAC std_ss[])
THEN ONCE_ASM_REWRITE_TAC[]
THEN RW_TAC std_ss[]
THEN RW_TAC std_ss[PROB_LIST_DEF,PROD_LIST_DEF])
THEN Induct_on `n`
THEN1(RW_TAC real_ss[compl_list_def,MAP,TAKE_def,PATH_DEF,PROB_LIST_DEF,PROD_LIST_DEF]
THEN FULL_SIMP_TAC std_ss[APPEND,LENGTH,LE_SUC]
THEN1 (NTAC 4 (POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `L2:('a ->bool)list`)
THEN RW_TAC std_ss[]
THEN NTAC 4 (POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `Q:('a ->bool)`)
THEN RW_TAC std_ss[]
THEN NTAC 4 (POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `0:num`)
THEN RW_TAC std_ss[]
THEN NTAC 4 (POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `p:( 'a -> bool) # (( 'a -> bool) -> bool) # (( 'a -> bool) -> real)`)
THEN RW_TAC std_ss[]
THEN FULL_SIMP_TAC std_ss[]
THEN (`MUTUAL_INDEP p (L1 ++ Q::L2) /\
(!x. MEM x (L1 ++ Q::L2) ==> x IN events p)` by STRIP_TAC)
THEN1( MATCH_MP_TAC MUTUAL_INDEP_CONS
THEN EXISTS_TAC (``h:'a event``)
THEN RW_TAC std_ss[])
THEN1 (RW_TAC std_ss[]
THEN FULL_SIMP_TAC list_ss[])
THEN FULL_SIMP_TAC std_ss[]
THEN FULL_SIMP_TAC list_ss[]
THEN FULL_SIMP_TAC list_ss[PATH_DEF]
THEN RW_TAC real_ss[PROB_LIST_DEF,PROD_LIST_DEF])
THEN FULL_SIMP_TAC std_ss[parallel_rbd_lem2]
THEN FULL_SIMP_TAC list_ss[APPEND,LENGTH_NIL])
THEN RW_TAC std_ss[compl_list_def,MAP,TAKE_def,HD,TL,PATH_DEF]
THEN RW_TAC std_ss[INTER_ASSOC]
THEN ONCE_REWRITE_TAC[parallel_rbd_lem3]
THEN RW_TAC std_ss[GSYM compl_list_def]
THEN RW_TAC std_ss[parallel_rbd_lem4]
THEN (`prob p
(PATH p (TAKE n (compl_list p (L1:('a ->bool) list))) INTER Q INTER PATH p (L2:('a ->bool) list) INTER
p_space p DIFF
PATH p (TAKE n (compl_list p L1)) INTER (Q:('a ->bool)) INTER PATH p L2 INTER h) = prob p
(PATH p (TAKE n (compl_list p L1)) INTER Q INTER PATH p L2 INTER
p_space p) - prob p
(PATH p (TAKE n (compl_list p L1)) INTER Q INTER PATH p L2 INTER h) ` by MATCH_MP_TAC prob_compl_subset)
THEN1(RW_TAC std_ss[]
THEN1(MATCH_MP_TAC EVENTS_INTER
THEN RW_TAC std_ss[]
THEN1(MATCH_MP_TAC EVENTS_INTER
THEN RW_TAC std_ss[]
THEN1(MATCH_MP_TAC EVENTS_INTER
THEN RW_TAC std_ss[]
THEN1(MATCH_MP_TAC in_events_PATH
THEN RW_TAC std_ss[]
THEN (`MEM x (compl_list p (L1:'a event list))` by MATCH_MP_TAC parallel_rbd_lem5)
THEN1(EXISTS_TAC(``n:num``)
THEN RW_TAC std_ss[])
THEN FULL_SIMP_TAC std_ss[compl_list_def,MEM_MAP]
THEN MATCH_MP_TAC EVENTS_COMPL
THEN RW_TAC std_ss[]
THEN FULL_SIMP_TAC list_ss[])
THEN FULL_SIMP_TAC list_ss[])
THEN MATCH_MP_TAC in_events_PATH
THEN RW_TAC std_ss[]
THEN FULL_SIMP_TAC list_ss[])
THEN MATCH_MP_TAC EVENTS_SPACE
THEN RW_TAC std_ss[])
THEN1 (MATCH_MP_TAC EVENTS_INTER
THEN RW_TAC std_ss[]
THEN1 (MATCH_MP_TAC EVENTS_INTER
THEN RW_TAC std_ss[]
THEN1(MATCH_MP_TAC EVENTS_INTER
THEN RW_TAC std_ss[]
THEN1(MATCH_MP_TAC in_events_PATH
THEN RW_TAC std_ss[]
THEN(`MEM x (compl_list p (L1:'a event list))` by MATCH_MP_TAC parallel_rbd_lem5)
THEN1(EXISTS_TAC(``n:num``)
THEN RW_TAC std_ss[])
THEN FULL_SIMP_TAC std_ss[compl_list_def,MEM_MAP]
THEN MATCH_MP_TAC EVENTS_COMPL
THEN RW_TAC std_ss[]
THEN FULL_SIMP_TAC list_ss[])
THEN FULL_SIMP_TAC list_ss[])
THEN MATCH_MP_TAC in_events_PATH
THEN RW_TAC std_ss[]
THEN FULL_SIMP_TAC list_ss[])
THEN FULL_SIMP_TAC list_ss[])
THEN (`PATH p L2 INTER p_space p = PATH p L2` by ONCE_REWRITE_TAC [INTER_COMM])
THEN1(MATCH_MP_TAC INTER_PSPACE
THEN RW_TAC std_ss[]
THEN MATCH_MP_TAC in_events_PATH
THEN RW_TAC std_ss[]
THEN FULL_SIMP_TAC list_ss[])
THEN RW_TAC std_ss[GSYM INTER_ASSOC]
THEN POP_ORW
THEN RW_TAC std_ss[INTER_ASSOC,INTER_SUBSET])
THEN POP_ORW
THEN (`(prob p
(PATH p (TAKE n (compl_list p L1)) INTER
PATH p (Q::L2)) =
PROD_LIST (PROB_LIST p (TAKE n (compl_list p L1))) *
PROD_LIST (PROB_LIST p (Q::L2)))` by ALL_TAC)
THEN1( NTAC 5(POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `L2:('a ->bool)list`)
THEN RW_TAC std_ss[]
THEN NTAC 5 (POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `Q:('a ->bool)`)
THEN RW_TAC std_ss[]
THEN NTAC 5 (POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `n:num`)
THEN RW_TAC std_ss[]
THEN NTAC 5 (POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `p:( 'a -> bool) # (( 'a -> bool) -> bool) # (( 'a -> bool) -> real)`)
THEN RW_TAC std_ss[]
THEN FULL_SIMP_TAC std_ss[]
THEN (`MUTUAL_INDEP p (L1 ++ Q::L2) /\
(!x. MEM x (L1 ++ Q::L2) ==> x IN events p)` by STRIP_TAC)
THEN1( MATCH_MP_TAC MUTUAL_INDEP_CONS
THEN EXISTS_TAC (``h:'a event``)
THEN FULL_SIMP_TAC list_ss[])
THEN1 (RW_TAC std_ss[]
THEN FULL_SIMP_TAC list_ss[])
THEN FULL_SIMP_TAC std_ss[]
THEN (` LENGTH (h::L1 ++ Q::L2) = LENGTH (h::(L1 ++ Q::L2))` by RW_TAC list_ss[])
THEN FULL_SIMP_TAC std_ss[]
THEN POP_ASSUM (K ALL_TAC)
THEN FULL_SIMP_TAC std_ss[LENGTH]
THEN FULL_SIMP_TAC std_ss[LE_SUC]
THEN FULL_SIMP_TAC list_ss[])
THEN (`PATH p (TAKE n (compl_list p L1)) INTER Q INTER PATH p L2 INTER p_space p = PATH p (TAKE n (compl_list p L1)) INTER PATH p (Q::L2)` by RW_TAC list_ss[PATH_DEF])
THEN1( RW_TAC std_ss[GSYM INTER_ASSOC]
THEN (`PATH p L2 INTER p_space p = PATH p L2` by ONCE_REWRITE_TAC [INTER_COMM])
THEN1(MATCH_MP_TAC INTER_PSPACE
THEN RW_TAC std_ss[]
THEN MATCH_MP_TAC in_events_PATH
THEN RW_TAC std_ss[]
THEN FULL_SIMP_TAC list_ss[])
THEN POP_ORW
THEN RW_TAC std_ss[])
THEN FULL_SIMP_TAC std_ss[]
THEN POP_ASSUM (K ALL_TAC)
THEN POP_ASSUM (K ALL_TAC)
THEN NTAC 5(POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `h::L2:('a ->bool)list`)
THEN RW_TAC std_ss[]
THEN NTAC 5 (POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `Q:('a ->bool)`)
THEN RW_TAC std_ss[]
THEN NTAC 5 (POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `n:num`)
THEN RW_TAC std_ss[]
THEN NTAC 5 (POP_ASSUM MP_TAC)
THEN POP_ASSUM (MP_TAC o Q.SPEC `p:( 'a -> bool) # (( 'a -> bool) -> bool) # (( 'a -> bool) -> real)`)
THEN RW_TAC std_ss[]
THEN FULL_SIMP_TAC std_ss[]
THEN (`MUTUAL_INDEP p (L1 ++ Q::h::L2) /\
(!x. MEM x (L1 ++ Q::h::L2) ==> x IN events p)` by STRIP_TAC)
THEN1( MATCH_MP_TAC MUTUAL_INDEP_CONS_append1
THEN FULL_SIMP_TAC list_ss[])
THEN1 (RW_TAC std_ss[]
THEN FULL_SIMP_TAC list_ss[])
THEN FULL_SIMP_TAC std_ss[]
THEN (` LENGTH (L1 ++ Q::h::L2) = LENGTH (h::L1 ++ Q::L2)` by RW_TAC list_ss[])
THEN FULL_SIMP_TAC std_ss[]
THEN POP_ASSUM (K ALL_TAC)
THEN (`(PATH p (TAKE n (compl_list p L1)) INTER Q INTER PATH p L2 INTER h) =(PATH p (TAKE n (compl_list p L1)) INTER PATH p (Q::h::L2)) ` by RW_TAC list_ss[PATH_DEF] )
THEN1(`(h INTER PATH p L2) = (PATH p L2 INTER h)` by RW_TAC std_ss[INTER_COMM]
THEN POP_ORW
THEN RW_TAC std_ss[INTER_ASSOC])
THEN FULL_SIMP_TAC std_ss[]
THEN POP_ASSUM (K ALL_TAC)
THEN POP_ASSUM (K ALL_TAC)
THEN RW_TAC list_ss[PROB_LIST_DEF,PROD_LIST_DEF]
THEN (`prob p (p_space p DIFF h) = 1 - prob p (h)` by MATCH_MP_TAC PROB_COMPL)
THEN1(FULL_SIMP_TAC list_ss[])
THEN POP_ORW
THEN REAL_ARITH_TAC);
(*-------------prob_PATH_compl_list--------------*)
val prob_PATH_compl_list = store_thm("prob_PATH_compl_list",``!(L1:('a ->bool) list) n p . prob_space p /\ MUTUAL_INDEP p (L1) /\ (!x. MEM x (L1) ==> x IN events p ) /\ 1 <= (LENGTH (L1)) ==> (prob p (PATH p (TAKE (n)(compl_list p L1) )) =
PROD_LIST (PROB_LIST p (TAKE (n)(compl_list p L1) )))``,
Induct
>> (RW_TAC std_ss[compl_list_def,MAP,TAKE_def,PATH_DEF,PROB_LIST_DEF,PROD_LIST_DEF,PROB_UNIV])
++ Induct_on `n`
>>(RW_TAC std_ss[compl_list_def,MAP,TAKE_def,PATH_DEF,PROB_LIST_DEF,PROD_LIST_DEF,PROB_UNIV])
++ RW_TAC std_ss[compl_list_def,MAP,TAKE_def,PATH_DEF,PROB_LIST_DEF,PROD_LIST_DEF,PROB_UNIV]
++ RW_TAC std_ss[GSYM compl_list_def]
++ ONCE_REWRITE_TAC[INTER_COMM]
++ RW_TAC std_ss[parallel_rbd_lem6]
++ (`prob p
(PATH p (TAKE n (compl_list p (L1:('a ->bool) list))) INTER p_space p DIFF
PATH p (TAKE n (compl_list p L1)) INTER (h:('a ->bool)) ) = prob p
(PATH p (TAKE n (compl_list p L1)) INTER p_space p ) - prob p (PATH p (TAKE n (compl_list p L1)) INTER h)` by MATCH_MP_TAC prob_compl_subset)
>> (RW_TAC std_ss[]
>> (MATCH_MP_TAC EVENTS_INTER
++ RW_TAC std_ss[]
>> (MATCH_MP_TAC in_events_PATH
++ RW_TAC std_ss[]
++(`MEM x (compl_list p (L1:'a event list))` by MATCH_MP_TAC parallel_rbd_lem5)
>> (EXISTS_TAC(``n:num``)
++ RW_TAC std_ss[])
++ FULL_SIMP_TAC std_ss[compl_list_def,MEM_MAP]
++ MATCH_MP_TAC EVENTS_COMPL
++ RW_TAC std_ss[]
++ FULL_SIMP_TAC list_ss[])
++ RW_TAC std_ss [EVENTS_SPACE])
>>(MATCH_MP_TAC EVENTS_INTER
++ RW_TAC std_ss[]
>>(MATCH_MP_TAC in_events_PATH
++ RW_TAC std_ss[]
++(`MEM x (compl_list p (L1:'a event list))` by MATCH_MP_TAC parallel_rbd_lem5)
>> (EXISTS_TAC(``n:num``)
++ RW_TAC std_ss[])
++ FULL_SIMP_TAC std_ss[compl_list_def,MEM_MAP]
++ MATCH_MP_TAC EVENTS_COMPL
++ RW_TAC std_ss[]
++ FULL_SIMP_TAC list_ss[])
++ FULL_SIMP_TAC list_ss[])
++ (`PATH p (TAKE n (compl_list p L1)) INTER p_space p = PATH p (TAKE n (compl_list p L1))` by ONCE_REWRITE_TAC [INTER_COMM])
>> (MATCH_MP_TAC INTER_PSPACE
++ RW_TAC std_ss[]
++ MATCH_MP_TAC in_events_PATH
++ RW_TAC std_ss[]
++(`MEM x (compl_list p (L1:'a event list))` by MATCH_MP_TAC parallel_rbd_lem5)
>> (EXISTS_TAC(``n:num``)
++ RW_TAC std_ss[])
++ FULL_SIMP_TAC std_ss[compl_list_def,MEM_MAP]
++ MATCH_MP_TAC EVENTS_COMPL
++ RW_TAC std_ss[]
++ FULL_SIMP_TAC list_ss[])
++ POP_ORW
++ RW_TAC std_ss[INTER_SUBSET])
++ POP_ORW
++ (`PATH p (TAKE n (compl_list p L1)) INTER p_space p = PATH p (TAKE n (compl_list p L1))` by ONCE_REWRITE_TAC [INTER_COMM])
>> (MATCH_MP_TAC INTER_PSPACE
++ RW_TAC std_ss[]
++ MATCH_MP_TAC in_events_PATH
++ RW_TAC std_ss[]
++(`MEM x (compl_list p (L1:'a event list))` by MATCH_MP_TAC parallel_rbd_lem5)
>> (EXISTS_TAC(``n:num``)
++ RW_TAC std_ss[])
++ FULL_SIMP_TAC std_ss[compl_list_def,MEM_MAP]
++ MATCH_MP_TAC EVENTS_COMPL
++ RW_TAC std_ss[]
++ FULL_SIMP_TAC list_ss[])
++ POP_ORW
++ NTAC 5 (POP_ASSUM MP_TAC)
++ POP_ASSUM (MP_TAC o Q.SPEC `n:num`)
++ RW_TAC std_ss[]
++ NTAC 5 (POP_ASSUM MP_TAC)
++ POP_ASSUM (MP_TAC o Q.SPEC `p:( 'a -> bool) # (( 'a -> bool) -> bool) # (( 'a -> bool) -> real)`)
++ RW_TAC std_ss[]
++ FULL_SIMP_TAC std_ss[]
++ (`MUTUAL_INDEP p L1 /\ (!x. MEM x L1 ==> x IN events p)` by STRIP_TAC)
>>(MATCH_MP_TAC MUTUAL_INDEP_CONS
++ EXISTS_TAC(``h:'a event``)
++ RW_TAC std_ss[])
>> (RW_TAC list_ss[])
++ FULL_SIMP_TAC std_ss[]
++ FULL_SIMP_TAC std_ss[LENGTH,LE_SUC]
>> (FULL_SIMP_TAC std_ss[]
++ (`(prob p (PATH p (TAKE (n)(compl_list p L1) ) INTER PATH p ((h::[]) )) =
PROD_LIST (PROB_LIST p (TAKE (n)(compl_list p L1) )) * PROD_LIST (PROB_LIST p ((( h::[]):('a ->bool) list) )))` by MATCH_MP_TAC prob_indep_PATH1)
>> (RW_TAC std_ss[]
>> (MATCH_MP_TAC MUTUAL_INDEP_CONS_SWAP
++ RW_TAC std_ss[])
>> ( FULL_SIMP_TAC list_ss[])
++ MATCH_MP_TAC LESS_EQ_TRANS
++ EXISTS_TAC(``LENGTH (L1:'a event list)``)
++ RW_TAC list_ss[])
++ FULL_SIMP_TAC std_ss[PATH_DEF]
++ (`h INTER p_space p = h` by ONCE_REWRITE_TAC[INTER_COMM])
>> (MATCH_MP_TAC INTER_PSPACE
++ RW_TAC std_ss[]
++ FULL_SIMP_TAC list_ss[])
++ FULL_SIMP_TAC std_ss[]
++ RW_TAC real_ss[PROB_LIST_DEF,PROD_LIST_DEF]
++ (`prob p (p_space p DIFF h) = 1 - prob p (h)` by MATCH_MP_TAC PROB_COMPL)
>> (FULL_SIMP_TAC list_ss[])
++ POP_ORW
++ REAL_ARITH_TAC)
++ FULL_SIMP_TAC std_ss[LENGTH_NIL]
++ RW_TAC real_ss[compl_list_def,MAP,TAKE_def,PATH_DEF,PROB_LIST_DEF,PROD_LIST_DEF,PROB_UNIV]
++ (`p_space p INTER h = h` by MATCH_MP_TAC INTER_PSPACE)
>> (FULL_SIMP_TAC list_ss[])
++ POP_ORW
++ (`prob p (p_space p DIFF h) = 1 - prob p (h)` by MATCH_MP_TAC PROB_COMPL)
>> (FULL_SIMP_TAC list_ss[])
++ POP_ORW
++ REAL_ARITH_TAC);
(*---------------MUTUAL_INDEP_compl_event_imp_norm_event-------------*)
val MUTUAL_INDEP_compl_event_imp_norm_event = store_thm("MUTUAL_INDEP_compl_event_imp_norm_event",
``!(L1:('a ->bool) list) p.
prob_space p /\
MUTUAL_INDEP p (compl_list p L1) /\
(!x. MEM x (L1) ==> x IN events p ) /\
1 <= (LENGTH (L1)) ==>
MUTUAL_INDEP p L1 ``,
RW_TAC std_ss[MUTUAL_INDEP_DEF]
++ (`(L1':('a ->bool) list) = compl_list p (compl_list p L1')` by MATCH_MP_TAC parallel_rbd_lem7)
>> (FULL_SIMP_TAC list_ss[]
++ (`(!x. MEM x L1 = MEM x (L1':('a ->bool) list))` by MATCH_MP_TAC PERM_MEM_EQ)
>> (RW_TAC std_ss[])
++ FULL_SIMP_TAC std_ss[])
++ POP_ORW
++ MATCH_MP_TAC prob_PATH_compl_list
++ RW_TAC std_ss[]
>> (RW_TAC std_ss[MUTUAL_INDEP_DEF]
++ NTAC 8 (POP_ASSUM MP_TAC)
++ POP_ASSUM (MP_TAC o Q.SPEC `L1'':('a ->bool) list`)
++ RW_TAC std_ss[]
++ NTAC 8 (POP_ASSUM MP_TAC)
++ POP_ASSUM (MP_TAC o Q.SPEC `n':num`)
++ RW_TAC std_ss[]
++ FULL_SIMP_TAC std_ss[]
++ (` PERM (compl_list p L1) (L1'':('a ->bool) list) /\ (n' <= LENGTH (compl_list p (L1:'a event list)))` by STRIP_TAC)
>> (MATCH_MP_TAC PERM_TRANS
++ EXISTS_TAC(``(compl_list p L1')``)
++ RW_TAC std_ss[compl_list_def]
++ MATCH_MP_TAC PERM_MAP
++ RW_TAC std_ss[])
>> (FULL_SIMP_TAC list_ss[compl_list_def,LENGTH_MAP]
++ (`LENGTH (L1:('a ->bool) list) = LENGTH (L1':('a ->bool) list)` by MATCH_MP_TAC PERM_LENGTH)
>> (RW_TAC std_ss[])
++ POP_ORW
++ RW_TAC std_ss[])
++ FULL_SIMP_TAC std_ss[])
>> (FULL_SIMP_TAC std_ss[compl_list_def,MEM_MAP]
++ MATCH_MP_TAC EVENTS_COMPL
++ RW_TAC std_ss[]
++ (`(!x. MEM x L1 = MEM x (L1':('a ->bool) list))` by MATCH_MP_TAC PERM_MEM_EQ)
>> (RW_TAC std_ss[])
++ FULL_SIMP_TAC std_ss[])
++ RW_TAC std_ss[compl_list_def,LENGTH_MAP]
++ (`LENGTH (L1:('a ->bool) list) = LENGTH (L1':('a ->bool) list)` by MATCH_MP_TAC PERM_LENGTH)
>> (RW_TAC std_ss[])
++ FULL_SIMP_TAC std_ss[]);
(*--------MUTUAL_INDEP_compl--------------------*)
val MUTUAL_INDEP_compl = store_thm("MUTUAL_INDEP_compl",
``!(L1:('a ->bool) list) p.
prob_space p /\
MUTUAL_INDEP p L1 /\
(!x. MEM x (L1) ==> x IN events p ) /\
1 <= (LENGTH (L1)) ==>
MUTUAL_INDEP p (compl_list p L1)``,
RW_TAC std_ss[]
++ MATCH_MP_TAC MUTUAL_INDEP_compl_event_imp_norm_event
++ RW_TAC std_ss[]
>> ((`compl_list p (compl_list p L1) = (L1:('a ->bool) list)` by MATCH_MP_TAC EQ_SYM)
>> (MATCH_MP_TAC parallel_rbd_lem7
++ RW_TAC std_ss[])
++ POP_ORW
++ RW_TAC std_ss[])
>> (FULL_SIMP_TAC list_ss[compl_list_def,MEM_MAP]
++ MATCH_MP_TAC EVENTS_COMPL
++ RW_TAC std_ss[])
++ RW_TAC std_ss[compl_list_def,LENGTH_MAP]);
(*------------------------------------*)
(*------Parallel RBD Configuration----*)
(*------------------------------------*)
(*------Parallel_Lemma1----*)
val parallel_lem1 = store_thm("parallel_lem1",``!p s t. p_space p DIFF (s UNION t) = (p_space p DIFF s) INTER (p_space p DIFF t)``,
SRW_TAC [][EXTENSION,GSPECIFICATION]
++ METIS_TAC[]);
(*----------- parallel_lem2---------------*)
val parallel_lem2 = store_thm("parallel_lem2",``!p (L:('a -> bool) list). prob_space p /\ (!x. MEM x L ==> x IN events p) ==>
( rbd_struct p (series (rbd_list (compl_list p L))) = p_space p DIFF (rbd_struct p ( parallel (rbd_list L)) ))``,
GEN_TAC
++ Induct
>> (RW_TAC list_ss[compl_list_def,rbd_list_def,rbd_struct_def,DIFF_EMPTY])
++ RW_TAC std_ss[]
++ RW_TAC list_ss[compl_list_def,rbd_list_def,rbd_struct_def]
++ FULL_SIMP_TAC std_ss[]
++ RW_TAC std_ss[GSYM compl_list_def]
++ (`(!x. MEM x L ==> x IN events p)` by FULL_SIMP_TAC list_ss[])
++ FULL_SIMP_TAC std_ss[]
++ RW_TAC std_ss[parallel_lem1]);
(*------------parallel_lem3-------------*)
val parallel_lem3 = store_thm("parallel_lem3",``!L p. (!x. MEM x L ==> x IN events p) /\
prob_space p ==>
(rbd_struct p (parallel (rbd_list L)) IN events p)``,
RW_TAC std_ss[]
++ Induct_on `L`
>> (RW_TAC list_ss[compl_list_def,rbd_list_def,rbd_struct_def,EVENTS_EMPTY])
++ RW_TAC std_ss[rbd_list_def,MAP, rbd_struct_def]
++ (`(!x. MEM x L ==> x IN events p)` by FULL_SIMP_TAC list_ss[])
++ FULL_SIMP_TAC std_ss[]
++ MATCH_MP_TAC EVENTS_UNION
++ FULL_SIMP_TAC list_ss[]);
(*----------------parallel_lem4----------------------*)
val parallel_lem4 = store_thm("parallel_lem4",``!p L. (!x. MEM x L ==> x IN events p) /\
prob_space p /\
((rbd_struct p (parallel (rbd_list L))) IN events p) ==> ((rbd_struct p (parallel (rbd_list L))) SUBSET p_space p )``,
GEN_TAC
++ Induct
>> (RW_TAC list_ss[compl_list_def,rbd_list_def,rbd_struct_def]
++ FULL_SIMP_TAC std_ss[SUBSET_DEF, NOT_IN_EMPTY])
++ RW_TAC std_ss[compl_list_def,MAP,rbd_list_def,rbd_struct_def]
++ RW_TAC std_ss[UNION_SUBSET]
>> ((`h = h INTER p_space p` by MATCH_MP_TAC EQ_SYM)
>> (ONCE_REWRITE_TAC[INTER_COMM]
++ MATCH_MP_TAC INTER_PSPACE
++ FULL_SIMP_TAC list_ss[])
++ POP_ORW
++ RW_TAC std_ss[INTER_SUBSET])
++ FULL_SIMP_TAC std_ss[]
++ (`(!x. MEM x L ==> x IN events p)` by FULL_SIMP_TAC list_ss[])
++ FULL_SIMP_TAC std_ss[parallel_lem3]);
(*----------------parallel_lem5----------------------*)
val parallel_lem5 = store_thm("parallel_lem5",``!p L. rbd_struct p (series (rbd_list L)) = PATH p L``,
RW_TAC std_ss[]
++ Induct_on `L`
>> (RW_TAC list_ss[rbd_list_def,rbd_struct_def,PATH_DEF])
++ RW_TAC list_ss[rbd_list_def,rbd_struct_def,PATH_DEF]);
(*-----------------parallel_lem6---------------------*)
val parallel_lem6 = store_thm("parallel_lem6",``!p x L. prob_space p /\ (!x'. MEM x' L ==> x' IN events p) ==>
(prob p (rbd_struct p (parallel (rbd_list L))) = 1 - prob p (rbd_struct p (series (rbd_list (compl_list p ( L))))))``,
RW_TAC std_ss[]
++ (`rbd_struct p (parallel (rbd_list L)) SUBSET p_space p` by MATCH_MP_TAC parallel_lem4)
>> (RW_TAC std_ss[]
++ MATCH_MP_TAC parallel_lem3
++ RW_TAC std_ss[])
++ (`(1 - prob p (rbd_struct p (series (rbd_list (compl_list p L))))) = (prob p (p_space p DIFF (rbd_struct p (series (rbd_list (compl_list p L))))))` by MATCH_MP_TAC EQ_SYM)
>> (MATCH_MP_TAC PROB_COMPL
++ RW_TAC std_ss[]
++ RW_TAC std_ss[parallel_lem5]
++ MATCH_MP_TAC in_events_PATH
++ RW_TAC list_ss[compl_list_def,MEM_MAP]
++ MATCH_MP_TAC EVENTS_COMPL
++ FULL_SIMP_TAC list_ss[])
++ POP_ORW
++ RW_TAC std_ss[]
++ RW_TAC std_ss[parallel_lem2]
++ RW_TAC std_ss[DIFF_DIFF_SUBSET]);
(*--------------parallel_lem7----------------------*)
val parallel_lem7 = store_thm("parallel_lem7",``!p (L). prob_space p /\ (!x'. MEM x' L ==> x' IN events p ) ==> (one_minus_list (PROB_LIST p L) = PROB_LIST p ( compl_list p L))``,
RW_TAC std_ss[]
++ Induct_on `L`
>> (RW_TAC std_ss[one_minus_list_def,compl_list_def,MAP,PROB_LIST_DEF])
++ RW_TAC std_ss[one_minus_list_def,compl_list_def,MAP,PROB_LIST_DEF]
>> (MATCH_MP_TAC EQ_SYM
++ MATCH_MP_TAC PROB_COMPL
++ FULL_SIMP_TAC list_ss[])
++ (`(!x'. MEM x' L ==> x' IN events p)` by FULL_SIMP_TAC list_ss[])
++ FULL_SIMP_TAC std_ss[]
++ RW_TAC std_ss[GSYM compl_list_def]);
(*------------------------------------*)
val parallel_lem8 = store_thm("parallel_lem8",
`` !L. one_minus_list L = MAP (\a. 1 - a) L ``,
Induct
++ RW_TAC list_ss[one_minus_list_def]);
(*------------------------------------*)
(*-----------Parallel_struct_thm------*)
(*------------------------------------*)
val parallel_struct_thm = store_thm("parallel_struct_thm", ``!p L . ~NULL L /\ (!x'. MEM x' L ==> x' IN events p) /\ prob_space p /\ MUTUAL_INDEP p L ==> (prob p (rbd_struct p (parallel (rbd_list L))) =
1 - PROD_LIST (one_minus_list (PROB_LIST p L)))``,
RW_TAC real_ss[parallel_lem6,real_sub,REAL_EQ_LADD,REAL_EQ_NEG]
++ (`prob p (rbd_struct p (series (rbd_list (compl_list p L)))) = PROD_LIST (PROB_LIST p (compl_list p L))` by MATCH_MP_TAC series_struct_thm)
>> (RW_TAC std_ss[]
>> (RW_TAC std_ss[GSYM LENGTH_NOT_NULL]
++ RW_TAC std_ss[compl_list_def,LENGTH_MAP]
++ RW_TAC std_ss[LENGTH_NOT_NULL])
>> (FULL_SIMP_TAC list_ss[compl_list_def,MEM_MAP]
++ MATCH_MP_TAC EVENTS_COMPL
++ FULL_SIMP_TAC list_ss[])