-
Notifications
You must be signed in to change notification settings - Fork 3
/
DineroVault.sol
158 lines (118 loc) · 5.38 KB
/
DineroVault.sol
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
// SPDX-License-Identifier: MIT
pragma solidity 0.8.17;
import "@interest-protocol/tokens/interfaces/IDinero.sol";
import "@interest-protocol/library/MathLib.sol";
import "@interest-protocol/library/SafeTransferErrors.sol";
import "@interest-protocol/library/SafeTransferLib.sol";
import "@interest-protocol/library/SafeCastLib.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/interfaces/IERC20Metadata.sol";
contract DineroVault is Ownable, SafeTransferErrors {
/*///////////////////////////////////////////////////////////////
LIBRARIES
//////////////////////////////////////////////////////////////*/
using SafeTransferLib for address;
using MathLib for uint256;
using SafeCastLib for uint256;
/*///////////////////////////////////////////////////////////////
EVENTS
//////////////////////////////////////////////////////////////*/
event Deposit(
address indexed user,
uint256 underlyingAmount,
uint256 dineroAmount
);
event Withdraw(
address indexed user,
uint256 underlyingAmount,
uint256 dineroAmount
);
event MaxDineroAmount(uint256 oldValue, uint256 newValue);
/*///////////////////////////////////////////////////////////////
ERRORS
//////////////////////////////////////////////////////////////*/
error DineroVault__MaxDineroAmountReached();
/*///////////////////////////////////////////////////////////////
STATE
//////////////////////////////////////////////////////////////*/
IDinero private immutable DINERO;
address private immutable UNDERLYING;
uint8 private immutable DECIMALS;
/*///////////////////////////////////////////////////////////////
STATE
//////////////////////////////////////////////////////////////*/
/*//////////////////////////////////////////////////////////////
STORAGE SLOT 0 */
// USER -> Underlying Amount
mapping(address => uint256) public balanceOf;
//////////////////////////////////////////////////////////////
/*//////////////////////////////////////////////////////////////
STORAGE SLOT 1 */
// This vault has a maximum amount of Dinero it can create to limit Dinero's collateral risk.
uint128 public maxDineroAmount;
// The total amount of Dinero created by this contract.
uint128 public mintedDineroAmount;
/*///////////////////////////////////////////////////////////////
CONSTRUCTOR
//////////////////////////////////////////////////////////////*/
constructor(
IDinero dinero,
address underlying,
uint256 _maxDineroAmount
) {
DINERO = dinero;
UNDERLYING = underlying;
DECIMALS = IERC20Metadata(underlying).decimals();
maxDineroAmount = _maxDineroAmount.toUint128();
}
/**
* @notice It allows a user to deposit a stablecoin and receive the same amount in Dinero.
* @param amount The number of underlying tokens the caller wishes to deposit.
*/
function deposit(uint256 amount) external {
// Get the underlying from the caller
UNDERLYING.safeTransferFrom(msg.sender, address(this), amount);
// Adjust the amount to 18 decimals. Some ERC20 tokens do not have 18 decimals.
uint256 dnrAmount = amount.adjust(DECIMALS);
// Update the total minted amount
mintedDineroAmount += dnrAmount.toUint128();
// Make sure that we are minting less than the maximum amount allowed
if (mintedDineroAmount > maxDineroAmount)
revert DineroVault__MaxDineroAmountReached();
unchecked {
// Save how much underlying the user has deposited
balanceOf[msg.sender] += amount;
}
// Mint Dinero to the user
DINERO.mint(msg.sender, dnrAmount);
emit Deposit(msg.sender, amount, dnrAmount);
}
/**
* @notice It allows users to withdraw their deposited stablecoin.
* @param amount The number of underlying tokens the caller wishes to withdraw.
*/
function withdraw(uint256 amount) external {
// User must have enough underlying to withdraw.
balanceOf[msg.sender] -= amount;
// Adjust the amount to 18 decimals. Some ERC20 tokens do not have 18 decimals.
uint256 dnrAmount = amount.adjust(DECIMALS);
unchecked {
// Update the total minted amount
mintedDineroAmount -= dnrAmount.toUint128();
}
DINERO.burn(msg.sender, dnrAmount);
UNDERLYING.safeTransfer(msg.sender, amount);
emit Withdraw(msg.sender, amount, dnrAmount);
}
/*///////////////////////////////////////////////////////////////
OWNER ONLY
//////////////////////////////////////////////////////////////*/
/**
* @notice It updates the maximum amount of Dinero this contract can create.
* @param _maxDineroAmount The new maximum amount of Dinero this contract can create.
*/
function setMaxDineroAmount(uint256 _maxDineroAmount) external onlyOwner {
emit MaxDineroAmount(maxDineroAmount, _maxDineroAmount);
maxDineroAmount = _maxDineroAmount.toUint128();
}
}