-
Notifications
You must be signed in to change notification settings - Fork 119
/
DebianAdapter.pm
827 lines (630 loc) · 23.5 KB
/
DebianAdapter.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
=head1 NAME
autoinstaller::Adapter::DebianAdapter - Debian autoinstaller adapter class
=cut
# i-MSCP - internet Multi Server Control Panel
# Copyright 2010-2015 by internet Multi Server Control Panel
#
# This program is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License
# as published by the Free Software Foundation; either version 2
# of the License, or (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
#
# @category i-MSCP
# @copyright 2010-2015 by i-MSCP | http://i-mscp.net
# @author Laurent Declercq <l.declercq@nuxwin.com>
# @link http://i-mscp.net i-MSCP Home Site
# @license http://www.gnu.org/licenses/gpl-2.0.html GPL v2
package autoinstaller::Adapter::DebianAdapter;
use strict;
use warnings;
no if $] >= 5.017011, warnings => 'experimental::smartmatch';
use iMSCP::Debug;
use iMSCP::EventManager;
use iMSCP::Execute;
use iMSCP::Dialog;
use iMSCP::File;
use iMSCP::Stepper;
use iMSCP::Getopt;
use iMSCP::ProgramFinder;
use File::Temp;
use parent 'autoinstaller::Adapter::AbstractAdapter';
=head1 DESCRIPTION
i-MSCP autoinstaller adapter implementation for Debian.
=head1 PUBLIC METHODS
=over 4
=item installPreRequiredPackages()
Install pre-required packages
Return int 0 on success, other on failure
=cut
sub installPreRequiredPackages
{
my $self = $_[0];
$self->{'eventManager'}->trigger('beforeInstallPreRequiredPackages', $self->{'preRequiredPackages'});
my $command = 'apt-get';
my $preseed = iMSCP::Getopt->preseed;
fatal('Not a Debian like system') unless iMSCP::ProgramFinder::find($command);
# Ensure packages index is up to date
my $rs = $self->_updatePackagesIndex();
return $rs if $rs;
unless($preseed || $main::noprompt || ! iMSCP::ProgramFinder::find('debconf-apt-progress')) {
$command = 'debconf-apt-progress --logstderr -- ' . $command;
}
my ($stdout, $stderr);
$rs = execute(
"$command -y -o DPkg::Options::='--force-confnew' -o DPkg::Options::='--force-confmiss' --auto-remove --purge " .
"--no-install-recommends install @{$self->{'preRequiredPackages'}}",
($preseed || $main::noprompt) ? \$stdout : undef, \$stderr
);
debug($stdout) if $stdout;
error($stderr) if $stderr && $rs;
error('Unable to install pre-required packages') if $rs && ! $stderr;
return $rs if $rs;
$self->{'eventManager'}->trigger('afterInstallPreRequiredPackages');
}
=item preBuild()
Process preBuild tasks
Return int 0 on success, other on failure
=cut
sub preBuild
{
my $self = $_[0];
my $rs = $self->{'eventManager'}->trigger('beforePreBuild');
return $rs if $rs;
unless($main::skippackages) {
if($main::imscpConfig{'DATABASE_PASSWORD'} ne '' && not $main::reconfigure ~~ [ 'sql', 'servers', 'all' ]) {
$ENV{'DEBIAN_PRIORITY'} = 'critical';
}
my @steps = (
[ sub { $self->_buildPackageList(); }, 'Building list of packages to install/uninstall' ],
[ sub { $self->_prefillDebconfDatabase(); }, 'Pre-fill debconf database' ],
[ sub { $self->_processAptRepositories(); }, 'Processing APT repositories if any' ],
[ sub { $self->_processAptPreferences(); }, 'Processing APT preferences if any' ],
[ sub { $self->_updatePackagesIndex(); }, 'Updating packages index' ]
);
my $step = 1;
my $nbSteps = scalar @steps;
for (@steps) {
$rs = step($_->[0], $_->[1], $nbSteps, $step);
return $rs if $rs;
$step++;
}
}
$self->{'eventManager'}->trigger('afterPreBuild');
}
=item installPackages()
Install Debian packages
Return int 0 on success, other on failure
=cut
sub installPackages
{
my $self = $_[0];
iMSCP::Dialog->getInstance()->endGauge();
# Remove packages which must be pre-removed
my $rs = $self->uninstallPackages($self->{'packagesToPreUninstall'});
return $rs if $rs;
$rs = $self->{'eventManager'}->trigger(
'beforeInstallPackages', $self->{'packagesToInstall'}, $self->{'packagesToInstallDelayed'}
);
return $rs if $rs;
# Prevent the package manager to start some services itself using the policy layer interface.
# Apache2: This prevents failures such as when nginx is installed after Apache2 which is already listening on port 80...
# Bind9: This avoid error when resolvconf is not configured yet
my $file = iMSCP::File->new( filename => '/usr/sbin/policy-rc.d' );
$rs = $file->set(<<EOF);
#/bin/sh
initscript=\$1
action=\$2
if [ "\$action" = "start" ] && { [ "\$initscript" = "apache2" ] || [ "\$initscript" = "bind9" ] ; } then
exit 101;
fi
exit 0
EOF
$rs ||= $file->save();
$rs ||= $file->mode(0755);
return $rs if $rs;
my $preseed = iMSCP::Getopt->preseed;
for my $packages($self->{'packagesToInstall'}, $self->{'packagesToInstallDelayed'}) {
if(@{$packages}) {
my @command = ();
unless($preseed || $main::noprompt || ! iMSCP::ProgramFinder::find('debconf-apt-progress')) {
push @command, 'debconf-apt-progress --logstderr --';
}
unshift @command, 'UCF_FORCE_CONFFMISS=1 '; # Force installation of missing conffiles which are managed by UCF
if($main::forcereinstall) {
push @command, "apt-get -y -o DPkg::Options::='--force-confnew' -o DPkg::Options::='--force-confmiss' " .
"--reinstall --auto-remove --purge --no-install-recommends install @{$packages}";
} else {
push @command, "apt-get -y -o DPkg::Options::='--force-confnew' -o DPkg::Options::='--force-confmiss' " .
"--auto-remove --purge --no-install-recommends install @{$packages}";
}
my ($stdout, $stderr);
$rs = execute("@command", ($preseed || $main::noprompt) ? \$stdout : undef, \$stderr);
debug($stdout) if $stdout;
error($stderr) if $stderr && $rs;
error('Unable to install packages') if $rs && ! $stderr;
return $rs if $rs;
}
}
# Delete '/usr/sbin/policy-rc.d file
$rs = $file->delFile();
return $rs if $rs;
$self->{'eventManager'}->trigger('afterInstallPackages');
}
=item uninstallPackages([ \@packages ])
Uninstall Debian packages
Param array \@packages OPTIONAL List of packages to uninstall ( default is list from the packagesToUninstall attribute )
Return int 0 on success, other on failure
=cut
sub uninstallPackages
{
my ($self, $packages) = @_;
$packages ||= $self->{'packagesToUninstall'};
eval "use List::MoreUtils qw(uniq); 1";
fatal($@) if $@;
# Remove any duplicate entry
# Do not try to remove any packages which were scheduled for installation
@{$packages} = grep {
not $_ ~~ [ @{$self->{'packagesToInstall'}}, @{$self->{'packagesToInstallDelayed'}} ]
} uniq(@{$packages});
# Do not try to remove packages which are no longer available
if(@{$packages}) {
my ($stdout, $stderr);
my $rs = execute("LANG=C dpkg-query -W -f='\${Package}\n' @{$packages} 2>/dev/null", \$stdout, \$stderr);
error($stderr) if $stderr && $rs > 1;
return $rs if $rs > 1;
@{$packages} = split /\n/, $stdout;
}
my $rs = $self->{'eventManager'}->trigger('beforeUninstallPackages', @{$packages});
return $rs if $rs;
if(@{$packages}) {
my $preseed = iMSCP::Getopt->preseed;
my @command = ();
unless($preseed || $main::noprompt || ! iMSCP::ProgramFinder::find('debconf-apt-progress')) {
iMSCP::Dialog->getInstance()->endGauge();
push @command, 'debconf-apt-progress --logstderr --';
}
push @command, "apt-get -y --auto-remove --purge --no-install-recommends remove @{$packages}";
my ($stdout, $stderr);
my $rs = execute("@command", ($preseed || $main::noprompt) ? \$stdout : undef, \$stderr);
debug($stdout) if $stdout;
error($stderr) if $stderr && $rs;
error('Unable to uninstall packages') if $rs && ! $stderr;
return $rs if $rs;
}
$self->{'eventManager'}->trigger('afterUninstallPackages');
}
=item postBuild()
Process postBuild tasks
Return int 0 on success, other on failure
=cut
sub postBuild
{
# Needed to fix #IP-1246
if(iMSCP::ProgramFinder::find('php5dismod')) {
for (
'apc', 'curl', 'gd', 'imap', 'intl', 'json', 'mcrypt', 'mysqlnd', 'mysqli', 'mysql', 'opcache', 'pdo',
'pdo_mysql'
) {
my($stdout, $stderr);
my $rs = execute("php5dismod $_", \$stdout, \$stderr);
debug($stdout) if $stdout;
unless($rs ~~ [ 0, 2 ]) {
error($stderr) if $stderr;
return $rs;
}
}
}
# Enable needed PHP modules ( only if they are available )
if(iMSCP::ProgramFinder::find('php5enmod')) {
for (
'apc', 'curl', 'gd', 'imap', 'intl', 'json', 'mcrypt', 'mysqlnd/10', 'mysqli', 'mysql', 'opcache', 'pdo/10',
'pdo_mysql'
) {
my($stdout, $stderr);
my $rs = execute("php5enmod $_", \$stdout, \$stderr);
debug($stdout) if $stdout;
unless($rs ~~ [ 0, 2 ]) {
error($stderr) if $stderr;
return $rs;
}
}
}
0;
}
=back
=head1 PRIVATE METHODS
=over 4
=item _init()
Initialize instance
Return autoinstaller::Adapter::DebianAdapter
=cut
sub _init
{
my $self = $_[0];
$self->{'eventManager'} = iMSCP::EventManager->getInstance();
delete $ENV{'DEBCONF_FORCE_DIALOG'};
$ENV{'DEBIAN_FRONTEND'} = 'noninteractive' if iMSCP::Getopt->preseed || iMSCP::Getopt->noprompt;
$self->{'repositorySections'} = [ 'main', 'non-free' ];
$self->{'preRequiredPackages'} = [
'aptitude', 'debconf-utils', 'dialog', 'libbit-vector-perl', 'libclass-insideout-perl', 'liblist-moreutils-perl',
'libscalar-defer-perl', 'libxml-simple-perl', 'wget', 'rsync'
];
$self->{'aptRepositoriesToRemove'} = [];
$self->{'aptRepositoriesToAdd'} = [];
$self->{'aptPreferences'} = [];
$self->{'packagesToInstall'} = [];
$self->{'packagesToInstallDelayed'} = [];
$self->{'packagesToPreUninstall'} = [];
$self->{'packagesToUninstall'} = [];
$self->_updateAptSourceList() and fatal('Unable to configure APT packages manager') unless $main::skippackages;
$self;
}
=item _buildPackageList()
Build lists of Debian packages to uninstalle and install
Return int 0 on success, other on failure
=cut
sub _buildPackageList
{
my $self = $_[0];
my $lsbRelease = iMSCP::LsbRelease->getInstance();
my $dist = lc($lsbRelease->getId(1));
my $codename = lc($lsbRelease->getCodename(1));
my $pkgFile = "$FindBin::Bin/docs/" . ucfirst($dist) . "/packages-$codename.xml";
eval "use XML::Simple; 1";
fatal($@) if $@;
my $xml = XML::Simple->new(NoEscape => 1);
my $pkgList = eval { $xml->XMLin($pkgFile, ForceArray => [ 'package', 'package_delayed', 'package_conflict' ]) };
unless($@) {
# For each package section found in package list
for my $section(sort keys %{$pkgList}) {
if(exists $pkgList->{$section}->{'package'} || exists $pkgList->{$section}->{'package_delayed'}) {
# Simple list of packages to install
if(exists $pkgList->{$section}->{'package'}) {
push @{$self->{'packagesToInstall'}}, @{$pkgList->{$section}->{'package'}};
}
if(exists $pkgList->{$section}->{'package_delayed'}) {
push @{$self->{'packagesToInstallDelayed'}}, @{$pkgList->{$section}->{'package_delayed'}};
}
} else {
# List of alternative services
my $dAlt = delete $pkgList->{$section}->{'default'};
my $sAlt = $main::questions{ uc($section) . '_SERVER' } || $main::imscpConfig{ uc($section) . '_SERVER' };
my $forceDialog = ($sAlt) ? 0 : 1;
$sAlt = $dAlt if $forceDialog;
my @alts = keys %{$pkgList->{$section}};
if(not $sAlt ~~ @alts) { # Handle wrong or deprecated entry case
$sAlt = $dAlt;
$forceDialog = 1;
}
if(exists $pkgList->{$section}->{$sAlt}->{'allow_switch_to'}) {
if($pkgList->{$section}->{$sAlt}->{'allow_switch_to'} ne '') {
my @allowedAlts = (split(',', $pkgList->{$section}->{$sAlt}->{'allow_switch_to'}), $sAlt);
@alts = grep { $section ~~ @allowedAlts } @alts;
} else {
@alts = ($sAlt);
}
}
@alts = sort @alts;
# Ask user service to install if needed
if(@alts > 1 && ($forceDialog || $main::reconfigure ~~ [ $section, 'servers', 'all' ])) {
iMSCP::Dialog->getInstance()->set('no-cancel', '');
(my $ret, $sAlt) = iMSCP::Dialog->getInstance()->radiolist(<<EOF, [@alts], $sAlt);
Please, choose the i-MSCP server implementation you want use for the $section service:
EOF
return $ret if $ret; # Handle ESC case
iMSCP::Dialog->getInstance()->set('no-cancel');
}
if($section eq 'sql') {
my ($stdout, $stderr);
my $rs = execute("$main::imscpConfig{'CMD_RM'} -f /var/lib/mysql/debian-*.flag", \$stdout, \$stderr);
debug($stdout) if $stdout;
error($stderr) if $rs && $stderr;
return $rs if $rs;
}
for my $alt(@alts) {
if($alt ne $sAlt) {
# APT repository to remove
if(exists $pkgList->{$section}->{$alt}->{'repository'}) {
push @{$self->{'aptRepositoriesToRemove'}}, $pkgList->{$section}->{$alt}->{'repository'};
}
# Packages to uninstall
if(exists $pkgList->{$section}->{$alt}->{'package'}) {
push @{$self->{'packagesToUninstall'}}, @{$pkgList->{$section}->{$alt}->{'package'}};
}
if(exists $pkgList->{$section}->{$alt}->{'package_delayed'}) {
push @{$self->{'packagesToUninstall'}}, @{$pkgList->{$section}->{$alt}->{'package_delayed'}};
}
}
}
# APT preferences to add
if(exists $pkgList->{$section}->{$sAlt}->{'pinning_package'}) {
push @{$self->{'aptPreferences'}}, {
'pinning_package' => $pkgList->{$section}->{$sAlt}->{'pinning_package'},
'pinning_pin' => $pkgList->{$section}->{$sAlt}->{'pinning_pin'} || undef,
'pinning_pin_priority' => $pkgList->{$section}->{$sAlt}->{'pinning_pin_priority'} || undef,
};
}
# Conflicting repository which must be removed
if(exists $pkgList->{$section}->{$sAlt}->{'repository_conflict'}) {
push @{$self->{'aptRepositoriesToRemove'}}, $pkgList->{$section}->{$sAlt}->{'repository_conflict'};
}
# APT repository to add
if(exists $pkgList->{$section}->{$sAlt}->{'repository'}) {
push @{$self->{'aptRepositoriesToAdd'}}, {
'repository' => $pkgList->{$section}->{$sAlt}->{'repository'},
'repository_key_uri' => $pkgList->{$section}->{$sAlt}->{'repository_key_uri'} || undef,
'repository_key_id' => $pkgList->{$section}->{$sAlt}->{'repository_key_id'} || undef,
'repository_key_srv' => $pkgList->{$section}->{$sAlt}->{'repository_key_srv'} || undef
};
}
# Conflicting packages which must be pre-removed
if(exists $pkgList->{$section}->{$sAlt}->{'package_conflict'}) {
push @{$self->{'packagesToPreUninstall'}}, @{$pkgList->{$section}->{$sAlt}->{'package_conflict'}};
}
# Packages to install
if(exists $pkgList->{$section}->{$sAlt}->{'package'}) {
push @{$self->{'packagesToInstall'}}, @{$pkgList->{$section}->{$sAlt}->{'package'}};
}
if(exists $pkgList->{$section}->{$sAlt}->{'package_delayed'}) {
push @{$self->{'packagesToInstallDelayed'}}, @{$pkgList->{$section}->{$sAlt}->{'package_delayed'}};
}
# Set server implementation to use
$main::questions{ uc($section) . '_SERVER' } = $sAlt;
}
}
} else {
error($@);
return 1;
}
0;
}
=item _updateAptSourceList()
Add required sections to repositories that support them
Return int 0 on success, other on failure
=cut
sub _updateAptSourceList
{
my $self = $_[0];
my $file = iMSCP::File->new( filename => '/etc/apt/sources.list' );
my $rs = $file->copyFile('/etc/apt/sources.list.bkp') unless -f '/etc/apt/sources.list.bkp';
return $rs if $rs;
my $fileContent = $file->get();
unless (defined $fileContent) {
error('Unable to read /etc/apt/sources.list file');
return 1;
}
my ($foundSection, $stdout, $stderr);
for(@{$self->{'repositorySections'}}) {
my $section = $_;
my @seen = ();
while($fileContent =~ /^deb\s+(?<uri>(?:https?|ftp)[^\s]+)\s+(?<distrib>[^\s]+)\s+(?<components>.+)$/gm) {
my %repository = %+;
if("$repository{'uri'} $repository{'distrib'}" ~~ @seen) {
debug("Repository '$repository{'uri'} $repository{'distrib'}' already checked for '$section' section");
next;
}
debug("Checking repository '$repository{'uri'} $repository{'distrib'}' for '$section' section");
unless($fileContent =~ /^deb\s+$repository{'uri'}\s+\b$repository{'distrib'}\b\s+.*\b$section\b/m) {
my $uri = "$repository{'uri'}/dists/$repository{'distrib'}/$section/";
$rs = execute("wget --spider $uri", \$stdout, \$stderr);
debug($stdout) if $stdout;
debug($stderr) if $rs && $stderr;
unless ($rs) {
$foundSection = 1;
debug("Enabling section '$section' on '$repository{'uri'} $repository{'distrib'}'");
$fileContent =~ s/^($&)$/$1 $section/m;
}
} else {
debug("Section '$section' already enabled on '$repository{'uri'} $repository{'distrib'}'");
$foundSection = 1;
}
push @seen, "$repository{'uri'} $repository{'distrib'}";
}
unless($foundSection) {
error("Unable to found repository supporting '$section' section");
return 1;
}
}
$rs = $file->set($fileContent);
$rs ||= $file->save();
}
=item _processAptRepositories()
Process APT repositories
Return int 0 on success, other on failure
=cut
sub _processAptRepositories
{
my $self = $_[0];
if(@{$self->{'aptRepositoriesToRemove'}} || @{$self->{'aptRepositoriesToAdd'}}) {
my ($stdout, $stderr);
my @cmd = ();
my $file = iMSCP::File->new( filename => '/etc/apt/sources.list' );
my $rs = $file->copyFile('/etc/apt/sources.list.bkp') unless -f '/etc/apt/sources.list.bkp';
return $rs if $rs;
my $fileContent = $file->get();
unless (defined $fileContent) {
error('Unable to read /etc/apt/sources.list file');
return 1;
}
# Filter list of repositories which must not be removed
for my $repository(@{$self->{'aptRepositoriesToAdd'}}) {
@{$self->{'aptRepositoriesToRemove'}} = grep {
not exists $repository->{'repository'}->{$_}
} @{$self->{'aptRepositoriesToRemove'}};
}
for my $repository(@{$self->{'aptRepositoriesToRemove'}}) {
# Remove the repository from the sources.list file
(my $regexp = $repository) =~ s/deb/(?:deb|deb-src)/; # Ensure backward compatibility (deb-src)
$fileContent =~ s/^\n?$regexp\n$//gm;
}
# Add needed APT repositories
for my $repository(@{$self->{'aptRepositoriesToAdd'}}) {
if($fileContent !~ /^$repository->{'repository'}/m) {
$fileContent .= "\n$repository->{'repository'}\n";
@cmd = ();
if($repository->{'repository_key_srv'}) { # Add the repository key from the given server, using key id
if($repository->{'repository_key_id'}) {
@cmd = (
'apt-key adv --recv-keys --keyserver',
escapeShell($repository->{'repository_key_srv'}),
escapeShell($repository->{'repository_key_id'})
);
} else {
error("The repository_key_id entry for the '$repository->{'repository'}' repository was not found");
return 1;
}
} elsif($repository->{'repository_key_uri'}) { # Add the repository key by fetching it from the given URI
@cmd = ('wget -qO-', escapeShell($repository->{'repository_key_uri'}), '| apt-key add -');
}
if(@cmd) {
$rs = execute("@cmd", \$stdout, \$stderr);
debug($stdout) if $stdout;
error($stderr) if $stderr && $rs;
return $rs if $rs;
}
}
}
# Save new sources.list file
$rs = $file->set($fileContent);
$rs ||= $file->save();
return $rs if $rs;
}
0;
}
=item _processAptPreferences()
Process apt preferences
Return 0 on success, other on failure
=cut
sub _processAptPreferences
{
my $self = $_[0];
my $fileContent = '';
for(@{$self->{'aptPreferences'}}) {
unless(exists $_->{'pinning_pin'} || exists $_->{'pinning_pin_priority'}) {
error('One of these attributes is missing: pinning_pin or pinning_pin_priority');
return 1;
}
$fileContent .= "Package: $_->{'pinning_package'}\n";
$fileContent .= "Pin: $_->{'pinning_pin'}\n";
$fileContent .= "Pin-Priority: $_->{'pinning_pin_priority'}\n\n";
}
my $file = iMSCP::File->new( filename => '/etc/apt/preferences.d/imscp' );
if($fileContent ne '') {
my $rs = $file->set($fileContent);
$rs ||= $file->save();
$rs ||= $file->mode(0644);
return $rs if $rs;
} elsif(-f '/etc/apt/preferences.d/imscp') {
my $rs = $file->delFile();
return $rs if $rs;
}
0;
}
=item _updatePackagesIndex()
Update Debian packages index
Return int 0 on success, other on failure
=cut
sub _updatePackagesIndex
{
my $self = $_[0];
my $command = 'apt-get';
my ($stdout, $stderr);
my $preseed = iMSCP::Getopt->preseed;
unless($preseed || $main::noprompt || ! iMSCP::ProgramFinder::find('debconf-apt-progress')) {
iMSCP::Dialog->getInstance()->endGauge() if iMSCP::ProgramFinder::find('dialog');
$command = 'debconf-apt-progress --logstderr -- ' . $command;
}
my $rs = execute("$command -y update", ($preseed || $main::noprompt) ? \$stdout : undef, \$stderr);
debug($stdout) if $stdout;
error($stderr) if $stderr && $rs;
error('Unable to update package index from remote repository') if $rs && ! $stderr;
$rs
}
=item _prefillDebconfDatabase()
Pre-fill debconf database
Return int 0 on success, other on failure
=cut
sub _prefillDebconfDatabase
{
my $self = $_[0];
my $sqlServer = $main::questions{'SQL_SERVER'} || undef;
my $poServer = $main::questions{'PO_SERVER'} || undef;
my $sqlServerPackageName = undef;
if(defined $sqlServer) {
if($sqlServer ne 'remote_server') {
if($sqlServer =~ /^(mysql|mariadb|percona)_(\d+\.\d+)$/) {
$sqlServerPackageName = "$1-server" . ($1 eq 'percona' ? '-server' : '') . "-$2";
} else {
error("Unknown SQL server package name: $sqlServer");
return 1;
}
}
} else {
error('Unable to retrieve SQL server name');
return 1;
}
# Most values below are not really important because i-MSCP will override them after package installation
my $mailname = `hostname --fqdn 2>/dev/null` || 'localdomain';
chomp $mailname;
my $hostname = ($mailname ne 'localdomain') ? $mailname : 'localhost';
my $domain = `hostname --domain 2>/dev/null` || 'localdomain';
chomp $domain;
# From postfix package postfix.config script
my $destinations;
if ($mailname eq $hostname) {
$destinations = join ', ', ($mailname, 'localhost.' . $domain, ', localhost');
} else {
$destinations = join ', ', ($mailname, $hostname, 'localhost.' . $domain . ', localhost');
}
my $selectionsFileContent = <<EOF;
postfix postfix/main_mailer_type select Internet Site
postfix postfix/mailname string $mailname
postfix postfix/destinations string $destinations
proftpd-basic shared/proftpd/inetd_or_standalone select standalone
EOF
if(defined $poServer) {
if($poServer eq 'courier') {
$selectionsFileContent .= <<EOF;
courier-base courier-base/webadmin-configmode boolean false
courier-ssl courier-ssl/certnotice note
EOF
} elsif($poServer eq 'dovecot') {
$selectionsFileContent .= <<EOF;
dovecot-core dovecot-core/create-ssl-cert boolean true
dovecot-core dovecot-core/ssl-cert-name string localhost
EOF
}
} else {
error('Unable to retrieve PO server name');
return 1;
}
if(iMSCP::Getopt->preseed && $sqlServer ne 'remote_server') {
$selectionsFileContent .= <<EOF;
$sqlServerPackageName mysql-server/root_password password $main::questions{'DATABASE_PASSWORD'}
$sqlServerPackageName mysql-server/root_password_again password $main::questions{'DATABASE_PASSWORD'}
EOF
}
my $debconfSelectionsFile = File::Temp->new();
print $debconfSelectionsFile $selectionsFileContent;
my ($stdout, $stderr);
my $rs = execute("debconf-set-selections $debconfSelectionsFile", \$stdout, \$stderr);
debug($stdout) if $stdout;
error($stderr) if $rs && $stderr;
error('Unable to pre-fill debconf database') if $rs && ! $stderr;
$rs;
}
=back
=head1 AUTHORS
Laurent Declercq <l.declercq@nuxwin.com>
=cut
1;
__END__