Add property `prop_multiple_putPoolRegistration_single_readPoolRegist…

…ration`.

lib/core/test/unit/Cardano/Pool/DB/Properties.hs

@@ -159,6 +159,9 @@ properties = do
             (property . prop_poolRegistration)
         it "putPoolRetirement then readPoolRetirement yields expected result"
             (property . prop_poolRetirement)
+        it "prop_multiple_putPoolRegistration_single_readPoolRegistration"
+            (property .
+                prop_multiple_putPoolRegistration_single_readPoolRegistration)
         it "readPoolRegistrationStatus should respect registration order"
             (property . prop_readPoolRegistrationStatus)
         it "rollback of PoolRegistration"
@@ -473,6 +476,56 @@ prop_poolRetirement DBLayer {..} entries =
             ]
         assert (entriesIn == entriesOut)
 
+-- | For the same pool, write multiple pool registration certificates to the
+--   database and then read back the current registration certificate.
+--
+prop_multiple_putPoolRegistration_single_readPoolRegistration
+    :: DBLayer IO
+    -> PoolId
+    -> [PoolRegistrationCertificate]
+    -> Property
+prop_multiple_putPoolRegistration_single_readPoolRegistration
+    DBLayer {..} sharedPoolId certificatesManyPoolIds =
+        monadicIO (setup >> prop)
+  where
+    setup = run $ atomically cleanDB
+
+    prop = do
+        run $ atomically $
+            mapM_ (uncurry putPoolRegistration) certificatePublications
+        mRetrievedCertificatePublication <-
+            run $ atomically $ readPoolRegistration sharedPoolId
+        monitor $ counterexample $ unlines
+            [ "\nExpected certificate publication: "
+            , show mExpectedCertificatePublication
+            , "\nRetrieved certificate publication: "
+            , show mRetrievedCertificatePublication
+            , "\nNumber of certificate publications: "
+            , show (length certificatePublications)
+            , "\nAll certificate publications: "
+            , unlines (("\n" <>) . show <$> certificatePublications)
+            ]
+        assert $ (==)
+            mRetrievedCertificatePublication
+            mExpectedCertificatePublication
+
+    certificatePublications
+        :: [(CertificatePublicationTime, PoolRegistrationCertificate)]
+    certificatePublications = publicationTimes `zip` certificates
+
+    mExpectedCertificatePublication = certificatePublications
+        & reverse
+        & listToMaybe
+
+    publicationTimes =
+        [(SlotId en sn, SlotInternalIndex ii)
+        | en <- [0 ..]
+        , sn <- [0 .. 3]
+        , ii <- [0 .. 3]
+        ]
+
+    certificates = set #poolId sharedPoolId <$> certificatesManyPoolIds
+
 prop_readPoolRegistrationStatus
     :: DBLayer IO
     -> PoolId